SL/Presenter/Part.pm

   1 package SL::Presenter::Part;
   2
   3 use strict;
   4
   5 use SL::DB::Part;
   6 use SL::DB::PartClassification;
   7 use SL::Locale::String qw(t8);
   8 use SL::Presenter::EscapedText qw(escape is_escaped);
   9 use SL::Presenter::Tag qw(input_tag html_tag name_to_id select_tag);
  10
  11 use Exporter qw(import);
  12 our @EXPORT_OK = qw(
  13   part_picker part select_classification classification_abbreviation
  14   type_abbreviation separate_abbreviation typeclass_abbreviation
  15 );
  16 our %EXPORT_TAGS = (ALL => \@EXPORT_OK);
  17
  18 use Carp;
  19
  20 sub part {
  21   my ($part, %params) = @_;
  22
  23   $params{display} ||= 'inline';
  24
  25   croak "Unknown display type '$params{display}'" unless $params{display} =~ m/^(?:inline|table-cell)$/;
  26
  27   my $text = join '', (
  28     $params{no_link} ? '' : '<a href="controller.pl?action=Part/edit&part.id=' . escape($part->id) . '">',
  29     escape($part->partnumber),
  30     $params{no_link} ? '' : '</a>',
  31   );
  32
  33   is_escaped($text);
  34 }
  35
  36 sub part_picker {
  37   my ($name, $value, %params) = @_;
  38
  39   $value = SL::DB::Manager::Part->find_by(id => $value) if $value && !ref $value;
  40   my $id = $params{id} || name_to_id($name);
  41
  42   my @classes = $params{class} ? ($params{class}) : ();
  43   push @classes, 'part_autocomplete';
  44
  45   my $ret =
  46     input_tag($name, (ref $value && $value->can('id') ? $value->id : ''), class => "@classes", type => 'hidden', id => $id,
  47       'data-part-picker-data' => JSON::to_json(\%params),
  48     ) .
  49     input_tag("", ref $value ? $value->displayable_name : '', id => "${id}_name", %params);
  50
  51   $::request->layout->add_javascripts('kivi.Part.js');
  52   $::request->presenter->need_reinit_widgets($id);
  53
  54   html_tag('span', $ret, class => 'part_picker');
  55 }
  56
  57 sub picker { goto &part_picker }
  58
  59 #
  60 # shortcut for article type
  61 #
  62 sub type_abbreviation {
  63   my ($part_type) = @_;
  64
  65   return ''                                               if !$part_type;
  66   return $::locale->text('Assembly (typeabbreviation)')   if $part_type eq 'assembly';
  67   return $::locale->text('Part (typeabbreviation)')       if $part_type eq 'part';
  68   return $::locale->text('Assortment (typeabbreviation)') if $part_type eq 'assortment';
  69   return $::locale->text('Service (typeabbreviation)');
  70 }
  71
  72 #
  73 # Translations for Abbreviations:
  74 #
  75 # $::locale->text('None (typeabbreviation)')
  76 # $::locale->text('Purchase (typeabbreviation)')
  77 # $::locale->text('Sales (typeabbreviation)')
  78 # $::locale->text('Merchandise (typeabbreviation)')
  79 # $::locale->text('Production (typeabbreviation)')
  80 #
  81 # and for descriptions
  82 # $::locale->text('Purchase')
  83 # $::locale->text('Sales')
  84 # $::locale->text('Merchandise')
  85 # $::locale->text('Production')
  86
  87 #
  88 # shortcut for article type
  89 #
  90 sub classification_abbreviation {
  91   my ($id) = @_;
  92
  93   return '' if !$id;
  94
  95   SL::DB::Manager::PartClassification->cache_all();
  96   my $obj = SL::DB::PartClassification->load_cached($id);
  97   $obj && $obj->abbreviation ? t8($obj->abbreviation) : '';
  98 }
  99
 100 sub typeclass_abbreviation {
 101   my ($part) = @_;
 102   return '' if !$part || !$part->isa('SL::DB::Part');
 103   return type_abbreviation($part->part_type) . classification_abbreviation($part->classification_id);
 104 }
 105
 106 #
 107 # shortcut for article type
 108 #
 109 sub separate_abbreviation {
 110   my ($id) = @_;
 111
 112   return '' if !$id;
 113
 114   SL::DB::Manager::PartClassification->cache_all();
 115   my $obj = SL::DB::PartClassification->load_cached($id);
 116   $obj && $obj->abbreviation && $obj->report_separate ? t8($obj->abbreviation) : '';
 117 }
 118
 119 #
 120 # generate selection tag
 121 #
 122 sub select_classification {
 123   my ($name, %attributes) = @_;
 124
 125   $attributes{value_key} = 'id';
 126   $attributes{title_key} = 'description';
 127
 128   my $classification_type_filter = delete $attributes{type} // [];
 129
 130   my $collection = SL::DB::Manager::PartClassification->get_all_sorted( where => $classification_type_filter );
 131   $_->description($::locale->text($_->description)) for @{ $collection };
 132   select_tag( $name, $collection, %attributes );
 133 }
 134
 135 1;
 136
 137 __END__
 138
 139 =encoding utf-8
 140
 141 =head1 NAME
 142
 143 SL::Presenter::Part - Part related presenter stuff
 144
 145 =head1 SYNOPSIS
 146
 147   # Create an html link for editing/opening a part/service/assembly
 148   my $object = SL::DB::Manager::Part->get_first;
 149   my $html   = SL::Presenter->get->part($object, display => 'inline');
 150
 151 see also L<SL::Presenter>
 152
 153 =head1 DESCRIPTION
 154
 155 see L<SL::Presenter>
 156
 157 =head1 FUNCTIONS
 158
 159 =over 2
 160
 161 =item C<part, $object, %params>
 162
 163 Returns a rendered version (actually an instance of
 164 L<SL::Presenter::EscapedText>) of the part object C<$object>
 165
 166 C<%params> can include:
 167
 168 =over 4
 169
 170 =item * display
 171
 172 Either C<inline> (the default) or C<table-cell>. At the moment both
 173 representations are identical and produce the part's name linked
 174 to the corresponding 'edit' action.
 175
 176 =back
 177
 178 =back
 179
 180 =over 2
 181
 182 =item C<classification_abbreviation $classification_id>
 183
 184 Returns the shortcut of the classification
 185
 186 =back
 187
 188 =over 2
 189
 190 =item C<separate_abbreviation $classification_id>
 191
 192 Returns the shortcut of the classification if the classification has the separate flag set.
 193
 194 =back
 195
 196 =over 2
 197
 198 =item C<select_classification $name,%params>
 199
 200 Returns an HTML select tag with all available classifications.
 201
 202 C<%params> can include:
 203
 204 =over 4
 205
 206 =item * default
 207
 208 The id of the selected item.
 209
 210 =back
 211
 212 =back
 213
 214 =over 2
 215
 216 =item C<part_picker $name, $value, %params>
 217
 218 All-in-one picker widget for parts. The name will be both id and name
 219 of the resulting hidden C<id> input field (but the ID can be
 220 overwritten with C<$params{id}>).
 221
 222 An additional dummy input will be generated which is used to find
 223 parts. For a detailed description of its behaviour, see section
 224 C<PART PICKER SPECIFICATION>.
 225
 226 C<$value> can be a parts id or a C<Rose::DB:Object> instance.
 227
 228 If C<%params> contains C<part_type> only parts of this type will be used
 229 for autocompletion. You may comma separate multiple types as in
 230 C<part,assembly>.
 231
 232 If C<%params> contains C<status> only parts of this status will be used
 233 for autocompletion. C<status> can be one of the following strings:
 234 C<active>, C<obsolete> or C<all>. C<active> is the default if C<status> is
 235 not given.
 236
 237 If C<%params> contains C<unit> only parts with this unit will be used
 238 for autocompletion. You may comma separate multiple units as in
 239 C<h,min>.
 240
 241 If C<%params> contains C<convertible_unit> only parts with a unit
 242 that's convertible to unit will be used for autocompletion.
 243
 244 If C<%params> contains C<with_makemodel> or C<with_customer_partnumber> even
 245 parts will be used for autocompletion which partnumber is a vendor partnumber
 246 (makemodel) or a customer partnumber.
 247
 248 Obsolete parts will by default not be displayed for selection. However they are
 249 accepted as default values and can persist during updates. As with other
 250 selectors though, they are not selectable once overridden.
 251
 252 C<part_picker> will register it's javascript for inclusion in the next header
 253 rendering. If you write a standard controller that only calls C<render> once, it
 254 will just work. In case the header is generated in a different render call
 255 (multiple blocks, ajax, old C<bin/mozilla> style controllers) you need to
 256 include C<kivi.Part.js> yourself.
 257
 258 On pressing <enter> the picker will try to commit the current selection,
 259 resulting in one of the following events, whose corresponding callbacks can be
 260 set in C<params.actions>:
 261
 262 =over 4
 263
 264 =item * C<commit_one>
 265
 266 If exactly one element matches the input, the internal id will be set to this
 267 id, the internal state will be set to C<PICKED> and the C<change> event on the
 268 picker will be fired. Additionally, if C<params> contains C<fat_set_item> a
 269 special event C<set_item:PartPicker> will be fired which is guaranteed to
 270 contain a complete JSON representation of the part.
 271
 272 After that the action C<commit_one> will be executed, which defaults to
 273 clicking a button with id C<update_button> for backward compatibility reasons.
 274
 275 =item * C<commit_many>
 276
 277 If more than one element matches the input, the internal state will be set to
 278 undefined.
 279
 280 After that the action C<commit_one> will be executed, which defaults to
 281 opening a popup dialog for graphical interaction. If C<params> contains
 282 C<multiple> an alternative popup will be opened, allowing multiple items to be
 283 selected. Note however that this requires an additional callback
 284 C<set_multi_items> to work.
 285
 286 =item * C<commit_none>
 287
 288 If no element matches the input, the internal state will be set to undefined.
 289
 290 If an action for C<commit_none> exists, it will be called with the picker
 291 object and current term. The caller can then implement creation of new parts.
 292
 293 =back
 294
 295 =back
 296
 297 =head1 PART PICKER SPECIFICATION
 298
 299 The following list of design goals were applied:
 300
 301 =over 4
 302
 303 =item *
 304
 305 Parts should not be perceived by the user as distinct inputs of partnumber and
 306 description but as a single object
 307
 308 =item *
 309
 310 Easy to use without documentation for novice users
 311
 312 =item *
 313
 314 Fast to use with keyboard for experienced users
 315
 316 =item *
 317
 318 Possible to use without any keyboard interaction for mouse (or touchscreen)
 319 users
 320
 321 =item *
 322
 323 Must not leave the current page in event of ambiguity (cf. current select_item
 324 mechanism)
 325
 326 =item *
 327
 328 Should be useable with hand scanners or similar alternative keyboard devices
 329
 330 =item *
 331
 332 Should not require a feedback/check loop in the common case
 333
 334 =item *
 335
 336 Should not be constrained to exact matches
 337
 338 =item *
 339
 340 Must be atomic
 341
 342 =item *
 343
 344 Action should be overridable
 345
 346 =back
 347
 348 The implementation consists of the following parts which will be referenced later:
 349
 350 =over 4
 351
 352 =item 1
 353
 354 A hidden input (id input), used to hold the id of the selected part. The only
 355 input that gets submitted
 356
 357 =item 2
 358
 359 An input (dummy input) containing a description of the currently selected part,
 360 also used by the user to search for parts
 361
 362 =item 3
 363
 364 A jquery.autocomplete mechanism attached to the dummy field
 365
 366 =item 4
 367
 368 A popup layer for both feedback and input of additional data in case of
 369 ambiguity.
 370
 371 =item 5
 372
 373 An internal status of the part picker, indicating whether id input and dummy
 374 input are consistent. After leaving the dummy input the part picker must
 375 place itself in a consistent status.
 376
 377 =item 6
 378
 379 A clickable icon (popup trigger) attached to the dummy input, which triggers the popup layer.
 380
 381 =back
 382
 383 =head1 BUGS
 384
 385 None atm :)
 386
 387 =head1 AUTHOR
 388
 389 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 390
 391 Martin Helmling E<lt>martin.helmling@opendynamic.deE<gt>
 392
 393 =cut