bin/mozilla/admin.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 2002
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  28 #======================================================================
  29 #
  30 # setup module
  31 # add/edit/delete users
  32 #
  33 #======================================================================
  34
  35 use DBI;
  36 use Encode;
  37 use English qw(-no_match_vars);
  38 use Fcntl;
  39 use File::Copy;
  40 use File::Find;
  41 use File::Spec;
  42 use Cwd;
  43 use IO::Dir;
  44 use IO::File;
  45 use POSIX qw(strftime);
  46 use Sys::Hostname;
  47
  48 use SL::Auth;
  49 use SL::Auth::PasswordPolicy;
  50 use SL::DB::AuthClient;
  51 use SL::DB::AuthUser;
  52 use SL::Form;
  53 use SL::Iconv;
  54 use SL::Mailer;
  55 use SL::User;
  56 use SL::Common;
  57 use SL::Inifile;
  58 use SL::DBUpgrade2;
  59 use SL::DBUtils;
  60 use SL::Template;
  61
  62 require "bin/mozilla/common.pl";
  63
  64 use strict;
  65
  66 # parserhappy(R):
  67
  68 #  $locale->text('periodic')
  69 #  $locale->text('income')
  70 #  $locale->text('perpetual')
  71 #  $locale->text('balance')
  72
  73 our $cgi;
  74 our $form;
  75 our $locale;
  76 our $auth;
  77
  78 sub run {
  79   $::lxdebug->enter_sub;
  80   my $session_result = shift;
  81
  82   $form   = $::form;
  83   $locale = $::locale;
  84   $auth   = $::auth;
  85
  86   $::request->{layout} = SL::Layout::Dispatcher->new(style => 'admin');
  87   $::request->{layout}->use_stylesheet("lx-office-erp.css");
  88   $form->{favicon}    = "favicon.ico";
  89
  90   if ($form->{action}) {
  91     if ($auth->authenticate_root($form->{'{AUTH}admin_password'}) != $auth->OK()) {
  92       $auth->punish_wrong_login;
  93       $form->{error} = $locale->text('Incorrect Password!');
  94       $auth->delete_session_value('admin_password');
  95       adminlogin();
  96     } else {
  97       if ($auth->session_tables_present()) {
  98         delete $::form->{'{AUTH}admin_password'};
  99       }
 100
 101       call_sub($locale->findsub($form->{action}));
 102     }
 103   } else {
 104     # if there are no drivers bail out
 105     $form->error($locale->text('No Database Drivers available!'))
 106       unless (User->dbdrivers);
 107
 108     adminlogin();
 109   }
 110   $::lxdebug->leave_sub;
 111 }
 112
 113 sub adminlogin {
 114   my $form   = $main::form;
 115   my $locale = $main::locale;
 116
 117   $form->{title} = qq|kivitendo $form->{version} | . $locale->text('Administration');
 118
 119   $form->header();
 120   print $form->parse_html_template('admin/adminlogin');
 121 }
 122
 123 sub login_name {
 124   my $login = shift;
 125
 126   $login =~ s/\[\]//g;
 127   return ($login) ? $login : undef;
 128
 129 }
 130
 131 sub get_value {
 132   my $line           = shift;
 133   my ($null, $value) = split(/=/, $line, 2);
 134
 135   # remove comments
 136   $value =~ s/\s#.*//g;
 137
 138   # remove any trailing whitespace
 139   $value =~ s/^\s*(.*?)\s*$/$1/;
 140
 141   $value;
 142 }
 143
 144 sub pg_database_administration {
 145   my $form = $main::form;
 146
 147   $form->{dbdriver} = 'Pg';
 148   dbselect_source();
 149
 150 }
 151
 152 sub dbselect_source {
 153   my $form           = $main::form;
 154   my $locale         = $main::locale;
 155
 156   $form->{dbport}    = $::auth->{DB_config}->{port} || 5432;
 157   $form->{dbuser}    = $::auth->{DB_config}->{user} || 'lxoffice';
 158   $form->{dbdefault} = 'template1';
 159   $form->{dbhost}    = $::auth->{DB_config}->{host} || 'localhost';
 160
 161   $form->{title}     = "kivitendo / " . $locale->text('Database Administration');
 162
 163   # Intentionnaly disabled unless fixed to work with the authentication DB.
 164   $form->{ALLOW_DBBACKUP} = 0; # "$pg_dump_exe" ne "DISABLED";
 165
 166   $form->header();
 167   print $form->parse_html_template("admin/dbadmin");
 168 }
 169
 170 sub test_db_connection {
 171   my $form   = $main::form;
 172   my $locale = $main::locale;
 173
 174   $form->{dbdriver} = 'Pg';
 175   User::dbconnect_vars($form, $form->{dbname});
 176
 177   my $dbh = DBI->connect($form->{dbconnect}, $form->{dbuser}, $form->{dbpasswd});
 178
 179   $form->{connection_ok} = $dbh ? 1 : 0;
 180   $form->{errstr}        = $DBI::errstr;
 181
 182   $dbh->disconnect() if ($dbh);
 183
 184   $form->{title} = $locale->text('Database Connection Test');
 185   $form->header();
 186   print $form->parse_html_template("admin/test_db_connection");
 187 }
 188
 189 sub continue {
 190   call_sub($main::form->{"nextsub"});
 191 }
 192
 193 sub update_dataset {
 194   my $form              = $main::form;
 195   my $locale            = $main::locale;
 196
 197   $form->{title}        = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Update Dataset');
 198
 199   my @need_updates      = User->dbneedsupdate($form);
 200   $form->{NEED_UPDATES} = \@need_updates;
 201   $form->{ALL_UPDATED}  = !scalar @need_updates;
 202
 203   $form->header();
 204   print $form->parse_html_template("admin/update_dataset");
 205 }
 206
 207 sub dbupdate {
 208   my $form            = $main::form;
 209   my $locale          = $main::locale;
 210
 211   $::request->{layout}->use_stylesheet("lx-office-erp.css");
 212   $form->{title}      = $locale->text("Dataset upgrade");
 213   $form->header();
 214
 215   my $rowcount           = $form->{rowcount} * 1;
 216   my @update_rows        = grep { $form->{"update_$_"} } (1 .. $rowcount);
 217   $form->{NOTHING_TO_DO} = !scalar @update_rows;
 218   my $saved_form         = save_form();
 219
 220   $| = 1;
 221
 222   print $form->parse_html_template("admin/dbupgrade_all_header");
 223
 224   foreach my $i (@update_rows) {
 225     restore_form($saved_form);
 226
 227     %::myconfig = ();
 228     map { $form->{$_} = $::myconfig{$_} = $form->{"${_}_${i}"} } qw(dbname dbdriver dbhost dbport dbuser dbpasswd);
 229
 230     print $form->parse_html_template("admin/dbupgrade_header");
 231
 232     $form->{dbupdate}        = $form->{dbname};
 233     $form->{$form->{dbname}} = 1;
 234
 235     User->dbupdate($form);
 236     User->dbupdate2($form, SL::DBUpgrade2->new(form => $form, dbdriver => $form->{dbdriver})->parse_dbupdate_controls);
 237
 238     print $form->parse_html_template("admin/dbupgrade_footer");
 239   }
 240
 241   print $form->parse_html_template("admin/dbupgrade_all_done");
 242 }
 243
 244 sub create_dataset {
 245   my $form           = $main::form;
 246   my $locale         = $main::locale;
 247
 248   $form->{dbsources} = join " ", map { "[${_}]" } sort User->dbsources($form);
 249
 250   $form->{CHARTS}    = [];
 251
 252   tie my %dir_h, 'IO::Dir', 'sql/';
 253   foreach my $item (map { s/-chart\.sql$//; $_ } sort grep { /-chart\.sql\z/ && !/Default-chart.sql\z/ } keys %dir_h) {
 254     push @{ $form->{CHARTS} }, { name     => $item,
 255                                  selected => $item eq "Germany-DATEV-SKR03EU" };
 256   }
 257
 258   $form->{ACCOUNTING_METHODS}    = [ map { { name => $_, selected => $_ eq 'cash'     } } qw(accrual cash)       ];
 259   $form->{INVENTORY_SYSTEMS}     = [ map { { name => $_, selected => $_ eq 'periodic' } } qw(perpetual periodic) ];
 260   $form->{PROFIT_DETERMINATIONS} = [ map { { name => $_, selected => $_ eq 'income'   } } qw(balance income)     ];
 261
 262   my $default_charset = $::lx_office_conf{system}->{dbcharset} || Common::DEFAULT_CHARSET;
 263
 264   my $cluster_encoding = User->dbclusterencoding($form);
 265   if ($cluster_encoding && ($cluster_encoding =~ m/^(?:UTF-?8|UNICODE)$/i)) {
 266     if ($::lx_office_conf{system}->{dbcharset} !~ m/^UTF-?8$/i) {
 267       $form->show_generic_error($locale->text('The selected  PostgreSQL installation uses UTF-8 as its encoding. ' .
 268                                               'Therefore you have to configure kivitendo to use UTF-8 as well.'),
 269                                 'back_button' => 1);
 270     }
 271
 272     $form->{FORCE_DBENCODING} = 'UNICODE';
 273
 274   } else {
 275     $form->{DBENCODINGS} = [ map { { %{$_}, selected => $_->{charset} eq $default_charset } } @Common::db_encodings ];
 276   }
 277
 278   $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Create Dataset');
 279
 280   $form->header();
 281   print $form->parse_html_template("admin/create_dataset");
 282 }
 283
 284 sub dbcreate {
 285   my $form   = $main::form;
 286   my $locale = $main::locale;
 287
 288   $form->isblank("db", $locale->text('Dataset missing!'));
 289   $form->isblank("defaultcurrency", $locale->text('Default currency missing!'));
 290
 291   User->dbcreate(\%$form);
 292
 293   $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Create Dataset');
 294
 295   $form->header();
 296   print $form->parse_html_template("admin/dbcreate");
 297 }
 298
 299 sub delete_dataset {
 300   my $form      = $main::form;
 301   my $locale    = $main::locale;
 302
 303   my @dbsources = User->dbsources_unused($form);
 304   $form->error($locale->text('Nothing to delete!')) unless @dbsources;
 305
 306   $form->{title}     = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Delete Dataset');
 307   $form->{DBSOURCES} = [ map { { "name", $_ } } sort @dbsources ];
 308
 309   $form->header();
 310   print $form->parse_html_template("admin/delete_dataset");
 311 }
 312
 313 sub dbdelete {
 314   my $form   = $main::form;
 315   my $locale = $main::locale;
 316
 317   if (!$form->{db}) {
 318     $form->error($locale->text('No Dataset selected!'));
 319   }
 320
 321   User->dbdelete(\%$form);
 322
 323   $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Delete Dataset');
 324   $form->header();
 325   print $form->parse_html_template("admin/dbdelete");
 326 }
 327
 328 sub backup_dataset {
 329   my $form       = $main::form;
 330   my $locale     = $main::locale;
 331
 332   $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Backup Dataset');
 333
 334   if ($::lx_office_conf{applications}->{pg_dump} eq "DISABLED") {
 335     $form->error($locale->text('Database backups and restorations are disabled in the configuration.'));
 336   }
 337
 338   my @dbsources         = sort User->dbsources($form);
 339   $form->{DATABASES}    = [ map { { "dbname" => $_ } } @dbsources ];
 340   $form->{NO_DATABASES} = !scalar @dbsources;
 341
 342   my $username  = getpwuid $UID || "unknown-user";
 343   my $hostname  = hostname() || "unknown-host";
 344   $form->{from} = "kivitendo Admin <${username}\@${hostname}>";
 345
 346   $form->header();
 347   print $form->parse_html_template("admin/backup_dataset");
 348 }
 349
 350 sub backup_dataset_start {
 351   my $form       = $main::form;
 352   my $locale     = $main::locale;
 353
 354   $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Backup Dataset');
 355
 356   my $pg_dump_exe = $::lx_office_conf{applications}->{pg_dump} || "pg_dump";
 357
 358   if ("$pg_dump_exe" eq "DISABLED") {
 359     $form->error($locale->text('Database backups and restorations are disabled in the configuration.'));
 360   }
 361
 362   $form->isblank("dbname", $locale->text('The dataset name is missing.'));
 363   $form->isblank("to", $locale->text('The email address is missing.')) if $form->{destination} eq "email";
 364
 365   my $tmpdir = "/tmp/lx_office_backup_" . Common->unique_id();
 366   mkdir $tmpdir, 0700 || $form->error($locale->text('A temporary directory could not be created:') . " $ERRNO");
 367
 368   my $pgpass = IO::File->new("${tmpdir}/.pgpass", O_WRONLY | O_CREAT, 0600);
 369
 370   if (!$pgpass) {
 371     unlink $tmpdir;
 372     $form->error($locale->text('A temporary file could not be created:') . " $ERRNO");
 373   }
 374
 375   print $pgpass "$form->{dbhost}:$form->{dbport}:$form->{dbname}:$form->{dbuser}:$form->{dbpasswd}\n";
 376   $pgpass->close();
 377
 378   $ENV{HOME} = $tmpdir;
 379
 380   my @args = ("-Ft", "-c", "-o", "-h", $form->{dbhost}, "-U", $form->{dbuser});
 381   push @args, ("-p", $form->{dbport}) if ($form->{dbport});
 382   push @args, $form->{dbname};
 383
 384   my $cmd  = "$pg_dump_exe " . join(" ", map { s/\\/\\\\/g; s/\"/\\\"/g; $_ } @args);
 385   my $name = "dataset_backup_$form->{dbname}_" . strftime("%Y%m%d", localtime()) . ".tar";
 386
 387   if ($form->{destination} ne "email") {
 388     my $in = IO::File->new("$cmd |");
 389
 390     if (!$in) {
 391       unlink "${tmpdir}/.pgpass";
 392       rmdir $tmpdir;
 393
 394       $form->error($locale->text('The pg_dump process could not be started.'));
 395     }
 396
 397     print "content-type: application/x-tar\n";
 398     print "content-disposition: attachment; filename=\"${name}\"\n\n";
 399
 400     while (my $line = <$in>) {
 401       print $line;
 402     }
 403
 404     $in->close();
 405
 406     unlink "${tmpdir}/.pgpass";
 407     rmdir $tmpdir;
 408
 409   } else {
 410     my $tmp = $tmpdir . "/dump_" . Common::unique_id();
 411
 412     if (system("$cmd > $tmp") != 0) {
 413       unlink "${tmpdir}/.pgpass", $tmp;
 414       rmdir $tmpdir;
 415
 416       $form->error($locale->text('The pg_dump process could not be started.'));
 417     }
 418
 419     my $mail = new Mailer;
 420
 421     map { $mail->{$_} = $form->{$_} } qw(from to cc subject message);
 422
 423     $mail->{charset}     = $::lx_office_conf{system}->{dbcharset} || Common::DEFAULT_CHARSET;
 424     $mail->{attachments} = [ { "filename" => $tmp, "name" => $name } ];
 425     $mail->send();
 426
 427     unlink "${tmpdir}/.pgpass", $tmp;
 428     rmdir $tmpdir;
 429
 430     $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Backup Dataset');
 431
 432     $form->header();
 433     print $form->parse_html_template("admin/backup_dataset_email_done");
 434   }
 435 }
 436
 437 sub restore_dataset {
 438   my $form       = $main::form;
 439   my $locale     = $main::locale;
 440
 441   $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Restore Dataset');
 442
 443   if ($::lx_office_conf{applications}->{pg_restore} eq "DISABLED") {
 444     $form->error($locale->text('Database backups and restorations are disabled in the configuration.'));
 445   }
 446
 447   my $default_charset   = $::lx_office_conf{system}->{dbcharset};
 448   $default_charset    ||= Common::DEFAULT_CHARSET;
 449
 450   $form->{DBENCODINGS}  = [];
 451
 452   foreach my $encoding (@Common::db_encodings) {
 453     push @{ $form->{DBENCODINGS} }, { "dbencoding" => $encoding->{dbencoding},
 454                                       "label"      => $encoding->{label},
 455                                       "selected"   => $encoding->{charset} eq $default_charset };
 456   }
 457
 458   $form->header();
 459   print $form->parse_html_template("admin/restore_dataset");
 460 }
 461
 462 sub restore_dataset_start {
 463   my $form       = $main::form;
 464   my $locale     = $main::locale;
 465
 466   $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Restore Dataset');
 467
 468   my $pg_restore_exe = $::lx_office_conf{applications}->{pg_restore} || "pg_restore";
 469
 470   if ("$pg_restore_exe" eq "DISABLED") {
 471     $form->error($locale->text('Database backups and restorations are disabled in the configuration.'));
 472   }
 473
 474   $form->isblank("new_dbname", $locale->text('The dataset name is missing.'));
 475   $form->isblank("content", $locale->text('No backup file has been uploaded.'));
 476
 477   # Create temporary directories. Write the backup file contents to a temporary
 478   # file. Create a .pgpass file with the username and password for the pg_restore
 479   # utility.
 480
 481   my $tmpdir = "/tmp/lx_office_backup_" . Common->unique_id();
 482   mkdir $tmpdir, 0700 || $form->error($locale->text('A temporary directory could not be created:') . " $ERRNO");
 483
 484   my $pgpass = IO::File->new("${tmpdir}/.pgpass", O_WRONLY | O_CREAT, 0600);
 485
 486   if (!$pgpass) {
 487     unlink $tmpdir;
 488     $form->error($locale->text('A temporary file could not be created:') . " $ERRNO");
 489   }
 490
 491   print $pgpass "$form->{dbhost}:$form->{dbport}:$form->{new_dbname}:$form->{dbuser}:$form->{dbpasswd}\n";
 492   $pgpass->close();
 493
 494   $ENV{HOME} = $tmpdir;
 495
 496   my $tmp = $tmpdir . "/dump_" . Common::unique_id();
 497   my $tmpfile;
 498
 499   if (substr($form->{content}, 0, 2) eq "\037\213") {
 500     $tmpfile = IO::File->new("| gzip -d > $tmp");
 501     $tmpfile->binary();
 502
 503   } else {
 504     $tmpfile = IO::File->new($tmp, O_WRONLY | O_CREAT | O_BINARY, 0600);
 505   }
 506
 507   if (!$tmpfile) {
 508     unlink "${tmpdir}/.pgpass";
 509     rmdir $tmpdir;
 510
 511     $form->error($locale->text('A temporary file could not be created:') . " $ERRNO");
 512   }
 513
 514   print $tmpfile $form->{content};
 515   $tmpfile->close();
 516
 517   delete $form->{content};
 518
 519   # Try to connect to the database. Find out if a database with the same name exists.
 520   # If yes, then drop the existing database. Create a new one with the name and encoding
 521   # given by the user.
 522
 523   User::dbconnect_vars($form, "template1");
 524
 525   my %myconfig = map { $_ => $form->{$_} } grep /^db/, keys %{ $form };
 526   my $dbh      = $form->dbconnect(\%myconfig) || $form->dberror();
 527
 528   my ($query, $sth);
 529
 530   $form->{new_dbname} =~ s|[^a-zA-Z0-9_\-]||g;
 531
 532   $query = qq|SELECT COUNT(*) FROM pg_database WHERE datname = ?|;
 533   my ($count) = selectrow_query($form, $dbh, $query, $form->{new_dbname});
 534   if ($count) {
 535     do_query($form, $dbh, qq|DROP DATABASE $form->{new_dbname}|);
 536   }
 537
 538   my $found = 0;
 539   foreach my $item (@Common::db_encodings) {
 540     if ($item->{dbencoding} eq $form->{dbencoding}) {
 541       $found = 1;
 542       last;
 543     }
 544   }
 545   $form->{dbencoding} = "LATIN9" unless $form->{dbencoding};
 546
 547   do_query($form, $dbh, qq|CREATE DATABASE $form->{new_dbname} ENCODING ? TEMPLATE template0|, $form->{dbencoding});
 548
 549   $dbh->disconnect();
 550
 551   # Spawn pg_restore on the temporary file.
 552
 553   my @args = ("-h", $form->{dbhost}, "-U", $form->{dbuser}, "-d", $form->{new_dbname});
 554   push @args, ("-p", $form->{dbport}) if ($form->{dbport});
 555   push @args, $tmp;
 556
 557   my $cmd = "$pg_restore_exe " . join(" ", map { s/\\/\\\\/g; s/\"/\\\"/g; $_ } @args);
 558
 559   my $in = IO::File->new("$cmd 2>&1 |");
 560
 561   if (!$in) {
 562     unlink "${tmpdir}/.pgpass", $tmp;
 563     rmdir $tmpdir;
 564
 565     $form->error($locale->text('The pg_restore process could not be started.'));
 566   }
 567
 568   $English::AUTOFLUSH = 1;
 569
 570   $form->header();
 571   print $form->parse_html_template("admin/restore_dataset_start_header");
 572
 573   while (my $line = <$in>) {
 574     print $line;
 575   }
 576   $in->close();
 577
 578   $form->{retval} = $CHILD_ERROR >> 8;
 579   print $form->parse_html_template("admin/restore_dataset_start_footer");
 580
 581   unlink "${tmpdir}/.pgpass", $tmp;
 582   rmdir $tmpdir;
 583 }
 584
 585 sub yes {
 586   call_sub($main::form->{yes_nextsub});
 587 }
 588
 589 sub no {
 590   call_sub($main::form->{no_nextsub});
 591 }
 592
 593 sub add {
 594   call_sub($main::form->{add_nextsub});
 595 }
 596
 597 sub edit {
 598   my $form = $main::form;
 599
 600   $form->{edit_nextsub} ||= 'edit_user';
 601
 602   call_sub($form->{edit_nextsub});
 603 }
 604
 605 sub delete {
 606   my $form     = $main::form;
 607
 608   $form->{delete_nextsub} ||= 'delete_user';
 609
 610   call_sub($form->{delete_nextsub});
 611 }
 612
 613 sub save {
 614   my $form = $main::form;
 615
 616   $form->{save_nextsub} ||= 'save_user';
 617
 618   call_sub($form->{save_nextsub});
 619 }
 620
 621 sub back {
 622   call_sub($main::form->{back_nextsub});
 623 }
 624
 625 sub dispatcher {
 626   my $form   = $main::form;
 627   my $locale = $main::locale;
 628
 629   foreach my $action (qw(create_standard_group dont_create_standard_group
 630                          save_user delete_user save_user_as_new)) {
 631     if ($form->{"action_${action}"}) {
 632       call_sub($action);
 633       return;
 634     }
 635   }
 636
 637   call_sub($form->{default_action}) if ($form->{default_action});
 638
 639   $form->error($locale->text('No action defined.'));
 640 }
 641
 642 sub _search_templates {
 643   my %templates = SL::Template->available_templates;
 644
 645   return ($templates{print_templates}, $templates{master_templates});
 646 }
 647
 648 1;