SL/SEPA.pm

   1 package SL::SEPA;
   2
   3 use strict;
   4
   5 use POSIX qw(strftime);
   6
   7 use SL::DBUtils;
   8
   9 sub retrieve_open_invoices {
  10   $main::lxdebug->enter_sub();
  11
  12   my $self     = shift;
  13   my %params   = @_;
  14
  15   my $myconfig = \%main::myconfig;
  16   my $form     = $main::form;
  17
  18   my $dbh      = $params{dbh} || $form->get_standard_dbh($myconfig);
  19   my $arap     = $params{vc} eq 'customer' ? 'ar'       : 'ap';
  20   my $vc       = $params{vc} eq 'customer' ? 'customer' : 'vendor';
  21
  22   my $query =
  23     qq|
  24        SELECT ${arap}.id, ${arap}.invnumber, ${arap}.${vc}_id, ${arap}.amount AS invoice_amount, ${arap}.invoice,
  25          vc.name AS vcname, ${arap}.duedate as duedate,
  26
  27          COALESCE(vc.iban, '') <> '' AND COALESCE(vc.bic, '') <> '' AS vc_bank_info_ok,
  28
  29          ${arap}.amount - ${arap}.paid - COALESCE(open_transfers.amount, 0) AS open_amount
  30
  31        FROM ${arap}
  32        LEFT JOIN ${vc} vc ON (${arap}.${vc}_id = vc.id)
  33        LEFT JOIN (SELECT sei.ap_id, SUM(sei.amount) AS amount
  34                   FROM sepa_export_items sei
  35                   LEFT JOIN sepa_export se ON (sei.sepa_export_id = se.id)
  36                   WHERE NOT se.closed
  37                     AND (se.vc = '${vc}')
  38                   GROUP BY sei.ap_id)
  39          AS open_transfers ON (${arap}.id = open_transfers.ap_id)
  40
  41        WHERE ${arap}.amount > (COALESCE(open_transfers.amount, 0) + ${arap}.paid)
  42
  43        ORDER BY lower(vc.name) ASC, lower(${arap}.invnumber) ASC
  44 |;
  45
  46   my $results = selectall_hashref_query($form, $dbh, $query);
  47
  48   $main::lxdebug->leave_sub();
  49
  50   return $results;
  51 }
  52
  53 sub create_export {
  54   $main::lxdebug->enter_sub();
  55
  56   my $self     = shift;
  57   my %params   = @_;
  58
  59   Common::check_params(\%params, qw(employee bank_transfers));
  60
  61   my $myconfig = \%main::myconfig;
  62   my $form     = $main::form;
  63
  64   my $dbh      = $params{dbh} || $form->get_standard_dbh($myconfig);
  65
  66   my ($export_id) = selectfirst_array_query($form, $dbh, qq|SELECT nextval('sepa_export_id_seq')|);
  67   my $query       =
  68     qq|INSERT INTO sepa_export (id, employee_id)
  69        VALUES (?, (SELECT id
  70                    FROM employee
  71                    WHERE login = ?))|;
  72   do_query($form, $dbh, $query, $export_id, $params{employee});
  73
  74   my $q_item_id = qq|SELECT nextval('id')|;
  75   my $h_item_id = prepare_query($form, $dbh, $q_item_id);
  76
  77   my $q_insert =
  78     qq|INSERT INTO sepa_export_items (id,          sepa_export_id,           ap_id,       chart_id,
  79                                       amount,      requested_execution_date, reference,   end_to_end_id,
  80                                       our_iban,    our_bic,                  vendor_iban, vendor_bic)
  81        VALUES                        (?,           ?,                        ?,           ?,
  82                                       ?,           ?,                        ?,           ?,
  83                                       ?,           ?,                        ?,           ?)|;
  84   my $h_insert = prepare_query($form, $dbh, $q_insert);
  85
  86   my $q_reference =
  87     qq|SELECT ap.invnumber,
  88          (SELECT COUNT(at.*)
  89           FROM acc_trans at
  90           LEFT JOIN chart c ON (at.chart_id = c.id)
  91           WHERE (at.trans_id = ?)
  92             AND (c.link LIKE '%AP_paid%'))
  93          +
  94          (SELECT COUNT(sei.*)
  95           FROM sepa_export_items sei
  96           WHERE (sei.ap_id = ?))
  97          AS num_payments
  98        FROM ap
  99        WHERE id = ?|;
 100   my $h_reference = prepare_query($form, $dbh, $q_reference);
 101
 102   my @now         = localtime;
 103
 104   foreach my $transfer (@{ $params{bank_transfers} }) {
 105     if (!$transfer->{reference}) {
 106       do_statement($form, $h_reference, $q_reference, (conv_i($transfer->{ap_id})) x 3);
 107
 108       my ($invnumber, $num_payments) = $h_reference->fetchrow_array();
 109       $num_payments++;
 110
 111       $transfer->{reference} = "${invnumber}-${num_payments}";
 112     }
 113
 114     $h_item_id->execute();
 115     my ($item_id)      = $h_item_id->fetchrow_array();
 116
 117     my $end_to_end_id  = strftime "LXO%Y%m%d%H%M%S", localtime;
 118     my $item_id_len    = length "$item_id";
 119     my $num_zeroes     = 35 - $item_id_len - length $end_to_end_id;
 120     $end_to_end_id    .= '0' x $num_zeroes if (0 < $num_zeroes);
 121     $end_to_end_id    .= $item_id;
 122     $end_to_end_id     = substr $end_to_end_id, 0, 35;
 123
 124     my @values = ($item_id,                   $export_id,
 125                   conv_i($transfer->{ap_id}), conv_i($transfer->{chart_id}),
 126                   $transfer->{amount},        conv_date($transfer->{requested_execution_date}),
 127                   $transfer->{reference},     $end_to_end_id,
 128                   map { my $pfx = $_; map { $transfer->{"${pfx}_${_}"} } qw(iban bic) } qw(our vendor));
 129
 130     do_statement($form, $h_insert, $q_insert, @values);
 131   }
 132
 133   $h_insert->finish();
 134   $h_item_id->finish();
 135
 136   $dbh->commit() unless ($params{dbh});
 137
 138   $main::lxdebug->leave_sub();
 139
 140   return $export_id;
 141 }
 142
 143 sub retrieve_export {
 144   $main::lxdebug->enter_sub();
 145
 146   my $self     = shift;
 147   my %params   = @_;
 148
 149   Common::check_params(\%params, qw(id));
 150
 151   my $myconfig = \%main::myconfig;
 152   my $form     = $main::form;
 153
 154   my $dbh      = $params{dbh} || $form->get_standard_dbh($myconfig);
 155
 156   my ($joins, $columns);
 157
 158   if ($params{details}) {
 159     $columns = ', ap.invoice';
 160     $joins   = 'LEFT JOIN ap ON (se.ap_id = ap.id)';
 161   }
 162
 163   my $query =
 164     qq|SELECT se.*,
 165          CASE WHEN COALESCE(e.name, '') <> '' THEN e.name ELSE e.login END AS employee
 166        FROM sepa_export se
 167        LEFT JOIN employee e ON (se.employee_id = e.id)
 168        WHERE se.id = ?|;
 169
 170   my $export = selectfirst_hashref_query($form, $dbh, $query, conv_i($params{id}));
 171
 172   if ($export->{id}) {
 173     my ($columns, $joins);
 174
 175     if ($params{details}) {
 176       $columns = qq|, ap.invnumber, ap.invoice, v.name AS vendor_name, c.accno AS chart_accno, c.description AS chart_description|;
 177       $joins   = qq|LEFT JOIN ap       ON (sei.ap_id    = ap.id)
 178                     LEFT JOIN vendor v ON (ap.vendor_id = v.id)
 179                     LEFT JOIN chart c  ON (sei.chart_id = c.id)|;
 180     }
 181
 182     $query = qq|SELECT sei.*
 183                   $columns
 184                 FROM sepa_export_items sei
 185                 $joins
 186                 WHERE sei.sepa_export_id = ?|;
 187     $export->{items} = selectall_hashref_query($form, $dbh, $query, conv_i($params{id}));
 188
 189   } else {
 190     $export->{items} = [];
 191   }
 192
 193   $main::lxdebug->leave_sub();
 194
 195   return $export;
 196 }
 197
 198 sub close_export {
 199   $main::lxdebug->enter_sub();
 200
 201   my $self     = shift;
 202   my %params   = @_;
 203
 204   Common::check_params(\%params, qw(id));
 205
 206   my $myconfig = \%main::myconfig;
 207   my $form     = $main::form;
 208
 209   my $dbh      = $params{dbh} || $form->get_standard_dbh($myconfig);
 210
 211   my @ids          = ref $params{id} eq 'ARRAY' ? @{ $params{id} } : ($params{id});
 212   my $placeholders = join ', ', ('?') x scalar @ids;
 213   my $query        = qq|UPDATE sepa_export SET closed = TRUE WHERE id IN ($placeholders)|;
 214
 215   do_query($form, $dbh, $query, map { conv_i($_) } @ids);
 216
 217   $dbh->commit() unless ($params{dbh});
 218
 219   $main::lxdebug->leave_sub();
 220 }
 221
 222 sub list_exports {
 223   $main::lxdebug->enter_sub();
 224
 225   my $self     = shift;
 226   my %params   = @_;
 227
 228   my $myconfig = \%main::myconfig;
 229   my $form     = $main::form;
 230
 231   my $dbh      = $params{dbh} || $form->get_standard_dbh($myconfig);
 232
 233   my %sort_columns = (
 234     'id'          => [ 'se.id',                ],
 235     'export_date' => [ 'se.itime',             ],
 236     'employee'    => [ 'e.name',      'se.id', ],
 237     'executed'    => [ 'se.executed', 'se.id', ],
 238     'closed'      => [ 'se.closed',   'se.id', ],
 239     );
 240
 241   my %sort_spec = create_sort_spec('defs' => \%sort_columns, 'default' => 'id', 'column' => $params{sortorder}, 'dir' => $params{sortdir});
 242
 243   my (@where, @values, @where_sub, @values_sub, %joins_sub);
 244
 245   my $filter = $params{filter} || { };
 246
 247   foreach (qw(executed closed)) {
 248     push @where, $filter->{$_} ? "se.$_" : "NOT se.$_" if (exists $filter->{$_});
 249   }
 250
 251   my %operators = ('from' => '>=',
 252                    'to'   => '<=');
 253
 254   foreach my $dir (qw(from to)) {
 255     next unless ($filter->{"export_date_${dir}"});
 256     push @where,  "se.itime $operators{$dir} ?::date";
 257     push @values, $filter->{"export_date_${dir}"};
 258   }
 259
 260   if ($filter->{invnumber}) {
 261     push @where_sub,  "ap.invnumber ILIKE ?";
 262     push @values_sub, '%' . $filter->{invnumber} . '%';
 263     $joins_sub{ap} = 1;
 264   }
 265
 266   if ($filter->{vendor}) {
 267     push @where_sub,  "v.name ILIKE ?";
 268     push @values_sub, '%' . $filter->{vendor} . '%';
 269     $joins_sub{ap}     = 1;
 270     $joins_sub{vendor} = 1;
 271   }
 272
 273   foreach my $type (qw(requested_execution execution)) {
 274     foreach my $dir (qw(from to)) {
 275       next unless ($filter->{"${type}_date_${dir}"});
 276       push @where_sub,  "(items.${type}_date IS NOT NULL) AND (items.${type}_date $operators{$dir} ?)";
 277       push @values_sub, $filter->{"${type}_date_${_}"};
 278     }
 279   }
 280
 281   if (@where_sub) {
 282     my $joins_sub  = '';
 283     $joins_sub    .= ' LEFT JOIN ap       ON (items.ap_id  = ap.id)' if ($joins_sub{ap});
 284     $joins_sub    .= ' LEFT JOIN vendor v ON (ap.vendor_id = v.id)'  if ($joins_sub{vendor});
 285
 286     my $where_sub  = join(' AND ', map { "(${_})" } @where_sub);
 287
 288     my $query_sub  = qq|se.id IN (SELECT items.sepa_export_id
 289                                   FROM sepa_export_items items
 290                                   $joins_sub
 291                                   WHERE $where_sub)|;
 292
 293     push @where,  $query_sub;
 294     push @values, @values_sub;
 295   }
 296
 297   my $where = ' WHERE ' . join(' AND ', map { "(${_})" } @where) if (@where);
 298
 299   my $query =
 300     qq|SELECT se.id, se.employee_id, se.executed, se.closed, itime::date AS export_date,
 301          e.name AS employee
 302        FROM sepa_export se
 303        LEFT JOIN (
 304          SELECT emp.id,
 305            CASE WHEN COALESCE(emp.name, '') <> '' THEN emp.name ELSE emp.login END AS name
 306          FROM employee emp
 307        ) AS e ON (se.employee_id = e.id)
 308        $where
 309        ORDER BY $sort_spec{sql}|;
 310
 311   my $results = selectall_hashref_query($form, $dbh, $query, @values);
 312
 313   $main::lxdebug->leave_sub();
 314
 315   return $results;
 316 }
 317
 318 sub post_payment {
 319   $main::lxdebug->enter_sub();
 320
 321   my $self     = shift;
 322   my %params   = @_;
 323
 324   Common::check_params(\%params, qw(items));
 325
 326   my $myconfig = \%main::myconfig;
 327   my $form     = $main::form;
 328
 329   my $dbh      = $params{dbh} || $form->get_standard_dbh($myconfig);
 330
 331   my @items    = ref $params{items} eq 'ARRAY' ? @{ $params{items} } : ($params{items});
 332
 333   my %handles  = (
 334     'get_item'       => [ qq|SELECT sei.*
 335                              FROM sepa_export_items sei
 336                              WHERE sei.id = ?| ],
 337
 338     'get_ap'         => [ qq|SELECT at.chart_id
 339                              FROM acc_trans at
 340                              LEFT JOIN chart c ON (at.chart_id = c.id)
 341                              WHERE (trans_id = ?)
 342                                AND ((c.link LIKE '%:AP') OR (c.link LIKE 'AP:%') OR (c.link = 'AP'))
 343                              LIMIT 1| ],
 344
 345     'add_acc_trans'  => [ qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, gldate,       source, memo)
 346                              VALUES                (?,        ?,        ?,      ?,         current_date, ?,      '')| ],
 347
 348     'update_ap'      => [ qq|UPDATE ap
 349                              SET paid = paid + ?
 350                              WHERE id = ?| ],
 351
 352     'finish_item'    => [ qq|UPDATE sepa_export_items
 353                              SET execution_date = ?, executed = TRUE
 354                              WHERE id = ?| ],
 355
 356     'has_unexecuted' => [ qq|SELECT sei1.id
 357                              FROM sepa_export_items sei1
 358                              WHERE (sei1.sepa_export_id = (SELECT sei2.sepa_export_id
 359                                                            FROM sepa_export_items sei2
 360                                                            WHERE sei2.id = ?))
 361                                AND NOT COALESCE(sei1.executed, FALSE)
 362                              LIMIT 1| ],
 363
 364     'do_close'       => [ qq|UPDATE sepa_export
 365                              SET executed = TRUE, closed = TRUE
 366                              WHERE (id = ?)| ],
 367     );
 368
 369   map { unshift @{ $_ }, prepare_query($form, $dbh, $_->[0]) } values %handles;
 370
 371   foreach my $item (@items) {
 372     my $item_id = conv_i($item->{id});
 373
 374     # Retrieve the item data belonging to the ID.
 375     do_statement($form, @{ $handles{get_item} }, $item_id);
 376     my $orig_item = $handles{get_item}->[0]->fetchrow_hashref();
 377
 378     next if (!$orig_item);
 379
 380     # Retrieve the invoice's AP chart ID.
 381     do_statement($form, @{ $handles{get_ap} }, $orig_item->{ap_id});
 382     my ($ap_chart_id) = $handles{get_ap}->[0]->fetchrow_array();
 383
 384     # Record the payment in acc_trans offsetting AP.
 385     do_statement($form, @{ $handles{add_acc_trans} }, $orig_item->{ap_id}, $ap_chart_id,           -1 * $orig_item->{amount}, $item->{execution_date}, '');
 386     do_statement($form, @{ $handles{add_acc_trans} }, $orig_item->{ap_id}, $orig_item->{chart_id},      $orig_item->{amount}, $item->{execution_date}, $orig_item->{reference});
 387
 388     # Update the invoice to reflect the new paid amount.
 389     do_statement($form, @{ $handles{update_ap} }, $orig_item->{amount}, $orig_item->{ap_id});
 390
 391     # Update the item to reflect that it has been posted.
 392     do_statement($form, @{ $handles{finish_item} }, $item->{execution_date}, $item_id);
 393
 394     # Check whether or not we can close the export itself if there are no unexecuted items left.
 395     do_statement($form, @{ $handles{has_unexecuted} }, $item_id);
 396     my ($has_unexecuted) = $handles{has_unexecuted}->[0]->fetchrow_array();
 397
 398     if (!$has_unexecuted) {
 399       do_statement($form, @{ $handles{do_close} }, $orig_item->{sepa_export_id});
 400     }
 401   }
 402
 403   map { $_->[0]->finish() } values %handles;
 404
 405   $dbh->commit() unless ($params{dbh});
 406
 407   $main::lxdebug->leave_sub();
 408 }
 409
 410 1;