bin/mozilla/datev.pl

   1 #=====================================================================
   2 # kivitendo ERP
   3 # Copyright (c) 2004
   4 #
   5 #  Author: Philip Reetz
   6 #   Email: p.reetz@linet-services.de
   7 #     Web: http://www.lx-office.org
   8 #
   9 #
  10 # This program is free software; you can redistribute it and/or modify
  11 # it under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 2 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # This program is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 # GNU General Public License for more details.
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
  22 # MA 02110-1335, USA.
  23 #======================================================================
  24 #
  25 # Datev export module
  26 #
  27 #======================================================================
  28
  29 use POSIX qw(strftime getcwd);
  30 use Archive::Zip qw(:ERROR_CODES :CONSTANTS);
  31
  32 use SL::Common;
  33 use SL::DATEV qw(:CONSTANTS);
  34 use SL::Locale::String qw(t8);
  35 use SL::DB::Department;
  36
  37 use strict;
  38
  39 1;
  40
  41 # end of main
  42
  43 require "bin/mozilla/common.pl";
  44
  45 sub continue { call_sub($main::form->{"nextsub"}); }
  46
  47 sub export {
  48   $::lxdebug->enter_sub;
  49   $::auth->assert('datev_export');
  50
  51   my $stamm = SL::DATEV->new->get_datev_stamm;
  52
  53   setup_datev_export_action_bar();
  54
  55   $::form->header;
  56   print $::form->parse_html_template('datev/export', $stamm);
  57
  58   $::lxdebug->leave_sub;
  59 }
  60
  61 sub export2 {
  62   $::lxdebug->enter_sub;
  63   $::auth->assert('datev_export');
  64
  65   if ($::form->{exporttype} == 0) {
  66     export_bewegungsdaten();
  67   } else {
  68     export_stammdaten();
  69   }
  70   $::lxdebug->leave_sub;
  71 }
  72
  73 sub export_bewegungsdaten {
  74   $::lxdebug->enter_sub;
  75   $::auth->assert('datev_export');
  76
  77   setup_datev_export2_action_bar();
  78
  79   $::form->header;
  80   $::form->{ALL_DEPARTMENTS} = SL::DB::Manager::Department->get_all;
  81   print $::form->parse_html_template('datev/export_bewegungsdaten');
  82
  83   $::lxdebug->leave_sub;
  84 }
  85
  86 sub export_stammdaten {
  87   $::lxdebug->enter_sub;
  88   $::auth->assert('datev_export');
  89
  90   setup_datev_export2_action_bar();
  91
  92   $::form->header;
  93   print $::form->parse_html_template('datev/export_stammdaten');
  94
  95   $::lxdebug->leave_sub;
  96 }
  97
  98 sub export3 {
  99   $::lxdebug->enter_sub;
 100   $::auth->assert('datev_export');
 101
 102   my %data = (
 103     exporttype => $::form->{exporttype} ? DATEV_ET_STAMM : DATEV_ET_BUCHUNGEN,
 104     format     => $::form->{kne}        ? DATEV_FORMAT_KNE : DATEV_FORMAT_OBE,
 105   );
 106
 107   if ($::form->{exporttype} == DATEV_ET_STAMM) {
 108     $data{accnofrom}  = $::form->{accnofrom},
 109     $data{accnoto}    = $::form->{accnoto},
 110   } elsif ($::form->{exporttype} == DATEV_ET_BUCHUNGEN) {
 111     @data{qw(from to)} = _get_dates(
 112       $::form->{zeitraum}, $::form->{monat}, $::form->{quartal},
 113       $::form->{transdatefrom}, $::form->{transdateto},
 114     );
 115   } else {
 116     die 'invalid exporttype';
 117   }
 118
 119   my $datev = SL::DATEV->new(%data);
 120
 121   $datev->clean_temporary_directories;
 122   $datev->save_datev_stamm($::form);
 123
 124   $datev->export;
 125
 126   if (!$datev->errors) {
 127     setup_datev_export3_action_bar(download_token => $datev->download_token);
 128
 129     $::form->header;
 130     print $::form->parse_html_template('datev/export3');
 131   } else {
 132     $::form->error("Export schlug fehl.\n" . join "\n", $datev->errors);
 133   }
 134
 135   $::lxdebug->leave_sub;
 136 }
 137
 138 sub download {
 139   $main::lxdebug->enter_sub();
 140
 141   my $form     = $main::form;
 142   my $locale   = $main::locale;
 143
 144   $::auth->assert('datev_export');
 145
 146   my $tmp_name = Common->tmpname();
 147   my $zip_name = strftime("kivitendo-datev-export-%Y%m%d.zip", localtime(time()));
 148
 149   my $cwd = getcwd();
 150
 151   my $datev = SL::DATEV->new(download_token => $form->{download_token});
 152
 153   my $path = $datev->export_path;
 154   if (!$path) {
 155     $form->error($locale->text("Your download does not exist anymore. Please re-run the DATEV export assistant."));
 156   }
 157
 158   chdir($path) || die("chdir $path");
 159
 160   my @filenames = glob "*";
 161
 162   if (!@filenames) {
 163     chdir($cwd);
 164     $form->error($locale->text("Your download does not exist anymore. Please re-run the DATEV export assistant."));
 165   }
 166
 167   my $zip = Archive::Zip->new();
 168   map { $zip->addFile($_); } @filenames;
 169   $zip->writeToFileNamed($tmp_name);
 170
 171   chdir($cwd);
 172
 173   open(IN, $tmp_name) || die("open $tmp_name");
 174   $::locale->with_raw_io(\*STDOUT, sub {
 175     print("Content-Type: application/zip\n");
 176     print("Content-Disposition: attachment; filename=\"${zip_name}\"\n\n");
 177     while (<IN>) {
 178       print($_);
 179     }
 180   });
 181   close(IN);
 182
 183   unlink($tmp_name);
 184
 185   $main::lxdebug->leave_sub();
 186 }
 187
 188 sub _get_dates {
 189   $::lxdebug->enter_sub;
 190
 191   my ($mode, $month, $quarter, $transdatefrom, $transdateto) = @_;
 192   my ($fromdate, $todate);
 193
 194   if ($mode eq "monat") {
 195     $fromdate = DateTime->new(day => 1, month => $month, year => DateTime->today->year);
 196     $todate   = $fromdate->clone->add(months => 1)->add(days => -1);
 197   } elsif ($mode eq "quartal") {
 198     die 'quarter out of of bounds' if $quarter < 1 || $quarter > 4;
 199     $fromdate = DateTime->new(day => 1, month => (3 * $quarter - 2), year => DateTime->today->year);
 200     $todate   = $fromdate->clone->add(months => 3)->add(days => -1);
 201   } elsif ($mode eq "zeit") {
 202     $fromdate = DateTime->from_lxoffice($transdatefrom);
 203     $todate   = DateTime->from_lxoffice($transdateto);
 204     die 'need from and to time' unless $fromdate && $todate;
 205   } else {
 206     die 'undefined interval mode';
 207   }
 208
 209   $::lxdebug->leave_sub;
 210
 211   return ($fromdate, $todate);
 212 }
 213
 214 sub setup_datev_export_action_bar {
 215   my %params = @_;
 216
 217   for my $bar ($::request->layout->get('actionbar')) {
 218     $bar->add(
 219       action => [
 220         t8('Continue'),
 221         submit    => [ '#form', { action => 'export2' } ],
 222         accesskey => 'enter',
 223       ],
 224     );
 225   }
 226 }
 227
 228 sub setup_datev_export2_action_bar {
 229   my %params = @_;
 230
 231   for my $bar ($::request->layout->get('actionbar')) {
 232     $bar->add(
 233       action => [
 234         t8('Export'),
 235         submit    => [ '#form', { action => 'export3' } ],
 236         accesskey => 'enter',
 237       ],
 238       action => [
 239         t8('Back'),
 240         call => [ 'kivi.history_back' ],
 241       ],
 242     );
 243   }
 244 }
 245
 246 sub setup_datev_export3_action_bar {
 247   my %params = @_;
 248
 249   for my $bar ($::request->layout->get('actionbar')) {
 250     $bar->add(
 251       link => [
 252         t8('Download'),
 253         link => [ 'datev.pl?action=download&download_token=' . $::form->escape($params{download_token}) ],
 254       ],
 255       action => [
 256         t8('Back'),
 257         call => [ 'kivi.history_back' ],
 258       ],
 259     );
 260   }
 261 }