SL/User.pm

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (C) 2001
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #  Contributors:
  16 #
  17 # This program is free software; you can redistribute it and/or modify
  18 # it under the terms of the GNU General Public License as published by
  19 # the Free Software Foundation; either version 2 of the License, or
  20 # (at your option) any later version.
  21 #
  22 # This program is distributed in the hope that it will be useful,
  23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 # GNU General Public License for more details.
  26 # You should have received a copy of the GNU General Public License
  27 # along with this program; if not, write to the Free Software
  28 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  29 #=====================================================================
  30 #
  31 # user related functions
  32 #
  33 #=====================================================================
  34
  35 package User;
  36
  37 use IO::File;
  38 use Fcntl qw(:seek);
  39
  40 #use SL::Auth;
  41 use SL::DB::AuthClient;
  42 use SL::DBConnect;
  43 use SL::DBUpgrade2;
  44 use SL::DBUtils;
  45 use SL::Iconv;
  46 use SL::Inifile;
  47 use SL::System::InstallationLock;
  48
  49 use strict;
  50
  51 use constant LOGIN_OK                      =>  0;
  52 use constant LOGIN_BASIC_TABLES_MISSING    => -1;
  53 use constant LOGIN_DBUPDATE_AVAILABLE      => -2;
  54 use constant LOGIN_AUTH_DBUPDATE_AVAILABLE => -3;
  55 use constant LOGIN_GENERAL_ERROR           => -4;
  56
  57 sub new {
  58   $main::lxdebug->enter_sub();
  59
  60   my ($type, %params) = @_;
  61
  62   my $self = {};
  63
  64   if ($params{id} || $params{login}) {
  65     my %user_data = $main::auth->read_user(%params);
  66     map { $self->{$_} = $user_data{$_} } keys %user_data;
  67   }
  68
  69   $main::lxdebug->leave_sub();
  70
  71   bless $self, $type;
  72 }
  73
  74 sub country_codes {
  75   $main::lxdebug->enter_sub();
  76
  77   local *DIR;
  78
  79   my %cc       = ();
  80   my @language = ();
  81
  82   # scan the locale directory and read in the LANGUAGE files
  83   opendir(DIR, "locale");
  84
  85   my @dir = grep(!/(^\.\.?$|\..*)/, readdir(DIR));
  86
  87   foreach my $dir (@dir) {
  88     next unless open(my $fh, '<:encoding(UTF-8)', "locale/$dir/LANGUAGE");
  89     @language = <$fh>;
  90     close $fh;
  91
  92     $cc{$dir} = "@language";
  93   }
  94
  95   closedir(DIR);
  96
  97   $main::lxdebug->leave_sub();
  98
  99   return %cc;
 100 }
 101
 102 sub login {
 103   my ($self, $form) = @_;
 104
 105   return LOGIN_GENERAL_ERROR() if !$self->{login} || !$::auth->client;
 106
 107   my %myconfig = $main::auth->read_user(login => $self->{login});
 108
 109   # Auth DB upgrades available?
 110   my $dbupdater_auth = SL::DBUpgrade2->new(form => $form, auth => 1)->parse_dbupdate_controls;
 111   return LOGIN_AUTH_DBUPDATE_AVAILABLE() if $dbupdater_auth->unapplied_upgrade_scripts($::auth->dbconnect);
 112
 113   # check if database is down
 114   my $dbh = $form->dbconnect_noauto;
 115
 116   # we got a connection, check the version
 117   my ($dbversion) = $dbh->selectrow_array(qq|SELECT version FROM defaults|);
 118   if (!$dbversion) {
 119     $dbh->disconnect;
 120     return LOGIN_BASIC_TABLES_MISSING();
 121   }
 122
 123   $self->create_schema_info_table($form, $dbh);
 124
 125   my $dbupdater        = SL::DBUpgrade2->new(form => $form)->parse_dbupdate_controls;
 126   my $update_available = $dbupdater->update2_available($dbh);
 127   $dbh->disconnect;
 128
 129   return LOGIN_OK() if !$update_available;
 130
 131   $form->{$_} = $::auth->client->{$_} for qw(dbname dbhost dbport dbuser dbpasswd);
 132   $form->{$_} = $myconfig{$_}         for qw(datestyle);
 133
 134   $form->{"title"} = $main::locale->text("Dataset upgrade");
 135   $form->header(no_layout => $form->{no_layout});
 136   print $form->parse_html_template("dbupgrade/header");
 137
 138   $form->{dbupdate} = "db" . $::auth->client->{dbname};
 139
 140   if ($form->{"show_dbupdate_warning"}) {
 141     print $form->parse_html_template("dbupgrade/warning");
 142     ::end_of_request();
 143   }
 144
 145   # update the tables
 146   SL::System::InstallationLock->lock;
 147
 148   # ignore HUP, QUIT in case the webserver times out
 149   $SIG{HUP}  = 'IGNORE';
 150   $SIG{QUIT} = 'IGNORE';
 151
 152   $self->dbupdate2(form => $form, updater => $dbupdater, database => $::auth->client->{dbname});
 153
 154   SL::System::InstallationLock->unlock;
 155
 156   print $form->parse_html_template("dbupgrade/footer");
 157
 158   return LOGIN_DBUPDATE_AVAILABLE();
 159 }
 160
 161 sub dbconnect_vars {
 162   $main::lxdebug->enter_sub();
 163
 164   my ($form, $db) = @_;
 165
 166   my %dboptions = (
 167     'yy-mm-dd'   => 'set DateStyle to \'ISO\'',
 168     'yyyy-mm-dd' => 'set DateStyle to \'ISO\'',
 169     'mm/dd/yy'   => 'set DateStyle to \'SQL, US\'',
 170     'dd/mm/yy'   => 'set DateStyle to \'SQL, EUROPEAN\'',
 171     'dd.mm.yy'   => 'set DateStyle to \'GERMAN\''
 172   );
 173
 174   $form->{dboptions} = $dboptions{ $form->{dateformat} };
 175   $form->{dbconnect} = "dbi:Pg:dbname=${db};host=" . ($form->{dbhost} || 'localhost') . ";port=" . ($form->{dbport} || 5432);
 176
 177   $main::lxdebug->leave_sub();
 178 }
 179
 180 sub dbsources {
 181   $main::lxdebug->enter_sub();
 182
 183   my ($self, $form) = @_;
 184
 185   my @dbsources = ();
 186   my ($sth, $query);
 187
 188   $form->{dbdefault} = $form->{dbuser} unless $form->{dbdefault};
 189   &dbconnect_vars($form, $form->{dbdefault});
 190
 191   my $dbh = SL::DBConnect->connect($form->{dbconnect}, $form->{dbuser}, $form->{dbpasswd}, SL::DBConnect->get_options)
 192     or $form->dberror;
 193
 194   $query =
 195     qq|SELECT datname FROM pg_database | .
 196     qq|WHERE NOT datname IN ('template0', 'template1')|;
 197   $sth = $dbh->prepare($query);
 198   $sth->execute() || $form->dberror($query);
 199
 200   while (my ($db) = $sth->fetchrow_array) {
 201
 202     if ($form->{only_acc_db}) {
 203
 204       next if ($db =~ /^template/);
 205
 206       &dbconnect_vars($form, $db);
 207       my $dbh = SL::DBConnect->connect($form->{dbconnect}, $form->{dbuser}, $form->{dbpasswd}, SL::DBConnect->get_options)
 208         or $form->dberror;
 209
 210       $query =
 211         qq|SELECT tablename FROM pg_tables | .
 212         qq|WHERE (tablename = 'defaults') AND (tableowner = ?)|;
 213       my $sth = $dbh->prepare($query);
 214       $sth->execute($form->{dbuser}) ||
 215         $form->dberror($query . " ($form->{dbuser})");
 216
 217       if ($sth->fetchrow_array) {
 218         push(@dbsources, $db);
 219       }
 220       $sth->finish;
 221       $dbh->disconnect;
 222       next;
 223     }
 224     push(@dbsources, $db);
 225   }
 226
 227   $sth->finish;
 228   $dbh->disconnect;
 229
 230   $main::lxdebug->leave_sub();
 231
 232   return @dbsources;
 233 }
 234
 235 sub dbcreate {
 236   $main::lxdebug->enter_sub();
 237
 238   my ($self, $form) = @_;
 239
 240   &dbconnect_vars($form, $form->{dbdefault});
 241   my $dbh =
 242     SL::DBConnect->connect($form->{dbconnect}, $form->{dbuser}, $form->{dbpasswd}, SL::DBConnect->get_options)
 243     or $form->dberror;
 244   $form->{db} =~ s/\"//g;
 245
 246   my @dboptions;
 247
 248   push @dboptions, "ENCODING = " . $dbh->quote($form->{"encoding"}) if $form->{"encoding"};
 249   if ($form->{"dbdefault"}) {
 250     my $dbdefault = $form->{"dbdefault"};
 251     $dbdefault =~ s/[^a-zA-Z0-9_\-]//g;
 252     push @dboptions, "TEMPLATE = $dbdefault";
 253   }
 254
 255   my $query = qq|CREATE DATABASE "$form->{db}"|;
 256   $query   .= " WITH " . join(" ", @dboptions) if @dboptions;
 257
 258   # Ignore errors if the database exists.
 259   $dbh->do($query);
 260
 261   $dbh->disconnect;
 262
 263   &dbconnect_vars($form, $form->{db});
 264
 265   $dbh = SL::DBConnect->connect($form->{dbconnect}, $form->{dbuser}, $form->{dbpasswd}, SL::DBConnect->get_options)
 266     or $form->dberror;
 267
 268   my $dbupdater = SL::DBUpgrade2->new(form => $form);
 269   # create the tables
 270   $dbupdater->process_query($dbh, "sql/lx-office.sql");
 271
 272   # load chart of accounts
 273   $dbupdater->process_query($dbh, "sql/$form->{chart}-chart.sql");
 274
 275   $query = qq|UPDATE defaults SET coa = ?, accounting_method = ?, profit_determination = ?, inventory_system = ?, curr = ?|;
 276   do_query($form, $dbh, $query, map { $form->{$_} } qw(chart accounting_method profit_determination inventory_system defaultcurrency));
 277
 278   $dbh->disconnect;
 279
 280   $main::lxdebug->leave_sub();
 281 }
 282
 283 sub dbdelete {
 284   $main::lxdebug->enter_sub();
 285
 286   my ($self, $form) = @_;
 287   $form->{db} =~ s/\"//g;
 288
 289   &dbconnect_vars($form, $form->{dbdefault});
 290   my $dbh = SL::DBConnect->connect($form->{dbconnect}, $form->{dbuser}, $form->{dbpasswd}, SL::DBConnect->get_options)
 291     or $form->dberror;
 292   my $query = qq|DROP DATABASE "$form->{db}"|;
 293   do_query($form, $dbh, $query);
 294
 295   $dbh->disconnect;
 296
 297   $main::lxdebug->leave_sub();
 298 }
 299
 300 sub calc_version {
 301   $main::lxdebug->enter_sub(2);
 302
 303   my (@v, $version, $i);
 304
 305   @v = split(/\./, $_[0]);
 306   while (scalar(@v) < 4) {
 307     push(@v, 0);
 308   }
 309   $version = 0;
 310   for ($i = 0; $i < 4; $i++) {
 311     $version *= 1000;
 312     $version += $v[$i];
 313   }
 314
 315   $main::lxdebug->leave_sub(2);
 316   return $version;
 317 }
 318
 319 sub cmp_script_version {
 320   my ($a_from, $a_to, $b_from, $b_to);
 321   my ($i, $res_a, $res_b);
 322   my ($my_a, $my_b) = do { no warnings 'once'; ($a, $b) };
 323
 324   $my_a =~ s/.*-upgrade-//;
 325   $my_a =~ s/.sql$//;
 326   $my_b =~ s/.*-upgrade-//;
 327   $my_b =~ s/.sql$//;
 328   my ($my_a_from, $my_a_to) = split(/-/, $my_a);
 329   my ($my_b_from, $my_b_to) = split(/-/, $my_b);
 330
 331   $res_a = calc_version($my_a_from);
 332   $res_b = calc_version($my_b_from);
 333
 334   if ($res_a == $res_b) {
 335     $res_a = calc_version($my_a_to);
 336     $res_b = calc_version($my_b_to);
 337   }
 338
 339   return $res_a <=> $res_b;
 340 }
 341
 342 sub create_schema_info_table {
 343   $main::lxdebug->enter_sub();
 344
 345   my ($self, $form, $dbh) = @_;
 346
 347   my $query = "SELECT tag FROM schema_info LIMIT 1";
 348   if (!$dbh->do($query)) {
 349     $dbh->rollback();
 350     $query =
 351       qq|CREATE TABLE schema_info (| .
 352       qq|  tag text, | .
 353       qq|  login text, | .
 354       qq|  itime timestamp DEFAULT now(), | .
 355       qq|  PRIMARY KEY (tag))|;
 356     $dbh->do($query) || $form->dberror($query);
 357   }
 358
 359   $main::lxdebug->leave_sub();
 360 }
 361
 362 sub dbupdate2 {
 363   $main::lxdebug->enter_sub();
 364
 365   my ($self, %params) = @_;
 366
 367   my $form            = $params{form};
 368   my $dbupdater       = $params{updater};
 369   my $db              = $params{database};
 370   my $rc              = -2;
 371
 372   map { $_->{description} = SL::Iconv::convert($_->{charset}, 'UTF-8', $_->{description}) } values %{ $dbupdater->{all_controls} };
 373
 374   &dbconnect_vars($form, $db);
 375
 376   my $dbh = SL::DBConnect->connect($form->{dbconnect}, $form->{dbuser}, $form->{dbpasswd}, SL::DBConnect->get_options) or $form->dberror;
 377
 378   $dbh->do($form->{dboptions}) if ($form->{dboptions});
 379
 380   $self->create_schema_info_table($form, $dbh);
 381
 382   my @upgradescripts = $dbupdater->unapplied_upgrade_scripts($dbh);
 383
 384   $dbh->disconnect and next if !@upgradescripts;
 385
 386   foreach my $control (@upgradescripts) {
 387     # apply upgrade
 388     $main::lxdebug->message(LXDebug->DEBUG2(), "Applying Update $control->{file}");
 389     print $form->parse_html_template("dbupgrade/upgrade_message2", $control);
 390
 391     $dbupdater->process_file($dbh, "sql/Pg-upgrade2/$control->{file}", $control);
 392   }
 393
 394   $rc = 0;
 395   $dbh->disconnect;
 396
 397   $main::lxdebug->leave_sub();
 398
 399   return $rc;
 400 }
 401
 402 sub data {
 403   +{ %{ $_[0] } }
 404 }
 405
 406 1;