SL/Presenter/CustomerVendor.pm

   1 package SL::Presenter::CustomerVendor;
   2
   3 use strict;
   4
   5 use SL::Presenter::EscapedText qw(escape is_escaped);
   6 use SL::Presenter::Tag qw(input_tag html_tag name_to_id select_tag);
   7
   8 use Exporter qw(import);
   9 our @EXPORT_OK = qw(customer_vendor customer vendor customer_vendor_picker customer_picker vendor_picker);
  10
  11 use Carp;
  12
  13 sub customer_vendor {
  14   my ($customer_vendor, %params) = @_;
  15   return _customer_vendor($customer_vendor, ref($customer_vendor) eq 'SL::DB::Customer' ? 'customer' : 'vendor', %params);
  16 }
  17
  18 sub customer {
  19   my ($customer, %params) = @_;
  20   return _customer_vendor($customer, 'customer', %params);
  21 }
  22
  23 sub vendor {
  24   my ($vendor, %params) = @_;
  25   return _customer_vendor($vendor, 'vendor', %params);
  26 }
  27
  28 sub _customer_vendor {
  29   my ($cv, $type, %params) = @_;
  30
  31   $params{display} ||= 'inline';
  32
  33   croak "Unknown display type '$params{display}'" unless $params{display} =~ m/^(?:inline|table-cell)$/;
  34
  35   my $callback = $params{callback} ? '&callback=' . $::form->escape($params{callback}) : '';
  36
  37   my $text = join '', (
  38     $params{no_link} ? '' : '<a href="controller.pl?action=CustomerVendor/edit&amp;db=' . $type . '&amp;id=' . escape($cv->id) . '">',
  39     escape($cv->name),
  40     $params{no_link} ? '' : '</a>',
  41   );
  42
  43   is_escaped($text);
  44 }
  45
  46 sub customer_vendor_picker {
  47   my ($name, $value, %params) = @_;
  48
  49   $params{type} //= 'customer' if 'SL::DB::Customer' eq ref $value;
  50   $params{type} //= 'vendor'   if 'SL::DB::Vendor'   eq ref $value;
  51
  52   croak 'Unknown "type" parameter' unless $params{type} =~ m{^(?:customer|vendor)$};
  53   croak 'Unknown value class'      if     $value && ref($value) && (ref($value) !~ m{^SL::DB::(?:Customer|Vendor)$});
  54
  55   if ($value && !ref $value) {
  56     my $class = $params{type} eq 'customer' ? 'SL::DB::Manager::Customer' : 'SL::DB::Manager::Vendor';
  57     $value    = $class->find_by(id => $value);
  58   }
  59
  60   my $id = delete($params{id}) || name_to_id($name);
  61
  62   my @classes = $params{class} ? ($params{class}) : ();
  63   push @classes, 'customer_vendor_autocomplete';
  64
  65   # do not use reserved html attribute 'type' for cv type
  66   $params{cv_type} = delete $params{type};
  67
  68   my $ret =
  69     input_tag($name, (ref $value && $value->can('id') ? $value->id : ''), class => "@classes", type => 'hidden', id => $id,
  70       'data-customer-vendor-picker-data' => JSON::to_json(\%params),
  71     ) .
  72     input_tag("", ref $value  ? $value->displayable_name : '', id => "${id}_name", %params);
  73
  74   $::request->layout->add_javascripts('kivi.CustomerVendor.js');
  75   $::request->presenter->need_reinit_widgets($id);
  76
  77   html_tag('span', $ret, class => 'customer_vendor_picker');
  78 }
  79
  80 sub customer_picker { my ($name, $value, @slurp) = @_; customer_vendor_picker($name, $value, @slurp, type => 'customer') }
  81 sub vendor_picker   { my ($name, $value, @slurp) = @_; customer_vendor_picker($name, $value, @slurp, type => 'vendor') }
  82 sub picker          { goto &customer_vendor_picker }
  83
  84 1;
  85
  86 __END__
  87
  88 =pod
  89
  90 =encoding utf8
  91
  92 =head1 NAME
  93
  94 SL::Presenter::CustomerVendor - Presenter module for customer and
  95 vendor Rose::DB objects
  96
  97 =head1 SYNOPSIS
  98
  99   # Customers:
 100   my $customer = SL::DB::Manager::Customer->get_first;
 101   my $html     = SL::Presenter::CustomerVendor::customer($customer, display => 'inline');
 102
 103   # Vendors:
 104   my $vendor = SL::DB::Manager::Vendor->get_first;
 105   my $html   = SL::Presenter::Customer::Vendor::vendor($customer, display => 'inline');
 106
 107 =head1 FUNCTIONS
 108
 109 =over 4
 110
 111 =item C<customer $object, %params>
 112
 113 Returns a rendered version (actually an instance of
 114 L<SL::Presenter::EscapedText>) of the customer object C<$object>.
 115
 116 C<%params> can include:
 117
 118 =over 2
 119
 120 =item * display
 121
 122 Either C<inline> (the default) or C<table-cell>. At the moment both
 123 representations are identical and produce the customer's name linked
 124 to the corresponding 'edit' action.
 125
 126 =item * no_link
 127
 128 If falsish (the default) then the customer's name will be linked to
 129 the "edit customer" dialog from the master data menu.
 130
 131 =back
 132
 133 =item C<vendor $object, %params>
 134
 135 Returns a rendered version (actually an instance of
 136 L<SL::Presenter::EscapedText>) of the vendor object C<$object>.
 137
 138 C<%params> can include:
 139
 140 =over 2
 141
 142 =item * display
 143
 144 Either C<inline> (the default) or C<table-cell>. At the moment both
 145 representations are identical and produce the vendor's name linked
 146 to the corresponding 'edit' action.
 147
 148 =item * no_link
 149
 150 If falsish (the default) then the vendor's name will be linked to
 151 the "edit vendor" dialog from the master data menu.
 152
 153 =back
 154
 155 =item C<customer_vendor $object, %params>
 156
 157 Returns a rendered version (actually an instance of
 158 L<SL::Presenter::EscapedText>) of the customer or vendor object
 159 C<$object> by calling either L</customer> or L</vendor> depending on
 160 C<$object>'s type. See the respective functions for available
 161 parameters.
 162
 163 =back
 164
 165 =head1 BUGS
 166
 167 Nothing here yet.
 168
 169 =head1 AUTHOR
 170
 171 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 172
 173 =cut