SL/PriceSource/Pricegroup.pm

   1 package SL::PriceSource::Pricegroup;
   2
   3 use strict;
   4 use parent qw(SL::PriceSource::Base);
   5
   6 use SL::PriceSource::Price;
   7 use SL::DB::Price;
   8 use SL::Locale::String;
   9 use List::UtilsBy qw(min_by);
  10 use List::Util qw(first);
  11
  12 sub name { 'pricegroup' }
  13
  14 sub description { t8('Pricegroup') }
  15
  16 sub available_prices {
  17   my ($self, %params) = @_;
  18
  19   return () unless $self->record->is_sales;
  20
  21   my $item = $self->record_item;
  22
  23   my $query = [ parts_id => $item->parts_id, price => { gt => 0 } ];
  24
  25   # add a pricegroup_filter for obsolete pricegroups, unless part of an
  26   # existing pricegroup where that pricegroup was actually used.
  27   if ( $self->record->id and $item->active_price_source =~ m/^pricegroup/ ) {
  28     my ($pricegroup_id) = $item->active_price_source =~ m/^pricegroup\/(\d+)$/;
  29     push(@{$query}, or => [ 'pricegroup.obsolete' => 0, 'pricegroup_id' => $pricegroup_id ]);
  30   } else {
  31     push(@{$query}, 'pricegroup.obsolete' => 0);
  32   }
  33
  34   my $prices = SL::DB::Manager::Price->get_all(
  35     query        => $query,
  36     with_objects => 'pricegroup',
  37     sort_by      => 'pricegroup.sortkey',
  38   );
  39
  40   return () unless @$prices;
  41
  42   return map {
  43     $self->make_price($_);
  44   } @$prices;
  45 }
  46
  47 sub available_discounts { }
  48
  49 sub price_from_source {
  50   my ($self, $source, $spec) = @_;
  51
  52   my $price = SL::DB::Manager::Price->find_by(pricegroup_id => $spec, parts_id => $self->part->id);
  53
  54   # TODO: if someone deletes the prices entry, this fails. add a fallback
  55   return $self->make_price($price);
  56 }
  57
  58 sub discount_from_source { }
  59
  60 sub best_price {
  61   my ($self, %params) = @_;
  62
  63   return () unless $self->record->is_sales;
  64
  65   my @prices    = $self->available_prices;
  66   my $customer  = $self->record->customer;
  67
  68   return () if !$customer || !$customer->pricegroup_id;
  69
  70   my $best_price = first { $_->spec == $customer->pricegroup_id } @prices;
  71
  72   return $best_price || ();
  73 }
  74
  75 sub best_discount { }
  76
  77 sub make_price {
  78   my ($self, $price_obj) = @_;
  79
  80   SL::PriceSource::Price->new(
  81     price        => $price_obj->price,
  82     spec         => $price_obj->pricegroup->id,
  83     description  => $price_obj->pricegroup->pricegroup,
  84     price_source => $self,
  85   )
  86 }
  87
  88 1;