SL/Presenter.pm

   1 package SL::Presenter;
   2
   3 use strict;
   4
   5 use parent qw(Rose::Object);
   6
   7 use Carp;
   8 use Template;
   9
  10 use SL::Presenter::Chart;
  11 use SL::Presenter::CustomerVendor;
  12 use SL::Presenter::DeliveryOrder;
  13 use SL::Presenter::EscapedText;
  14 use SL::Presenter::Invoice;
  15 use SL::Presenter::GL;
  16 use SL::Presenter::Letter;
  17 use SL::Presenter::Order;
  18 use SL::Presenter::Part;
  19 use SL::Presenter::Project;
  20 use SL::Presenter::Record;
  21 use SL::Presenter::RequirementSpec;
  22 use SL::Presenter::RequirementSpecItem;
  23 use SL::Presenter::RequirementSpecTextBlock;
  24 use SL::Presenter::SepaExport;
  25 use SL::Presenter::Text;
  26 use SL::Presenter::Tag;
  27 use SL::Presenter::BankAccount;
  28
  29 use Rose::Object::MakeMethods::Generic (
  30   scalar => [ qw(need_reinit_widgets) ],
  31 );
  32
  33 sub get {
  34   return $::request->presenter;
  35 }
  36
  37 sub render {
  38   my $self               = shift;
  39   my $template           = shift;
  40   my ($options, %locals) = (@_ && ref($_[0])) ? @_ : ({ }, @_);
  41
  42   # Set defaults for all available options.
  43   my %defaults = (
  44     type       => 'html',
  45     process    => 1,
  46   );
  47   $options->{$_} //= $defaults{$_} for keys %defaults;
  48   $options->{type} = lc $options->{type};
  49
  50   # Check supplied options for validity.
  51   foreach (keys %{ $options }) {
  52     croak "Unsupported option: $_" unless $defaults{$_};
  53   }
  54
  55   # Only certain types are supported.
  56   croak "Unsupported type: " . $options->{type} unless $options->{type} =~ m/^(?:html|js|json|text)$/;
  57
  58   # The "template" argument must be a string or a reference to one.
  59   $template = ${ $template }                                       if ((ref($template) || '') eq 'REF') && (ref(${ $template }) eq 'SL::Presenter::EscapedText');
  60   croak "Unsupported 'template' reference type: " . ref($template) if ref($template) && (ref($template) !~ m/^(?:SCALAR|SL::Presenter::EscapedText)$/);
  61
  62   # Look for the file given by $template if $template is not a reference.
  63   my $source;
  64   if (!ref $template) {
  65     my $ext = $options->{type} eq 'text' ? 'txt' : $options->{type};
  66     $source = "templates/webpages/${template}.${ext}";
  67     croak "Template file ${source} not found" unless -f $source;
  68
  69   } elsif (ref($template) eq 'SCALAR') {
  70     # Normal scalar reference: hand over to Template
  71     $source = $template;
  72
  73   } else {
  74     # Instance of SL::Presenter::EscapedText. Get reference to its content.
  75     $source = \$template->{text};
  76   }
  77
  78   # If no processing is requested then return the content.
  79   if (!$options->{process}) {
  80     # If $template is a reference then don't try to read a file.
  81     my $ref = ref $template;
  82     return $template                                                                if $ref eq 'SL::Presenter::EscapedText';
  83     return SL::Presenter::EscapedText->new(text => ${ $template }, is_escaped => 1) if $ref eq 'SCALAR';
  84
  85     # Otherwise return the file's content.
  86     my $file    = IO::File->new($source, "r") || croak("Template file ${source} could not be read");
  87     my $content = do { local $/ = ''; <$file> };
  88     $file->close;
  89
  90     return SL::Presenter::EscapedText->new(text => $content, is_escaped => 1);
  91   }
  92
  93   # Processing was requested. Set up all variables.
  94   my %params = ( %locals,
  95                  AUTH          => $::auth,
  96                  FLASH         => $::form->{FLASH},
  97                  FORM          => $::form,
  98                  INSTANCE_CONF => $::instance_conf,
  99                  LOCALE        => $::locale,
 100                  LXCONFIG      => \%::lx_office_conf,
 101                  LXDEBUG       => $::lxdebug,
 102                  MYCONFIG      => \%::myconfig,
 103                  PRESENTER     => $self,
 104                );
 105
 106   my $output;
 107   my $parser = $self->get_template;
 108   $parser->process($source, \%params, \$output) || croak $parser->error;
 109
 110   return SL::Presenter::EscapedText->new(text => $output, is_escaped => 1);
 111 }
 112
 113 sub get_template {
 114   my ($self) = @_;
 115
 116   $self->{template} ||=
 117     Template->new({ INTERPOLATE  => 0,
 118                     EVAL_PERL    => 0,
 119                     ABSOLUTE     => 1,
 120                     CACHE_SIZE   => 0,
 121                     PLUGIN_BASE  => 'SL::Template::Plugin',
 122                     INCLUDE_PATH => '.:templates/webpages',
 123                     COMPILE_EXT  => '.tcc',
 124                     COMPILE_DIR  => $::lx_office_conf{paths}->{userspath} . '/templates-cache',
 125                     ERROR        => 'templates/webpages/generic/exception.html',
 126                     ENCODING     => 'utf8',
 127                   }) || croak;
 128
 129   return $self->{template};
 130 }
 131
 132 sub escape {
 133   my ($self, $text) = @_;
 134
 135   return SL::Presenter::EscapedText->new(text => $text);
 136 }
 137
 138 sub escaped_text {
 139   my ($self, $text) = @_;
 140
 141   return SL::Presenter::EscapedText->new(text => $text, is_escaped => 1);
 142 }
 143
 144 sub escape_js {
 145   my ($self, $text) = @_;
 146
 147   $text =~ s|\\|\\\\|g;
 148   $text =~ s|\"|\\\"|g;
 149   $text =~ s|\n|\\n|g;
 150
 151   return SL::Presenter::EscapedText->new(text => $text, is_escaped => 1);
 152 }
 153
 154 1;
 155
 156 __END__
 157
 158 =head1 NAME
 159
 160 SL::Presenter - presentation layer class
 161
 162 =head1 SYNOPSIS
 163
 164   use SL::Presenter;
 165   my $presenter = SL::Presenter->get;
 166
 167   # Lower-level template parsing:
 168   my $html = $presenter->render(
 169     'presenter/dir/template.html',
 170     var1 => 'value',
 171   );
 172
 173   # Higher-level rendering of certain objects:
 174   use SL::DB::Customer;
 175
 176   my $linked_customer_name = $presenter->customer($customer, display => 'table-cell');
 177
 178   # Render a list of links to sales/purchase records:
 179   use SL::DB::Order;
 180
 181   my $quotation = SL::DB::Manager::Order->get_first(where => { quotation => 1 });
 182   my $records   = $quotation->linked_records(direction => 'to');
 183   my $html      = $presenter->grouped_record_list($records);
 184
 185 =head1 CLASS FUNCTIONS
 186
 187 =over 4
 188
 189 =item C<get>
 190
 191 Returns the global presenter object and creates it if it doesn't exist
 192 already.
 193
 194 =back
 195
 196 =head1 INSTANCE FUNCTIONS
 197
 198 =over 4
 199
 200 =item C<render $template, [ $options, ] %locals>
 201
 202 Renders the template C<$template>. Provides other variables than
 203 C<Form::parse_html_template> does.
 204
 205 C<$options>, if present, must be a hash reference. All remaining
 206 parameters are slurped into C<%locals>.
 207
 208 This is the backend function that L<SL::Controller::Base/render>
 209 calls. The big difference is that the presenter's L<render> function
 210 always returns the input and never sends anything to the browser while
 211 the controller's function usually sends the result to the
 212 controller. Therefore the presenter's L<render> function does not use
 213 all of the parameters for controlling the output that the controller's
 214 function does.
 215
 216 What is rendered and how C<$template> is interpreted is determined
 217 both by C<$template>'s reference type and by the supplied options.
 218
 219 If C<$template> is a normal scalar (not a reference) then it is meant
 220 to be a template file name relative to the C<templates/webpages>
 221 directory. The file name to use is determined by the C<type> option.
 222
 223 If C<$template> is a reference to a scalar then the referenced
 224 scalar's content is used as the content to process. The C<type> option
 225 is not considered in this case.
 226
 227 C<$template> can also be an instance of L<SL::Presenter::EscapedText>
 228 or a reference to such an instance. Both of these cases are handled
 229 the same way as if C<$template> were a reference to a scalar: its
 230 content is processed, and C<type> is not considered.
 231
 232 Other reference types, unknown options and unknown arguments to the
 233 C<type> option cause the function to L<croak>.
 234
 235 The following options are available:
 236
 237 =over 2
 238
 239 =item C<type>
 240
 241 The template type. Can be C<html> (the default), C<js> for JavaScript,
 242 C<json> for JSON and C<text> for plain text content. Affects only the
 243 extension that's added to the file name given with a non-reference
 244 C<$template> argument.
 245
 246 =item C<process>
 247
 248 If trueish (which is also the default) it causes the template/content
 249 to be processed by the Template toolkit. Otherwise the
 250 template/content is returned as-is.
 251
 252 =back
 253
 254 If template processing is requested then the template has access to
 255 the following variables:
 256
 257 =over 2
 258
 259 =item * C<AUTH> -- C<$::auth>
 260
 261 =item * C<FLASH> -- the flash instance (C<$::form-E<gt>{FLASH}>)
 262
 263 =item * C<FORM> -- C<$::form>
 264
 265 =item * C<INSTANCE_CONF> -- C<$::instance_conf>
 266
 267 =item * C<LOCALE> -- C<$::locale>
 268
 269 =item * C<LXCONFIG> -- all parameters from C<config/kivitendo.conf>
 270 with the same name they appear in the file (first level is the
 271 section, second the actual variable, e.g. C<system.language>,
 272 C<features.webdav> etc)
 273
 274 =item * C<LXDEBUG> -- C<$::lxdebug>
 275
 276 =item * C<MYCONFIG> -- C<%::myconfig>
 277
 278 =item * C<SELF> -- the controller instance
 279
 280 =item * C<PRESENTER> -- the presenter instance the template is
 281 rendered with
 282
 283 =item * All items from C<%locals>
 284
 285 =back
 286
 287 The function will always return the output and never send anything to
 288 the browser.
 289
 290 Example: Render a HTML template with a certain title and a few locals
 291
 292   $presenter->render('todo/list',
 293                      title      => 'List TODO items',
 294                      TODO_ITEMS => SL::DB::Manager::Todo->get_all_sorted);
 295
 296 Example: Render a string and return its content for further processing
 297 by the calling function.
 298
 299   my $content = $presenter->render(\'[% USE JavaScript %][% JavaScript.replace_with("#someid", "js/something") %]');
 300
 301 Example: Return the content of a JSON template file without processing
 302 it at all:
 303
 304   my $template_content = $presenter->render(
 305     'customer/contact',
 306     { type => 'json', process => 0 }
 307   );
 308
 309 =item C<escape $text>
 310
 311 Returns an HTML-escaped version of C<$text>. Instead of a string an
 312 instance of the thin proxy-object L<SL::Presenter::EscapedText> is
 313 returned.
 314
 315 It is safe to call C<escape> on an instance of
 316 L<SL::Presenter::EscapedText>. This is a no-op (the same instance will
 317 be returned).
 318
 319 =item C<escaped_text $text>
 320
 321 Returns an instance of L<SL::Presenter::EscapedText>. C<$text> is
 322 assumed to be a string that has already been HTML-escaped.
 323
 324 It is safe to call C<escaped_text> on an instance of
 325 L<SL::Presenter::EscapedText>. This is a no-op (the same instance will
 326 be returned).
 327
 328 =item C<escape_js $text>
 329
 330 Returns a JavaScript-escaped version of C<$text>. Instead of a string
 331 an instance of the thin proxy-object L<SL::Presenter::EscapedText> is
 332 returned.
 333
 334 It is safe to call C<escape> on an instance of
 335 L<SL::Presenter::EscapedText>. This is a no-op (the same instance will
 336 be returned).
 337
 338 =item C<get_template>
 339
 340 Returns the global instance of L<Template> and creates it if it
 341 doesn't exist already.
 342
 343 =back
 344
 345 =head1 AUTHOR
 346
 347 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 348
 349 =cut