SL/TransNumber.pm

   1 package SL::TransNumber;
   2
   3 use strict;
   4
   5 use parent qw(Rose::Object);
   6
   7 use Carp;
   8 use List::MoreUtils qw(any none);
   9 use SL::DBUtils;
  10
  11 use Rose::Object::MakeMethods::Generic
  12 (
  13  scalar => [ qw(type id number save dbh dbh_provided business_id) ],
  14 );
  15
  16 my @SUPPORTED_TYPES = qw(invoice credit_note customer vendor sales_delivery_order purchase_delivery_order sales_order purchase_order sales_quotation request_quotation part service assembly);
  17
  18 sub new {
  19   my $class = shift;
  20   my $self  = $class->SUPER::new(@_);
  21
  22   croak "Invalid type " . $self->type if none { $_ eq $self->type } @SUPPORTED_TYPES;
  23
  24   $self->dbh_provided($self->dbh);
  25   $self->dbh($::form->get_standard_dbh) if !$self->dbh;
  26   $self->save(1) unless defined $self->save;
  27   $self->business_id(undef) if $self->type ne 'customer';
  28
  29   return $self;
  30 }
  31
  32 sub _get_filters {
  33   my $self    = shift;
  34
  35   my $type    = $self->type;
  36   my %filters = ( where => '' );
  37
  38   if (any { $_ eq $type } qw(invoice credit_note)) {
  39     $filters{trans_number}  = "invnumber";
  40     $filters{numberfield}   = $type eq 'credit_note' ? "cnnumber" : "invnumber";
  41     $filters{table}         = "ar";
  42
  43   } elsif (any { $_ eq $type } qw(customer vendor)) {
  44     $filters{trans_number}  = "${type}number";
  45     $filters{numberfield}   = "${type}number";
  46     $filters{table}         = $type;
  47
  48   } elsif ($type =~ /_delivery_order$/) {
  49     $filters{trans_number}  = "donumber";
  50     $filters{numberfield}   = $type eq 'sales_delivery_order' ? "sdonumber" : "pdonumber";
  51     $filters{table}         = "delivery_orders";
  52     $filters{where}         = $type =~ /^sales/ ? '(customer_id IS NOT NULL)' : '(vendor_id IS NOT NULL)';
  53
  54   } elsif ($type =~ /_order$/) {
  55     $filters{trans_number}  = "ordnumber";
  56     $filters{numberfield}   = $type eq 'sales_order' ? "sonumber" : "ponumber";
  57     $filters{table}         = "oe";
  58     $filters{where}         = 'NOT COALESCE(quotation, FALSE)';
  59     $filters{where}        .= $type =~ /^sales/ ? ' AND (customer_id IS NOT NULL)' : ' AND (vendor_id IS NOT NULL)';
  60
  61   } elsif ($type =~ /_quotation$/) {
  62     $filters{trans_number}  = "quonumber";
  63     $filters{numberfield}   = $type eq 'sales_quotation' ? "sqnumber" : "rfqnumber";
  64     $filters{table}         = "oe";
  65     $filters{where}         = 'COALESCE(quotation, FALSE)';
  66     $filters{where}        .= $type =~ /^sales/ ? ' AND (customer_id IS NOT NULL)' : ' AND (vendor_id IS NOT NULL)';
  67
  68   } elsif ($type =~ /part|service|assembly/) {
  69     $filters{trans_number}  = "partnumber";
  70     $filters{numberfield}   = $type eq 'service' ? 'servicenumber' : 'articlenumber';
  71     $filters{table}         = "parts";
  72     $filters{where}         = 'COALESCE(inventory_accno_id, 0) ' . ($type eq 'service' ? '=' : '<>') . ' 0';
  73   }
  74
  75   return %filters;
  76 }
  77
  78 sub is_unique {
  79   my $self = shift;
  80
  81   return undef if !$self->number;
  82
  83   my %filters = $self->_get_filters();
  84
  85   my @where;
  86   my @values = ($self->number);
  87
  88   push @where, $filters{where} if $filters{where};
  89
  90   if ($self->id) {
  91     push @where,  qq|id <> ?|;
  92     push @values, conv_i($self->id);
  93   }
  94
  95   my $where_str = @where ? ' AND ' . join(' AND ', map { "($_)" } @where) : '';
  96   my $query     = <<SQL;
  97     SELECT $filters{trans_number}
  98     FROM $filters{table}
  99     WHERE ($filters{trans_number} = ?)
 100       $where_str
 101     LIMIT 1
 102 SQL
 103   my ($existing_number) = selectfirst_array_query($main::form, $self->dbh, $query, @values);
 104
 105   return $existing_number ? 0 : 1;
 106 }
 107
 108 sub create_unique {
 109   my $self    = shift;
 110
 111   my $form    = $main::form;
 112   my %filters = $self->_get_filters();
 113
 114   $self->dbh->begin_work if $self->dbh->{AutoCommit};
 115   do_query($form, $self->dbh, qq|LOCK TABLE defaults|);
 116   do_query($form, $self->dbh, qq|LOCK TABLE business|) if $self->business_id;
 117
 118   my $where = $filters{where} ? ' WHERE ' . $filters{where} : '';
 119   my $query = <<SQL;
 120     SELECT DISTINCT $filters{trans_number}, 1 AS in_use
 121     FROM $filters{table}
 122     $where
 123 SQL
 124
 125   my %numbers_in_use = selectall_as_map($form, $self->dbh, $query, $filters{trans_number}, 'in_use');
 126
 127   my $business_number;
 128   ($business_number) = selectfirst_array_query($form, $self->dbh, qq|SELECT customernumberinit FROM business WHERE id = ?|, $self->business_id) if $self->business_id;
 129   my $number         = $business_number;
 130   ($number)          = selectfirst_array_query($form, $self->dbh, qq|SELECT $filters{numberfield} FROM defaults|)                               if !$number;
 131   $number          ||= '';
 132
 133   do {
 134     if ($number =~ m/\d+$/) {
 135       my $new_number = substr($number, $-[0]) * 1 + 1;
 136       my $len_diff   = length($number) - $-[0] - length($new_number);
 137       $number        = substr($number, 0, $-[0]) . ($len_diff > 0 ? '0' x $len_diff : '') . $new_number;
 138
 139     } else {
 140       $number = $number . '1';
 141     }
 142   } while ($numbers_in_use{$number});
 143
 144   if ($self->save) {
 145     if ($self->business_id && $business_number) {
 146       do_query($form, $self->dbh, qq|UPDATE business SET customernumberinit = ? WHERE id = ?|, $number, $self->business_id);
 147     } else {
 148       do_query($form, $self->dbh, qq|UPDATE defaults SET $filters{numberfield} = ?|, $number);
 149     }
 150     $self->dbh->commit if !$self->dbh_provided;
 151   }
 152
 153   return $number;
 154 }
 155
 156 1;