SL/WH.pm

   1 #====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (C) 1999-2003
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #  Contributors:
  16 #
  17 # This program is free software; you can redistribute it and/or modify
  18 # it under the terms of the GNU General Public License as published by
  19 # the Free Software Foundation; either version 2 of the License, or
  20 # (at your option) any later version.
  21 #
  22 # This program is distributed in the hope that it will be useful,
  23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 # GNU General Public License for more details.
  26 # You should have received a copy of the GNU General Public License
  27 # along with this program; if not, write to the Free Software
  28 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  29 #======================================================================
  30 #
  31 #  Warehouse module
  32 #
  33 #======================================================================
  34
  35 package WH;
  36
  37 use SL::AM;
  38 use SL::DBUtils;
  39 use SL::Form;
  40
  41 use warnings;
  42 use strict;
  43
  44 sub transfer {
  45   $::lxdebug->enter_sub;
  46
  47   my ($self, @args) = @_;
  48
  49   if (!@args) {
  50     $::lxdebug->leave_sub;
  51     return;
  52   }
  53
  54   require SL::DB::TransferType;
  55   require SL::DB::Part;
  56   require SL::DB::Employee;
  57   require SL::DB::Inventory;
  58   my $employee   = SL::DB::Manager::Employee->find_by(login => $::form->{login});
  59   my ($now)      = selectrow_query($::form, $::form->get_standard_dbh, qq|SELECT current_date|);
  60   my @directions = (undef, qw(out in transfer));
  61   my $db         = SL::DB->create(undef, 'LXOFFICE');
  62
  63   for my $transfer (@args) {
  64     my ($trans_id) = selectrow_query($::form, $::form->get_standard_dbh, qq|SELECT nextval('id')|);
  65
  66     my $direction = 0;
  67     $direction |= 1 if ($transfer->{src_warehouse_id} && $transfer->{src_bin_id});
  68     $direction |= 2 if ($transfer->{dst_warehouse_id} && $transfer->{dst_bin_id});
  69
  70     $transfer->{trans_type_id} = $transfer->{transfer_type_id} || SL::DB::Manager::TransferType->find_by(
  71       direction   => $directions[$direction],
  72       description => $transfer->{transfer_type},
  73     )->id;
  74
  75     my %params = (
  76         shippingdate     => !$transfer->{shippingdate} || $transfer->{shippingdate} eq 'current_date' ? $now : $transfer->{shippingdate},
  77         employee         => $employee,
  78         trans_id         => $trans_id,
  79         map { $_ => $transfer->{$_} } qw(
  80           parts_id chargenumber bestbefore oe_id orderitems_id project_id comment trans_type_id),
  81     );
  82
  83     my $qty = $transfer->{qty};
  84
  85     if ($transfer->{unit}) {
  86       my $part          = SL::DB::Manager::Part->find_by(id => $transfer->{parts_id});
  87       my $transfer_unit = SL::DB::Manager::Unit->find_by(name => $transfer->{unit});
  88
  89       $qty *= $transfer_unit->factor;
  90       $qty /= $part->unit_obj->factor || 1 if $part->unit;
  91     }
  92
  93     if ($direction & 1) {
  94       SL::DB::Inventory->new(
  95         %params,
  96         warehouse_id => $transfer->{src_warehouse_id},
  97         bin_id       => $transfer->{src_bin_id},
  98         qty          => $qty * -1
  99       )->save;
 100     }
 101
 102     if ($direction & 2) {
 103       SL::DB::Inventory->new(
 104         %params,
 105         warehouse_id => $transfer->{dst_warehouse_id},
 106         bin_id       => $transfer->{dst_bin_id},
 107         qty          => $qty
 108       )->save;
 109     }
 110   }
 111
 112   $db->commit;
 113
 114   $::lxdebug->leave_sub;
 115 }
 116
 117 sub transfer_assembly {
 118   $main::lxdebug->enter_sub();
 119
 120   my $self     = shift;
 121   my %params   = @_;
 122   Common::check_params(\%params, qw(assembly_id dst_warehouse_id login qty unit dst_bin_id chargenumber bestbefore comment));
 123
 124 #  my $maxcreate=WH->check_assembly_max_create(assembly_id =>$params{'assembly_id'}, dbh => $my_dbh);
 125
 126   my $myconfig = \%main::myconfig;
 127   my $form     = $main::form;
 128   my $dbh      = $params{dbh} || $form->get_standard_dbh($myconfig);
 129
 130
 131   # Ablauferklärung
 132   #
 133   # ... Standard-Check oben Ende. Hier die eigentliche SQL-Abfrage
 134   # select parts_id,qty from assembly where id=1064;
 135   # Erweiterung für bug 935 am 23.4.09 -
 136   # Erzeugnisse können Dienstleistungen enthalten, die ja nicht 'lagerbar' sind.
 137   # select parts_id,qty from assembly inner join parts on assembly.parts_id = parts.id
 138   # where assembly.id=1066 and inventory_accno_id IS NOT NULL;
 139   #
 140   # Erweiterung für bug 23.4.09 -2 Erzeugnisse in Erzeugnissen können nicht ausgelagert werden,
 141   # wenn assembly nicht überprüft wird ...
 142   # patch von joachim eingespielt 24.4.2009:
 143   # my $query    = qq|select parts_id,qty from assembly inner join parts
 144   # on assembly.parts_id = parts.id  where assembly.id = ? and
 145   # (inventory_accno_id IS NOT NULL or parts.assembly = TRUE)|;
 146
 147
 148   my $query = qq|select parts_id,qty from assembly inner join parts on assembly.parts_id = parts.id
 149                   where assembly.id = ? and (inventory_accno_id IS NOT NULL or parts.assembly = TRUE)|;
 150
 151   my $sth_part_qty_assembly = prepare_execute_query($form, $dbh, $query, $params{assembly_id});
 152
 153   # Hier wird das prepared Statement für die Schleife über alle Lagerplätze vorbereitet
 154   my $transferPartSQL = qq|INSERT INTO inventory (parts_id, warehouse_id, bin_id, chargenumber, bestbefore, comment, employee_id, qty, trans_id, trans_type_id)
 155                            VALUES (?, ?, ?, ?, ?, ?, (SELECT id FROM employee WHERE login = ?), ?, nextval('id'),
 156                            (SELECT id FROM transfer_type WHERE direction = 'out' AND description = 'used'))|;
 157   my $sthTransferPartSQL   = prepare_query($form, $dbh, $transferPartSQL);
 158
 159   # der return-string für die fehlermeldung inkl. welche waren zum fertigen noch fehlen
 160
 161   my $kannNichtFertigen ="";  # Falls leer dann erfolgreich
 162   my $schleife_durchlaufen=0; # Falls die Schleife nicht ausgeführt wird -> Keine Einzelteile definiert. Bessere Idee? jan
 163   while (my $hash_ref = $sth_part_qty_assembly->fetchrow_hashref()) { #Schleife für select parts_id,(...) from assembly
 164     $schleife_durchlaufen=1;  # Erzeugnis definiert
 165     my $partsQTY = $hash_ref->{qty} * $params{qty}; # benötigte teile * anzahl erzeugnisse
 166     my $currentPart_ID = $hash_ref->{parts_id};
 167
 168     # Überprüfen, ob diese Anzahl gefertigt werden kann
 169     my $max_parts = $self->get_max_qty_parts(parts_id => $currentPart_ID, # $self->method() == this.method()
 170                                              warehouse_id => $params{dst_warehouse_id});
 171
 172     if ($partsQTY  > $max_parts){
 173       # Gibt es hier ein Problem mit nicht "escapten" Zeichen?
 174       # 25.4.09 Antwort: Ja.  Aber erst wenn im Frontend die locales-Funktion aufgerufen wird
 175
 176       $kannNichtFertigen .= "Zum Fertigen fehlen:" . abs($partsQTY - $max_parts) .
 177                             " Einheiten der Ware:" . $self->get_part_description(parts_id => $currentPart_ID) .
 178                             ", um das Erzeugnis herzustellen. <br>"; # Konnte die Menge nicht mit der aktuellen Anzahl der Waren fertigen
 179       next; # die weiteren Überprüfungen sind unnötig, daher das nächste elemente prüfen (genaue Ausgabe, was noch fehlt)
 180     }
 181
 182     # Eine kurze Vorabfrage, um den Lagerplatz, Chargennummer und die Mindesthaltbarkeit zu bestimmen
 183     # Offen: Die Summe über alle Lagerplätze wird noch nicht gebildet
 184     # Gelöst: Wir haben vorher schon die Abfrage durchgeführt, ob wir fertigen können.
 185     # Noch besser gelöst: Wir laufen durch alle benötigten Waren zum Fertigen und geben eine Rückmeldung an den Benutzer was noch fehlt
 186     # und lösen den Rest dann so wie bei xplace im Barcode-Programm
 187     # S.a. Kommentar im bin/mozilla-Code mb übernimmt und macht das in ordentlich
 188
 189     my $tempquery = qq|SELECT SUM(qty), bin_id, chargenumber, bestbefore   FROM inventory
 190                        WHERE warehouse_id = ? AND parts_id = ?  GROUP BY bin_id, chargenumber, bestbefore having SUM(qty)>0|;
 191     my $tempsth   = prepare_execute_query($form, $dbh, $tempquery, $params{dst_warehouse_id}, $currentPart_ID);
 192
 193     # Alle Werte zu dem einzelnen Artikel, die wir später auslagern
 194     my $tmpPartsQTY = $partsQTY;
 195
 196     while (my $temphash_ref = $tempsth->fetchrow_hashref()) {
 197       my $temppart_bin_id       = $temphash_ref->{bin_id}; # kann man hier den quelllagerplatz beim verbauen angeben?
 198       my $temppart_chargenumber = $temphash_ref->{chargenumber};
 199       my $temppart_bestbefore   = conv_date($temphash_ref->{bestbefore});
 200       my $temppart_qty          = $temphash_ref->{sum};
 201
 202       if ($tmpPartsQTY > $temppart_qty) {  # wir haben noch mehr waren zum wegbuchen.
 203                                            # Wir buchen den kompletten Lagerplatzbestand und zählen die Hilfsvariable runter
 204         $tmpPartsQTY = $tmpPartsQTY - $temppart_qty;
 205         $temppart_qty = $temppart_qty * -1; # TODO beim analyiseren des sql-trace, war dieser wert positiv,
 206                                             # wenn * -1 als berechnung in der parameter-übergabe angegeben wird.
 207                                             # Dieser Wert IST und BLEIBT positiv!! Hilfe.
 208                                             # Liegt das daran, dass dieser Wert aus einem SQL-Statement stammt?
 209         do_statement($form, $sthTransferPartSQL, $transferPartSQL, $currentPart_ID, $params{dst_warehouse_id},
 210                      $temppart_bin_id, $temppart_chargenumber, $temppart_bestbefore, 'Verbraucht für ' .
 211                      $self->get_part_description(parts_id => $params{assembly_id}), $params{login}, $temppart_qty);
 212
 213         # hier ist noch ein fehler am besten mit definierten erzeugnissen debuggen 02/2009 jb
 214         # idee: ausbuch algorithmus mit rekursion lösen und an- und abschaltbar machen
 215         # das problem könnte sein, dass strict nicht an war und sth global eine andere zuweisung bekam
 216         # auf jeden fall war der internal-server-error nach aktivierung von strict und warnings plus ein paar my-definitionen weg
 217       } else { # okay, wir haben weniger oder gleich Waren die wir wegbuchen müssen, wir können also aufhören
 218         $tmpPartsQTY *=-1;
 219         do_statement($form, $sthTransferPartSQL, $transferPartSQL, $currentPart_ID, $params{dst_warehouse_id},
 220                      $temppart_bin_id, $temppart_chargenumber, $temppart_bestbefore, 'Verbraucht für ' .
 221                      $self->get_part_description(parts_id => $params{assembly_id}), $params{login}, $tmpPartsQTY);
 222         last; # beendet die schleife (springt zum letzten element)
 223       }
 224     }  # ende while SELECT SUM(qty), bin_id, chargenumber, bestbefore   FROM inventory  WHERE warehouse_id
 225   } #ende while select parts_id,qty from assembly where id = ?
 226
 227   if ($schleife_durchlaufen==0){  # falls die schleife nicht durchlaufen wurde, wurden auch
 228                                   # keine einzelteile definiert
 229       $kannNichtFertigen ="Für dieses Erzeugnis sind keine Einzelteile definiert.
 230                            Dementsprechend kann auch nichts hergestellt werden";
 231  }
 232   # gibt die Fehlermeldung zurück. A.) Keine Teile definiert
 233   #                                B.) Artikel und Anzahl der fehlenden Teile/Dienstleistungen
 234   if ($kannNichtFertigen) {
 235     return $kannNichtFertigen;
 236   }
 237
 238   # soweit alles gut. Jetzt noch die wirkliche Lagerbewegung für das Erzeugnis ausführen ...
 239   my $transferAssemblySQL = qq|INSERT INTO inventory (parts_id, warehouse_id, bin_id, chargenumber, bestbefore,
 240                                                       comment, employee_id, qty, trans_id, trans_type_id)
 241                                VALUES (?, ?, ?, ?, ?, ?, (SELECT id FROM employee WHERE login = ?), ?, nextval('id'),
 242                                (SELECT id FROM transfer_type WHERE direction = 'in' AND description = 'stock'))|;
 243   my $sthTransferAssemblySQL   = prepare_query($form, $dbh, $transferAssemblySQL);
 244   do_statement($form, $sthTransferAssemblySQL, $transferAssemblySQL, $params{assembly_id}, $params{dst_warehouse_id},
 245                $params{dst_bin_id}, $params{chargenumber}, conv_date($params{bestbefore}), $params{comment}, $params{login}, $params{qty});
 246   $dbh->commit();
 247
 248   $main::lxdebug->leave_sub();
 249   return 1; # Alles erfolgreich
 250 }
 251
 252 sub get_warehouse_journal {
 253   $main::lxdebug->enter_sub();
 254
 255   my $self      = shift;
 256   my %filter    = @_;
 257
 258   my $myconfig  = \%main::myconfig;
 259   my $form      = $main::form;
 260
 261   my $all_units = AM->retrieve_units($myconfig, $form);
 262
 263   # connect to database
 264   my $dbh = $form->get_standard_dbh($myconfig);
 265
 266   # filters
 267   my (@filter_ary, @filter_vars, $joins, %select_tokens, %select);
 268
 269   if ($filter{warehouse_id}) {
 270     push @filter_ary, "w1.id = ? OR w2.id = ?";
 271     push @filter_vars, $filter{warehouse_id}, $filter{warehouse_id};
 272   }
 273
 274   if ($filter{bin_id}) {
 275     push @filter_ary, "b1.id = ? OR b2.id = ?";
 276     push @filter_vars, $filter{bin_id}, $filter{bin_id};
 277   }
 278
 279   if ($filter{partnumber}) {
 280     push @filter_ary, "p.partnumber ILIKE ?";
 281     push @filter_vars, '%' . $filter{partnumber} . '%';
 282   }
 283
 284   if ($filter{description}) {
 285     push @filter_ary, "(p.description ILIKE ?)";
 286     push @filter_vars, '%' . $filter{description} . '%';
 287   }
 288
 289   if ($filter{chargenumber}) {
 290     push @filter_ary, "i1.chargenumber ILIKE ?";
 291     push @filter_vars, '%' . $filter{chargenumber} . '%';
 292   }
 293
 294   if ($form->{bestbefore}) {
 295     push @filter_ary, "?::DATE = i1.bestbefore::DATE";
 296     push @filter_vars, $form->{bestbefore};
 297   }
 298
 299   if ($form->{fromdate}) {
 300     push @filter_ary, "?::DATE <= i1.itime::DATE";
 301     push @filter_vars, $form->{fromdate};
 302   }
 303
 304   if ($form->{todate}) {
 305     push @filter_ary, "?::DATE >= i1.itime::DATE";
 306     push @filter_vars, $form->{todate};
 307   }
 308
 309   if ($form->{l_employee}) {
 310     $joins .= "";
 311   }
 312
 313   # prepare qty comparison for later filtering
 314   my ($f_qty_op, $f_qty, $f_qty_base_unit);
 315   if ($filter{qty_op} && defined($filter{qty}) && $filter{qty_unit} && $all_units->{$filter{qty_unit}}) {
 316     $f_qty_op        = $filter{qty_op};
 317     $f_qty           = $filter{qty} * $all_units->{$filter{qty_unit}}->{factor};
 318     $f_qty_base_unit = $all_units->{$filter{qty_unit}}->{base_unit};
 319   }
 320
 321   map { $_ = "(${_})"; } @filter_ary;
 322
 323   # if of a property number or description is requested,
 324   # automatically check the matching id too.
 325   map { $form->{"l_${_}id"} = "Y" if ($form->{"l_${_}description"} || $form->{"l_${_}number"}); } qw(warehouse bin);
 326
 327   # customize shown entry for not available fields.
 328   $filter{na} = '-' unless $filter{na};
 329
 330   # make order, search in $filter and $form
 331   my $sort_col   = $form->{sort};
 332   my $sort_order = $form->{order};
 333
 334   $sort_col      = $filter{sort}         unless $sort_col;
 335   $sort_order    = ($sort_col = 'itime') unless $sort_col;
 336   $sort_col      = 'itime'               if     $sort_col eq 'date';
 337   $sort_order    = $filter{order}        unless $sort_order;
 338   my $sort_spec  = "${sort_col} " . ($sort_order ? " DESC" : " ASC");
 339
 340   my $where_clause = @filter_ary ? join(" AND ", @filter_ary) . " AND " : '';
 341
 342   $select_tokens{'trans'} = {
 343      "parts_id"             => "i1.parts_id",
 344      "qty"                  => "ABS(SUM(i1.qty))",
 345      "partnumber"           => "p.partnumber",
 346      "partdescription"      => "p.description",
 347      "bindescription"       => "b.description",
 348      "chargenumber"         => "i1.chargenumber",
 349      "bestbefore"           => "i1.bestbefore",
 350      "warehousedescription" => "w.description",
 351      "partunit"             => "p.unit",
 352      "bin_from"             => "b1.description",
 353      "bin_to"               => "b2.description",
 354      "warehouse_from"       => "w1.description",
 355      "warehouse_to"         => "w2.description",
 356      "comment"              => "i1.comment",
 357      "trans_type"           => "tt.description",
 358      "trans_id"             => "i1.trans_id",
 359      "oe_id"                => "COALESCE(i1.oe_id, i2.oe_id)",
 360      "date"                 => "i1.itime::DATE",
 361      "itime"                => "i1.itime",
 362      "employee"             => "e.name",
 363      "projectnumber"        => "COALESCE(pr.projectnumber, '$filter{na}')",
 364      };
 365
 366   $select_tokens{'out'} = {
 367      "bin_to"               => "'$filter{na}'",
 368      "warehouse_to"         => "'$filter{na}'",
 369      };
 370
 371   $select_tokens{'in'} = {
 372      "bin_from"             => "'$filter{na}'",
 373      "warehouse_from"       => "'$filter{na}'",
 374      };
 375
 376   # build the select clauses.
 377   # take all the requested ones from the first hash and overwrite them from the out/in hashes if present.
 378   for my $i ('trans', 'out', 'in') {
 379     $select{$i} = join ', ', map { +/^l_/; ($select_tokens{$i}{"$'"} || $select_tokens{'trans'}{"$'"}) . " AS r_$'" }
 380           ( grep( { !/qty$/ and /^l_/ and $form->{$_} eq 'Y' } keys %$form), qw(l_parts_id l_qty l_partunit l_itime) );
 381   }
 382
 383   my $group_clause = join ", ", map { +/^l_/; "r_$'" }
 384         ( grep( { !/qty$/ and /^l_/ and $form->{$_} eq 'Y' } keys %$form), qw(l_parts_id l_partunit l_itime) );
 385
 386   $where_clause = defined($where_clause) ? $where_clause : '';
 387   my $query =
 388   qq|SELECT DISTINCT $select{trans}
 389     FROM inventory i1
 390     LEFT JOIN inventory i2 ON i1.trans_id = i2.trans_id
 391     LEFT JOIN parts p ON i1.parts_id = p.id
 392     LEFT JOIN bin b1 ON i1.bin_id = b1.id
 393     LEFT JOIN bin b2 ON i2.bin_id = b2.id
 394     LEFT JOIN warehouse w1 ON i1.warehouse_id = w1.id
 395     LEFT JOIN warehouse w2 ON i2.warehouse_id = w2.id
 396     LEFT JOIN transfer_type tt ON i1.trans_type_id = tt.id
 397     LEFT JOIN project pr ON i1.project_id = pr.id
 398     LEFT JOIN employee e ON i1.employee_id = e.id
 399     WHERE $where_clause i2.qty = -i1.qty AND i2.qty > 0 AND
 400           i1.trans_id IN ( SELECT i.trans_id FROM inventory i GROUP BY i.trans_id HAVING COUNT(i.trans_id) = 2 )
 401     GROUP BY $group_clause
 402
 403     UNION
 404
 405     SELECT DISTINCT $select{out}
 406     FROM inventory i1
 407     LEFT JOIN inventory i2 ON i1.trans_id = i2.trans_id
 408     LEFT JOIN parts p ON i1.parts_id = p.id
 409     LEFT JOIN bin b1 ON i1.bin_id = b1.id
 410     LEFT JOIN bin b2 ON i2.bin_id = b2.id
 411     LEFT JOIN warehouse w1 ON i1.warehouse_id = w1.id
 412     LEFT JOIN warehouse w2 ON i2.warehouse_id = w2.id
 413     LEFT JOIN transfer_type tt ON i1.trans_type_id = tt.id
 414     LEFT JOIN project pr ON i1.project_id = pr.id
 415     LEFT JOIN employee e ON i1.employee_id = e.id
 416     WHERE $where_clause i1.qty < 0 AND
 417           i1.trans_id IN ( SELECT i.trans_id FROM inventory i GROUP BY i.trans_id HAVING COUNT(i.trans_id) = 1 )
 418     GROUP BY $group_clause
 419
 420     UNION
 421
 422     SELECT DISTINCT $select{in}
 423     FROM inventory i1
 424     LEFT JOIN inventory i2 ON i1.trans_id = i2.trans_id
 425     LEFT JOIN parts p ON i1.parts_id = p.id
 426     LEFT JOIN bin b1 ON i1.bin_id = b1.id
 427     LEFT JOIN bin b2 ON i2.bin_id = b2.id
 428     LEFT JOIN warehouse w1 ON i1.warehouse_id = w1.id
 429     LEFT JOIN warehouse w2 ON i2.warehouse_id = w2.id
 430     LEFT JOIN transfer_type tt ON i1.trans_type_id = tt.id
 431     LEFT JOIN project pr ON i1.project_id = pr.id
 432     LEFT JOIN employee e ON i1.employee_id = e.id
 433     WHERE $where_clause i1.qty > 0 AND
 434           i1.trans_id IN ( SELECT i.trans_id FROM inventory i GROUP BY i.trans_id HAVING COUNT(i.trans_id) = 1 )
 435     GROUP BY $group_clause
 436     ORDER BY r_${sort_spec}|;
 437
 438   my $sth = prepare_execute_query($form, $dbh, $query, @filter_vars, @filter_vars, @filter_vars);
 439
 440   my ($h_oe_id, $q_oe_id);
 441   if ($form->{l_oe_id}) {
 442     $q_oe_id = <<SQL;
 443       SELECT oe.id AS id,
 444         CASE WHEN oe.quotation THEN oe.quonumber ELSE oe.ordnumber END AS number,
 445         CASE
 446           WHEN oe.customer_id IS NOT NULL AND     COALESCE(oe.quotation, FALSE) THEN 'sales_quotation'
 447           WHEN oe.customer_id IS NOT NULL AND NOT COALESCE(oe.quotation, FALSE) THEN 'sales_order'
 448           WHEN oe.customer_id IS     NULL AND     COALESCE(oe.quotation, FALSE) THEN 'request_quotation'
 449           ELSE                                                                       'purchase_order'
 450         END AS type
 451       FROM oe
 452       WHERE oe.id = ?
 453
 454       UNION
 455
 456       SELECT dord.id AS id, dord.donumber AS number,
 457         CASE
 458           WHEN dord.customer_id IS NULL THEN 'purchase_delivery_order'
 459           ELSE                               'sales_delivery_order'
 460         END AS type
 461       FROM delivery_orders dord
 462       WHERE dord.id = ?
 463
 464       UNION
 465
 466       SELECT ar.id AS id, ar.invnumber AS number, 'sales_invoice' AS type
 467       FROM ar
 468       WHERE ar.id = ?
 469
 470       UNION
 471
 472       SELECT ap.id AS id, ap.invnumber AS number, 'purchase_invoice' AS type
 473       FROM ap
 474       WHERE ap.id = ?
 475 SQL
 476     $h_oe_id = prepare_query($form, $dbh, $q_oe_id);
 477   }
 478
 479   my @contents = ();
 480   while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 481     map { /^r_/; $ref->{"$'"} = $ref->{$_} } keys %$ref;
 482     my $qty = $ref->{"qty"} * 1;
 483
 484     next unless ($qty > 0);
 485
 486     if ($f_qty_op) {
 487       my $part_unit = $all_units->{$ref->{"partunit"}};
 488       next unless ($part_unit && ($part_unit->{"base_unit"} eq $f_qty_base_unit));
 489       $qty *= $part_unit->{"factor"};
 490       next if (('=' eq $f_qty_op) && ($qty != $f_qty));
 491       next if (('>=' eq $f_qty_op) && ($qty < $f_qty));
 492       next if (('<=' eq $f_qty_op) && ($qty > $f_qty));
 493     }
 494
 495     if ($h_oe_id && $ref->{oe_id}) {
 496       do_statement($form, $h_oe_id, $q_oe_id, ($ref->{oe_id}) x 4);
 497       $ref->{oe_id_info} = $h_oe_id->fetchrow_hashref() || {};
 498     }
 499
 500     push @contents, $ref;
 501   }
 502
 503   $sth->finish();
 504   $h_oe_id->finish() if $h_oe_id;
 505
 506   $main::lxdebug->leave_sub();
 507
 508   return @contents;
 509 }
 510
 511 #
 512 # This sub is the primary function to retrieve information about items in warehouses.
 513 # $filter is a hashref and supports the following keys:
 514 #  - warehouse_id - will return matches with this warehouse_id only
 515 #  - partnumber   - will return only matches where the given string is a substring of the partnumber
 516 #  - partsid      - will return matches with this parts_id only
 517 #  - description  - will return only matches where the given string is a substring of the description
 518 #  - chargenumber - will return only matches where the given string is a substring of the chargenumber
 519 #  - bestbefore   - will return only matches with this bestbefore date
 520 #  - ean          - will return only matches where the given string is a substring of the ean as stored in the table parts (article)
 521 #  - charge_ids   - must be an arrayref. will return contents with these ids only
 522 #  - expires_in   - will only return matches that expire within the given number of days
 523 #                   will also add a column named 'has_expired' containing if the match has already expired or not
 524 #  - hazardous    - will return matches with the flag hazardous only
 525 #  - oil          - will return matches with the flag oil only
 526 #  - qty, qty_op  - quantity filter (more info to come)
 527 #  - sort, order_by - sorting (more to come)
 528 #  - reservation  - will provide an extra column containing the amount reserved of this match
 529 # note: reservation flag turns off warehouse_* or bin_* information. both together don't make sense, since reserved info is stored separately
 530 #
 531 sub get_warehouse_report {
 532   $main::lxdebug->enter_sub();
 533
 534   my $self      = shift;
 535   my %filter    = @_;
 536
 537   my $myconfig  = \%main::myconfig;
 538   my $form      = $main::form;
 539
 540   my $all_units = AM->retrieve_units($myconfig, $form);
 541
 542   # connect to database
 543   my $dbh = $form->get_standard_dbh($myconfig);
 544
 545   # filters
 546   my (@filter_ary, @filter_vars, @wh_bin_filter_ary, @wh_bin_filter_vars);
 547
 548   delete $form->{include_empty_bins} unless ($form->{l_warehousedescription} || $form->{l_bindescription});
 549
 550   if ($filter{warehouse_id}) {
 551     push @wh_bin_filter_ary,  "w.id = ?";
 552     push @wh_bin_filter_vars, $filter{warehouse_id};
 553   }
 554
 555   if ($filter{bin_id}) {
 556     push @wh_bin_filter_ary,  "b.id = ?";
 557     push @wh_bin_filter_vars, $filter{bin_id};
 558   }
 559
 560   push @filter_ary,  @wh_bin_filter_ary;
 561   push @filter_vars, @wh_bin_filter_vars;
 562
 563   if ($filter{partnumber}) {
 564     push @filter_ary,  "p.partnumber ILIKE ?";
 565     push @filter_vars, '%' . $filter{partnumber} . '%';
 566   }
 567
 568   if ($filter{description}) {
 569     push @filter_ary,  "p.description ILIKE ?";
 570     push @filter_vars, '%' . $filter{description} . '%';
 571   }
 572
 573   if ($filter{partsid}) {
 574     push @filter_ary,  "p.id = ?";
 575     push @filter_vars, $filter{partsid};
 576   }
 577
 578   if ($filter{chargenumber}) {
 579     push @filter_ary,  "i.chargenumber ILIKE ?";
 580     push @filter_vars, '%' . $filter{chargenumber} . '%';
 581   }
 582
 583   if ($form->{bestbefore}) {
 584     push @filter_ary, "?::DATE = i.bestbefore::DATE";
 585     push @filter_vars, $form->{bestbefore};
 586   }
 587
 588   if ($filter{ean}) {
 589     push @filter_ary,  "p.ean ILIKE ?";
 590     push @filter_vars, '%' . $filter{ean} . '%';
 591   }
 592
 593   # prepare qty comparison for later filtering
 594   my ($f_qty_op, $f_qty, $f_qty_base_unit);
 595
 596   if ($filter{qty_op} && defined $filter{qty} && $filter{qty_unit} && $all_units->{$filter{qty_unit}}) {
 597     $f_qty_op        = $filter{qty_op};
 598     $f_qty           = $filter{qty} * $all_units->{$filter{qty_unit}}->{factor};
 599     $f_qty_base_unit = $all_units->{$filter{qty_unit}}->{base_unit};
 600   }
 601
 602   map { $_ = "(${_})"; } @filter_ary;
 603
 604   # if of a property number or description is requested,
 605   # automatically check the matching id too.
 606   map { $form->{"l_${_}id"} = "Y" if ($form->{"l_${_}description"} || $form->{"l_${_}number"}); } qw(warehouse bin);
 607
 608   # make order, search in $filter and $form
 609   my $sort_col    =  $form->{sort};
 610   my $sort_order  = $form->{order};
 611
 612   $sort_col       =  $filter{sort}  unless $sort_col;
 613   # falls $sort_col gar nicht in dem Bericht aufgenommen werden soll,
 614   # führt ein entsprechenes order by $sort_col zu einem SQL-Fehler
 615   # entsprechend parts_id als default lassen, wenn $sort_col UND l_$sort_col
 616   # vorhanden sind (bpsw. l_partnumber = 'Y', für in Bericht aufnehmen).
 617   # S.a. Bug 1597 jb 12.5.2011
 618   $sort_col       =  "parts_id"     unless ($sort_col && $form->{"l_$sort_col"});
 619   $sort_order     =  $filter{order} unless $sort_order;
 620   $sort_col       =~ s/ASC|DESC//; # kill stuff left in from previous queries
 621   my $orderby     =  $sort_col;
 622   my $sort_spec   =  "${sort_col} " . ($sort_order ? " DESC" : " ASC");
 623
 624   my $where_clause = join " AND ", ("1=1", @filter_ary);
 625
 626   my %select_tokens = (
 627      "parts_id"              => "i.parts_id",
 628      "qty"                  => "SUM(i.qty)",
 629      "warehouseid"          => "i.warehouse_id",
 630      "partnumber"           => "p.partnumber",
 631      "partdescription"      => "p.description",
 632      "bindescription"       => "b.description",
 633      "binid"                => "b.id",
 634      "chargenumber"         => "i.chargenumber",
 635      "bestbefore"           => "i.bestbefore",
 636      "ean"                  => "p.ean",
 637      "chargeid"             => "c.id",
 638      "warehousedescription" => "w.description",
 639      "partunit"             => "p.unit",
 640      "stock_value"          => "p.lastcost / COALESCE(pfac.factor, 1)",
 641   );
 642   my $select_clause = join ', ', map { +/^l_/; "$select_tokens{$'} AS $'" }
 643         ( grep( { !/qty/ and /^l_/ and $form->{$_} eq 'Y' } keys %$form),
 644           qw(l_parts_id l_qty l_partunit) );
 645
 646   my $group_clause = join ", ", map { +/^l_/; "$'" }
 647         ( grep( { !/qty/ and /^l_/ and $form->{$_} eq 'Y' } keys %$form),
 648           qw(l_parts_id l_partunit) );
 649
 650   my %join_tokens = (
 651     "stock_value" => "LEFT JOIN price_factors pfac ON (p.price_factor_id = pfac.id)",
 652     );
 653
 654   my $joins = join ' ', grep { $_ } map { +/^l_/; $join_tokens{"$'"} }
 655         ( grep( { !/qty/ and /^l_/ and $form->{$_} eq 'Y' } keys %$form),
 656           qw(l_parts_id l_qty l_partunit) );
 657
 658   my $query =
 659     qq|SELECT $select_clause
 660       FROM inventory i
 661       LEFT JOIN parts     p ON i.parts_id     = p.id
 662       LEFT JOIN bin       b ON i.bin_id       = b.id
 663       LEFT JOIN warehouse w ON i.warehouse_id = w.id
 664       $joins
 665       WHERE $where_clause
 666       GROUP BY $group_clause
 667       ORDER BY $sort_spec|;
 668
 669   my $sth = prepare_execute_query($form, $dbh, $query, @filter_vars);
 670
 671   my (%non_empty_bins, @all_fields, @contents);
 672
 673   while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 674     $ref->{qty} *= 1;
 675     my $qty      = $ref->{qty};
 676
 677     next unless ($qty != 0);
 678
 679     if ($f_qty_op) {
 680       my $part_unit = $all_units->{$ref->{partunit}};
 681       next if (!$part_unit || ($part_unit->{base_unit} ne $f_qty_base_unit));
 682       $qty *= $part_unit->{factor};
 683       next if (('='  eq $f_qty_op) && ($qty != $f_qty));
 684       next if (('>=' eq $f_qty_op) && ($qty <  $f_qty));
 685       next if (('<=' eq $f_qty_op) && ($qty >  $f_qty));
 686     }
 687
 688     if ($form->{include_empty_bins}) {
 689       $non_empty_bins{$ref->{binid}} = 1;
 690       @all_fields                    = keys %{ $ref } unless (@all_fields);
 691     }
 692
 693     $ref->{stock_value} = ($ref->{stock_value} || 0) * $ref->{qty};
 694
 695     push @contents, $ref;
 696   }
 697
 698   $sth->finish();
 699
 700   if ($form->{include_empty_bins}) {
 701     $query =
 702       qq|SELECT
 703            w.id AS warehouseid, w.description AS warehousedescription,
 704            b.id AS binid, b.description AS bindescription
 705          FROM bin b
 706          LEFT JOIN warehouse w ON (b.warehouse_id = w.id)|;
 707
 708     @filter_ary  = @wh_bin_filter_ary;
 709     @filter_vars = @wh_bin_filter_vars;
 710
 711     my @non_empty_bin_ids = keys %non_empty_bins;
 712     if (@non_empty_bin_ids) {
 713       push @filter_ary,  qq|NOT b.id IN (| . join(', ', map { '?' } @non_empty_bin_ids) . qq|)|;
 714       push @filter_vars, @non_empty_bin_ids;
 715     }
 716
 717     $query .= qq| WHERE | . join(' AND ', map { "($_)" } @filter_ary) if (@filter_ary);
 718
 719     $sth    = prepare_execute_query($form, $dbh, $query, @filter_vars);
 720
 721     while (my $ref = $sth->fetchrow_hashref()) {
 722       map { $ref->{$_} ||= "" } @all_fields;
 723       push @contents, $ref;
 724     }
 725     $sth->finish();
 726
 727     if (grep { $orderby eq $_ } qw(bindescription warehousedescription)) {
 728       @contents = sort { ($a->{$orderby} cmp $b->{$orderby}) * (($form->{order}) ? 1 : -1) } @contents;
 729     }
 730   }
 731
 732   $main::lxdebug->leave_sub();
 733
 734   return @contents;
 735 }
 736
 737 sub convert_qty_op {
 738   $main::lxdebug->enter_sub();
 739
 740   my ($self, $qty_op) = @_;
 741
 742   if (!$qty_op || ($qty_op eq "dontcare")) {
 743     $main::lxdebug->leave_sub();
 744     return undef;
 745   }
 746
 747   if ($qty_op eq "atleast") {
 748     $qty_op = '>=';
 749   } elsif ($qty_op eq "atmost") {
 750     $qty_op = '<=';
 751   } else {
 752     $qty_op = '=';
 753   }
 754
 755   $main::lxdebug->leave_sub();
 756
 757   return $qty_op;
 758 }
 759
 760 sub retrieve_transfer_types {
 761   $main::lxdebug->enter_sub();
 762
 763   my $self      = shift;
 764   my $direction = shift;
 765
 766   my $myconfig  = \%main::myconfig;
 767   my $form      = $main::form;
 768
 769   my $dbh       = $form->get_standard_dbh($myconfig);
 770
 771   my $types     = selectall_hashref_query($form, $dbh, qq|SELECT * FROM transfer_type WHERE direction = ? ORDER BY sortkey|, $direction);
 772
 773   $main::lxdebug->leave_sub();
 774
 775   return $types;
 776 }
 777
 778 sub get_basic_bin_info {
 779   $main::lxdebug->enter_sub();
 780
 781   my $self     = shift;
 782   my %params   = @_;
 783
 784   Common::check_params(\%params, qw(id));
 785
 786   my $myconfig = \%main::myconfig;
 787   my $form     = $main::form;
 788
 789   my $dbh      = $params{dbh} || $form->get_standard_dbh();
 790
 791   my @ids      = 'ARRAY' eq ref $params{id} ? @{ $params{id} } : ($params{id});
 792
 793   my $query    =
 794     qq|SELECT b.id AS bin_id, b.description AS bin_description,
 795          w.id AS warehouse_id, w.description AS warehouse_description
 796        FROM bin b
 797        LEFT JOIN warehouse w ON (b.warehouse_id = w.id)
 798        WHERE b.id IN (| . join(', ', ('?') x scalar(@ids)) . qq|)|;
 799
 800   my $result = selectall_hashref_query($form, $dbh, $query, map { conv_i($_) } @ids);
 801
 802   if ('' eq ref $params{id}) {
 803     $result = $result->[0] || { };
 804     $main::lxdebug->leave_sub();
 805
 806     return $result;
 807   }
 808
 809   $main::lxdebug->leave_sub();
 810
 811   return map { $_->{bin_id} => $_ } @{ $result };
 812 }
 813 #
 814 # Eingabe:  Teilenummer, Lagernummer (warehouse)
 815 # Ausgabe:  Die maximale Anzahl der Teile in diesem Lager
 816 #
 817 sub get_max_qty_parts {
 818 $main::lxdebug->enter_sub();
 819
 820   my $self     = shift;
 821   my %params   = @_;
 822
 823   Common::check_params(\%params, qw(parts_id warehouse_id)); #die brauchen wir
 824
 825   my $myconfig = \%main::myconfig;
 826   my $form     = $main::form;
 827
 828   my $dbh      = $params{dbh} || $form->get_standard_dbh();
 829
 830   my $query = qq| SELECT SUM(qty), bin_id, chargenumber, bestbefore  FROM inventory where parts_id = ? AND warehouse_id = ? GROUP BY bin_id, chargenumber, bestbefore|;
 831
 832   my $sth_QTY      = prepare_execute_query($form, $dbh, $query, ,$params{parts_id}, $params{warehouse_id}); #info: aufruf an DBUtils.pm
 833
 834   my $max_qty_parts = 0; #Initialisierung mit 0
 835   while (my $ref = $sth_QTY->fetchrow_hashref()) {  # wir laufen über alle Haltbarkeiten, chargen und Lagerorte (s.a. SQL-Query oben)
 836     $max_qty_parts += $ref->{sum};
 837   }
 838
 839   $main::lxdebug->leave_sub();
 840
 841   return $max_qty_parts;
 842 }
 843
 844 #
 845 # Eingabe:  Teilenummer, Lagernummer (warehouse)
 846 # Ausgabe:  Die Beschreibung der Ware bzw. Erzeugnis
 847 #
 848 sub get_part_description {
 849 $main::lxdebug->enter_sub();
 850
 851   my $self     = shift;
 852   my %params   = @_;
 853
 854   Common::check_params(\%params, qw(parts_id)); #die brauchen wir
 855
 856   my $myconfig = \%main::myconfig;
 857   my $form     = $main::form;
 858
 859   my $dbh      = $params{dbh} || $form->get_standard_dbh();
 860
 861   my $query = qq| SELECT partnumber, description FROM parts where id = ? |;
 862
 863   my $sth      = prepare_execute_query($form, $dbh, $query, ,$params{parts_id}); #info: aufruf zu DBUtils.pm
 864
 865   my $ref = $sth->fetchrow_hashref();
 866   my $part_description = $ref->{partnumber} . " " . $ref->{description};
 867
 868   $main::lxdebug->leave_sub();
 869
 870   return $part_description;
 871 }
 872
 873
 874 1;