bin/mozilla/dn.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2006
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 1998-2002
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  28 #======================================================================
  29 #
  30 # Dunning process module
  31 #
  32 #======================================================================
  33
  34 use POSIX;
  35
  36 use SL::IS;
  37 use SL::PE;
  38 use SL::DN;
  39 use SL::ReportGenerator;
  40
  41 require "bin/mozilla/common.pl";
  42 require "bin/mozilla/reportgenerator.pl";
  43 require "bin/mozilla/io.pl";
  44
  45 use strict;
  46
  47 1;
  48
  49 sub edit_config {
  50   $main::lxdebug->enter_sub();
  51
  52   my $form     = $main::form;
  53   my %myconfig = %main::myconfig;
  54   my $locale   = $main::locale;
  55
  56   $main::auth->assert('config');
  57
  58   DN->get_config(\%myconfig, \%$form);
  59   $form->get_lists('charts' => { 'key'       => 'ALL_CHARTS',
  60                                  'transdate' => 'current_date' });
  61
  62   $form->{SELECT_AR_AMOUNT} = [];
  63   $form->{SELECT_AR}        = [];
  64
  65   foreach my $chart (@{ $form->{ALL_CHARTS} }) {
  66     $chart->{LINKS} = { map { $_, 1 } split m/:/, $chart->{link} };
  67
  68     if ($chart->{LINKS}->{AR}) {
  69       $chart->{AR_selected} = "selected" if $chart->{id} == $form->{AR};
  70       push @{ $form->{SELECT_AR} }, $chart;
  71     }
  72
  73     if ($chart->{LINKS}->{AR_amount}) {
  74       $chart->{AR_amount_fee_selected}      = "selected" if $chart->{id} == $form->{AR_amount_fee};
  75       $chart->{AR_amount_interest_selected} = "selected" if $chart->{id} == $form->{AR_amount_interest};
  76       push @{ $form->{SELECT_AR_AMOUNT} }, $chart;
  77     }
  78   }
  79
  80   $form->{title}      = $locale->text('Edit Dunning Process Config');
  81   $form->{callback} ||= build_std_url("action=edit_config");
  82
  83   $form->header();
  84   print $form->parse_html_template("dunning/edit_config");
  85
  86   $main::lxdebug->leave_sub();
  87 }
  88
  89 sub add {
  90   $main::lxdebug->enter_sub();
  91
  92   my $form     = $main::form;
  93   my %myconfig = %main::myconfig;
  94   my $locale   = $main::locale;
  95
  96   $main::auth->assert('dunning_edit');
  97
  98   # setup customer selection
  99   $form->all_vc(\%myconfig, "customer", "AR");
 100
 101   DN->get_config(\%myconfig, \%$form);
 102
 103   $form->{SHOW_CUSTOMER_SELECTION}      = $form->{all_customer}    && scalar @{ $form->{all_customer} };
 104   $form->{SHOW_DUNNING_LEVEL_SELECTION} = $form->{DUNNING}         && scalar @{ $form->{DUNNING} };
 105   $form->{SHOW_DEPARTMENT_SELECTION}    = $form->{all_departments} && scalar @{ $form->{all_departments} || [] };
 106
 107   $form->{title}    = $locale->text('Start Dunning Process');
 108   $form->{jsscript} = 1;
 109   $form->{fokus}    = "search.customer";
 110   $form->header();
 111
 112   print $form->parse_html_template("dunning/add");
 113
 114   $main::lxdebug->leave_sub();
 115 }
 116
 117 sub show_invoices {
 118   $main::lxdebug->enter_sub();
 119
 120   my $form     = $main::form;
 121   my %myconfig = %main::myconfig;
 122   my $locale   = $main::locale;
 123
 124   $main::auth->assert('dunning_edit');
 125
 126   DN->get_invoices(\%myconfig, \%$form);
 127   $form->{title} = $locale->text('Start Dunning Process');
 128
 129   foreach my $row (@{ $form->{DUNNINGS} }) {
 130     $row->{DUNNING_CONFIG} = [ map +{ %{ $_ } }, @{ $form->{DUNNING_CONFIG} } ];
 131
 132     if ($row->{next_dunning_config_id}) {
 133       map { $_->{SELECTED} = $_->{id} == $row->{next_dunning_config_id} } @{ $row->{DUNNING_CONFIG } };
 134     }
 135     map { $row->{$_} = $form->format_amount(\%myconfig, $row->{$_} * 1, -2) } qw(amount open_amount fee interest);
 136   }
 137
 138   $form->get_lists('printers'  => 'printers',
 139                    'languages' => 'languages');
 140
 141   $form->{type}           = 'dunning';
 142   $form->{rowcount}       = scalar @{ $form->{DUNNINGS} };
 143   $form->{jsscript}       = 1;
 144   $form->{callback}     ||= build_std_url("action=show_invoices", qw(customer invnumber ordnumber groupinvoices minamount dunning_level notes));
 145
 146   $form->{PRINT_OPTIONS}  = print_options('inline'          => 1,
 147                                           'no_queue'        => 1,
 148                                           'no_postscript'   => 1,
 149                                           'no_html'         => 1,
 150                                           'no_opendocument' => 1,);
 151
 152   $form->header();
 153   print $form->parse_html_template("dunning/show_invoices");
 154
 155   $main::lxdebug->leave_sub();
 156 }
 157
 158 sub save {
 159   $main::lxdebug->enter_sub();
 160
 161   my $form     = $main::form;
 162   my %myconfig = %main::myconfig;
 163   my $locale   = $main::locale;
 164
 165   $main::auth->assert('config');
 166
 167   for my $i (1 .. $form->{rowcount}) {
 168     if ($form->{"dunning_description_$i"} ne "") {
 169       $form->isblank("dunning_level_$i", $locale->text('Dunning Level missing in row '). $i);
 170       $form->isblank("dunning_description_$i", $locale->text('Dunning Description missing in row '). $i);
 171       $form->isblank("terms_$i", $locale->text('Terms missing in row '). $i);
 172       $form->isblank("payment_terms_$i", $locale->text('Payment Terms missing in row '). $i);
 173     }
 174   }
 175
 176   DN->save_config(\%myconfig, \%$form);
 177   # saving the history
 178   if(!exists $form->{addition} && $form->{id} ne "") {
 179     $form->{snumbers} = qq|dunning_id_| . $form->{"dunning_id"};
 180     $form->{addition} = "SAVED FOR DUNNING";
 181     $form->save_history($form->dbconnect(\%myconfig));
 182   }
 183   # /saving the history
 184   $form->redirect($locale->text('Dunning Process Config saved!'));
 185
 186   $main::lxdebug->leave_sub();
 187 }
 188
 189 sub save_dunning {
 190   $main::lxdebug->enter_sub();
 191
 192   my $form     = $main::form;
 193   my %myconfig = %main::myconfig;
 194   my $locale   = $main::locale;
 195
 196   $main::auth->assert('dunning_edit');
 197
 198   my $active=1;
 199   my @rows = ();
 200   undef($form->{DUNNING_PDFS});
 201
 202   if ($form->{groupinvoices}) {
 203     my %dunnings_for;
 204
 205     for my $i (1 .. $form->{rowcount}) {
 206       next unless ($form->{"active_$i"});
 207
 208       $dunnings_for{$form->{"customer_id_$i"}} ||= {};
 209       my $dunning_levels = $dunnings_for{$form->{"customer_id_$i"}};
 210
 211       $dunning_levels->{$form->{"next_dunning_config_id_$i"}} ||= [];
 212       my $level = $dunning_levels->{$form->{"next_dunning_config_id_$i"}};
 213
 214       push @{ $level }, { "row"                    => $i,
 215                           "invoice_id"             => $form->{"inv_id_$i"},
 216                           "customer_id"            => $form->{"customer_id_$i"},
 217                           "next_dunning_config_id" => $form->{"next_dunning_config_id_$i"},
 218                           "email"                  => $form->{"email_$i"}, };
 219     }
 220
 221     foreach my $levels (values %dunnings_for) {
 222       foreach my $level (values %{ $levels }) {
 223         next unless scalar @{ $level };
 224
 225         DN->save_dunning(\%myconfig, $form, $level, $main::userspath, $main::spool);
 226       }
 227     }
 228
 229   } else {
 230     for my $i (1 .. $form->{rowcount}) {
 231       next unless $form->{"active_$i"};
 232
 233       my $level = [ { "row"                    => $i,
 234                       "invoice_id"             => $form->{"inv_id_$i"},
 235                       "customer_id"            => $form->{"customer_id_$i"},
 236                       "next_dunning_config_id" => $form->{"next_dunning_config_id_$i"},
 237                       "email"                  => $form->{"email_$i"}, } ];
 238       DN->save_dunning(\%myconfig, $form, $level, $main::userspath, $main::spool);
 239     }
 240   }
 241
 242   if($form->{DUNNING_PDFS}) {
 243     DN->melt_pdfs(\%myconfig, $form, $form->{copies});
 244   }
 245
 246   # saving the history
 247   if(!exists $form->{addition} && $form->{id} ne "") {
 248     $form->{snumbers} = qq|dunning_id_| . $form->{"dunning_id"};
 249     $form->{addition} = "DUNNING STARTED";
 250     $form->save_history($form->dbconnect(\%myconfig));
 251   }
 252   # /saving the history
 253
 254   if ($form->{media} eq 'printer') {
 255     delete $form->{callback};
 256     $form->redirect($locale->text('Dunning Process started for selected invoices!'));
 257   }
 258
 259   $main::lxdebug->leave_sub();
 260 }
 261
 262 sub set_email {
 263   $main::lxdebug->enter_sub();
 264
 265   my $form     = $main::form;
 266   my $locale   = $main::locale;
 267
 268   $main::auth->assert('dunning_edit');
 269
 270   $form->{"title"} = $locale->text("Set eMail text");
 271   $form->header();
 272   print($form->parse_html_template("dunning/set_email"));
 273
 274   $main::lxdebug->leave_sub();
 275 }
 276
 277 sub search {
 278   $main::lxdebug->enter_sub();
 279
 280   my $form     = $main::form;
 281   my %myconfig = %main::myconfig;
 282   my $locale   = $main::locale;
 283
 284   $main::auth->assert('dunning_edit');
 285
 286   $form->get_lists("customers"   => "ALL_CUSTOMERS",
 287                    "departments" => "ALL_DEPARTMENTS",
 288                    "salesmen"     => "ALL_SALESMEN");
 289
 290   DN->get_config(\%myconfig, \%$form);
 291
 292   $form->{SHOW_CUSTOMER_DDBOX}   = scalar @{ $form->{ALL_CUSTOMERS} } <= $myconfig{vclimit};
 293   $form->{SHOW_DEPARTMENT_DDBOX} = scalar @{ $form->{ALL_CUSTOMERS} };
 294   $form->{SHOW_DUNNING_LEVELS}   = scalar @{ $form->{DUNNING} };
 295
 296   $form->{jsscript} = 1;
 297   $form->{title}    = $locale->text('Dunnings');
 298   $form->{fokus}    = "search.customer";
 299   $form->{salesman_labels} = sub { $_[0]->{"name"} || $_[0]->{"login"} };
 300
 301   $form->header();
 302
 303   $form->{onload} = qq|focus()|
 304     . qq|;setupDateFormat('|. $myconfig{dateformat} .qq|', '|. $locale->text("Falsches Datumsformat!") .qq|')|
 305     . qq|;setupPoints('|. $myconfig{numberformat} .qq|', '|. $locale->text("wrongformat") .qq|')|;
 306
 307   print $form->parse_html_template("dunning/search");
 308
 309   $main::lxdebug->leave_sub();
 310
 311 }
 312
 313 sub show_dunning {
 314   $main::lxdebug->enter_sub();
 315
 316   my $form     = $main::form;
 317   my %myconfig = %main::myconfig;
 318   my $locale   = $main::locale;
 319   my $cgi      = $main::cgi;
 320
 321   $main::auth->assert('dunning_edit');
 322
 323   my @filter_field_list = qw(customer_id customer dunning_level department_id invnumber ordnumber
 324                              transdatefrom transdateto dunningfrom dunningto notes showold l_salesman salesman_id);
 325
 326   report_generator_set_default_sort('customername', 1);
 327
 328   DN->get_dunning(\%myconfig, \%$form);
 329
 330   if (!$form->{callback}) {
 331     $form->{callback} = build_std_url("action=show_dunning", @filter_field_list);
 332   }
 333
 334   $form->get_lists('printers'  => 'printers',
 335                    'languages' => 'languages');
 336
 337   $form->{type}          = 'dunning';
 338   $form->{PRINT_OPTIONS} = print_options('inline'          => 1,
 339                                          'no_queue'        => 1,
 340                                          'no_postscript'   => 1,
 341                                          'no_html'         => 1,
 342                                          'no_opendocument' => 1,);
 343   $form->{title}         = $locale->text('Dunning overview');
 344
 345   my $report = SL::ReportGenerator->new(\%myconfig, $form);
 346
 347   $report->set_options('std_column_visibility' => 1,
 348                        'title'                 => $form->{title});
 349   $report->set_export_options('show_dunning', @filter_field_list, qw(sort sortdir));
 350
 351   my %column_defs         =  (
 352     'checkbox'            => { 'text' => '', 'visible' => 'HTML' },
 353     'dunning_description' => { 'text' => $locale->text('Dunning Level') },
 354     'customername'        => { 'text' => $locale->text('Customername') },
 355     'invnumber'           => { 'text' => $locale->text('Invnumber') },
 356     'transdate'           => { 'text' => $locale->text('Invdate') },
 357     'duedate'             => { 'text' => $locale->text('Invoice Duedate') },
 358     'amount'              => { 'text' => $locale->text('Amount') },
 359     'dunning_date'        => { 'text' => $locale->text('Dunning Date') },
 360     'dunning_duedate'     => { 'text' => $locale->text('Dunning Duedate') },
 361     'fee'                 => { 'text' => $locale->text('Total Fees') },
 362     'interest'            => { 'text' => $locale->text('Interest') },
 363     'salesman'            => { 'text' => $locale->text('Salesperson'), 'visible' => $form->{l_salesman} ? 1 : 0 },
 364   );
 365
 366   $report->set_columns(%column_defs);
 367   $report->set_column_order(qw(checkbox dunning_description customername invnumber transdate
 368                                duedate amount dunning_date dunning_duedate fee interest salesman));
 369   $report->set_sort_indicator($form->{sort}, $form->{sortdir});
 370
 371   my $edit_url  = build_std_url('script=is.pl', 'action=edit', 'callback') . '&id=';
 372   my $print_url = build_std_url('action=print_dunning', 'format=pdf', 'media=screen') . '&dunning_id=';
 373   my $sort_url  = build_std_url('action=show_dunning', grep { $form->{$_} } @filter_field_list);
 374
 375   foreach my $name (qw(dunning_description customername invnumber transdate duedate dunning_date dunning_duedate salesman)) {
 376     my $sortdir                 = $form->{sort} eq $name ? 1 - $form->{sortdir} : $form->{sortdir};
 377     $column_defs{$name}->{link} = $sort_url . "&sort=$name&sortdir=$sortdir";
 378   }
 379
 380   my %alignment = map { $_ => 'right' } qw(transdate duedate amount dunning_date dunning_duedate fee interest salesman);
 381
 382   my ($current_dunning_rows, $previous_dunning_id, $first_row_for_dunning);
 383
 384   $current_dunning_rows  = [];
 385   $first_row_for_dunning = 1;
 386   $form->{rowcount}      = scalar @{ $form->{DUNNINGS} };
 387
 388   my $i = 0;
 389
 390   foreach my $ref (@{ $form->{DUNNINGS} }) {
 391     $i++;
 392
 393     if ($previous_dunning_id != $ref->{dunning_id}) {
 394       $report->add_data($current_dunning_rows) if (scalar @{ $current_dunning_rows });
 395       $current_dunning_rows  = [];
 396       $first_row_for_dunning = 1;
 397     }
 398
 399     my $row = { };
 400     foreach my $column (keys %{ $ref }) {
 401       $row->{$column} = {
 402         'data'  => $first_row_for_dunning || (($column ne 'dunning_description') && ($column ne 'customername')) ? $ref->{$column} : '',
 403
 404         'align' => $alignment{$column},
 405
 406         'link'  => ($column eq 'invnumber'           ? $edit_url  . E($ref->{id})         :
 407                     $column eq 'dunning_description' ? $print_url . E($ref->{dunning_id}) : ''),
 408       };
 409     }
 410
 411     $row->{checkbox} = !$first_row_for_dunning ? { } : {
 412       'raw_data' =>   $cgi->hidden('-name' => "dunning_id_$i", '-value' => $ref->{dunning_id})
 413                     . $cgi->checkbox('-name' => "selected_$i", '-value' => 1, '-label' => ''),
 414       'valign'   => 'center',
 415       'align'    => 'center',
 416     };
 417
 418     push @{ $current_dunning_rows }, $row;
 419
 420     $previous_dunning_id   = $ref->{dunning_id};
 421     $first_row_for_dunning = 0;
 422   }
 423
 424   $report->add_data($current_dunning_rows) if (scalar @{ $current_dunning_rows });
 425
 426   $report->set_options('raw_top_info_text'    => $form->parse_html_template('dunning/show_dunning_top'),
 427                        'raw_bottom_info_text' => $form->parse_html_template('dunning/show_dunning_bottom'),
 428                        'output_format'        => 'HTML',
 429                        'attachment_basename'  => $locale->text('dunning_list') . strftime('_%Y%m%d', localtime time),
 430     );
 431
 432   $report->set_options_from_form();
 433
 434   $report->generate_with_headers();
 435
 436   $main::lxdebug->leave_sub();
 437
 438 }
 439
 440 sub print_dunning {
 441   $main::lxdebug->enter_sub();
 442
 443   my $form     = $main::form;
 444
 445   $main::auth->assert('dunning_edit');
 446
 447   $form->{rowcount}     = 1;
 448   $form->{selected_1}   = 1;
 449   $form->{dunning_id_1} = $form->{dunning_id};
 450
 451   print_multiple();
 452
 453   $main::lxdebug->leave_sub();
 454 }
 455
 456 sub print_multiple {
 457   $main::lxdebug->enter_sub();
 458
 459   my $form     = $main::form;
 460   my %myconfig = %main::myconfig;
 461   my $locale   = $main::locale;
 462
 463   $main::auth->assert('dunning_edit');
 464
 465   $form->{title} = $locale->text('Print dunnings');
 466
 467   my @dunning_ids = map { $form->{"dunning_id_$_"} } grep { $form->{"selected_$_"} } (1..$form->{rowcount});
 468
 469   if (!scalar @dunning_ids) {
 470     $form->error($locale->text('No dunnings have been selected for printing.'));
 471   }
 472
 473   $form->{DUNNING_PDFS} = [];
 474
 475   foreach my $dunning_id (@dunning_ids) {
 476     DN->print_invoice_for_fees(\%myconfig, $form, $dunning_id);
 477     DN->print_dunning(\%myconfig, $form, $dunning_id);
 478   }
 479
 480   if (scalar @{ $form->{DUNNING_PDFS} }) {
 481     $form->{dunning_id} = strftime("%Y%m%d", localtime time);
 482     DN->melt_pdfs(\%myconfig, $form, $form->{copies});
 483
 484     if ($form->{media} eq 'printer') {
 485       $form->header();
 486       $form->info($locale->text('The dunnings have been printed.'));
 487     }
 488
 489   } else {
 490     $form->redirect($locale->text('Could not print dunning.'));
 491   }
 492
 493   $main::lxdebug->leave_sub();
 494 }
 495
 496 sub continue {
 497   call_sub($main::form->{nextsub});
 498 }
 499
 500 # end of main