SL/Template/Plugin/L.pm

   1 package SL::Template::Plugin::L;
   2
   3 use base qw( Template::Plugin );
   4 use Template::Plugin;
   5
   6 use strict;
   7
   8 { # This will give you an id for identifying html tags and such.
   9   # It's guaranteed to be unique unless you exceed 10 mio calls per request.
  10   # Do not use these id's to store information across requests.
  11 my $_id_sequence = int rand 1e7;
  12 sub _tag_id {
  13   return $_id_sequence = ($_id_sequence + 1) % 1e7;
  14 }
  15 }
  16
  17 sub _H {
  18   my $string = shift;
  19   return $::locale->quote_special_chars('HTML', $string);
  20 }
  21
  22 sub _hashify {
  23   return (@_ && (ref($_[0]) eq 'HASH')) ? %{ $_[0] } : @_;
  24 }
  25
  26 sub new {
  27   my $class   = shift;
  28   my $context = shift;
  29
  30   return bless { }, $class;
  31 }
  32
  33 sub name_to_id {
  34   my $self =  shift;
  35   my $name =  shift;
  36
  37   $name    =~ s/[^\w_]/_/g;
  38   $name    =~ s/_+/_/g;
  39
  40   return $name;
  41 }
  42
  43 sub attributes {
  44   my $self    = shift;
  45   my %options = _hashify(@_);
  46
  47   my @result = ();
  48   while (my ($name, $value) = each %options) {
  49     next unless $name;
  50     $value ||= '';
  51     push @result, _H($name) . '="' . _H($value) . '"';
  52   }
  53
  54   return @result ? ' ' . join(' ', @result) : '';
  55 }
  56
  57 sub html_tag {
  58   my $self       = shift;
  59   my $tag        = shift;
  60   my $content    = shift;
  61   my $attributes = $self->attributes(@_);
  62
  63   return "<${tag}${attributes}/>" unless defined($content);
  64   return "<${tag}${attributes}>${content}</${tag}>";
  65 }
  66
  67 sub select_tag {
  68   my $self            = shift;
  69   my $name            = shift;
  70   my $options_str     = shift;
  71   my %attributes      = _hashify(@_);
  72
  73   $attributes{id}   ||= $self->name_to_id($name);
  74
  75   return $self->html_tag('select', $options_str, %attributes, name => $name);
  76 }
  77
  78 sub textarea_tag {
  79   my $self            = shift;
  80   my $name            = shift;
  81   my $content         = shift;
  82   my %attributes      = _hashify(@_);
  83
  84   $attributes{id}   ||= $self->name_to_id($name);
  85   $content            = $content ? '' : _H($content);
  86
  87   return $self->html_tag('textarea', $content, %attributes, name => $name);
  88 }
  89
  90 sub checkbox_tag {
  91   my $self             = shift;
  92   my $name             = shift;
  93   my %attributes       = _hashify(@_);
  94
  95   $attributes{id}    ||= $self->name_to_id($name);
  96   $attributes{value}   = 1 unless defined $attributes{value};
  97   my $label            = delete $attributes{label};
  98
  99   if ($attributes{checked}) {
 100     $attributes{checked} = 'checked';
 101   } else {
 102     delete $attributes{checked};
 103   }
 104
 105   my $code  = $self->html_tag('input', undef,  %attributes, name => $name, type => 'checkbox');
 106   $code    .= $self->html_tag('label', $label, for => $attributes{id}) if $label;
 107
 108   return $code;
 109 }
 110
 111 sub radio_button_tag {
 112   my $self             = shift;
 113   my $name             = shift;
 114   my %attributes       = _hashify(@_);
 115
 116   $attributes{value}   = 1 unless defined $attributes{value};
 117   $attributes{id}    ||= $self->name_to_id($name . "_" . $attributes{value});
 118   my $label            = delete $attributes{label};
 119
 120   if ($attributes{checked}) {
 121     $attributes{checked} = 'checked';
 122   } else {
 123     delete $attributes{checked};
 124   }
 125
 126   my $code  = $self->html_tag('input', undef,  %attributes, name => $name, type => 'radio');
 127   $code    .= $self->html_tag('label', $label, for => $attributes{id}) if $label;
 128
 129   return $code;
 130 }
 131
 132 sub input_tag {
 133   my $self            = shift;
 134   my $name            = shift;
 135   my $value           = shift;
 136   my %attributes      = _hashify(@_);
 137
 138   $attributes{id}   ||= $self->name_to_id($name);
 139   $attributes{type} ||= 'text';
 140
 141   return $self->html_tag('input', undef, %attributes, name => $name, value => $value);
 142 }
 143
 144 sub options_for_select {
 145   my $self          = shift;
 146   my $collection    = shift;
 147   my %options       = _hashify(@_);
 148
 149   my $value_key     = $options{value} || 'id';
 150   my $title_key     = $options{title} || $value_key;
 151
 152   my @elements      = ();
 153   push @elements, [ undef, $options{empty_title} || '' ] if $options{with_empty};
 154
 155   if ($collection && (ref $collection eq 'ARRAY')) {
 156     foreach my $element (@{ $collection }) {
 157       my @result = !ref $element            ? ( $element,               $element               )
 158                  :  ref $element eq 'ARRAY' ? ( $element->[0],          $element->[1]          )
 159                  :  ref $element eq 'HASH'  ? ( $element->{$value_key}, $element->{$title_key} )
 160                  :                            ( $element->$value_key,   $element->$title_key   );
 161
 162       push @elements, \@result;
 163     }
 164   }
 165
 166   my $code = '';
 167   foreach my $result (@elements) {
 168     my %attributes = ( value => $result->[0] );
 169     $attributes{selected} = 'selected' if $options{default} && ($options{default} eq ($result->[0] || ''));
 170
 171     $code .= $self->html_tag('option', _H($result->[1]), %attributes);
 172   }
 173
 174   return $code;
 175 }
 176
 177 sub javascript {
 178   my ($self, $data) = @_;
 179   return $self->html_tag('script', $data, type => 'text/javascript');
 180 }
 181
 182 sub date_tag {
 183   my ($self, $name, $value, @slurp) = @_;
 184   my %params   = _hashify(@slurp);
 185   my $name_e   = _H($name);
 186   my $seq      = _tag_id();
 187
 188   $params{cal_align} ||= 'BR';
 189
 190   $self->input_tag($name, $value,
 191     id     => $name_e,
 192     size   => 11,
 193     title  => _H($::myconfig{dateformat}),
 194     onBlur => 'check_right_date_format(this)',
 195     %params,
 196   ) . ((!$params{no_cal}) ?
 197   $self->html_tag('img', undef,
 198     src    => 'image/calendar.png',
 199     id     => "trigger$seq",
 200     title  => _H($::myconfig{dateformat}),
 201     %params,
 202   ) .
 203   $self->javascript(
 204     "Calendar.setup({ inputField: '$name_e', ifFormat: '$::myconfig{jsc_dateformat}', align: '$params{cal_align}', button: 'trigger$seq'  });"
 205   ) : '');
 206 }
 207
 208 1;
 209
 210 __END__
 211
 212 =head1 NAME
 213
 214 SL::Templates::Plugin::L -- Layouting / tag generation
 215
 216 =head1 SYNOPSIS
 217
 218 Usage from a template:
 219
 220   [% USE L %]
 221
 222   [% L.select_tag('direction', [ [ 'left', 'To the left' ], [ 'right', 'To the right' ] ]) %]
 223
 224   [% L.select_tag('direction', L.options_for_select([ { direction => 'left',  display => 'To the left'  },
 225                                                       { direction => 'right', display => 'To the right' } ],
 226                                                     value => 'direction', title => 'display', default => 'right')) %]
 227
 228 =head1 DESCRIPTION
 229
 230 A module modeled a bit after Rails' ActionView helpers. Several small
 231 functions that create HTML tags from various kinds of data sources.
 232
 233 =head1 FUNCTIONS
 234
 235 =head2 LOW-LEVEL FUNCTIONS
 236
 237 =over 4
 238
 239 =item C<name_to_id $name>
 240
 241 Converts a name to a HTML id by replacing various characters.
 242
 243 =item C<attributes %items>
 244
 245 Creates a string from all elements in C<%items> suitable for usage as
 246 HTML tag attributes. Keys and values are HTML escaped even though keys
 247 must not contain non-ASCII characters for browsers to accept them.
 248
 249 =item C<html_tag $tag_name, $content_string, %attributes>
 250
 251 Creates an opening and closing HTML tag for C<$tag_name> and puts
 252 C<$content_string> between the two. If C<$content_string> is undefined
 253 or empty then only a E<lt>tag/E<gt> tag will be created. Attributes
 254 are key/value pairs added to the opening tag.
 255
 256 C<$content_string> is not HTML escaped.
 257
 258 =back
 259
 260 =head2 HIGH-LEVEL FUNCTIONS
 261
 262 =over 4
 263
 264 =item C<select_tag $name, $options_string, %attributes>
 265
 266 Creates a HTML 'select' tag named C<$name> with the contents
 267 C<$options_string> and with arbitrary HTML attributes from
 268 C<%attributes>. The tag's C<id> defaults to C<name_to_id($name)>.
 269
 270 The $options_string is usually created by the C<options_for_select>
 271 function.
 272
 273 =item C<input_tag $name, $value, %attributes>
 274
 275 Creates a HTML 'input type=text' tag named C<$name> with the value
 276 C<$value> and with arbitrary HTML attributes from C<%attributes>. The
 277 tag's C<id> defaults to C<name_to_id($name)>.
 278
 279 =item C<textarea_tag $name, $value, %attributes>
 280
 281 Creates a HTML 'textarea' tag named C<$name> with the content
 282 C<$value> and with arbitrary HTML attributes from C<%attributes>. The
 283 tag's C<id> defaults to C<name_to_id($name)>.
 284
 285 =item C<checkbox_tag $name, %attributes>
 286
 287 Creates a HTML 'input type=checkbox' tag named C<$name> with arbitrary
 288 HTML attributes from C<%attributes>. The tag's C<id> defaults to
 289 C<name_to_id($name)>. The tag's C<value> defaults to C<1>.
 290
 291 If C<%attributes> contains a key C<label> then a HTML 'label' tag is
 292 created with said C<label>. No attribute named C<label> is created in
 293 that case.
 294
 295 =item C<date_tag $name, $value, cal_align =E<gt> $align_code, %attributes>
 296
 297 Creates a date input field, with an attached javascript that will open a
 298 calendar on click. The javascript ist by default anchoered at the bottom right
 299 sight. This can be overridden with C<cal_align>, see Calendar documentation for
 300 the details, usually you'll want a two letter abbreviation of the alignment.
 301 Right + Bottom becomes C<BL>.
 302
 303 =item C<radio_button_tag $name, %attributes>
 304
 305 Creates a HTML 'input type=radio' tag named C<$name> with arbitrary
 306 HTML attributes from C<%attributes>. The tag's C<value> defaults to
 307 C<1>. The tag's C<id> defaults to C<name_to_id($name . "_" . $value)>.
 308
 309 If C<%attributes> contains a key C<label> then a HTML 'label' tag is
 310 created with said C<label>. No attribute named C<label> is created in
 311 that case.
 312
 313 =back
 314
 315 =head2 CONVERSION FUNCTIONS
 316
 317 =over 4
 318
 319 =item C<options_for_select \@collection, %options>
 320
 321 Creates a string suitable for a HTML 'select' tag consisting of one
 322 'E<lt>optionE<gt>' tag for each element in C<\@collection>. The value
 323 to use and the title to display are extracted from the elements in
 324 C<\@collection>. Each element can be one of four things:
 325
 326 =over 12
 327
 328 =item 1. An array reference with at least two elements. The first element is
 329 the value, the second element is its title.
 330
 331 =item 2. A scalar. The scalar is both the value and the title.
 332
 333 =item 3. A hash reference. In this case C<%options> must contain
 334 I<value> and I<title> keys that name the keys in the element to use
 335 for the value and title respectively.
 336
 337 =item 4. A blessed reference. In this case C<%options> must contain
 338 I<value> and I<title> keys that name functions called on the blessed
 339 reference whose return values are used as the value and title
 340 respectively.
 341
 342 =back
 343
 344 For cases 3 and 4 C<$options{value}> defaults to C<id> and
 345 C<$options{title}> defaults to C<$options{value}>.
 346
 347 If the option C<with_empty> is set then an empty element (value
 348 C<undef>) will be used as the first element. The title to display for
 349 this element can be set with the option C<empty_title> and defaults to
 350 an empty string.
 351
 352 =back
 353
 354 =head1 MODULE AUTHORS
 355
 356 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 357
 358 L<http://linet-services.de>