SL/PriceSource/PriceRules.pm

   1 package SL::PriceSource::PriceRules;
   2
   3 use strict;
   4 use parent qw(SL::PriceSource::Base);
   5
   6 use SL::PriceSource::Price;
   7 use SL::Locale::String;
   8 use SL::DB::PriceRule;
   9 use List::UtilsBy qw(min_by max_by);
  10
  11 sub name { 'price_rules' }
  12
  13 sub description { t8('Price Rules') }
  14
  15 sub available_rules {
  16   my ($self, %params) = @_;
  17
  18   SL::DB::Manager::PriceRule->get_all_matching(record => $self->record, record_item => $self->record_item);
  19 }
  20
  21 sub available_prices {
  22   my ($self, %params) = @_;
  23
  24   my $rules = $self->available_rules;
  25
  26   map { $self->make_price_from_rule($_) } @$rules;
  27 }
  28
  29 sub price_from_source {
  30   my ($self, $source, $spec) = @_;
  31
  32   my $rule = SL::DB::Manager::PriceRule->find_by(id => $spec);
  33   $self->make_price_from_rule($rule);
  34 }
  35
  36 sub best_price {
  37   my ($self) = @_;
  38
  39   my $rules     = $self->available_rules;
  40
  41   return unless @$rules;
  42
  43   my @max_prio  = max_by { $_->priority } @$rules;
  44   my $min_price = min_by { $self->price_for_rule($_) } @max_prio;
  45
  46   $self->make_price_from_rule($min_price);
  47 }
  48
  49 sub price_for_rule {
  50   my ($self, $rule) = @_;
  51   $rule->price_or_discount
  52     ? (1 - $rule->discount / 100) * ($rule->is_sales ? $self->part->sellprice : $self->part->lastcost)
  53     : $rule->price;
  54 }
  55
  56 sub make_price_from_rule {
  57   my ($self, $rule) = @_;
  58
  59   SL::PriceSource::Price->new(
  60     price        => $self->price_for_rule($rule),
  61     spec         => $rule->id,
  62     description  => $rule->name,
  63     price_source => $self,
  64   )
  65 }
  66
  67 1;