bin/mozilla/ir.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger, Accounting
   9 # Copyright (c) 1998-2002
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
  28 # MA 02110-1335, USA.
  29 #======================================================================
  30 #
  31 # Inventory received module
  32 #
  33 #======================================================================
  34
  35 use SL::FU;
  36 use SL::IR;
  37 use SL::IS;
  38 use SL::DB::Default;
  39 use SL::DB::Department;
  40 use SL::DB::PurchaseInvoice;
  41 use SL::DB::Vendor;
  42 use List::Util qw(max sum);
  43 use List::UtilsBy qw(sort_by);
  44
  45 require "bin/mozilla/io.pl";
  46 require "bin/mozilla/common.pl";
  47
  48 use strict;
  49
  50 1;
  51
  52 # end of main
  53
  54 sub add {
  55   $main::lxdebug->enter_sub();
  56
  57   my $form     = $main::form;
  58   my $locale   = $main::locale;
  59
  60   $main::auth->assert('vendor_invoice_edit');
  61
  62   if (!$::instance_conf->get_allow_new_purchase_invoice) {
  63     $::form->show_generic_error($::locale->text("You do not have the permissions to access this function."));
  64   }
  65
  66   $form->{show_details} = $::myconfig{show_form_details};
  67
  68   $form->{title} = $locale->text('Record Vendor Invoice');
  69
  70   &invoice_links;
  71   &prepare_invoice;
  72   &display_form;
  73
  74   $main::lxdebug->leave_sub();
  75 }
  76
  77 sub edit {
  78   $main::lxdebug->enter_sub();
  79
  80   my $form     = $main::form;
  81   my $locale   = $main::locale;
  82
  83   $main::auth->assert('vendor_invoice_edit');
  84
  85   $form->{show_details} = $::myconfig{show_form_details};
  86
  87   # show history button
  88   $form->{javascript} = qq|<script type=text/javascript src=js/show_history.js></script>|;
  89   #/show hhistory button
  90
  91   $form->{title} = $locale->text('Edit Vendor Invoice');
  92
  93   &invoice_links;
  94   &prepare_invoice;
  95   &display_form;
  96
  97   $main::lxdebug->leave_sub();
  98 }
  99
 100 sub invoice_links {
 101   $main::lxdebug->enter_sub();
 102
 103   my $form     = $main::form;
 104   my %myconfig = %main::myconfig;
 105
 106   $main::auth->assert('vendor_invoice_edit');
 107
 108   $form->{vc} = 'vendor';
 109
 110   # create links
 111   $form->create_links("AP", \%myconfig, "vendor");
 112
 113   $form->backup_vars(qw(payment_id language_id taxzone_id
 114                         currency delivery_term_id intnotes cp_id));
 115
 116   IR->get_vendor(\%myconfig, \%$form);
 117   IR->retrieve_invoice(\%myconfig, \%$form);
 118
 119   $form->restore_vars(qw(payment_id language_id taxzone_id
 120                          currency delivery_term_id intnotes cp_id));
 121
 122   my @curr = $form->get_all_currencies();
 123   map { $form->{selectcurrency} .= "<option>$_\n" } @curr;
 124
 125   # forex
 126   $form->{forex} = $form->{exchangerate};
 127   my $exchangerate = ($form->{exchangerate}) ? $form->{exchangerate} : 1;
 128
 129   foreach my $key (keys %{ $form->{AP_links} }) {
 130
 131     foreach my $ref (@{ $form->{AP_links}{$key} }) {
 132       $form->{"select$key"} .= "<option>$ref->{accno}--$ref->{description}</option>";
 133     }
 134
 135     next unless $form->{acc_trans}{$key};
 136
 137     if ($key eq "AP_paid") {
 138       for my $i (1 .. scalar @{ $form->{acc_trans}{$key} }) {
 139         $form->{"AP_paid_$i"} =
 140           "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 141
 142         $form->{"acc_trans_id_$i"} = $form->{acc_trans}{$key}->[$i - 1]->{acc_trans_id};
 143         # reverse paid
 144         $form->{"paid_$i"}     = $form->{acc_trans}{$key}->[$i - 1]->{amount};
 145         $form->{"datepaid_$i"} =
 146           $form->{acc_trans}{$key}->[$i - 1]->{transdate};
 147         $form->{"gldate_$i"}   = $form->{acc_trans}{$key}->[$i - 1]->{gldate};
 148         $form->{"forex_$i"} = $form->{"exchangerate_$i"} =
 149           $form->{acc_trans}{$key}->[$i - 1]->{exchangerate};
 150         $form->{"source_$i"} = $form->{acc_trans}{$key}->[$i - 1]->{source};
 151         $form->{"memo_$i"}   = $form->{acc_trans}{$key}->[$i - 1]->{memo};
 152
 153         $form->{paidaccounts} = $i;
 154       }
 155     } else {
 156       $form->{$key} =
 157         "$form->{acc_trans}{$key}->[0]->{accno}--$form->{acc_trans}{$key}->[0]->{description}";
 158     }
 159
 160   }
 161
 162   $form->{paidaccounts} = 1 unless (exists $form->{paidaccounts});
 163
 164   $form->{AP} = $form->{AP_1} unless $form->{id};
 165
 166   $form->{locked} =
 167     ($form->datetonum($form->{invdate}, \%myconfig) <=
 168      $form->datetonum($form->{closedto}, \%myconfig));
 169
 170   $main::lxdebug->leave_sub();
 171 }
 172
 173 sub prepare_invoice {
 174   $main::lxdebug->enter_sub();
 175
 176   my $form     = $main::form;
 177   my %myconfig = %main::myconfig;
 178
 179   $main::auth->assert('vendor_invoice_edit');
 180
 181   $form->{type}     = "purchase_invoice";
 182
 183   if ($form->{id}) {
 184
 185     map { $form->{$_} =~ s/\"/&quot;/g } qw(invnumber ordnumber quonumber);
 186
 187     my $i = 0;
 188     foreach my $ref (@{ $form->{invoice_details} }) {
 189       $i++;
 190       map { $form->{"${_}_$i"} = $ref->{$_} } keys %{$ref};
 191       # übernommen aus is.pl Fix für Bug 1642. Nebenwirkungen? jb 12.5.2011
 192       # getestet: Lieferantenauftrag -> Rechnung i.O.
 193       #           Lieferantenauftrag -> Lieferschein -> Rechnung i.O.
 194       # Werte: 20% (Lieferantenrabatt), 12,4% individuell und 0,4 individuell s.a.
 195       # Screenshot zu Bug 1642
 196       $form->{"discount_$i"}   = $form->format_amount(\%myconfig, $form->{"discount_$i"} * 100);
 197
 198       my ($dec) = ($form->{"sellprice_$i"} =~ /\.(\d+)/);
 199       $dec           = length $dec;
 200       my $decimalplaces = ($dec > 2) ? $dec : 2;
 201
 202       $form->{"sellprice_$i"} =
 203         $form->format_amount(\%myconfig, $form->{"sellprice_$i"},
 204                              $decimalplaces);
 205
 206       (my $dec_qty) = ($form->{"qty_$i"} =~ /\.(\d+)/);
 207       $dec_qty = length $dec_qty;
 208
 209       $form->{"qty_$i"} =
 210         $form->format_amount(\%myconfig, ($form->{"qty_$i"} * -1), $dec_qty);
 211
 212       $form->{rowcount} = $i;
 213     }
 214   }
 215
 216   $main::lxdebug->leave_sub();
 217 }
 218
 219 sub form_header {
 220   $main::lxdebug->enter_sub();
 221
 222   my $form     = $main::form;
 223   my %myconfig = %main::myconfig;
 224   my $locale   = $main::locale;
 225   my $cgi      = $::request->{cgi};
 226
 227   $main::auth->assert('vendor_invoice_edit');
 228
 229   my %TMPL_VAR = ();
 230   my @custom_hiddens;
 231
 232   $TMPL_VAR{invoice_obj} = SL::DB::PurchaseInvoice->load_cached($form->{id}) if $form->{id};
 233   $TMPL_VAR{vendor_obj}  = SL::DB::Vendor->load_cached($form->{vendor_id})   if $form->{vendor_id};
 234   $form->{employee_id} = $form->{old_employee_id} if $form->{old_employee_id};
 235   $form->{salesman_id} = $form->{old_salesman_id} if $form->{old_salesman_id};
 236
 237   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 238
 239   my @old_project_ids = ($form->{"globalproject_id"});
 240   map { push @old_project_ids, $form->{"project_id_$_"} if $form->{"project_id_$_"}; } 1..$form->{"rowcount"};
 241
 242   $form->get_lists("taxzones"      => ($form->{id} ? "ALL_TAXZONES" : "ALL_ACTIVE_TAXZONES"),
 243                    "currencies"    => "ALL_CURRENCIES",
 244                    "price_factors" => "ALL_PRICE_FACTORS");
 245
 246   $TMPL_VAR{ALL_DEPARTMENTS}       = SL::DB::Manager::Department->get_all_sorted;
 247   $TMPL_VAR{ALL_EMPLOYEES}         = SL::DB::Manager::Employee->get_all_sorted(query => [ or => [ id => $::form->{employee_id},  deleted => 0 ] ]);
 248   $TMPL_VAR{ALL_CONTACTS}          = SL::DB::Manager::Contact->get_all_sorted(query => [
 249     or => [
 250       cp_cv_id => $::form->{"$::form->{vc}_id"} * 1,
 251       and      => [
 252         cp_cv_id => undef,
 253         cp_id    => $::form->{cp_id} * 1
 254       ]
 255     ]
 256   ]);
 257
 258   # currencies and exchangerate
 259   my @values = map { $_       } @{ $form->{ALL_CURRENCIES} };
 260   my %labels = map { $_ => $_ } @{ $form->{ALL_CURRENCIES} };
 261   $form->{currency}            = $form->{defaultcurrency} unless $form->{currency};
 262   # show_exchangerate is also later needed in another template
 263   $form->{show_exchangerate} = $form->{currency} ne $form->{defaultcurrency};
 264   $TMPL_VAR{currencies}        = NTI($cgi->popup_menu('-name' => 'currency', '-default' => $form->{"currency"},
 265                                                       '-values' => \@values, '-labels' => \%labels,
 266                                                       '-onchange' => "document.getElementById('update_button').click();"
 267                                      )) if scalar @values;
 268   push @custom_hiddens, "forex";
 269   push @custom_hiddens, "exchangerate" if $form->{forex};
 270
 271   $TMPL_VAR{creditwarning} = ($form->{creditlimit} != 0) && ($form->{creditremaining} < 0) && !$form->{update};
 272   $TMPL_VAR{is_credit_remaining_negativ} = $form->{creditremaining} =~ /-/;
 273
 274 # set option selected
 275   foreach my $item (qw(AP)) {
 276     $form->{"select$item"} =~ s/ selected//;
 277     $form->{"select$item"} =~ s/option>\Q$form->{$item}\E/option selected>$form->{$item}/;
 278   }
 279
 280   $TMPL_VAR{is_type_credit_note} = $form->{type}   eq "credit_note";
 281   $TMPL_VAR{is_format_html}      = $form->{format} eq 'html';
 282   $TMPL_VAR{dateformat}          = $myconfig{dateformat};
 283   $TMPL_VAR{numberformat}        = $myconfig{numberformat};
 284
 285   # hiddens
 286   $TMPL_VAR{HIDDENS} = [qw(
 287     id action type media format queued printed emailed title vc discount
 288     title creditlimit creditremaining tradediscount business closedto locked shipped storno storno_id
 289     max_dunning_level dunning_amount
 290     shiptoname shiptostreet shiptozipcode shiptocity shiptocountry shiptogln shiptocontact shiptophone shiptofax
 291     shiptoemail shiptodepartment_1 shiptodepartment_2 message email subject cc bcc taxaccounts cursor_fokus
 292     convert_from_do_ids convert_from_oe_ids convert_from_ap_ids show_details gldate useasnew
 293   ), @custom_hiddens,
 294   map { $_.'_rate', $_.'_description', $_.'_taxnumber' } split / /, $form->{taxaccounts}];
 295
 296   $TMPL_VAR{payment_terms_obj} = get_payment_terms_for_invoice();
 297   $form->{duedate}             = $TMPL_VAR{payment_terms_obj}->calc_date(reference_date => $form->{invdate}, due_date => $form->{duedate})->to_kivitendo if $TMPL_VAR{payment_terms_obj};
 298
 299   $::request->{layout}->use_javascript(map { "${_}.js" } qw(kivi.Draft kivi.File  kivi.SalesPurchase kivi.Part ckeditor/ckeditor ckeditor/adapters/jquery kivi.io autocomplete_customer autocomplete_project client_js));
 300
 301   my $show_delete = $::instance_conf->get_ir_changeable == 2 ? $form->current_date(\%myconfig) eq $form->{gldate}
 302                   : $::instance_conf->get_ir_changeable == 1;
 303
 304   for my $bar ($::request->layout->get('actionbar')) {
 305     $bar->add_actions([ t8('Update'),
 306       submit => [ '#form', { action_update         => 1 } ],
 307       id => 'update_button',
 308       accesskey => '13',
 309     ]);
 310     $bar->add_actions("combobox");
 311     $bar->actions->[-1]->add_actions([ t8('Post'),
 312       submit => [ '#form', { action_post           => 1 } ],
 313       disabled => (!$::form->{id} && $::form->{locked}) || ($::form->{id} && !$show_delete),
 314     ]);
 315     $bar->actions->[-1]->add_actions([ t8('Post Payment'),
 316       submit => [ '#form', { action_post_payment    => 1 } ],
 317       disabled => !$::form->{id},
 318     ]);
 319     $bar->actions->[-1]->add_actions([ t8('mark as paid'),
 320       submit => [ '#form', { action_mark_as_paid    => 1 } ],
 321       confirm => t8('This will remove the invoice from showing as unpaid even if the unpaid amount does not match the amount. Proceed?'),
 322       disabled => !$::form->{id},
 323     ]) if $::instance_conf->get_ir_show_mark_as_paid;
 324
 325     $bar->add_actions("combobox");
 326     $bar->actions->[-1]->add_actions([ t8('Storno'),
 327       submit => [ '#form', { action_storno         => 1 } ],
 328       confirm => t8('Do you really want to cancel this invoice?'),
 329       disabled => !$::form->{id} || !$show_delete,
 330     ]);
 331     $bar->actions->[-1]->add_actions([ t8('Delete'),
 332       submit => [ '#form', { action_delete         => 1 } ],
 333       confirm => t8('Do you really want to delete this object?'),
 334       disabled => !$::form->{id} || !$show_delete,
 335     ]);
 336     $bar->add_actions('separator');
 337     $bar->add_actions('combobox');
 338     $bar->actions->[-1]->add_actions([ t8('more'),
 339       disabled => 1,
 340     ]);
 341     $bar->actions->[-1]->add_actions([ t8('History'),
 342       call     => [ 'set_history_window', $::form->{id} * 1, 'id', 'glid' ],
 343       disabled => !$::form->{id},
 344     ]);
 345     $bar->actions->[-1]->add_actions([ t8('Follow-Up'),
 346       call     => [ 'follow_up_window' ],
 347       disabled => !$::form->{id},
 348     ]);
 349     $bar->actions->[-1]->add_actions([ t8('Drafts'),
 350       call     => [ 'kivi.Draft.popup', 'ir', 'invoice', $::form->{draft_id}, $::form->{draft_description} ],
 351       disabled => $::form->{id},
 352     ]);
 353   }
 354
 355   $form->header();
 356
 357   print $form->parse_html_template("ir/form_header", \%TMPL_VAR);
 358
 359   $main::lxdebug->leave_sub();
 360 }
 361
 362 sub _sort_payments {
 363   my @fields   = qw(acc_trans_id gldate datepaid source memo paid AP_paid);
 364   my @payments =
 365     grep { $_->{paid} != 0 }
 366     map  {
 367       my $idx = $_;
 368       +{ map { ($_ => delete($::form->{"${_}_${idx}"})) } @fields }
 369     } (1..$::form->{paidaccounts});
 370
 371   @payments = sort_by { DateTime->from_kivitendo($_->{datepaid}) } @payments;
 372
 373   $::form->{paidaccounts} = max scalar(@payments), 1;
 374
 375   foreach my $idx (1 .. scalar(@payments)) {
 376     my $payment = $payments[$idx - 1];
 377     $::form->{"${_}_${idx}"} = $payment->{$_} for @fields;
 378   }
 379 }
 380
 381 sub form_footer {
 382   $main::lxdebug->enter_sub();
 383
 384   my $form     = $main::form;
 385   my %myconfig = %main::myconfig;
 386   my $locale   = $main::locale;
 387
 388   $main::auth->assert('vendor_invoice_edit');
 389
 390   $form->{invtotal}    = $form->{invsubtotal};
 391   $form->{oldinvtotal} = $form->{invtotal};
 392
 393   # note rows
 394   $form->{rows} = max 2,
 395     $form->numtextrows($form->{notes},    26, 8),
 396     $form->numtextrows($form->{intnotes}, 35, 8);
 397
 398
 399   # tax, total and subtotal calculations
 400   my ($tax, $subtotal);
 401   $form->{taxaccounts_array} = [ split / /, $form->{taxaccounts} ];
 402
 403   foreach my $item (@{ $form->{taxaccounts_array} }) {
 404     if ($form->{"${item}_base"}) {
 405       if ($form->{taxincluded}) {
 406         $form->{"${item}_total"} = $form->round_amount( ($form->{"${item}_base"} * $form->{"${item}_rate"}
 407                                                                                  / (1 + $form->{"${item}_rate"})), 2);
 408         $form->{"${item}_netto"} = $form->round_amount( ($form->{"${item}_base"} - $form->{"${item}_total"}), 2);
 409       } else {
 410         $form->{"${item}_total"} = $form->round_amount( $form->{"${item}_base"} * $form->{"${item}_rate"}, 2);
 411         $form->{invtotal} += $form->{"${item}_total"};
 412       }
 413     }
 414   }
 415
 416   # follow ups
 417   if ($form->{id}) {
 418     $form->{follow_ups}            = FU->follow_ups('trans_id' => $form->{id}, 'not_done' => 1) || [];
 419     $form->{follow_ups_unfinished} = ( sum map { $_->{due} * 1 } @{ $form->{follow_ups} } ) || 0;
 420   }
 421
 422   # payments
 423   _sort_payments();
 424
 425   my $totalpaid = 0;
 426   $form->{paidaccounts}++ if ($form->{"paid_$form->{paidaccounts}"});
 427   $form->{paid_indices} = [ 1 .. $form->{paidaccounts} ];
 428
 429   # Standard Konto für Umlaufvermögen
 430   my $accno_arap = IS->get_standard_accno_current_assets(\%myconfig, \%$form);
 431
 432   for my $i (1 .. $form->{paidaccounts}) {
 433     $form->{"changeable_$i"} = 1;
 434     if (SL::DB::Default->get->payments_changeable == 0) {
 435       # never
 436       $form->{"changeable_$i"} = ($form->{"acc_trans_id_$i"})? 0 : 1;
 437     } elsif (SL::DB::Default->get->payments_changeable == 2) {
 438       # on the same day
 439       $form->{"changeable_$i"} = (($form->{"gldate_$i"} eq '') ||
 440                                   ($form->current_date(\%myconfig) eq $form->{"gldate_$i"}));
 441     }
 442
 443     $form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 444       if ($form->date_max_future($form->{"datepaid_$i"}, \%myconfig));
 445
 446     #deaktivieren von Zahlungen ausserhalb der Bücherkontrolle
 447     if ($form->date_closed($form->{"gldate_$i"})) {
 448       $form->{"changeable_$i"} = 0;
 449     }
 450
 451     $form->{"selectAP_paid_$i"} = $form->{selectAP_paid};
 452     if (!$form->{"AP_paid_$i"}) {
 453       $form->{"selectAP_paid_$i"} =~ s/option>$accno_arap--(.*?)>/option selected>$accno_arap--$1>/;
 454     } else {
 455       $form->{"selectAP_paid_$i"} =~ s/option>\Q$form->{"AP_paid_$i"}\E/option selected>$form->{"AP_paid_$i"}/;
 456     }
 457
 458     $totalpaid += $form->{"paid_$i"};
 459   }
 460
 461   $form->{ALL_DELIVERY_TERMS} = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 462
 463   print $form->parse_html_template('ir/form_footer', {
 464     is_type_credit_note => ($form->{type} eq "credit_note"),
 465     totalpaid           => $totalpaid,
 466     paid_missing        => $form->{invtotal} - $totalpaid,
 467     show_storno         => $form->{id} && !$form->{storno} && !IS->has_storno(\%myconfig, $form, "ap") && !$totalpaid,
 468     show_delete         => ($::instance_conf->get_ir_changeable == 2)
 469                              ? ($form->current_date(\%myconfig) eq $form->{gldate})
 470                              : ($::instance_conf->get_ir_changeable == 1),
 471     today               => DateTime->today,
 472   });
 473 ##print $form->parse_html_template('ir/_payments'); # parser
 474 ##print $form->parse_html_template('webdav/_list'); # parser
 475
 476   $main::lxdebug->leave_sub();
 477 }
 478
 479 sub mark_as_paid {
 480   $::auth->assert('vendor_invoice_edit');
 481
 482   SL::DB::PurchaseInvoice->new(id => $::form->{id})->load->mark_as_paid;
 483
 484   $::form->redirect($::locale->text("Marked as paid"));
 485 }
 486
 487 sub show_draft {
 488   update();
 489 }
 490
 491 sub update {
 492   $main::lxdebug->enter_sub();
 493
 494   my $form     = $main::form;
 495   my %myconfig = %main::myconfig;
 496
 497   $main::auth->assert('vendor_invoice_edit');
 498
 499   if (($form->{previous_vendor_id} || $form->{vendor_id}) != $form->{vendor_id}) {
 500     IR->get_vendor(\%myconfig, $form);
 501   }
 502
 503   if (!$form->{forex}) {        # read exchangerate from input field (not hidden)
 504     $form->{exchangerate} = $form->parse_amount(\%myconfig, $form->{exchangerate});
 505   }
 506   $form->{forex}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{invdate}, 'sell');
 507   $form->{exchangerate} = $form->{forex} if $form->{forex};
 508
 509   for my $i (1 .. $form->{paidaccounts}) {
 510     next unless $form->{"paid_$i"};
 511     map { $form->{"${_}_$i"} = $form->parse_amount(\%myconfig, $form->{"${_}_$i"}) } qw(paid exchangerate);
 512     $form->{"forex_$i"}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'sell');
 513     $form->{"exchangerate_$i"} = $form->{"forex_$i"} if $form->{"forex_$i"};
 514   }
 515
 516   my $i            = $form->{rowcount};
 517   my $exchangerate = ($form->{exchangerate} * 1) || 1;
 518
 519   if (   ($form->{"partnumber_$i"} eq "")
 520       && ($form->{"description_$i"} eq "")
 521       && ($form->{"partsgroup_$i"} eq "")) {
 522     $form->{creditremaining} += ($form->{oldinvtotal} - $form->{oldtotalpaid});
 523     &check_form;
 524
 525   } else {
 526
 527     IR->retrieve_item(\%myconfig, \%$form);
 528
 529     my $rows = scalar @{ $form->{item_list} };
 530
 531     $form->{"discount_$i"}   = $form->parse_amount(\%myconfig, $form->{"discount_$i"}) / 100.0;
 532     $form->{"discount_$i"} ||= $form->{vendor_discount};
 533
 534     if ($rows) {
 535       $form->{"qty_$i"} = $form->parse_amount(\%myconfig, $form->{"qty_$i"});
 536       if( !$form->{"qty_$i"} ) {
 537         $form->{"qty_$i"} = 1;
 538       }
 539
 540       if ($rows > 1) {
 541
 542         select_item(mode => 'IR', pre_entered_qty => $form->{"qty_$i"});
 543         $::dispatcher->end_request;
 544
 545       } else {
 546
 547         # override sellprice if there is one entered
 548         my $sellprice = $form->parse_amount(\%myconfig, $form->{"sellprice_$i"});
 549
 550         map { $form->{item_list}[$i]{$_} =~ s/\"/&quot;/g } qw(partnumber description unit);
 551         map { $form->{"${_}_$i"} = $form->{item_list}[0]{$_} } keys %{ $form->{item_list}[0] };
 552
 553         $form->{"marge_price_factor_$i"} = $form->{item_list}->[0]->{price_factor};
 554
 555         ($sellprice || $form->{"sellprice_$i"}) =~ /\.(\d+)/;
 556         my $dec_qty       = length $1;
 557         my $decimalplaces = max 2, $dec_qty;
 558
 559         if ($sellprice) {
 560           $form->{"sellprice_$i"} = $sellprice;
 561         } else {
 562           my $record        = _make_record();
 563           my $price_source  = SL::PriceSource->new(record_item => $record->items->[$i-1], record => $record);
 564           my $best_price    = $price_source->best_price;
 565           my $best_discount = $price_source->best_discount;
 566
 567           if ($best_price) {
 568             $::form->{"sellprice_$i"}           = $best_price->price;
 569             $::form->{"active_price_source_$i"} = $best_price->source;
 570           }
 571           if ($best_discount) {
 572             $::form->{"discount_$i"}               = $best_discount->discount;
 573             $::form->{"active_discount_source_$i"} = $best_discount->source;
 574           }
 575
 576           # if there is an exchange rate adjust sellprice
 577           $form->{"sellprice_$i"} /= $exchangerate;
 578         }
 579
 580         my $amount                = $form->{"sellprice_$i"} * $form->{"qty_$i"} * (1 - $form->{"discount_$i"});
 581         $form->{creditremaining} -= $amount;
 582         $form->{"sellprice_$i"}   = $form->format_amount(\%myconfig, $form->{"sellprice_$i"}, $decimalplaces);
 583         $form->{"qty_$i"}         = $form->format_amount(\%myconfig, $form->{"qty_$i"},       $dec_qty);
 584         $form->{"discount_$i"}    = $form->format_amount(\%myconfig, $form->{"discount_$i"} * 100.0);
 585       }
 586
 587       &display_form;
 588
 589     } else {
 590
 591       # ok, so this is a new part
 592       # ask if it is a part or service item
 593
 594       if (   $form->{"partsgroup_$i"}
 595           && ($form->{"partsnumber_$i"} eq "")
 596           && ($form->{"description_$i"} eq "")) {
 597         $form->{rowcount}--;
 598         $form->{"discount_$i"} = "";
 599         display_form();
 600
 601       } else {
 602         $form->{"id_$i"}   = 0;
 603         new_item();
 604       }
 605     }
 606   }
 607   $main::lxdebug->leave_sub();
 608 }
 609
 610 sub storno {
 611   $main::lxdebug->enter_sub();
 612
 613   my $form     = $main::form;
 614   my %myconfig = %main::myconfig;
 615   my $locale   = $main::locale;
 616
 617   $main::auth->assert('vendor_invoice_edit');
 618
 619   if ($form->{storno}) {
 620     $form->error($locale->text('Cannot storno storno invoice!'));
 621   }
 622
 623   if (IS->has_storno(\%myconfig, $form, "ap")) {
 624     $form->error($locale->text("Invoice has already been storno'd!"));
 625   }
 626
 627   $form->error($locale->text('Cannot post storno for a closed period!'))
 628     if ( $form->date_closed($form->{invdate}, \%myconfig));
 629
 630   my $employee_id = $form->{employee_id};
 631   invoice_links();
 632   prepare_invoice();
 633   relink_accounts();
 634
 635   # Payments must not be recorded for the new storno invoice.
 636   $form->{paidaccounts} = 0;
 637   map { my $key = $_; delete $form->{$key} if grep { $key =~ /^$_/ } qw(datepaid_ gldate_ acc_trans_id_ source_ memo_ paid_ exchangerate_ AR_paid_) } keys %{ $form };
 638   # set new ids for storno invoice
 639   # set new persistent ids for storno invoice items
 640   $form->{"converted_from_invoice_id_$_"} = delete $form->{"invoice_id_$_"} for 1 .. $form->{"rowcount"};
 641
 642   # saving the history
 643   if(!exists $form->{addition} && $form->{id} ne "") {
 644     $form->{snumbers}  = qq|invnumber_| . $form->{invnumber};
 645     $form->{what_done} = "invoice";
 646     $form->{addition}  = "CANCELED";
 647     $form->save_history;
 648   }
 649   # /saving the history
 650
 651   # record link invoice to storno
 652   $form->{convert_from_ap_ids} = $form->{id};
 653   $form->{storno_id} = $form->{id};
 654   $form->{storno} = 1;
 655   $form->{id} = "";
 656   $form->{invnumber} = "Storno zu " . $form->{invnumber};
 657   $form->{rowcount}++;
 658   $form->{employee_id} = $employee_id;
 659   post();
 660   $main::lxdebug->leave_sub();
 661
 662 }
 663
 664 sub use_as_new {
 665   $main::lxdebug->enter_sub();
 666
 667   my $form     = $main::form;
 668   my %myconfig = %main::myconfig;
 669
 670   $main::auth->assert('vendor_invoice_edit');
 671
 672   map { delete $form->{$_} } qw(printed emailed queued invnumber invdate deliverydate id datepaid_1 gldate_1 acc_trans_id_1 source_1 memo_1 paid_1 exchangerate_1 AP_paid_1 storno);
 673   $form->{paidaccounts} = 1;
 674   $form->{rowcount}--;
 675   $form->{invdate} = $form->current_date(\%myconfig);
 676
 677   $form->{"converted_from_invoice_id_$_"} = delete $form->{"invoice_id_$_"} for 1 .. $form->{"rowcount"};
 678
 679   $form->{useasnew} = 1;
 680   &display_form;
 681
 682   $main::lxdebug->leave_sub();
 683 }
 684
 685 sub post_payment {
 686   $main::lxdebug->enter_sub();
 687
 688   my $form     = $main::form;
 689   my %myconfig = %main::myconfig;
 690   my $locale   = $main::locale;
 691
 692   $main::auth->assert('vendor_invoice_edit');
 693
 694   $form->mtime_ischanged('ap') ;
 695   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 696   for my $i (1 .. $form->{paidaccounts}) {
 697     if ($form->{"paid_$i"}) {
 698       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 699
 700       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 701
 702       $form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 703         if ($form->date_max_future($form->{"datepaid_$i"}, \%myconfig));
 704
 705       #Zusätzlich noch das Buchungsdatum in die Bücherkontrolle einbeziehen
 706       # (Dient zur Prüfung ob ZE oder ZA geprüft werden soll)
 707       $form->error($locale->text('Cannot post payment for a closed period!'))
 708         if ($form->date_closed($form->{"datepaid_$i"})  && !$form->date_closed($form->{"gldate_$i"}, \%myconfig));
 709
 710       if ($form->{currency} ne $form->{defaultcurrency}) {
 711 #        $form->{"exchangerate_$i"} = $form->{exchangerate} if ($invdate == $datepaid); # invdate isn't set here
 712         $form->isblank("exchangerate_$i", $locale->text('Exchangerate for payment missing!'));
 713       }
 714     }
 715   }
 716
 717   ($form->{AP})      = split /--/, $form->{AP};
 718   ($form->{AP_paid}) = split /--/, $form->{AP_paid};
 719   if (IR->post_payment(\%myconfig, \%$form)){
 720     if (!exists $form->{addition} && $form->{id} ne "") {
 721       # saving the history
 722       $form->{snumbers}  = qq|invnumber_| . $form->{invnumber};
 723       $form->{addition}  = "PAYMENT POSTED";
 724       $form->{what_done} = "invoice";
 725       $form->save_history;
 726       # /saving the history
 727     }
 728
 729     $form->redirect($locale->text('Payment posted!'));
 730   }
 731
 732   $form->error($locale->text('Cannot post payment!'));
 733
 734   $main::lxdebug->leave_sub();
 735 }
 736
 737 sub _max_datepaid {
 738   my $form  =  $main::form;
 739
 740   my @dates = sort { $b->[1] cmp $a->[1] }
 741               map  { [ $_, $main::locale->reformat_date(\%main::myconfig, $_, 'yyyy-mm-dd') ] }
 742               grep { $_ }
 743               map  { $form->{"datepaid_${_}"} }
 744               (1..$form->{rowcount});
 745
 746   return @dates ? $dates[0]->[0] : undef;
 747 }
 748
 749
 750 sub post {
 751   $main::lxdebug->enter_sub();
 752
 753   my $form     = $main::form;
 754   my %myconfig = %main::myconfig;
 755   my $locale   = $main::locale;
 756
 757   $main::auth->assert('vendor_invoice_edit');
 758
 759   $form->mtime_ischanged('ap');
 760   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 761
 762   $form->isblank("invdate",   $locale->text('Invoice Date missing!'));
 763   $form->isblank("vendor_id", $locale->text('Vendor missing!'));
 764   $form->isblank("invnumber", $locale->text('Invnumber missing!'));
 765
 766   $form->{invnumber} =~ s/^\s*//g;
 767   $form->{invnumber} =~ s/\s*$//g;
 768
 769   # if the vendor changed get new values
 770   if (($form->{previous_vendor_id} || $form->{vendor_id}) != $form->{vendor_id}) {
 771     &update;
 772     $::dispatcher->end_request;
 773   }
 774
 775   if ($myconfig{mandatory_departments} && !$form->{department_id}) {
 776     $form->{saved_message} = $::locale->text('You have to specify a department.');
 777     update();
 778     exit;
 779   }
 780
 781   remove_emptied_rows();
 782   &validate_items;
 783
 784   my $closedto     = $form->datetonum($form->{closedto}, \%myconfig);
 785   my $invdate      = $form->datetonum($form->{invdate},  \%myconfig);
 786   my $max_datepaid = _max_datepaid();
 787
 788   $form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 789     if ($form->date_max_future($invdate, \%myconfig));
 790   $form->error($locale->text('Cannot post invoice for a closed period!'))
 791     if ($invdate <= $closedto);
 792
 793   $form->isblank("exchangerate", $locale->text('Exchangerate missing!'))
 794     if ($form->{currency} ne $form->{defaultcurrency});
 795
 796   my $i;
 797   for $i (1 .. $form->{paidaccounts}) {
 798     if ($form->parse_amount(\%myconfig, $form->{"paid_$i"})) {
 799       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 800
 801       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 802
 803       $form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 804         if ($form->date_max_future($form->{"datepaid_$i"}, \%myconfig));
 805
 806       #Zusätzlich noch das Buchungsdatum in die Bücherkontrolle einbeziehen
 807       # (Dient zur Prüfung ob ZE oder ZA geprüft werden soll)
 808       $form->error($locale->text('Cannot post payment for a closed period!'))
 809         if ($form->date_closed($form->{"datepaid_$i"})  && !$form->date_closed($form->{"gldate_$i"}, \%myconfig));
 810
 811       if ($form->{currency} ne $form->{defaultcurrency}) {
 812         $form->{"exchangerate_$i"} = $form->{exchangerate}
 813           if ($invdate == $datepaid);
 814         $form->isblank("exchangerate_$i",
 815                        $locale->text('Exchangerate for payment missing!'));
 816       }
 817     }
 818   }
 819
 820   ($form->{AP})      = split /--/, $form->{AP};
 821   ($form->{AP_paid}) = split /--/, $form->{AP_paid};
 822   $form->{storno}  ||= 0;
 823
 824   $form->{id} = 0 if $form->{postasnew};
 825
 826
 827   relink_accounts();
 828   if (IR->post_invoice(\%myconfig, \%$form)){
 829     # saving the history
 830     if(!exists $form->{addition} && $form->{id} ne "") {
 831       $form->{snumbers}  = qq|invnumber_| . $form->{invnumber};
 832       $form->{addition}  = "POSTED";
 833       $form->{what_done} = 'invoice';
 834       $form->save_history;
 835     }
 836     # /saving the history
 837     $form->{callback} = 'ir.pl?action=add';
 838     $form->redirect(  $locale->text('Invoice')
 839                   . " $form->{invnumber} "
 840                   . $locale->text('posted!'));
 841   }
 842   $form->error($locale->text('Cannot post invoice!'));
 843
 844   $main::lxdebug->leave_sub();
 845 }
 846
 847 sub delete {
 848   $main::lxdebug->enter_sub();
 849
 850   my $form     = $main::form;
 851   my $locale   = $main::locale;
 852
 853   $main::auth->assert('vendor_invoice_edit');
 854
 855   $form->header;
 856   print qq|
 857 <form method=post action=$form->{script}>
 858 |;
 859
 860   # delete action variable
 861   map { delete $form->{$_} } qw(action header);
 862
 863   foreach my $key (keys %$form) {
 864     next if (($key eq 'login') || ($key eq 'password') || ('' ne ref $form->{$key}));
 865     $form->{$key} =~ s/\"/&quot;/g;
 866     print qq|<input type=hidden name=$key value="$form->{$key}">\n|;
 867   }
 868
 869   print qq|
 870 <h2 class=confirm>| . $locale->text('Confirm!') . qq|</h2>
 871
 872 <h4>|
 873     . $locale->text('Are you sure you want to delete Invoice Number')
 874     . qq| $form->{invnumber}</h4>
 875 <p>
 876 <input name=action class=submit type=submit value="|
 877     . $locale->text('Yes') . qq|">
 878 </form>
 879 |;
 880
 881   $main::lxdebug->leave_sub();
 882 }
 883
 884 sub display_form {
 885   $::lxdebug->enter_sub;
 886
 887   $::auth->assert('vendor_invoice_edit');
 888
 889   relink_accounts();
 890
 891   my $new_rowcount = $::form->{"rowcount"} * 1 + 1;
 892   $::form->{"project_id_${new_rowcount}"} = $::form->{"globalproject_id"};
 893
 894   $::form->language_payment(\%::myconfig);
 895
 896   Common::webdav_folder($::form);
 897
 898   form_header();
 899   display_row(++$::form->{rowcount});
 900   form_footer();
 901
 902   $::lxdebug->leave_sub;
 903 }
 904
 905 sub yes {
 906   $main::lxdebug->enter_sub();
 907
 908   my $form     = $main::form;
 909   my %myconfig = %main::myconfig;
 910   my $locale   = $main::locale;
 911
 912   $main::auth->assert('vendor_invoice_edit');
 913
 914   if (IR->delete_invoice(\%myconfig, \%$form)) {
 915     # saving the history
 916     if(!exists $form->{addition}) {
 917       $form->{snumbers} = qq|invnumber_| . $form->{invnumber};
 918       $form->{addition} = "DELETED";
 919       $form->save_history;
 920     }
 921     # /saving the history
 922     $form->redirect($locale->text('Invoice deleted!'));
 923   }
 924   $form->error($locale->text('Cannot delete invoice!'));
 925
 926   $main::lxdebug->leave_sub();
 927 }
 928
 929 sub get_duedate_vendor {
 930   $::lxdebug->enter_sub;
 931
 932   my $result = IR->get_duedate(
 933     vendor_id => $::form->{vendor_id},
 934     invdate   => $::form->{invdate},
 935     default   => $::form->{old_duedate},
 936   );
 937
 938   print $::form->ajax_response_header, $result;
 939   $::lxdebug->leave_sub;
 940 }