SL/Presenter/Part.pm

   1 package SL::Presenter::Part;
   2
   3 use strict;
   4
   5 use SL::DB::Part;
   6
   7 use Exporter qw(import);
   8 our @EXPORT = qw(part_picker part);
   9
  10 use Carp;
  11
  12 sub part {
  13   my ($self, $part, %params) = @_;
  14
  15   $params{display} ||= 'inline';
  16
  17   croak "Unknown display type '$params{display}'" unless $params{display} =~ m/^(?:inline|table-cell)$/;
  18
  19   my $text = join '', (
  20     $params{no_link} ? '' : '<a href="ic.pl?action=edit&id=' . $self->escape($part->id) . '">',
  21     $self->escape($part->partnumber),
  22     $params{no_link} ? '' : '</a>',
  23   );
  24   return $self->escaped_text($text);
  25 }
  26
  27 sub part_picker {
  28   my ($self, $name, $value, %params) = @_;
  29
  30   $value = SL::DB::Manager::Part->find_by(id => $value) if $value && !ref $value;
  31   my $id = delete($params{id}) || $self->name_to_id($name);
  32   my $fat_set_item = delete $params{fat_set_item};
  33
  34   my @classes = $params{class} ? ($params{class}) : ();
  35   push @classes, 'part_autocomplete';
  36   push @classes, 'partpicker_fat_set_item' if $fat_set_item;
  37
  38   my $ret =
  39     $self->input_tag($name, (ref $value && $value->can('id') ? $value->id : ''), class => "@classes", type => 'hidden', id => $id) .
  40     join('', map { $params{$_} ? $self->input_tag("", delete $params{$_}, id => "${id}_${_}", type => 'hidden') : '' } qw(column type unit convertible_unit)) .
  41     $self->input_tag("", (ref $value && $value->can('description')) ? $value->description : '', id => "${id}_name", %params);
  42
  43   $::request->layout->add_javascripts('autocomplete_part.js');
  44   $::request->presenter->need_reinit_widgets($id);
  45
  46   $self->html_tag('span', $ret, class => 'part_picker');
  47 }
  48
  49 1;
  50
  51 __END__
  52
  53 =encoding utf-8
  54
  55 =head1 NAME
  56
  57 SL::Presenter::Part - Part related presenter stuff
  58
  59 =head1 SYNOPSIS
  60
  61   # Create an html link for editing/opening a part/service/assembly
  62   my $object = my $object = SL::DB::Manager::Part->get_first;
  63   my $html   = SL::Presenter->get->part($object, display => 'inline');
  64
  65 see also L<SL::Presenter>
  66
  67 =head1 DESCRIPTION
  68
  69 see L<SL::Presenter>
  70
  71 =head1 FUNCTIONS
  72
  73 =over 2
  74
  75 =item C<part, $object, %params>
  76
  77 Returns a rendered version (actually an instance of
  78 L<SL::Presenter::EscapedText>) of the part object C<$object>
  79
  80 C<%params> can include:
  81
  82 =over 4
  83
  84 =item * display
  85
  86 Either C<inline> (the default) or C<table-cell>. At the moment both
  87 representations are identical and produce the part's name linked
  88 to the corresponding 'edit' action.
  89
  90 =back
  91
  92 =back
  93
  94 =over 2
  95
  96 =item C<part_picker $name, $value, %params>
  97
  98 All-in-one picker widget for parts. The name will be both id and name
  99 of the resulting hidden C<id> input field (but the ID can be
 100 overwritten with C<$params{id}>).
 101
 102 An additional dummy input will be generated which is used to find
 103 parts. For a detailed description of it's behaviour, see section
 104 C<PART PICKER SPECIFICATION>.
 105
 106 C<$value> can be a parts id or a C<Rose::DB:Object> instance.
 107
 108 If C<%params> contains C<type> only parts of this type will be used
 109 for autocompletion. You may comma separate multiple types as in
 110 C<part,assembly>.
 111
 112 If C<%params> contains C<unit> only parts with this unit will be used
 113 for autocompletion. You may comma separate multiple units as in
 114 C<h,min>.
 115
 116 If C<%params> contains C<convertible_unit> only parts with a unit
 117 that's convertible to unit will be used for autocompletion.
 118
 119 Obsolete parts will by default not displayed for selection. However they are
 120 accepted as default values and can persist during updates. As with other
 121 selectors though, they are not selectable once overridden.
 122
 123 Currently you must include C<js/autocomplete_part.js> in your controller, the
 124 presenter can not do this from the template.
 125
 126 =back
 127
 128 =head1 PART PICKER SPECIFICATION
 129
 130 The following list of design goals were applied:
 131
 132 =over 4
 133
 134 =item *
 135
 136 Parts should not be perceived by the user as distinct inputs of partnumber and
 137 description but as a single object
 138
 139 =item *
 140
 141 Easy to use without documentation for novice users
 142
 143 =item *
 144
 145 Fast to use with keyboard for experienced users
 146
 147 =item *
 148
 149 Possible to use without any keyboard interaction for mouse (or touchscreen)
 150 users
 151
 152 =item *
 153
 154 Must not leave the current page in event of ambiguity (cf. current select_item
 155 mechanism)
 156
 157 =item *
 158
 159 Should be useable with hand scanners or similar alternative keyboard devices
 160
 161 =item *
 162
 163 Should not require a feedback/check loop in the common case
 164
 165 =item *
 166
 167 Should not be constraint to exact matches
 168
 169 =back
 170
 171 The implementation consists of the following parts which will be referenced later:
 172
 173 =over 4
 174
 175 =item 1
 176
 177 A hidden input (id input), used to hold the id of the selected part. The only
 178 input that gets submitted
 179
 180 =item 2
 181
 182 An input (dummy input) containing a description of the currently selected part,
 183 also used by the user to search for parts
 184
 185 =item 3
 186
 187 A jquery.autocomplete mechanism attached to the dummy field
 188
 189 =item 4
 190
 191 A popup layer for both feedback and input of additional data in case of
 192 ambiguity.
 193
 194 =item 5
 195
 196 An internal status of the part picker, indicating wether id input and dummy
 197 input are consistent. After leaving the dummy input the part picker must
 198 place itself in a consistent status.
 199
 200 =item 6
 201
 202 A clickable icon (popup trigger) attached to the dummy input, which triggers the popup layer.
 203
 204 =back
 205
 206 =head1 BUGS
 207
 208 None atm :)
 209
 210 =head1 AUTHOR
 211
 212 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 213
 214 =cut