bin/mozilla/admin.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 2002
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  28 #======================================================================
  29 #
  30 # setup module
  31 # add/edit/delete users
  32 #
  33 #======================================================================
  34
  35 use DBI;
  36 use Encode;
  37 use English qw(-no_match_vars);
  38 use Fcntl;
  39 use File::Copy;
  40 use File::Find;
  41 use File::Spec;
  42 use Cwd;
  43 use IO::Dir;
  44 use IO::File;
  45 use POSIX qw(strftime);
  46 use Sys::Hostname;
  47
  48 use SL::Auth;
  49 use SL::Auth::PasswordPolicy;
  50 use SL::DB::AuthClient;
  51 use SL::DB::AuthUser;
  52 use SL::Form;
  53 use SL::Iconv;
  54 use SL::Mailer;
  55 use SL::User;
  56 use SL::Common;
  57 use SL::Inifile;
  58 use SL::DBUpgrade2;
  59 use SL::DBUtils;
  60 use SL::Template;
  61
  62 require "bin/mozilla/common.pl";
  63
  64 use strict;
  65
  66 # parserhappy(R):
  67
  68 #  $locale->text('periodic')
  69 #  $locale->text('income')
  70 #  $locale->text('perpetual')
  71 #  $locale->text('balance')
  72
  73 our $cgi;
  74 our $form;
  75 our $locale;
  76 our $auth;
  77
  78 sub run {
  79   $::lxdebug->enter_sub;
  80   my $session_result = shift;
  81
  82   $form   = $::form;
  83   $locale = $::locale;
  84   $auth   = $::auth;
  85
  86   $::request->{layout} = SL::Layout::Dispatcher->new(style => 'admin');
  87   $::request->{layout}->use_stylesheet("lx-office-erp.css");
  88   $form->{favicon}    = "favicon.ico";
  89
  90   if ($form->{action}) {
  91     if ($auth->authenticate_root($form->{'{AUTH}admin_password'}) != $auth->OK()) {
  92       $auth->punish_wrong_login;
  93       $form->{error} = $locale->text('Incorrect password!');
  94       $auth->delete_session_value('admin_password');
  95       adminlogin();
  96     } else {
  97       if ($auth->session_tables_present()) {
  98         delete $::form->{'{AUTH}admin_password'};
  99       }
 100
 101       call_sub($locale->findsub($form->{action}));
 102     }
 103   } else {
 104     adminlogin();
 105   }
 106   $::lxdebug->leave_sub;
 107 }
 108
 109 sub adminlogin {
 110   my $form   = $main::form;
 111   my $locale = $main::locale;
 112
 113   $form->{title} = qq|kivitendo $form->{version} | . $locale->text('Administration');
 114
 115   $form->header();
 116   print $form->parse_html_template('admin/adminlogin');
 117 }
 118
 119 sub login_name {
 120   my $login = shift;
 121
 122   $login =~ s/\[\]//g;
 123   return ($login) ? $login : undef;
 124
 125 }
 126
 127 sub get_value {
 128   my $line           = shift;
 129   my ($null, $value) = split(/=/, $line, 2);
 130
 131   # remove comments
 132   $value =~ s/\s#.*//g;
 133
 134   # remove any trailing whitespace
 135   $value =~ s/^\s*(.*?)\s*$/$1/;
 136
 137   $value;
 138 }
 139
 140 sub pg_database_administration {
 141   my $form = $main::form;
 142   dbselect_source();
 143 }
 144
 145 sub dbselect_source {
 146   my $form           = $main::form;
 147   my $locale         = $main::locale;
 148
 149   $form->{dbport}    = $::auth->{DB_config}->{port} || 5432;
 150   $form->{dbuser}    = $::auth->{DB_config}->{user} || 'lxoffice';
 151   $form->{dbdefault} = 'template1';
 152   $form->{dbhost}    = $::auth->{DB_config}->{host} || 'localhost';
 153
 154   $form->{title}     = "kivitendo / " . $locale->text('Database Administration');
 155
 156   # Intentionnaly disabled unless fixed to work with the authentication DB.
 157   $form->{ALLOW_DBBACKUP} = 0; # "$pg_dump_exe" ne "DISABLED";
 158
 159   $form->header();
 160   print $form->parse_html_template("admin/dbadmin");
 161 }
 162
 163 sub test_db_connection {
 164   my $form   = $main::form;
 165   my $locale = $main::locale;
 166
 167   User::dbconnect_vars($form, $form->{dbname});
 168
 169   my $dbh = DBI->connect($form->{dbconnect}, $form->{dbuser}, $form->{dbpasswd});
 170
 171   $form->{connection_ok} = $dbh ? 1 : 0;
 172   $form->{errstr}        = $DBI::errstr;
 173
 174   $dbh->disconnect() if ($dbh);
 175
 176   $form->{title} = $locale->text('Database Connection Test');
 177   $form->header();
 178   print $form->parse_html_template("admin/test_db_connection");
 179 }
 180
 181 sub continue {
 182   call_sub($main::form->{"nextsub"});
 183 }
 184
 185 sub update_dataset {
 186   my $form              = $main::form;
 187   my $locale            = $main::locale;
 188
 189   $form->{title}        = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Update Dataset');
 190
 191   my @need_updates      = User->dbneedsupdate($form);
 192   $form->{NEED_UPDATES} = \@need_updates;
 193   $form->{ALL_UPDATED}  = !scalar @need_updates;
 194
 195   $form->header();
 196   print $form->parse_html_template("admin/update_dataset");
 197 }
 198
 199 sub dbupdate {
 200   my $form            = $main::form;
 201   my $locale          = $main::locale;
 202
 203   $::request->{layout}->use_stylesheet("lx-office-erp.css");
 204   $form->{title}      = $locale->text("Dataset upgrade");
 205   $form->header();
 206
 207   my $rowcount           = $form->{rowcount} * 1;
 208   my @update_rows        = grep { $form->{"update_$_"} } (1 .. $rowcount);
 209   $form->{NOTHING_TO_DO} = !scalar @update_rows;
 210   my $saved_form         = save_form();
 211
 212   $| = 1;
 213
 214   print $form->parse_html_template("admin/dbupgrade_all_header");
 215
 216   foreach my $i (@update_rows) {
 217     restore_form($saved_form);
 218
 219     %::myconfig = ();
 220     map { $form->{$_} = $::myconfig{$_} = $form->{"${_}_${i}"} } qw(dbname dbhost dbport dbuser dbpasswd);
 221
 222     print $form->parse_html_template("admin/dbupgrade_header");
 223
 224     $form->{dbupdate}        = $form->{dbname};
 225     $form->{$form->{dbname}} = 1;
 226
 227     User->dbupdate($form);
 228     User->dbupdate2($form, SL::DBUpgrade2->new(form => $form)->parse_dbupdate_controls);
 229
 230     print $form->parse_html_template("admin/dbupgrade_footer");
 231   }
 232
 233   print $form->parse_html_template("admin/dbupgrade_all_done");
 234 }
 235
 236 sub create_dataset {
 237   my $form           = $main::form;
 238   my $locale         = $main::locale;
 239
 240   $form->{dbsources} = join " ", map { "[${_}]" } sort User->dbsources($form);
 241
 242   $form->{CHARTS}    = [];
 243
 244   tie my %dir_h, 'IO::Dir', 'sql/';
 245   foreach my $item (map { s/-chart\.sql$//; $_ } sort grep { /-chart\.sql\z/ && !/Default-chart.sql\z/ } keys %dir_h) {
 246     push @{ $form->{CHARTS} }, { name     => $item,
 247                                  selected => $item eq "Germany-DATEV-SKR03EU" };
 248   }
 249
 250   $form->{ACCOUNTING_METHODS}    = [ map { { name => $_, selected => $_ eq 'cash'     } } qw(accrual cash)       ];
 251   $form->{INVENTORY_SYSTEMS}     = [ map { { name => $_, selected => $_ eq 'periodic' } } qw(perpetual periodic) ];
 252   $form->{PROFIT_DETERMINATIONS} = [ map { { name => $_, selected => $_ eq 'income'   } } qw(balance income)     ];
 253
 254   my $default_charset = $::lx_office_conf{system}->{dbcharset} || Common::DEFAULT_CHARSET;
 255
 256   my $cluster_encoding = User->dbclusterencoding($form);
 257   if ($cluster_encoding && ($cluster_encoding =~ m/^(?:UTF-?8|UNICODE)$/i)) {
 258     if ($::lx_office_conf{system}->{dbcharset} !~ m/^UTF-?8$/i) {
 259       $form->show_generic_error($locale->text('The selected  PostgreSQL installation uses UTF-8 as its encoding. ' .
 260                                               'Therefore you have to configure kivitendo to use UTF-8 as well.'),
 261                                 'back_button' => 1);
 262     }
 263
 264     $form->{FORCE_DBENCODING} = 'UNICODE';
 265
 266   } else {
 267     $form->{DBENCODINGS} = [ map { { %{$_}, selected => $_->{charset} eq $default_charset } } @Common::db_encodings ];
 268   }
 269
 270   $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Create Dataset');
 271
 272   $form->header();
 273   print $form->parse_html_template("admin/create_dataset");
 274 }
 275
 276 sub dbcreate {
 277   my $form   = $main::form;
 278   my $locale = $main::locale;
 279
 280   $form->isblank("db", $locale->text('Dataset missing!'));
 281   $form->isblank("defaultcurrency", $locale->text('Default currency missing!'));
 282
 283   User->dbcreate(\%$form);
 284
 285   $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Create Dataset');
 286
 287   $form->header();
 288   print $form->parse_html_template("admin/dbcreate");
 289 }
 290
 291 sub delete_dataset {
 292   my $form      = $main::form;
 293   my $locale    = $main::locale;
 294
 295   my @dbsources = User->dbsources_unused($form);
 296   $form->error($locale->text('Nothing to delete!')) unless @dbsources;
 297
 298   $form->{title}     = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Delete Dataset');
 299   $form->{DBSOURCES} = [ map { { "name", $_ } } sort @dbsources ];
 300
 301   $form->header();
 302   print $form->parse_html_template("admin/delete_dataset");
 303 }
 304
 305 sub dbdelete {
 306   my $form   = $main::form;
 307   my $locale = $main::locale;
 308
 309   if (!$form->{db}) {
 310     $form->error($locale->text('No Dataset selected!'));
 311   }
 312
 313   User->dbdelete(\%$form);
 314
 315   $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Delete Dataset');
 316   $form->header();
 317   print $form->parse_html_template("admin/dbdelete");
 318 }
 319
 320 sub backup_dataset {
 321   my $form       = $main::form;
 322   my $locale     = $main::locale;
 323
 324   $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Backup Dataset');
 325
 326   if ($::lx_office_conf{applications}->{pg_dump} eq "DISABLED") {
 327     $form->error($locale->text('Database backups and restorations are disabled in the configuration.'));
 328   }
 329
 330   my @dbsources         = sort User->dbsources($form);
 331   $form->{DATABASES}    = [ map { { "dbname" => $_ } } @dbsources ];
 332   $form->{NO_DATABASES} = !scalar @dbsources;
 333
 334   my $username  = getpwuid $UID || "unknown-user";
 335   my $hostname  = hostname() || "unknown-host";
 336   $form->{from} = "kivitendo Admin <${username}\@${hostname}>";
 337
 338   $form->header();
 339   print $form->parse_html_template("admin/backup_dataset");
 340 }
 341
 342 sub backup_dataset_start {
 343   my $form       = $main::form;
 344   my $locale     = $main::locale;
 345
 346   $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Backup Dataset');
 347
 348   my $pg_dump_exe = $::lx_office_conf{applications}->{pg_dump} || "pg_dump";
 349
 350   if ("$pg_dump_exe" eq "DISABLED") {
 351     $form->error($locale->text('Database backups and restorations are disabled in the configuration.'));
 352   }
 353
 354   $form->isblank("dbname", $locale->text('The dataset name is missing.'));
 355   $form->isblank("to", $locale->text('The email address is missing.')) if $form->{destination} eq "email";
 356
 357   my $tmpdir = "/tmp/lx_office_backup_" . Common->unique_id();
 358   mkdir $tmpdir, 0700 || $form->error($locale->text('A temporary directory could not be created:') . " $ERRNO");
 359
 360   my $pgpass = IO::File->new("${tmpdir}/.pgpass", O_WRONLY | O_CREAT, 0600);
 361
 362   if (!$pgpass) {
 363     unlink $tmpdir;
 364     $form->error($locale->text('A temporary file could not be created:') . " $ERRNO");
 365   }
 366
 367   print $pgpass "$form->{dbhost}:$form->{dbport}:$form->{dbname}:$form->{dbuser}:$form->{dbpasswd}\n";
 368   $pgpass->close();
 369
 370   $ENV{HOME} = $tmpdir;
 371
 372   my @args = ("-Ft", "-c", "-o", "-h", $form->{dbhost}, "-U", $form->{dbuser});
 373   push @args, ("-p", $form->{dbport}) if ($form->{dbport});
 374   push @args, $form->{dbname};
 375
 376   my $cmd  = "$pg_dump_exe " . join(" ", map { s/\\/\\\\/g; s/\"/\\\"/g; $_ } @args);
 377   my $name = "dataset_backup_$form->{dbname}_" . strftime("%Y%m%d", localtime()) . ".tar";
 378
 379   if ($form->{destination} ne "email") {
 380     my $in = IO::File->new("$cmd |");
 381
 382     if (!$in) {
 383       unlink "${tmpdir}/.pgpass";
 384       rmdir $tmpdir;
 385
 386       $form->error($locale->text('The pg_dump process could not be started.'));
 387     }
 388
 389     print "content-type: application/x-tar\n";
 390     print "content-disposition: attachment; filename=\"${name}\"\n\n";
 391
 392     while (my $line = <$in>) {
 393       print $line;
 394     }
 395
 396     $in->close();
 397
 398     unlink "${tmpdir}/.pgpass";
 399     rmdir $tmpdir;
 400
 401   } else {
 402     my $tmp = $tmpdir . "/dump_" . Common::unique_id();
 403
 404     if (system("$cmd > $tmp") != 0) {
 405       unlink "${tmpdir}/.pgpass", $tmp;
 406       rmdir $tmpdir;
 407
 408       $form->error($locale->text('The pg_dump process could not be started.'));
 409     }
 410
 411     my $mail = new Mailer;
 412
 413     map { $mail->{$_} = $form->{$_} } qw(from to cc subject message);
 414
 415     $mail->{charset}     = $::lx_office_conf{system}->{dbcharset} || Common::DEFAULT_CHARSET;
 416     $mail->{attachments} = [ { "filename" => $tmp, "name" => $name } ];
 417     $mail->send();
 418
 419     unlink "${tmpdir}/.pgpass", $tmp;
 420     rmdir $tmpdir;
 421
 422     $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Backup Dataset');
 423
 424     $form->header();
 425     print $form->parse_html_template("admin/backup_dataset_email_done");
 426   }
 427 }
 428
 429 sub restore_dataset {
 430   my $form       = $main::form;
 431   my $locale     = $main::locale;
 432
 433   $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Restore Dataset');
 434
 435   if ($::lx_office_conf{applications}->{pg_restore} eq "DISABLED") {
 436     $form->error($locale->text('Database backups and restorations are disabled in the configuration.'));
 437   }
 438
 439   my $default_charset   = $::lx_office_conf{system}->{dbcharset};
 440   $default_charset    ||= Common::DEFAULT_CHARSET;
 441
 442   $form->{DBENCODINGS}  = [];
 443
 444   foreach my $encoding (@Common::db_encodings) {
 445     push @{ $form->{DBENCODINGS} }, { "dbencoding" => $encoding->{dbencoding},
 446                                       "label"      => $encoding->{label},
 447                                       "selected"   => $encoding->{charset} eq $default_charset };
 448   }
 449
 450   $form->header();
 451   print $form->parse_html_template("admin/restore_dataset");
 452 }
 453
 454 sub restore_dataset_start {
 455   my $form       = $main::form;
 456   my $locale     = $main::locale;
 457
 458   $form->{title} = "kivitendo " . $locale->text('Database Administration') . " / " . $locale->text('Restore Dataset');
 459
 460   my $pg_restore_exe = $::lx_office_conf{applications}->{pg_restore} || "pg_restore";
 461
 462   if ("$pg_restore_exe" eq "DISABLED") {
 463     $form->error($locale->text('Database backups and restorations are disabled in the configuration.'));
 464   }
 465
 466   $form->isblank("new_dbname", $locale->text('The dataset name is missing.'));
 467   $form->isblank("content", $locale->text('No backup file has been uploaded.'));
 468
 469   # Create temporary directories. Write the backup file contents to a temporary
 470   # file. Create a .pgpass file with the username and password for the pg_restore
 471   # utility.
 472
 473   my $tmpdir = "/tmp/lx_office_backup_" . Common->unique_id();
 474   mkdir $tmpdir, 0700 || $form->error($locale->text('A temporary directory could not be created:') . " $ERRNO");
 475
 476   my $pgpass = IO::File->new("${tmpdir}/.pgpass", O_WRONLY | O_CREAT, 0600);
 477
 478   if (!$pgpass) {
 479     unlink $tmpdir;
 480     $form->error($locale->text('A temporary file could not be created:') . " $ERRNO");
 481   }
 482
 483   print $pgpass "$form->{dbhost}:$form->{dbport}:$form->{new_dbname}:$form->{dbuser}:$form->{dbpasswd}\n";
 484   $pgpass->close();
 485
 486   $ENV{HOME} = $tmpdir;
 487
 488   my $tmp = $tmpdir . "/dump_" . Common::unique_id();
 489   my $tmpfile;
 490
 491   if (substr($form->{content}, 0, 2) eq "\037\213") {
 492     $tmpfile = IO::File->new("| gzip -d > $tmp");
 493     $tmpfile->binary();
 494
 495   } else {
 496     $tmpfile = IO::File->new($tmp, O_WRONLY | O_CREAT | O_BINARY, 0600);
 497   }
 498
 499   if (!$tmpfile) {
 500     unlink "${tmpdir}/.pgpass";
 501     rmdir $tmpdir;
 502
 503     $form->error($locale->text('A temporary file could not be created:') . " $ERRNO");
 504   }
 505
 506   print $tmpfile $form->{content};
 507   $tmpfile->close();
 508
 509   delete $form->{content};
 510
 511   # Try to connect to the database. Find out if a database with the same name exists.
 512   # If yes, then drop the existing database. Create a new one with the name and encoding
 513   # given by the user.
 514
 515   User::dbconnect_vars($form, "template1");
 516
 517   my %myconfig = map { $_ => $form->{$_} } grep /^db/, keys %{ $form };
 518   my $dbh      = $form->dbconnect(\%myconfig) || $form->dberror();
 519
 520   my ($query, $sth);
 521
 522   $form->{new_dbname} =~ s|[^a-zA-Z0-9_\-]||g;
 523
 524   $query = qq|SELECT COUNT(*) FROM pg_database WHERE datname = ?|;
 525   my ($count) = selectrow_query($form, $dbh, $query, $form->{new_dbname});
 526   if ($count) {
 527     do_query($form, $dbh, qq|DROP DATABASE $form->{new_dbname}|);
 528   }
 529
 530   my $found = 0;
 531   foreach my $item (@Common::db_encodings) {
 532     if ($item->{dbencoding} eq $form->{dbencoding}) {
 533       $found = 1;
 534       last;
 535     }
 536   }
 537   $form->{dbencoding} = "LATIN9" unless $form->{dbencoding};
 538
 539   do_query($form, $dbh, qq|CREATE DATABASE $form->{new_dbname} ENCODING ? TEMPLATE template0|, $form->{dbencoding});
 540
 541   $dbh->disconnect();
 542
 543   # Spawn pg_restore on the temporary file.
 544
 545   my @args = ("-h", $form->{dbhost}, "-U", $form->{dbuser}, "-d", $form->{new_dbname});
 546   push @args, ("-p", $form->{dbport}) if ($form->{dbport});
 547   push @args, $tmp;
 548
 549   my $cmd = "$pg_restore_exe " . join(" ", map { s/\\/\\\\/g; s/\"/\\\"/g; $_ } @args);
 550
 551   my $in = IO::File->new("$cmd 2>&1 |");
 552
 553   if (!$in) {
 554     unlink "${tmpdir}/.pgpass", $tmp;
 555     rmdir $tmpdir;
 556
 557     $form->error($locale->text('The pg_restore process could not be started.'));
 558   }
 559
 560   $English::AUTOFLUSH = 1;
 561
 562   $form->header();
 563   print $form->parse_html_template("admin/restore_dataset_start_header");
 564
 565   while (my $line = <$in>) {
 566     print $line;
 567   }
 568   $in->close();
 569
 570   $form->{retval} = $CHILD_ERROR >> 8;
 571   print $form->parse_html_template("admin/restore_dataset_start_footer");
 572
 573   unlink "${tmpdir}/.pgpass", $tmp;
 574   rmdir $tmpdir;
 575 }
 576
 577 sub yes {
 578   call_sub($main::form->{yes_nextsub});
 579 }
 580
 581 sub no {
 582   call_sub($main::form->{no_nextsub});
 583 }
 584
 585 sub add {
 586   call_sub($main::form->{add_nextsub});
 587 }
 588
 589 sub edit {
 590   my $form = $main::form;
 591
 592   $form->{edit_nextsub} ||= 'edit_user';
 593
 594   call_sub($form->{edit_nextsub});
 595 }
 596
 597 sub delete {
 598   my $form     = $main::form;
 599
 600   $form->{delete_nextsub} ||= 'delete_user';
 601
 602   call_sub($form->{delete_nextsub});
 603 }
 604
 605 sub save {
 606   my $form = $main::form;
 607
 608   $form->{save_nextsub} ||= 'save_user';
 609
 610   call_sub($form->{save_nextsub});
 611 }
 612
 613 sub back {
 614   call_sub($main::form->{back_nextsub});
 615 }
 616
 617 sub dispatcher {
 618   my $form   = $main::form;
 619   my $locale = $main::locale;
 620
 621   foreach my $action (qw(create_standard_group dont_create_standard_group
 622                          save_user delete_user save_user_as_new)) {
 623     if ($form->{"action_${action}"}) {
 624       call_sub($action);
 625       return;
 626     }
 627   }
 628
 629   call_sub($form->{default_action}) if ($form->{default_action});
 630
 631   $form->error($locale->text('No action defined.'));
 632 }
 633
 634 sub _search_templates {
 635   my %templates = SL::Template->available_templates;
 636
 637   return ($templates{print_templates}, $templates{master_templates});
 638 }
 639
 640 1;