SL/Template/Plugin/L.pm

   1 package SL::Template::Plugin::L;
   2
   3 use base qw( Template::Plugin );
   4 use Template::Plugin;
   5
   6 use strict;
   7
   8 { # This will give you an id for identifying html tags and such.
   9   # It's guaranteed to be unique unless you exceed 10 mio calls per request.
  10   # Do not use these id's to store information across requests.
  11 my $_id_sequence = int rand 1e7;
  12 sub _tag_id {
  13   return $_id_sequence = ($_id_sequence + 1) % 1e7;
  14 }
  15 }
  16
  17 sub _H {
  18   my $string = shift;
  19   return $::locale->quote_special_chars('HTML', $string);
  20 }
  21
  22 sub _hashify {
  23   return (@_ && (ref($_[0]) eq 'HASH')) ? %{ $_[0] } : @_;
  24 }
  25
  26 sub new {
  27   my $class   = shift;
  28   my $context = shift;
  29
  30   return bless { }, $class;
  31 }
  32
  33 sub name_to_id {
  34   my $self =  shift;
  35   my $name =  shift;
  36
  37   $name    =~ s/[^\w_]/_/g;
  38   $name    =~ s/_+/_/g;
  39
  40   return $name;
  41 }
  42
  43 sub attributes {
  44   my $self    = shift;
  45   my %options = _hashify(@_);
  46
  47   my @result = ();
  48   while (my ($name, $value) = each %options) {
  49     next unless $name;
  50     $value ||= '';
  51     push @result, _H($name) . '="' . _H($value) . '"';
  52   }
  53
  54   return @result ? ' ' . join(' ', @result) : '';
  55 }
  56
  57 sub html_tag {
  58   my $self       = shift;
  59   my $tag        = shift;
  60   my $content    = shift;
  61   my $attributes = $self->attributes(@_);
  62
  63   return "<${tag}${attributes}/>" unless defined($content);
  64   return "<${tag}${attributes}>${content}</${tag}>";
  65 }
  66
  67 sub select_tag {
  68   my $self            = shift;
  69   my $name            = shift;
  70   my $options_str     = shift;
  71   my %attributes      = _hashify(@_);
  72
  73   $attributes{id}   ||= $self->name_to_id($name);
  74   $options_str        = $self->options_for_select($options_str) if ref $options_str;
  75
  76   return $self->html_tag('select', $options_str, %attributes, name => $name);
  77 }
  78
  79 sub textarea_tag {
  80   my $self            = shift;
  81   my $name            = shift;
  82   my $content         = shift;
  83   my %attributes      = _hashify(@_);
  84
  85   $attributes{id}   ||= $self->name_to_id($name);
  86   $content            = $content ? '' : _H($content);
  87
  88   return $self->html_tag('textarea', $content, %attributes, name => $name);
  89 }
  90
  91 sub checkbox_tag {
  92   my $self             = shift;
  93   my $name             = shift;
  94   my %attributes       = _hashify(@_);
  95
  96   $attributes{id}    ||= $self->name_to_id($name);
  97   $attributes{value}   = 1 unless defined $attributes{value};
  98   my $label            = delete $attributes{label};
  99
 100   if ($attributes{checked}) {
 101     $attributes{checked} = 'checked';
 102   } else {
 103     delete $attributes{checked};
 104   }
 105
 106   my $code  = $self->html_tag('input', undef,  %attributes, name => $name, type => 'checkbox');
 107   $code    .= $self->html_tag('label', $label, for => $attributes{id}) if $label;
 108
 109   return $code;
 110 }
 111
 112 sub radio_button_tag {
 113   my $self             = shift;
 114   my $name             = shift;
 115   my %attributes       = _hashify(@_);
 116
 117   $attributes{value}   = 1 unless defined $attributes{value};
 118   $attributes{id}    ||= $self->name_to_id($name . "_" . $attributes{value});
 119   my $label            = delete $attributes{label};
 120
 121   if ($attributes{checked}) {
 122     $attributes{checked} = 'checked';
 123   } else {
 124     delete $attributes{checked};
 125   }
 126
 127   my $code  = $self->html_tag('input', undef,  %attributes, name => $name, type => 'radio');
 128   $code    .= $self->html_tag('label', $label, for => $attributes{id}) if $label;
 129
 130   return $code;
 131 }
 132
 133 sub input_tag {
 134   my $self            = shift;
 135   my $name            = shift;
 136   my $value           = shift;
 137   my %attributes      = _hashify(@_);
 138
 139   $attributes{id}   ||= $self->name_to_id($name);
 140   $attributes{type} ||= 'text';
 141
 142   return $self->html_tag('input', undef, %attributes, name => $name, value => $value);
 143 }
 144
 145 sub hidden_tag {
 146   return shift->input_tag(@_, type => 'hidden');
 147 }
 148
 149 sub submit_tag {
 150   return shift->input_tag(@_, type => 'submit', class => 'submit');
 151 }
 152
 153 sub options_for_select {
 154   my $self          = shift;
 155   my $collection    = shift;
 156   my %options       = _hashify(@_);
 157
 158   my $value_key     = $options{value} || 'id';
 159   my $title_key     = $options{title} || $value_key;
 160
 161   my @elements      = ();
 162   push @elements, [ undef, $options{empty_title} || '' ] if $options{with_empty};
 163
 164   if ($collection && (ref $collection eq 'ARRAY')) {
 165     foreach my $element (@{ $collection }) {
 166       my @result = !ref $element            ? ( $element,               $element               )
 167                  :  ref $element eq 'ARRAY' ? ( $element->[0],          $element->[1]          )
 168                  :  ref $element eq 'HASH'  ? ( $element->{$value_key}, $element->{$title_key} )
 169                  :                            ( $element->$value_key,   $element->$title_key   );
 170
 171       push @elements, \@result;
 172     }
 173   }
 174
 175   my $code = '';
 176   foreach my $result (@elements) {
 177     my %attributes = ( value => $result->[0] );
 178     $attributes{selected} = 'selected' if $options{default} && ($options{default} eq ($result->[0] || ''));
 179
 180     $code .= $self->html_tag('option', _H($result->[1]), %attributes);
 181   }
 182
 183   return $code;
 184 }
 185
 186 sub javascript {
 187   my ($self, $data) = @_;
 188   return $self->html_tag('script', $data, type => 'text/javascript');
 189 }
 190
 191 sub date_tag {
 192   my ($self, $name, $value, @slurp) = @_;
 193   my %params   = _hashify(@slurp);
 194   my $name_e   = _H($name);
 195   my $seq      = _tag_id();
 196
 197   $params{cal_align} ||= 'BR';
 198
 199   $self->input_tag($name, $value,
 200     id     => $name_e,
 201     size   => 11,
 202     title  => _H($::myconfig{dateformat}),
 203     onBlur => 'check_right_date_format(this)',
 204     %params,
 205   ) . ((!$params{no_cal}) ?
 206   $self->html_tag('img', undef,
 207     src    => 'image/calendar.png',
 208     id     => "trigger$seq",
 209     title  => _H($::myconfig{dateformat}),
 210     %params,
 211   ) .
 212   $self->javascript(
 213     "Calendar.setup({ inputField: '$name_e', ifFormat: '$::myconfig{jsc_dateformat}', align: '$params{cal_align}', button: 'trigger$seq'  });"
 214   ) : '');
 215
 216 sub javascript_tag {
 217   my $self = shift;
 218   my $code = '';
 219
 220   foreach my $file (@_) {
 221     $file .= '.js'        unless $file =~ m/\.js$/;
 222     $file  = "js/${file}" unless $file =~ m|/|;
 223
 224     $code .= qq|<script type="text/javascript" src="${file}"></script>|;
 225   }
 226
 227   return $code;
 228 }
 229
 230 1;
 231
 232 __END__
 233
 234 =head1 NAME
 235
 236 SL::Templates::Plugin::L -- Layouting / tag generation
 237
 238 =head1 SYNOPSIS
 239
 240 Usage from a template:
 241
 242   [% USE L %]
 243
 244   [% L.select_tag('direction', [ [ 'left', 'To the left' ], [ 'right', 'To the right' ] ]) %]
 245
 246   [% L.select_tag('direction', L.options_for_select([ { direction => 'left',  display => 'To the left'  },
 247                                                       { direction => 'right', display => 'To the right' } ],
 248                                                     value => 'direction', title => 'display', default => 'right')) %]
 249
 250 =head1 DESCRIPTION
 251
 252 A module modeled a bit after Rails' ActionView helpers. Several small
 253 functions that create HTML tags from various kinds of data sources.
 254
 255 =head1 FUNCTIONS
 256
 257 =head2 LOW-LEVEL FUNCTIONS
 258
 259 =over 4
 260
 261 =item C<name_to_id $name>
 262
 263 Converts a name to a HTML id by replacing various characters.
 264
 265 =item C<attributes %items>
 266
 267 Creates a string from all elements in C<%items> suitable for usage as
 268 HTML tag attributes. Keys and values are HTML escaped even though keys
 269 must not contain non-ASCII characters for browsers to accept them.
 270
 271 =item C<html_tag $tag_name, $content_string, %attributes>
 272
 273 Creates an opening and closing HTML tag for C<$tag_name> and puts
 274 C<$content_string> between the two. If C<$content_string> is undefined
 275 or empty then only a E<lt>tag/E<gt> tag will be created. Attributes
 276 are key/value pairs added to the opening tag.
 277
 278 C<$content_string> is not HTML escaped.
 279
 280 =back
 281
 282 =head2 HIGH-LEVEL FUNCTIONS
 283
 284 =over 4
 285
 286 =item C<select_tag $name, $options_string, %attributes>
 287
 288 Creates a HTML 'select' tag named C<$name> with the contents
 289 C<$options_string> and with arbitrary HTML attributes from
 290 C<%attributes>. The tag's C<id> defaults to C<name_to_id($name)>.
 291
 292 The C<$options_string> is usually created by the
 293 L</options_for_select> function. If C<$options_string> is an array
 294 reference then it will be passed to L</options_for_select>
 295 automatically.
 296
 297 =item C<input_tag $name, $value, %attributes>
 298
 299 Creates a HTML 'input type=text' tag named C<$name> with the value
 300 C<$value> and with arbitrary HTML attributes from C<%attributes>. The
 301 tag's C<id> defaults to C<name_to_id($name)>.
 302
 303 =item C<textarea_tag $name, $value, %attributes>
 304
 305 Creates a HTML 'textarea' tag named C<$name> with the content
 306 C<$value> and with arbitrary HTML attributes from C<%attributes>. The
 307 tag's C<id> defaults to C<name_to_id($name)>.
 308
 309 =item C<checkbox_tag $name, %attributes>
 310
 311 Creates a HTML 'input type=checkbox' tag named C<$name> with arbitrary
 312 HTML attributes from C<%attributes>. The tag's C<id> defaults to
 313 C<name_to_id($name)>. The tag's C<value> defaults to C<1>.
 314
 315 If C<%attributes> contains a key C<label> then a HTML 'label' tag is
 316 created with said C<label>. No attribute named C<label> is created in
 317 that case.
 318
 319 =item C<date_tag $name, $value, cal_align =E<gt> $align_code, %attributes>
 320
 321 Creates a date input field, with an attached javascript that will open a
 322 calendar on click. The javascript ist by default anchoered at the bottom right
 323 sight. This can be overridden with C<cal_align>, see Calendar documentation for
 324 the details, usually you'll want a two letter abbreviation of the alignment.
 325 Right + Bottom becomes C<BL>.
 326
 327 =item C<radio_button_tag $name, %attributes>
 328
 329 Creates a HTML 'input type=radio' tag named C<$name> with arbitrary
 330 HTML attributes from C<%attributes>. The tag's C<value> defaults to
 331 C<1>. The tag's C<id> defaults to C<name_to_id($name . "_" . $value)>.
 332
 333 If C<%attributes> contains a key C<label> then a HTML 'label' tag is
 334 created with said C<label>. No attribute named C<label> is created in
 335 that case.
 336
 337 =item C<javascript_tag $file1, $file2, $file3...>
 338
 339 Creates a HTML 'E<lt>script type="text/javascript" src="..."E<gt>'
 340 tag for each file name parameter passed. Each file name will be
 341 postfixed with '.js' if it isn't already and prefixed with 'js/' if it
 342 doesn't contain a slash.
 343
 344 =back
 345
 346 =head2 CONVERSION FUNCTIONS
 347
 348 =over 4
 349
 350 =item C<options_for_select \@collection, %options>
 351
 352 Creates a string suitable for a HTML 'select' tag consisting of one
 353 'E<lt>optionE<gt>' tag for each element in C<\@collection>. The value
 354 to use and the title to display are extracted from the elements in
 355 C<\@collection>. Each element can be one of four things:
 356
 357 =over 12
 358
 359 =item 1. An array reference with at least two elements. The first element is
 360 the value, the second element is its title.
 361
 362 =item 2. A scalar. The scalar is both the value and the title.
 363
 364 =item 3. A hash reference. In this case C<%options> must contain
 365 I<value> and I<title> keys that name the keys in the element to use
 366 for the value and title respectively.
 367
 368 =item 4. A blessed reference. In this case C<%options> must contain
 369 I<value> and I<title> keys that name functions called on the blessed
 370 reference whose return values are used as the value and title
 371 respectively.
 372
 373 =back
 374
 375 For cases 3 and 4 C<$options{value}> defaults to C<id> and
 376 C<$options{title}> defaults to C<$options{value}>.
 377
 378 If the option C<with_empty> is set then an empty element (value
 379 C<undef>) will be used as the first element. The title to display for
 380 this element can be set with the option C<empty_title> and defaults to
 381 an empty string.
 382
 383 =back
 384
 385 =head1 MODULE AUTHORS
 386
 387 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 388
 389 L<http://linet-services.de>