bin/mozilla/is.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 1998-2002
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  28 #======================================================================
  29 #
  30 # Inventory invoicing module
  31 #
  32 #======================================================================
  33
  34 use SL::FU;
  35 use SL::IS;
  36 use SL::PE;
  37 use SL::OE;
  38 use Data::Dumper;
  39 use DateTime;
  40 use List::MoreUtils qw(uniq);
  41 use List::Util qw(max sum);
  42 use List::UtilsBy qw(sort_by);
  43 use English qw(-no_match_vars);
  44
  45 use SL::DB::Default;
  46 use SL::DB::Customer;
  47 use SL::DB::PaymentTerm;
  48
  49 require "bin/mozilla/io.pl";
  50 require "bin/mozilla/invoice_io.pl";
  51 require "bin/mozilla/arap.pl";
  52 require "bin/mozilla/drafts.pl";
  53
  54 use strict;
  55
  56 1;
  57
  58 # end of main
  59
  60 sub add {
  61   $main::lxdebug->enter_sub();
  62
  63   my $form     = $main::form;
  64   my $locale   = $main::locale;
  65
  66   $main::auth->assert('invoice_edit');
  67
  68   return $main::lxdebug->leave_sub() if (load_draft_maybe());
  69
  70   if ($form->{type} eq "credit_note") {
  71     $form->{title} = $locale->text('Add Credit Note');
  72
  73     if ($form->{storno}) {
  74       $form->{title} = $locale->text('Add Storno Credit Note');
  75     }
  76   } else {
  77     $form->{title} = $locale->text('Add Sales Invoice');
  78
  79   }
  80
  81
  82   $form->{callback} = "$form->{script}?action=add&type=$form->{type}" unless $form->{callback};
  83
  84   &invoice_links;
  85   &prepare_invoice;
  86   &display_form;
  87
  88   $main::lxdebug->leave_sub();
  89 }
  90
  91 sub edit {
  92   $main::lxdebug->enter_sub();
  93
  94   my $form     = $main::form;
  95   my $locale   = $main::locale;
  96
  97   $main::auth->assert('invoice_edit');
  98
  99   $form->{taxincluded_changed_by_user} = 1;
 100
 101   # show history button
 102   $form->{javascript} = qq|<script type="text/javascript" src="js/show_history.js"></script>|;
 103
 104   my ($language_id, $printer_id);
 105   if ($form->{print_and_post}) {
 106     $form->{action}   = "print";
 107     $form->{resubmit} = 1;
 108     $language_id = $form->{language_id};
 109     $printer_id = $form->{printer_id};
 110   }
 111
 112   &invoice_links;
 113   if ($form->{type} eq "credit_note") {
 114     $form->{title} = $locale->text('Edit Credit Note');
 115     $form->{title} = $locale->text('Edit Storno Credit Note') if $form->{storno};
 116   } else {
 117     $form->{title} = $locale->text('Edit Sales Invoice');
 118     $form->{title} = $locale->text('Edit Storno Invoice')     if $form->{storno};
 119   }
 120
 121   &prepare_invoice;
 122   if ($form->{print_and_post}) {
 123     $form->{language_id} = $language_id;
 124     $form->{printer_id} = $printer_id;
 125   }
 126
 127   &display_form;
 128
 129   $main::lxdebug->leave_sub();
 130 }
 131
 132 sub invoice_links {
 133   $main::lxdebug->enter_sub();
 134
 135   my $form     = $main::form;
 136   my %myconfig = %main::myconfig;
 137
 138   $main::auth->assert('invoice_edit');
 139
 140   $form->{vc} = 'customer';
 141
 142   # create links
 143   $form->{webdav}   = $::instance_conf->get_webdav;
 144
 145   $form->create_links("AR", \%myconfig, "customer");
 146
 147   if ($form->{all_customer}) {
 148     unless ($form->{customer_id}) {
 149       $form->{customer_id} = $form->{all_customer}->[0]->{id};
 150       $form->{salesman_id} = $form->{all_customer}->[0]->{salesman_id};
 151     }
 152   }
 153
 154   my $editing = $form->{id};
 155
 156   $form->backup_vars(qw(payment_id language_id taxzone_id salesman_id
 157                         taxincluded currency cp_id intnotes id shipto_id
 158                         delivery_term_id));
 159
 160   IS->get_customer(\%myconfig, \%$form);
 161
 162   #quote all_customer Bug 133
 163   foreach my $ref (@{ $form->{all_customer} }) {
 164     $ref->{name} = $form->quote($ref->{name});
 165   }
 166
 167   $form->restore_vars(qw(id));
 168
 169   IS->retrieve_invoice(\%myconfig, \%$form);
 170   $form->restore_vars(qw(payment_id language_id taxzone_id currency intnotes
 171                          cp_id shipto_id delivery_term_id));
 172   $form->restore_vars(qw(taxincluded)) if $form->{id};
 173   $form->restore_vars(qw(salesman_id)) if $editing;
 174
 175
 176   # build vendor/customer drop down compatibility... don't ask
 177   if (@{ $form->{"all_customer"} }) {
 178     $form->{"selectcustomer"} = 1;
 179     $form->{customer}         = qq|$form->{customer}--$form->{"customer_id"}|;
 180   }
 181
 182   $form->{"oldcustomer"}  = $form->{customer};
 183
 184   if ($form->{"oldcustomer"} !~ m/--\d+$/ && $form->{"customer_id"}) {
 185     $form->{"oldcustomer"} .= qq|--$form->{"customer_id"}|
 186   }
 187
 188
 189 #  $form->{oldcustomer} = "$form->{customer}--$form->{customer_id}";
 190 #  $form->{selectcustomer} = 1;
 191
 192   $form->{employee} = "$form->{employee}--$form->{employee_id}";
 193
 194   # forex
 195   $form->{forex} = $form->{exchangerate};
 196   my $exchangerate = ($form->{exchangerate}) ? $form->{exchangerate} : 1;
 197
 198   foreach my $key (keys %{ $form->{AR_links} }) {
 199     foreach my $ref (@{ $form->{AR_links}{$key} }) {
 200       $form->{"select$key"} .= "<option>$ref->{accno}--$ref->{description}</option>\n";
 201     }
 202
 203     if ($key eq "AR_paid") {
 204       next unless $form->{acc_trans}{$key};
 205       for my $i (1 .. scalar @{ $form->{acc_trans}{$key} }) {
 206         $form->{"AR_paid_$i"}      = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 207
 208         $form->{"acc_trans_id_$i"}    = $form->{acc_trans}{$key}->[$i - 1]->{acc_trans_id};
 209         # reverse paid
 210         $form->{"paid_$i"}         = $form->{acc_trans}{$key}->[$i - 1]->{amount} * -1;
 211         $form->{"datepaid_$i"}     = $form->{acc_trans}{$key}->[$i - 1]->{transdate};
 212         $form->{"gldate_$i"}       = $form->{acc_trans}{$key}->[$i - 1]->{gldate};
 213         $form->{"exchangerate_$i"} = $form->{acc_trans}{$key}->[$i - 1]->{exchangerate};
 214         $form->{"forex_$i"}        = $form->{"exchangerate_$i"};
 215         $form->{"source_$i"}       = $form->{acc_trans}{$key}->[$i - 1]->{source};
 216         $form->{"memo_$i"}         = $form->{acc_trans}{$key}->[$i - 1]->{memo};
 217
 218         $form->{paidaccounts} = $i;
 219       }
 220     } else {
 221       $form->{$key} = "$form->{acc_trans}{$key}->[0]->{accno}--$form->{acc_trans}{$key}->[0]->{description}";
 222     }
 223   }
 224
 225   $form->{paidaccounts} = 1 unless (exists $form->{paidaccounts});
 226
 227   $form->{AR} = $form->{AR_1} unless $form->{id};
 228
 229   $form->{locked} = ($form->datetonum($form->{invdate},  \%myconfig)
 230                   <= $form->datetonum($form->{closedto}, \%myconfig));
 231
 232   $main::lxdebug->leave_sub();
 233 }
 234
 235 sub prepare_invoice {
 236   $main::lxdebug->enter_sub();
 237
 238   my $form     = $main::form;
 239   my %myconfig = %main::myconfig;
 240
 241   $main::auth->assert('invoice_edit');
 242
 243   if ($form->{type} eq "credit_note") {
 244     $form->{type}     = "credit_note";
 245     $form->{formname} = "credit_note";
 246   } else {
 247     $form->{type}     = "invoice";
 248     $form->{formname} = "invoice";
 249   }
 250
 251   if ($form->{id}) {
 252
 253     my $i = 0;
 254
 255     foreach my $ref (@{ $form->{invoice_details} }) {
 256       $i++;
 257
 258       map { $form->{"${_}_$i"} = $ref->{$_} } keys %{$ref};
 259
 260       $form->{"discount_$i"}   = $form->format_amount(\%myconfig, $form->{"discount_$i"} * 100);
 261       my ($dec)                = ($form->{"sellprice_$i"} =~ /\.(\d+)/);
 262       $dec                     = length $dec;
 263       my $decimalplaces        = ($dec > 2) ? $dec : 2;
 264
 265       $form->{"sellprice_$i"}  = $form->format_amount(\%myconfig, $form->{"sellprice_$i"}, $decimalplaces);
 266       (my $dec_qty)            = ($form->{"qty_$i"} =~ /\.(\d+)/);
 267       $dec_qty                 = length $dec_qty;
 268
 269       $form->{"lastcost_$i"}  = $form->format_amount(\%myconfig, $form->{"lastcost_$i"}, $decimalplaces);
 270
 271       $form->{"qty_$i"}        = $form->format_amount(\%myconfig, $form->{"qty_$i"}, $dec_qty);
 272
 273       $form->{"sellprice_pg_$i"} = join ('--', $form->{"sellprice_$i"}, $form->{"pricegroup_id_$i"});
 274
 275       $form->{rowcount}        = $i;
 276
 277     }
 278   }
 279   $main::lxdebug->leave_sub();
 280 }
 281
 282 sub form_header {
 283   $main::lxdebug->enter_sub();
 284
 285   my $form     = $main::form;
 286   my %myconfig = %main::myconfig;
 287   my $locale   = $main::locale;
 288   my $cgi      = $::request->{cgi};
 289
 290   $main::auth->assert('invoice_edit');
 291
 292   my %TMPL_VAR = ();
 293   my @custom_hiddens;
 294
 295   if ($form->{id}) {
 296     require SL::DB::Invoice;
 297     $TMPL_VAR{invoice_obj} = SL::DB::Invoice->new(id => $form->{id})->load;
 298   }
 299   $form->{employee_id} = $form->{old_employee_id} if $form->{old_employee_id};
 300   $form->{salesman_id} = $form->{old_salesman_id} if $form->{old_salesman_id};
 301
 302   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 303
 304   $form->get_lists("taxzones"      => ($form->{id} ? "ALL_TAXZONES" : "ALL_ACTIVE_TAXZONES"),
 305                    "currencies"    => "ALL_CURRENCIES",
 306                    "customers"     => "ALL_CUSTOMERS",
 307                    "departments"   => "all_departments",
 308                    "price_factors" => "ALL_PRICE_FACTORS");
 309
 310   # Projects
 311   my @old_project_ids = uniq grep { $_ } map { $_ * 1 } ($form->{"globalproject_id"}, map { $form->{"project_id_$_"} } 1..$form->{"rowcount"});
 312   my @old_ids_cond    = @old_project_ids ? (id => \@old_project_ids) : ();
 313   my @customer_cond;
 314   if ($::instance_conf->get_customer_projects_only_in_sales) {
 315     @customer_cond = (
 316       or => [
 317         customer_id          => $::form->{customer_id},
 318         billable_customer_id => $::form->{customer_id},
 319       ]);
 320   }
 321   my @conditions = (
 322     or => [
 323       and => [ active => 1, @customer_cond ],
 324       @old_ids_cond,
 325     ]);
 326
 327   $TMPL_VAR{ALL_PROJECTS}          = SL::DB::Manager::Project->get_all_sorted(query => \@conditions);
 328   $form->{ALL_PROJECTS}            = $TMPL_VAR{ALL_PROJECTS}; # make projects available for second row drop-down in io.pl
 329   $TMPL_VAR{ALL_EMPLOYEES}         = SL::DB::Manager::Employee->get_all_sorted(query => [ or => [ id => $::form->{employee_id},  deleted => 0 ] ]);
 330   $TMPL_VAR{ALL_SALESMEN}          = SL::DB::Manager::Employee->get_all_sorted(query => [ or => [ id => $::form->{salesman_id},  deleted => 0 ] ]);
 331   $TMPL_VAR{ALL_SHIPTO}            = SL::DB::Manager::Shipto->get_all_sorted(query => [
 332     or => [ trans_id  => $::form->{"$::form->{vc}_id"} * 1, and => [ shipto_id => $::form->{shipto_id} * 1, trans_id => undef ] ]
 333   ]);
 334   $TMPL_VAR{ALL_CONTACTS}          = SL::DB::Manager::Contact->get_all_sorted(query => [
 335     or => [
 336       cp_cv_id => $::form->{"$::form->{vc}_id"} * 1,
 337       and      => [
 338         cp_cv_id => undef,
 339         cp_id    => $::form->{cp_id} * 1
 340       ]
 341     ]
 342   ]);
 343   $TMPL_VAR{department_labels}     = sub { "$_[0]->{description}--$_[0]->{id}" };
 344
 345   # customer
 346   $TMPL_VAR{vc_keys} = sub { "$_[0]->{name}--$_[0]->{id}" };
 347   $TMPL_VAR{vclimit} = $myconfig{vclimit};
 348   $TMPL_VAR{vc_select} = "customer_or_vendor_selection_window('customer', '', 0, 0)";
 349   push @custom_hiddens, "customer_id";
 350   push @custom_hiddens, "oldcustomer";
 351   push @custom_hiddens, "selectcustomer";
 352
 353   # currencies and exchangerate
 354   my @values = map { $_       } @{ $form->{ALL_CURRENCIES} };
 355   my %labels = map { $_ => $_ } @{ $form->{ALL_CURRENCIES} };
 356   $form->{currency}            = $form->{defaultcurrency} unless $form->{currency};
 357   $form->{show_exchangerate}   = $form->{currency} ne $form->{defaultcurrency};
 358   $TMPL_VAR{currencies}        = NTI($::request->{cgi}->popup_menu('-name' => 'currency', '-default' => $form->{"currency"},
 359                                                       '-values' => \@values, '-labels' => \%labels,
 360                                                       '-onchange' => "document.getElementById('update_button').click();"
 361                                      )) if scalar @values;
 362   push @custom_hiddens, "forex";
 363   push @custom_hiddens, "exchangerate" if $form->{forex};
 364
 365   $TMPL_VAR{creditwarning} = ($form->{creditlimit} != 0) && ($form->{creditremaining} < 0) && !$form->{update};
 366   $TMPL_VAR{is_credit_remaining_negativ} = $form->{creditremaining} =~ /-/;
 367
 368   my $follow_up_vc         =  $form->{customer};
 369   $follow_up_vc            =~ s/--\d*\s*$//;
 370   $TMPL_VAR{customer_name} = $follow_up_vc;
 371
 372 # set option selected
 373   foreach my $item (qw(AR)) {
 374     $form->{"select$item"} =~ s/ selected//;
 375     $form->{"select$item"} =~ s/option>\Q$form->{$item}\E/option selected>$form->{$item}/;
 376   }
 377
 378   $TMPL_VAR{is_type_credit_note} = $form->{type}   eq "credit_note";
 379   $TMPL_VAR{is_format_html}      = $form->{format} eq 'html';
 380   $TMPL_VAR{dateformat}          = $myconfig{dateformat};
 381   $TMPL_VAR{numberformat}        = $myconfig{numberformat};
 382
 383   # hiddens
 384   $TMPL_VAR{HIDDENS} = [qw(
 385     id action type media format queued printed emailed title vc discount
 386     title creditlimit creditremaining tradediscount business closedto locked shipped storno storno_id
 387     max_dunning_level dunning_amount dunning_description
 388     shiptoname shiptostreet shiptozipcode shiptocity shiptocountry  shiptocontact shiptophone shiptofax
 389     shiptoemail shiptodepartment_1 shiptodepartment_2  shiptocp_gender message email subject cc bcc taxaccounts cursor_fokus
 390     convert_from_do_ids convert_from_oe_ids convert_from_ar_ids useasnew
 391     invoice_id
 392     show_details
 393   ), @custom_hiddens,
 394   map { $_.'_rate', $_.'_description', $_.'_taxnumber' } split / /, $form->{taxaccounts}];
 395
 396   $::request->{layout}->use_javascript(map { "${_}.js" } qw(kivi.SalesPurchase ckeditor/ckeditor ckeditor/adapters/jquery kivi.io autocomplete_customer autocomplete_part client_js));
 397
 398   $TMPL_VAR{payment_terms_obj} = get_payment_terms_for_invoice();
 399   $form->{duedate}             = $TMPL_VAR{payment_terms_obj}->calc_date(reference_date => $form->{invdate}, due_date => $form->{due_due})->to_kivitendo if $TMPL_VAR{payment_terms_obj};
 400
 401   $form->header();
 402
 403   print $form->parse_html_template("is/form_header", \%TMPL_VAR);
 404
 405   $main::lxdebug->leave_sub();
 406 }
 407
 408 sub _sort_payments {
 409   my @fields   = qw(acc_trans_id gldate datepaid source memo paid AR_paid);
 410   my @payments =
 411     grep { $_->{paid} != 0 }
 412     map  {
 413       my $idx = $_;
 414       +{ map { ($_ => delete($::form->{"${_}_${idx}"})) } @fields }
 415     } (1..$::form->{paidaccounts});
 416
 417   @payments = sort_by { DateTime->from_kivitendo($_->{datepaid}) } @payments;
 418
 419   $::form->{paidaccounts} = max scalar(@payments), 1;
 420
 421   foreach my $idx (1 .. scalar(@payments)) {
 422     my $payment = $payments[$idx - 1];
 423     $::form->{"${_}_${idx}"} = $payment->{$_} for @fields;
 424   }
 425 }
 426
 427 sub form_footer {
 428   $main::lxdebug->enter_sub();
 429
 430   my $form     = $main::form;
 431   my %myconfig = %main::myconfig;
 432   my $locale   = $main::locale;
 433
 434   $main::auth->assert('invoice_edit');
 435
 436   $form->{invtotal}    = $form->{invsubtotal};
 437
 438   # note rows
 439   $form->{rows} = max 2,
 440     $form->numtextrows($form->{notes},    26, 8),
 441     $form->numtextrows($form->{intnotes}, 35, 8);
 442
 443
 444   # tax, total and subtotal calculations
 445   my ($tax, $subtotal);
 446   $form->{taxaccounts_array} = [ split(/ /, $form->{taxaccounts}) ];
 447
 448   if( $form->{customer_id} && !$form->{taxincluded_changed_by_user} ) {
 449     my $customer = SL::DB::Customer->new(id => $form->{customer_id})->load();
 450     $form->{taxincluded} = defined($customer->taxincluded_checked) ? $customer->taxincluded_checked : $myconfig{taxincluded_checked};
 451   }
 452
 453   foreach my $item (@{ $form->{taxaccounts_array} }) {
 454     if ($form->{"${item}_base"}) {
 455       if ($form->{taxincluded}) {
 456         $form->{"${item}_total"} = $form->round_amount( ($form->{"${item}_base"} * $form->{"${item}_rate"}
 457                                                                                  / (1 + $form->{"${item}_rate"})), 2);
 458         $form->{"${item}_netto"} = $form->round_amount( ($form->{"${item}_base"} - $form->{"${item}_total"}), 2);
 459       } else {
 460         $form->{"${item}_total"} = $form->round_amount( $form->{"${item}_base"} * $form->{"${item}_rate"}, 2);
 461         $form->{invtotal} += $form->{"${item}_total"};
 462       }
 463     }
 464   }
 465
 466   my $total = $form->round_amount( $form->{invtotal}, 2, 1 );
 467   $form->{rounding} = $form->round_amount( $total-$form->{invtotal}, 2 );
 468   $form->{invtotal} = $total;
 469
 470   # follow ups
 471   if ($form->{id}) {
 472     $form->{follow_ups}            = FU->follow_ups('trans_id' => $form->{id}) || [];
 473     $form->{follow_ups_unfinished} = ( sum map { $_->{due} * 1 } @{ $form->{follow_ups} } ) || 0;
 474   }
 475
 476   # payments
 477   _sort_payments();
 478
 479   my $totalpaid = 0;
 480   $form->{paidaccounts}++ if ($form->{"paid_$form->{paidaccounts}"});
 481   $form->{paid_indices} = [ 1 .. $form->{paidaccounts} ];
 482
 483   # Standard Konto für Umlaufvermögen
 484   my $accno_arap = IS->get_standard_accno_current_assets(\%myconfig, \%$form);
 485
 486   for my $i (1 .. $form->{paidaccounts}) {
 487     $form->{"changeable_$i"} = 1;
 488     if (SL::DB::Default->get->payments_changeable == 0) {
 489       # never
 490       $form->{"changeable_$i"} = ($form->{"acc_trans_id_$i"})? 0 : 1;
 491     } elsif (SL::DB::Default->get->payments_changeable == 2) {
 492       # on the same day
 493       $form->{"changeable_$i"} = (($form->{"gldate_$i"} eq '') ||
 494                                   ($form->current_date(\%myconfig) eq $form->{"gldate_$i"}));
 495     }
 496
 497     $form->{"selectAR_paid_$i"} = $form->{selectAR_paid};
 498     if (!$form->{"AR_paid_$i"}) {
 499       $form->{"selectAR_paid_$i"} =~ s/option>$accno_arap--(.*?)</option selected>$accno_arap--$1</;
 500     } else {
 501       $form->{"selectAR_paid_$i"} =~ s/option>\Q$form->{"AR_paid_$i"}\E/option selected>$form->{"AR_paid_$i"}/;
 502     }
 503
 504     $totalpaid += $form->{"paid_$i"};
 505   }
 506
 507   $form->{oldinvtotal} = $form->{invtotal};
 508
 509   $form->{ALL_DELIVERY_TERMS} = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 510
 511   print $form->parse_html_template('is/form_footer', {
 512     is_type_credit_note => ($form->{type} eq "credit_note"),
 513     totalpaid           => $totalpaid,
 514     paid_missing        => $form->{invtotal} - $totalpaid,
 515     print_options       => print_options(inline => 1),
 516     show_storno         => $form->{id} && !$form->{storno} && !IS->has_storno(\%myconfig, $form, "ar") && !$totalpaid,
 517     show_delete         => ($::instance_conf->get_is_changeable == 2)
 518                              ? ($form->current_date(\%myconfig) eq $form->{gldate})
 519                              : ($::instance_conf->get_is_changeable == 1),
 520     today               => DateTime->today,
 521   });
 522 ##print $form->parse_html_template('is/_payments'); # parser
 523 ##print $form->parse_html_template('webdav/_list'); # parser
 524
 525   $main::lxdebug->leave_sub();
 526 }
 527
 528 sub mark_as_paid {
 529   $main::lxdebug->enter_sub();
 530
 531   my $form     = $main::form;
 532   my %myconfig = %main::myconfig;
 533
 534   $main::auth->assert('invoice_edit');
 535
 536   &mark_as_paid_common(\%myconfig,"ar");
 537
 538   $main::lxdebug->leave_sub();
 539 }
 540
 541 sub update {
 542   $main::lxdebug->enter_sub();
 543
 544   my $form     = $main::form;
 545   my %myconfig = %main::myconfig;
 546
 547   $main::auth->assert('invoice_edit');
 548
 549   my ($recursive_call) = @_;
 550
 551   $form->{print_and_post} = 0         if $form->{second_run};
 552   my $taxincluded         = $form->{taxincluded} ? "checked" : '';
 553   $form->{update} = 1;
 554
 555   &check_name("customer");
 556
 557   $form->{taxincluded} ||= $taxincluded;
 558
 559   if (!$form->{forex}) {        # read exchangerate from input field (not hidden)
 560     $form->{exchangerate} = $form->parse_amount(\%myconfig, $form->{exchangerate}) unless $recursive_call;
 561   }
 562   $form->{forex}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{invdate}, 'buy');
 563   $form->{exchangerate} = $form->{forex} if $form->{forex};
 564
 565   for my $i (1 .. $form->{paidaccounts}) {
 566     next unless $form->{"paid_$i"};
 567     map { $form->{"${_}_$i"} = $form->parse_amount(\%myconfig, $form->{"${_}_$i"}) } qw(paid exchangerate);
 568     if (!$form->{"forex_$i"}) {   #read exchangerate from input field (not hidden)
 569       $form->{exchangerate} = $form->{"exchangerate_$i"};
 570     }
 571     $form->{"forex_$i"}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'buy');
 572     $form->{"exchangerate_$i"} = $form->{"forex_$i"} if $form->{"forex_$i"};
 573   }
 574
 575   my $i            = $form->{rowcount};
 576   my $exchangerate = $form->{exchangerate} || 1;
 577
 578   # if last row empty, check the form otherwise retrieve new item
 579   if (   ($form->{"partnumber_$i"} eq "")
 580       && ($form->{"description_$i"} eq "")
 581       && ($form->{"partsgroup_$i"}  eq "")) {
 582
 583     $form->{creditremaining} += ($form->{oldinvtotal} - $form->{oldtotalpaid});
 584     &check_form;
 585
 586   } else {
 587
 588     IS->retrieve_item(\%myconfig, \%$form);
 589
 590     my $rows = scalar @{ $form->{item_list} };
 591
 592     $form->{"discount_$i"}   = $form->parse_amount(\%myconfig, $form->{"discount_$i"}) / 100.0;
 593     $form->{"discount_$i"} ||= $form->{customer_discount};
 594
 595     if ($rows) {
 596       $form->{"qty_$i"} = $form->parse_amount(\%myconfig, $form->{"qty_$i"});
 597       if( !$form->{"qty_$i"} ) {
 598         $form->{"qty_$i"} = 1;
 599       }
 600
 601       if ($rows > 1) {
 602
 603         select_item(mode => 'IS', pre_entered_qty => $form->{"qty_$i"});
 604         ::end_of_request();
 605
 606       } else {
 607
 608         my $sellprice = $form->parse_amount(\%myconfig, $form->{"sellprice_$i"});
 609
 610         map { $form->{item_list}[$i]{$_} =~ s/\"/&quot;/g } qw(partnumber description unit);
 611         map { $form->{"${_}_$i"} = $form->{item_list}[0]{$_} } keys %{ $form->{item_list}[0] };
 612
 613         $form->{payment_id}    = $form->{"part_payment_id_$i"} if $form->{"part_payment_id_$i"} ne "";
 614         $form->{"discount_$i"} = 0                             if $form->{"not_discountable_$i"};
 615
 616         $form->{"marge_price_factor_$i"} = $form->{item_list}->[0]->{price_factor};
 617
 618         ($sellprice || $form->{"sellprice_$i"}) =~ /\.(\d+)/;
 619         my $decimalplaces = max 2, length $1;
 620
 621         if ($sellprice) {
 622           $form->{"sellprice_$i"} = $sellprice;
 623         } else {
 624           my $record        = _make_record();
 625           my $price_source  = SL::PriceSource->new(record_item => $record->items->[$i-1], record => $record);
 626           my $best_price    = $price_source->best_price;
 627           my $best_discount = $price_source->best_discount;
 628
 629           if ($best_price) {
 630             $::form->{"sellprice_$i"}           = $best_price->price;
 631             $::form->{"active_price_source_$i"} = $best_price->source;
 632           }
 633           if ($best_discount) {
 634             $::form->{"discount_$i"}               = $best_discount->discount;
 635             $::form->{"active_discount_source_$i"} = $best_discount->source;
 636           }
 637
 638           # if there is an exchange rate adjust sellprice
 639           $form->{"sellprice_$i"} /= $exchangerate;
 640         }
 641
 642         $form->{"listprice_$i"} /= $exchangerate;
 643
 644         my $amount = $form->{"sellprice_$i"} * $form->{"qty_$i"} * (1 - $form->{"discount_$i"});
 645         map { $form->{"${_}_base"} = 0 }                                 split / /, $form->{taxaccounts};
 646         map { $form->{"${_}_base"} += $amount }                          split / /, $form->{"taxaccounts_$i"};
 647         map { $amount += ($form->{"${_}_base"} * $form->{"${_}_rate"}) } split / /, $form->{"taxaccounts_$i"} if !$form->{taxincluded};
 648
 649         $form->{creditremaining} -= $amount;
 650
 651         map { $form->{"${_}_$i"} = $form->format_amount(\%myconfig, $form->{"${_}_$i"}, $decimalplaces) } qw(sellprice lastcost);
 652
 653         $form->{"qty_$i"}      = $form->format_amount(\%myconfig, $form->{"qty_$i"});
 654         $form->{"discount_$i"} = $form->format_amount(\%myconfig, $form->{"discount_$i"} * 100.0);
 655       }
 656
 657       &display_form;
 658
 659     } else {
 660
 661       # ok, so this is a new part
 662       # ask if it is a part or service item
 663
 664       if (   $form->{"partsgroup_$i"}
 665           && ($form->{"partsnumber_$i"} eq "")
 666           && ($form->{"description_$i"} eq "")) {
 667         $form->{rowcount}--;
 668         $form->{"discount_$i"} = "";
 669         display_form();
 670
 671       } else {
 672         $form->{"id_$i"}   = 0;
 673         new_item();
 674       }
 675     }
 676   }
 677   $main::lxdebug->leave_sub();
 678 }
 679
 680 sub post_payment {
 681   $main::lxdebug->enter_sub();
 682
 683   my $form     = $main::form;
 684   my %myconfig = %main::myconfig;
 685   my $locale   = $main::locale;
 686
 687   $main::auth->assert('invoice_edit');
 688
 689   $form->mtime_ischanged('ar') ;
 690   my $invdate = $form->datetonum($form->{invdate}, \%myconfig);
 691
 692   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 693   for my $i (1 .. $form->{paidaccounts}) {
 694     if ($form->{"paid_$i"}) {
 695       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 696
 697       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 698
 699
 700       if ($form->{currency} ne $form->{defaultcurrency}) {
 701         $form->{"exchangerate_$i"} = $form->{exchangerate}
 702           if ($invdate == $datepaid);
 703         $form->isblank("exchangerate_$i",
 704                        $locale->text('Exchangerate for payment missing!'));
 705       }
 706     }
 707   }
 708   # Abgeschlossene Zeiträume nur für den letzten (aktuellen) Zahlungseingang prüfen
 709   # Details s.a. Bug 1502
 710   # Das Problem ist jetzt, dass man Zahlungseingänge nachträglich ändern kann
 711   # Wobei dies für Installationen die sowieso nicht mit Bücherkontrolle arbeiten keinen
 712   # keinen Unterschied macht.
 713   # Optimal wäre, wenn gegen einen Zeitstempel des Zahlungsfelds geprüft würde ...
 714   # Das Problem hierbei ist, dass in IS.pm post_invoice IMMER alle Zahlungseingänge aus $form
 715   # erneut gespeichert werden. Prinzipiell wäre es besser NUR die Änderungen des Rechnungs-
 716   # belegs (neue Zahlung aber nichts anderes) zu speichern ...
 717   # Vielleicht könnte man ähnlich wie bei Rechnung löschen verfahren
 718   $form->error($locale->text('Cannot post payment for a closed period!'))
 719     if ($form->date_closed($form->{"datepaid_$form->{paidaccounts}"}, \%myconfig));
 720
 721   ($form->{AR})      = split /--/, $form->{AR};
 722   ($form->{AR_paid}) = split /--/, $form->{AR_paid};
 723   relink_accounts();
 724   if ( IS->post_payment(\%myconfig, \%$form) ) {
 725     $form->{snumbers}  = qq|invnumber_| . $form->{invnumber};
 726     $form->{what_done} = 'invoice';
 727     $form->{addition}  = "PAYMENT POSTED";
 728     $form->save_history;
 729     $form->redirect($locale->text('Payment posted!'))
 730   } else {
 731    $form->error($locale->text('Cannot post payment!'));
 732   };
 733
 734   $main::lxdebug->leave_sub();
 735 }
 736
 737 sub post {
 738   $main::lxdebug->enter_sub();
 739
 740   my $form     = $main::form;
 741   my %myconfig = %main::myconfig;
 742   my $locale   = $main::locale;
 743
 744   $main::auth->assert('invoice_edit');
 745   $form->mtime_ischanged('ar');
 746
 747   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 748   $form->isblank("invdate",  $locale->text('Invoice Date missing!'));
 749   $form->isblank("customer", $locale->text('Customer missing!'));
 750   $form->error($locale->text('Cannot post invoice for a closed period!'))
 751         if ($form->date_closed($form->{"invdate"}, \%myconfig));
 752
 753   $form->{invnumber} =~ s/^\s*//g;
 754   $form->{invnumber} =~ s/\s*$//g;
 755
 756   # if oldcustomer ne customer redo form
 757   if (&check_name('customer')) {
 758     &update;
 759     ::end_of_request();
 760   }
 761
 762   if ($myconfig{mandatory_departments} && !$form->{department_id}) {
 763     $form->{saved_message} = $::locale->text('You have to specify a department.');
 764     update();
 765     exit;
 766   }
 767
 768   if ($form->{second_run}) {
 769     $form->{print_and_post} = 0;
 770   }
 771
 772   remove_emptied_rows();
 773   &validate_items;
 774
 775   my $closedto = $form->datetonum($form->{closedto}, \%myconfig);
 776   my $invdate  = $form->datetonum($form->{invdate},  \%myconfig);
 777
 778   $form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 779     if ($form->date_max_future($invdate, \%myconfig));
 780   $form->error($locale->text('Cannot post invoice for a closed period!'))
 781     if ($invdate <= $closedto);
 782
 783   $form->isblank("exchangerate", $locale->text('Exchangerate missing!'))
 784     if ($form->{currency} ne $form->{defaultcurrency});
 785
 786   for my $i (1 .. $form->{paidaccounts}) {
 787     if ($form->parse_amount(\%myconfig, $form->{"paid_$i"})) {
 788       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 789
 790       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 791
 792       $form->error($locale->text('Cannot post payment for a closed period!'))
 793         if ($form->date_closed($form->{"datepaid_$i"}, \%myconfig));
 794
 795       if ($form->{currency} ne $form->{defaultcurrency}) {
 796         $form->{"exchangerate_$i"} = $form->{exchangerate}
 797           if ($invdate == $datepaid);
 798         $form->isblank("exchangerate_$i",
 799                        $locale->text('Exchangerate for payment missing!'));
 800       }
 801     }
 802   }
 803
 804   ($form->{AR})        = split /--/, $form->{AR};
 805   ($form->{AR_paid})   = split /--/, $form->{AR_paid};
 806   $form->{storno}    ||= 0;
 807
 808   $form->{label} = $form->{type} eq 'credit_note' ? $locale->text('Credit Note') : $locale->text('Invoice');
 809
 810   $form->{id} = 0 if $form->{postasnew};
 811
 812   # get new invnumber in sequence if no invnumber is given or if posasnew was requested
 813   if ($form->{postasnew}) {
 814     if ($form->{type} eq "credit_note") {
 815       undef($form->{cnnumber});
 816     } else {
 817       undef($form->{invnumber});
 818     }
 819   }
 820
 821   relink_accounts();
 822
 823   my $terms        = get_payment_terms_for_invoice();
 824   $form->{duedate} = $terms->calc_date(reference_date => $form->{invdate}, due_date => $form->{due_due})->to_kivitendo if $terms;
 825
 826   # If transfer_out is requested, get rose db handle and do post and
 827   # transfer out in one transaction. Otherwise just post the invoice.
 828   if ($::instance_conf->get_is_transfer_out && $form->{type} ne 'credit_note' && !$form->{storno}) {
 829     require SL::DB::Inventory;
 830     my $rose_db = SL::DB::Inventory->new->db;
 831     my @errors;
 832
 833     if (!$rose_db->with_transaction(sub {
 834       if (!eval {
 835         if (!IS->post_invoice(\%myconfig, \%$form, $rose_db->dbh)) {
 836           push @errors, $locale->text('Cannot post invoice!');
 837           die 'posting error';
 838         }
 839         my $err = IS->transfer_out(\%$form, $rose_db->dbh);
 840         if (@{ $err }) {
 841           push @errors, @{ $err };
 842           die 'transfer error';
 843         }
 844
 845         1;
 846       }) {
 847         push @errors, $EVAL_ERROR;
 848         die 'transaction error';
 849       }
 850
 851       1;
 852     })) {
 853       push @errors, $rose_db->error;
 854       $form->error($locale->text('Cannot post invoice and/or transfer out! Error message:') . "\n" . join("\n", @errors));
 855     }
 856   } else {
 857     if (!IS->post_invoice(\%myconfig, \%$form)) {
 858       $form->error($locale->text('Cannot post invoice!'));
 859     }
 860   }
 861
 862   remove_draft() if $form->{remove_draft};
 863
 864   if(!exists $form->{addition}) {
 865     $form->{snumbers}  =  'invnumber' .'_'. $form->{invnumber}; # ($form->{type} eq 'credit_note' ? 'cnnumber' : 'invnumber') .'_'. $form->{invnumber};
 866     $form->{what_done} = 'invoice';
 867     $form->{addition}  = $form->{print_and_post} ? "PRINTED AND POSTED" :
 868                          $form->{storno}         ? "STORNO"             :
 869                                                    "POSTED";
 870     $form->save_history;
 871   }
 872
 873   if (!$form->{no_redirect_after_post}) {
 874     $form->{action} = 'edit';
 875     $form->{script} = 'is.pl';
 876     $form->{saved_message} = $form->{label} . " $form->{invnumber} " . $locale->text('posted!');
 877     $form->{callback} = build_std_url(qw(action edit id callback saved_message));
 878     $form->redirect;
 879   }
 880
 881   $main::lxdebug->leave_sub();
 882 }
 883
 884 sub print_and_post {
 885   $main::lxdebug->enter_sub();
 886
 887   my $form     = $main::form;
 888
 889   $main::auth->assert('invoice_edit');
 890
 891   my $old_form                    = Form->new;
 892   $form->{no_redirect_after_post} = 1;
 893   $form->{print_and_post}         = 1;
 894   &post();
 895
 896   &edit();
 897   $main::lxdebug->leave_sub();
 898
 899 }
 900
 901 sub use_as_new {
 902   $main::lxdebug->enter_sub();
 903
 904   my $form     = $main::form;
 905   my %myconfig = %main::myconfig;
 906
 907   $main::auth->assert('invoice_edit');
 908
 909   delete @{ $form }{qw(printed emailed queued invnumber invdate exchangerate forex deliverydate id datepaid_1 gldate_1 acc_trans_id_1 source_1 memo_1 paid_1 exchangerate_1 AP_paid_1 storno locked)};
 910   $form->{rowcount}--;
 911   $form->{paidaccounts} = 1;
 912   $form->{invdate}      = $form->current_date(\%myconfig);
 913   my $terms             = get_payment_terms_for_invoice();
 914   $form->{duedate}      = $terms ? $terms->calc_date(reference_date => $form->{invdate})->to_kivitendo : $form->{invdate};
 915   $form->{employee_id}  = SL::DB::Manager::Employee->current->id;
 916   $form->{forex}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{invdate}, 'buy');
 917   $form->{exchangerate} = $form->{forex} if $form->{forex};
 918
 919   $form->{"converted_from_invoice_id_$_"} = delete $form->{"invoice_id_$_"} for 1 .. $form->{"rowcount"};
 920
 921   $form->{useasnew} = 1;
 922   &display_form;
 923
 924   $main::lxdebug->leave_sub();
 925 }
 926
 927 sub storno {
 928   $main::lxdebug->enter_sub();
 929
 930   my $form     = $main::form;
 931   my %myconfig = %main::myconfig;
 932   my $locale   = $main::locale;
 933
 934   $main::auth->assert('invoice_edit');
 935
 936   if ($form->{storno}) {
 937     $form->error($locale->text('Cannot storno storno invoice!'));
 938   }
 939
 940   if (IS->has_storno(\%myconfig, $form, "ar")) {
 941     $form->error($locale->text("Invoice has already been storno'd!"));
 942   }
 943   if ($form->datetonum($form->{invdate},  \%myconfig) <= $form->datetonum($form->{closedto}, \%myconfig)) {
 944     $form->error($locale->text('Cannot storno invoice for a closed period!'));
 945   }
 946
 947   # save the history of invoice being stornoed
 948   $form->{snumbers}  = qq|invnumber_| . $form->{invnumber};
 949   $form->{what_done} = 'invoice';
 950   $form->{addition}  = "STORNO";
 951   $form->save_history;
 952
 953   map({ my $key = $_; delete($form->{$key}) unless (grep({ $key eq $_ } qw(id login password type))); } keys(%{ $form }));
 954
 955   invoice_links();
 956   prepare_invoice();
 957   relink_accounts();
 958
 959   # Payments must not be recorded for the new storno invoice.
 960   $form->{paidaccounts} = 0;
 961   map { my $key = $_; delete $form->{$key} if grep { $key =~ /^$_/ } qw(datepaid_ gldate_ acc_trans_id_ source_ memo_ paid_ exchangerate_ AR_paid_) } keys %{ $form };
 962
 963   $form->{storno_id} = $form->{id};
 964   $form->{storno} = 1;
 965   $form->{id} = "";
 966   $form->{invnumber} = "Storno zu " . $form->{invnumber};
 967   $form->{invdate}   = DateTime->today->to_lxoffice;
 968   $form->{rowcount}++;
 969   # set new ids for storno invoice
 970   delete $form->{"invoice_id_$_"} for 1 .. $form->{"rowcount"};
 971
 972   post();
 973   $main::lxdebug->leave_sub();
 974 }
 975
 976 sub preview {
 977   $main::lxdebug->enter_sub();
 978
 979   my $form     = $main::form;
 980
 981   $main::auth->assert('invoice_edit');
 982
 983   $form->{preview} = 1;
 984   my $old_form = Form->new;
 985   for (keys %$form) { $old_form->{$_} = $form->{$_} }
 986
 987   &print_form($old_form);
 988   $main::lxdebug->leave_sub();
 989
 990 }
 991
 992 sub delete {
 993   $main::lxdebug->enter_sub();
 994
 995   my $form     = $main::form;
 996   my $locale   = $main::locale;
 997
 998   $main::auth->assert('invoice_edit');
 999
1000   if ($form->{second_run}) {
1001     $form->{print_and_post} = 0;
1002   }
1003   $form->header;
1004
1005   print qq|
1006 <form method="post" action="$form->{script}">
1007 |;
1008
1009   # delete action variable
1010   map { delete $form->{$_} } qw(action header);
1011
1012   foreach my $key (keys %$form) {
1013     next if (($key eq 'login') || ($key eq 'password') || ('' ne ref $form->{$key}));
1014     $form->{$key} =~ s/\"/&quot;/g;
1015     print qq|<input type="hidden" name="$key" value="$form->{$key}">\n|;
1016   }
1017
1018   print qq|
1019 <h2 class="confirm">| . $locale->text('Confirm!') . qq|</h2>
1020
1021 <h4>|
1022     . $locale->text('Are you sure you want to delete Invoice Number')
1023     . qq| $form->{invnumber}
1024 </h4>
1025
1026 <p>
1027 <input name="action" class="submit" type="submit" value="|
1028     . $locale->text('Yes') . qq|">
1029 </form>
1030 |;
1031
1032   $main::lxdebug->leave_sub();
1033 }
1034
1035 sub credit_note {
1036   $main::lxdebug->enter_sub();
1037
1038   my $form     = $main::form;
1039   my %myconfig = %main::myconfig;
1040   my $locale   = $main::locale;
1041
1042   $main::auth->assert('invoice_edit');
1043
1044   $form->{transdate} = $form->{invdate} = $form->current_date(\%myconfig);
1045   $form->{duedate} =
1046     $form->current_date(\%myconfig, $form->{invdate}, $form->{terms} * 1);
1047
1048   $form->{convert_from_ar_ids} = $form->{id};
1049   $form->{id}     = '';
1050   $form->{rowcount}--;
1051
1052
1053   $form->{title}  = $locale->text('Add Credit Note');
1054   $form->{script} = 'is.pl';
1055
1056   # Bei Gutschriften bezug zur Rechnungsnummer
1057   $form->{invnumber_for_credit_note} = $form->{invnumber};
1058   # bo creates the id, reset it
1059   map { delete $form->{$_} }
1060     qw(id invnumber subject message cc bcc printed emailed queued);
1061   $form->{ $form->{vc} } =~ s/--.*//g;
1062   $form->{type} = "credit_note";
1063
1064
1065   map { $form->{"select$_"} = "" } ($form->{vc}, 'currency');
1066
1067 #  map { $form->{$_} = $form->parse_amount(\%myconfig, $form->{$_}) }
1068 #    qw(creditlimit creditremaining);
1069
1070   # set new persistent ids for credit note and link previous invoice id
1071   $form->{"converted_from_invoice_id_$_"} = delete $form->{"invoice_id_$_"} for 1 .. $form->{"rowcount"};
1072
1073   my $currency = $form->{currency};
1074   &invoice_links;
1075
1076   $form->{currency}     = $currency;
1077   $form->{forex}        = $form->check_exchangerate( \%myconfig, $form->{currency}, $form->{invdate}, 'buy');
1078   $form->{exchangerate} = $form->{forex} || '';
1079
1080   $form->{creditremaining} -= ($form->{oldinvtotal} - $form->{ordtotal});
1081
1082   # bei Gutschriften werden Zahlungseingänge aus Rechnung nicht übernommen
1083   for my $i (1 .. $form->{paidaccounts}) {
1084     delete $form->{"paid_$i"};
1085     delete $form->{"source_$i"};
1086     delete $form->{"memo_$i"};
1087     delete $form->{"datepaid_$i"};
1088     delete $form->{"gldate_$i"};
1089     delete $form->{"acc_trans_id_$i"};
1090     delete $form->{"AR_paid_$i"};
1091   };
1092   $form->{paidaccounts} = 1;
1093
1094   &prepare_invoice;
1095
1096
1097   &display_form;
1098
1099   $main::lxdebug->leave_sub();
1100 }
1101
1102 sub yes {
1103   $main::lxdebug->enter_sub();
1104
1105   my $form     = $main::form;
1106   my %myconfig = %main::myconfig;
1107   my $locale   = $main::locale;
1108
1109   $main::auth->assert('invoice_edit');
1110
1111   if (IS->delete_invoice(\%myconfig, \%$form)) {
1112     # saving the history
1113     if(!exists $form->{addition}) {
1114       $form->{snumbers}  = 'invnumber' .'_'. $form->{invnumber}; # ($form->{type} eq 'credit_note' ? 'cnnumber' : 'invnumber') .'_'. $form->{invnumber};
1115       $form->{what_done} = 'invoice';
1116       $form->{addition}  = "DELETED";
1117       $form->save_history;
1118     }
1119     # /saving the history
1120     $form->redirect($locale->text('Invoice deleted!'));
1121   }
1122   $form->error($locale->text('Cannot delete invoice!'));
1123
1124   $main::lxdebug->leave_sub();
1125 }
1126
1127 sub post_and_e_mail {
1128   e_mail();
1129 };
1130
1131 sub e_mail {
1132   $main::lxdebug->enter_sub();
1133
1134   my $form     = $main::form;
1135
1136   $main::auth->assert('invoice_edit');
1137
1138   if (!$form->{id}) {
1139     $form->{no_redirect_after_post} = 1;
1140
1141     my $saved_form = save_form();
1142
1143     post();
1144
1145     restore_form($saved_form, 0, qw(id invnumber));
1146   }
1147
1148   edit_e_mail();
1149
1150   $main::lxdebug->leave_sub();
1151 }