SL/System/TaskServer.pm

   1 package SL::System::TaskServer;
   2
   3 use strict;
   4
   5 use parent qw(Rose::Object);
   6
   7 use Rose::Object::MakeMethods::Generic (
   8   scalar => [ qw(last_command_output) ],
   9 );
  10
  11 use File::Slurp;
  12 use File::Spec::Functions qw(:ALL);
  13 use File::Temp qw(tempfile);
  14
  15 use SL::System::Process;
  16
  17 use constant {
  18   OK           =>  0,
  19   ERR_PID_FILE => -1,
  20   ERR_PROCESS  => -2,
  21 };
  22
  23 use constant PID_BASE => "users/pid";
  24
  25 sub status {
  26   my ($self) = @_;
  27
  28   my $pid = $self->_read_pid;
  29   return ERR_PID_FILE unless $pid;
  30
  31   return kill(0, $pid) ? OK : ERR_PROCESS;
  32 }
  33
  34 sub is_running {
  35   my ($self) = @_;
  36
  37   return $self->status == OK;
  38 }
  39
  40 sub start {
  41   my ($self) = @_;
  42
  43   return $self->_run_script_command('start');
  44 }
  45
  46 sub start_if_not_running {
  47   my ($self) = @_;
  48
  49   $self->start unless $self->is_running;
  50 }
  51
  52 sub stop {
  53   my ($self) = @_;
  54
  55   return $self->_run_script_command('stop');
  56 }
  57
  58 sub wake_up {
  59   my ($self) = @_;
  60
  61   my $pid = $self->_read_pid;
  62   return undef unless $pid;
  63   return kill('ALRM', $pid) ? 1 : undef;
  64 }
  65
  66 #
  67 # private methods
  68 #
  69
  70 sub _read_pid {
  71   my ($self) = @_;
  72
  73   my $exe_dir = SL::System::Process->exe_dir;
  74
  75   foreach my $conf (qw(kivitendo.conf lx_office.conf kivitendo.conf.default)) {
  76     my $pid_file_path = catfile(catdir($exe_dir, splitdir(PID_BASE())), "config.${conf}.pid");
  77
  78     return join('', read_file($pid_file_path)) * 1 if -f $pid_file_path;
  79   }
  80 }
  81
  82 sub _run_script_command {
  83   my ($self, $command) = @_;
  84
  85   my ($fh, $file_name) = tempfile();
  86   my $exe              = catfile(catdir(SL::System::Process->exe_dir, 'scripts'), 'task_server.pl');
  87
  88   system "${exe} ${command} >> ${file_name} 2>&1";
  89
  90   $fh->close;
  91
  92   $self->last_command_output(read_file($file_name));
  93
  94   return $? == 0 ? 1 : undef;
  95 }
  96
  97 1;
  98 __END__
  99
 100 =pod
 101
 102 =encoding utf8
 103
 104 =head1 NAME
 105
 106 SL::System::TaskServer - programmatic interface to the external task server component
 107
 108 =head1 SYNOPSIS
 109
 110   # Create interface
 111   my $task_server = SL->TaskServer->new;
 112
 113   # Start the server if it is not running
 114   if (!$task_server->is_running) {
 115     $task_server->start;
 116   }
 117
 118   # Stop it if it is running
 119   if ($task_server->is_running) {
 120     $task_server->stop;
 121   }
 122
 123 =head1 FUNCTIONS
 124
 125 =over 4
 126
 127 =item C<is_running>
 128
 129 Returns C<trueish> if the server is running. This is done by using
 130 Perl's C<kill> function with a "signal" of C<0> for the process ID
 131 which in turn is read from the daemon's PID file.
 132
 133 If the PID file is not found or if C<kill> returns a non-successful
 134 value then a C<falsish> value is returned.
 135
 136 =item C<last_command_output>
 137
 138 Returns the output of the last C<system> command executed, e.g. from a
 139 call to L<start> or L<stop>.
 140
 141 =item C<start>
 142
 143 Starts the task server. Does not check whether or not it is running,
 144 neither before not after trying to start it.
 145
 146 Returns C<1> if the system command C<./scripts/task_server.pl start>
 147 exits with an exit code of C<0> and C<undef> otherwise.
 148
 149 The command's output can be queried with L<last_command_output>.
 150
 151 =item C<status>
 152
 153 Queries the task server status. Returns one of these values:
 154
 155 =over 4
 156
 157 =item *
 158
 159 C<OK> or C<0>: the task server is running and signals can be sent to
 160 it.
 161
 162 =item *
 163
 164 C<ERR_PID_FILE> or C<-1>: the PID file could not be found or read
 165
 166 =item *
 167
 168 C<ERR_PROCESS> or C<-2>: the PID file could was found and read, but
 169 it's not possible to send signals to the process, e.g. because it is
 170 not running or owned by a different user ID.
 171
 172 =back
 173
 174 =item C<stop>
 175
 176 Stops the task server. Does not check whether or not it is running,
 177 neither before not after trying to start it.
 178
 179 Returns C<1> if the system command C<./scripts/task_server.pl stop>
 180 exits with an exit code of C<0> and C<undef> otherwise.
 181
 182 The command's output can be queried with L<last_command_output>.
 183
 184 =item C<wake_up>
 185
 186 Sends a signal to the task server process causing it to wake up and
 187 process its job queue immediately.
 188
 189 Returns C<1> if the signal could be sent and C<undef> otherwise.
 190
 191 =back
 192
 193 =head1 BUGS
 194
 195 Nothing here yet.
 196
 197 =head1 AUTHOR
 198
 199 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 200
 201 =cut