SL/Template/Plugin/L.pm

   1 package SL::Template::Plugin::L;
   2
   3 use base qw( Template::Plugin );
   4 use Template::Plugin;
   5
   6 use strict;
   7
   8 { # This will give you an id for identifying html tags and such.
   9   # It's guaranteed to be unique unless you exceed 10 mio calls per request.
  10   # Do not use these id's to store information across requests.
  11 my $_id_sequence = int rand 1e7;
  12 sub _tag_id {
  13   return $_id_sequence = ($_id_sequence + 1) % 1e7;
  14 }
  15 }
  16
  17 sub _H {
  18   my $string = shift;
  19   return $::locale->quote_special_chars('HTML', $string);
  20 }
  21
  22 sub _hashify {
  23   return (@_ && (ref($_[0]) eq 'HASH')) ? %{ $_[0] } : @_;
  24 }
  25
  26 sub new {
  27   my $class   = shift;
  28   my $context = shift;
  29
  30   return bless { }, $class;
  31 }
  32
  33 sub name_to_id {
  34   my $self =  shift;
  35   my $name =  shift;
  36
  37   $name    =~ s/[^\w_]/_/g;
  38   $name    =~ s/_+/_/g;
  39
  40   return $name;
  41 }
  42
  43 sub attributes {
  44   my $self    = shift;
  45   my %options = _hashify(@_);
  46
  47   my @result = ();
  48   while (my ($name, $value) = each %options) {
  49     next unless $name;
  50     $value ||= '';
  51     push @result, _H($name) . '="' . _H($value) . '"';
  52   }
  53
  54   return @result ? ' ' . join(' ', @result) : '';
  55 }
  56
  57 sub html_tag {
  58   my $self       = shift;
  59   my $tag        = shift;
  60   my $content    = shift;
  61   my $attributes = $self->attributes(@_);
  62
  63   return "<${tag}${attributes}/>" unless $content;
  64   return "<${tag}${attributes}>${content}</${tag}>";
  65 }
  66
  67 sub select_tag {
  68   my $self            = shift;
  69   my $name            = shift;
  70   my $options_str     = shift;
  71   my %attributes      = _hashify(@_);
  72
  73   $attributes{id}   ||= $self->name_to_id($name);
  74
  75   return $self->html_tag('select', $options_str, %attributes, name => $name);
  76 }
  77
  78 sub checkbox_tag {
  79   my $self             = shift;
  80   my $name             = shift;
  81   my %attributes       = _hashify(@_);
  82
  83   $attributes{id}    ||= $self->name_to_id($name);
  84   $attributes{value}   = 1 unless defined $attributes{value};
  85   my $label            = delete $attributes{label};
  86
  87   if ($attributes{checked}) {
  88     $attributes{checked} = 'checked';
  89   } else {
  90     delete $attributes{checked};
  91   }
  92
  93   my $code  = $self->html_tag('input', undef,  %attributes, name => $name, type => 'checkbox');
  94   $code    .= $self->html_tag('label', $label, for => $attributes{id}) if $label;
  95
  96   return $code;
  97 }
  98
  99 sub input_tag {
 100   my $self            = shift;
 101   my $name            = shift;
 102   my $value           = shift;
 103   my %attributes      = _hashify(@_);
 104
 105   $attributes{id}   ||= $self->name_to_id($name);
 106   $attributes{type} ||= 'text';
 107
 108   return $self->html_tag('input', undef, %attributes, name => $name, value => $value);
 109 }
 110
 111 sub options_for_select {
 112   my $self          = shift;
 113   my $collection    = shift;
 114   my %options       = _hashify(@_);
 115
 116   my $value_key     = $options{value} || 'id';
 117   my $title_key     = $options{title} || $value_key;
 118
 119   my @elements      = ();
 120   push @elements, [ undef, $options{empty_title} || '' ] if $options{with_empty};
 121
 122   if ($collection && (ref $collection eq 'ARRAY')) {
 123     foreach my $element (@{ $collection }) {
 124       my @result = !ref $element            ? ( $element,               $element               )
 125                  :  ref $element eq 'ARRAY' ? ( $element->[0],          $element->[1]          )
 126                  :  ref $element eq 'HASH'  ? ( $element->{$value_key}, $element->{$title_key} )
 127                  :                            ( $element->$value_key,   $element->$title_key   );
 128
 129       push @elements, \@result;
 130     }
 131   }
 132
 133   my $code = '';
 134   foreach my $result (@elements) {
 135     my %attributes = ( value => $result->[0] );
 136     $attributes{selected} = 'selected' if $options{default} && ($options{default} eq ($result->[0] || ''));
 137
 138     $code .= $self->html_tag('option', _H($result->[1]), %attributes);
 139   }
 140
 141   return $code;
 142 }
 143
 144 sub javascript {
 145   my ($self, $data) = @_;
 146   return $self->html_tag('script', $data, type => 'text/javascript');
 147 }
 148
 149 sub date_tag {
 150   my ($self, $name, $value, @slurp) = @_;
 151   my %params   = _hashify(@slurp);
 152   my $name_e   = _H($name);
 153   my $seq      = _tag_id();
 154
 155   $params{cal_align} ||= 'BR';
 156
 157   $self->input_tag($name, $value,
 158     size   => 11,
 159     title  => _H($::myconfig{dateformat}),
 160     onBlur => 'check_right_date_format(this)',
 161     %params,
 162   ) . ((!$params{no_cal}) ?
 163   $self->html_tag('img', undef,
 164     src    => 'image/calendar.png',
 165     id     => "trigger$seq",
 166     title  => _H($::myconfig{dateformat}),
 167     %params,
 168   ) .
 169   $self->javascript(
 170     "Calendar.setup({ inputField: '$name_e', ifFormat: '$::myconfig{jsc_dateformat}', align: '$params{cal_align}', button: 'trigger$seq'  });"
 171   ) : '');
 172 }
 173
 174 1;
 175
 176 __END__
 177
 178 =head1 NAME
 179
 180 SL::Templates::Plugin::L -- Layouting / tag generation
 181
 182 =head1 SYNOPSIS
 183
 184 Usage from a template:
 185
 186   [% USE L %]
 187
 188   [% L.select_tag('direction', [ [ 'left', 'To the left' ], [ 'right', 'To the right' ] ]) %]
 189
 190   [% L.select_tag('direction', L.options_for_select([ { direction => 'left',  display => 'To the left'  },
 191                                                       { direction => 'right', display => 'To the right' } ],
 192                                                     value => 'direction', title => 'display', default => 'right')) %]
 193
 194 =head1 DESCRIPTION
 195
 196 A module modeled a bit after Rails' ActionView helpers. Several small
 197 functions that create HTML tags from various kinds of data sources.
 198
 199 =head1 FUNCTIONS
 200
 201 =head2 LOW-LEVEL FUNCTIONS
 202
 203 =over 4
 204
 205 =item C<name_to_id $name>
 206
 207 Converts a name to a HTML id by replacing various characters.
 208
 209 =item C<attributes %items>
 210
 211 Creates a string from all elements in C<%items> suitable for usage as
 212 HTML tag attributes. Keys and values are HTML escaped even though keys
 213 must not contain non-ASCII characters for browsers to accept them.
 214
 215 =item C<html_tag $tag_name, $content_string, %attributes>
 216
 217 Creates an opening and closing HTML tag for C<$tag_name> and puts
 218 C<$content_string> between the two. If C<$content_string> is undefined
 219 or empty then only a E<lt>tag/E<gt> tag will be created. Attributes
 220 are key/value pairs added to the opening tag.
 221
 222 C<$content_string> is not HTML escaped.
 223
 224 =back
 225
 226 =head2 HIGH-LEVEL FUNCTIONS
 227
 228 =over 4
 229
 230 =item C<select_tag $name, $options_string, %attributes>
 231
 232 Creates a HTML 'select' tag named C<$name> with the contents
 233 C<$options_string> and with arbitrary HTML attributes from
 234 C<%attributes>. The tag's C<id> defaults to C<name_to_id($name)>.
 235
 236 The $options_string is usually created by the C<options_for_select>
 237 function.
 238
 239 =item C<input_tag $name, $value, %attributes>
 240
 241 Creates a HTML 'input type=text' tag named C<$name> with the value
 242 C<$value> and with arbitrary HTML attributes from C<%attributes>. The
 243 tag's C<id> defaults to C<name_to_id($name)>.
 244
 245 =item C<checkbox_tag $name, %attributes>
 246
 247 Creates a HTML 'input type=checkbox' tag named C<$name> with arbitrary
 248 HTML attributes from C<%attributes>. The tag's C<id> defaults to
 249 C<name_to_id($name)>. The tag's C<value> defaults to C<1>.
 250
 251 If C<%attributes> contains a key C<label> then a HTML 'label' tag is
 252 created with said C<label>. No attribute named C<label> is created in
 253 that case.
 254
 255 =item C<date_tag $name, $value, %attributes>
 256
 257 =item C<date_tag $name, $value, cal_align =E<gt> $align_code, %attributes>
 258
 259 Creates a date input field, with an attached javascript that will open a
 260 calendar on click. The javascript ist by default anchoered at the bottom right
 261 sight. This can be overridden with C<cal_align>, see Calendar documentation for
 262 the details, usually you'll want a two letter abbreviation of the alignment.
 263 Right + Bottom becomes C<BL>.
 264
 265 =back
 266
 267 =head2 CONVERSION FUNCTIONS
 268
 269 =over 4
 270
 271 =item C<options_for_select \@collection, %options>
 272
 273 Creates a string suitable for a HTML 'select' tag consisting of one
 274 'E<lt>optionE<gt>' tag for each element in C<\@collection>. The value
 275 to use and the title to display are extracted from the elements in
 276 C<\@collection>. Each element can be one of four things:
 277
 278 =over 12
 279
 280 =item 1. An array reference with at least two elements. The first element is
 281 the value, the second element is its title.
 282
 283 =item 2. A scalar. The scalar is both the value and the title.
 284
 285 =item 3. A hash reference. In this case C<%options> must contain
 286 I<value> and I<title> keys that name the keys in the element to use
 287 for the value and title respectively.
 288
 289 =item 4. A blessed reference. In this case C<%options> must contain
 290 I<value> and I<title> keys that name functions called on the blessed
 291 reference whose return values are used as the value and title
 292 respectively.
 293
 294 =back
 295
 296 For cases 3 and 4 C<$options{value}> defaults to C<id> and
 297 C<$options{title}> defaults to C<$options{value}>.
 298
 299 If the option C<with_empty> is set then an empty element (value
 300 C<undef>) will be used as the first element. The title to display for
 301 this element can be set with the option C<empty_title> and defaults to
 302 an empty string.
 303
 304 =back
 305
 306 =head1 MODULE AUTHORS
 307
 308 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 309
 310 L<http://linet-services.de>