bin/mozilla/is.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 1998-2002
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  28 #======================================================================
  29 #
  30 # Inventory invoicing module
  31 #
  32 #======================================================================
  33
  34 use SL::FU;
  35 use SL::IS;
  36 use SL::PE;
  37 use SL::OE;
  38 use Data::Dumper;
  39 use DateTime;
  40 use List::Util qw(max sum);
  41
  42 use SL::DB::Default;
  43 use SL::DB::Customer;
  44
  45 require "bin/mozilla/io.pl";
  46 require "bin/mozilla/invoice_io.pl";
  47 require "bin/mozilla/arap.pl";
  48 require "bin/mozilla/drafts.pl";
  49
  50 use strict;
  51
  52 1;
  53
  54 # end of main
  55
  56 sub add {
  57   $main::lxdebug->enter_sub();
  58
  59   my $form     = $main::form;
  60   my $locale   = $main::locale;
  61
  62   $main::auth->assert('invoice_edit');
  63
  64   return $main::lxdebug->leave_sub() if (load_draft_maybe());
  65
  66   if ($form->{type} eq "credit_note") {
  67     $form->{title} = $locale->text('Add Credit Note');
  68
  69     if ($form->{storno}) {
  70       $form->{title} = $locale->text('Add Storno Credit Note');
  71     }
  72   } else {
  73     $form->{title} = $locale->text('Add Sales Invoice');
  74
  75   }
  76
  77
  78   $form->{callback} = "$form->{script}?action=add&type=$form->{type}" unless $form->{callback};
  79
  80   &invoice_links;
  81   &prepare_invoice;
  82   &display_form;
  83
  84   $main::lxdebug->leave_sub();
  85 }
  86
  87 sub edit {
  88   $main::lxdebug->enter_sub();
  89
  90   my $form     = $main::form;
  91   my $locale   = $main::locale;
  92
  93   $main::auth->assert('invoice_edit');
  94
  95   $form->{taxincluded_changed_by_user} = 1;
  96
  97   # show history button
  98   $form->{javascript} = qq|<script type="text/javascript" src="js/show_history.js"></script>|;
  99   #/show hhistory button
 100
 101   my ($language_id, $printer_id);
 102   if ($form->{print_and_post}) {
 103     $form->{action}   = "print";
 104     $form->{resubmit} = 1;
 105     $language_id = $form->{language_id};
 106     $printer_id = $form->{printer_id};
 107   }
 108
 109   &invoice_links;
 110   if ($form->{type} eq "credit_note") {
 111     $form->{title} = $locale->text('Edit Credit Note');
 112     $form->{title} = $locale->text('Edit Storno Credit Note') if $form->{storno};
 113   } else {
 114     $form->{title} = $locale->text('Edit Sales Invoice');
 115     $form->{title} = $locale->text('Edit Storno Invoice')     if $form->{storno};
 116   }
 117
 118   &prepare_invoice;
 119   if ($form->{print_and_post}) {
 120     $form->{language_id} = $language_id;
 121     $form->{printer_id} = $printer_id;
 122   }
 123
 124   &display_form;
 125
 126   $main::lxdebug->leave_sub();
 127 }
 128
 129 sub invoice_links {
 130   $main::lxdebug->enter_sub();
 131
 132   my $form     = $main::form;
 133   my %myconfig = %main::myconfig;
 134
 135   $main::auth->assert('invoice_edit');
 136
 137   $form->{vc} = 'customer';
 138
 139   # create links
 140   $form->{webdav}   = $::instance_conf->get_webdav;
 141
 142   $form->create_links("AR", \%myconfig, "customer");
 143
 144   if ($form->{all_customer}) {
 145     unless ($form->{customer_id}) {
 146       $form->{customer_id} = $form->{all_customer}->[0]->{id};
 147       $form->{salesman_id} = $form->{all_customer}->[0]->{salesman_id};
 148     }
 149   }
 150
 151   my $editing = $form->{id};
 152
 153   $form->backup_vars(qw(payment_id language_id taxzone_id salesman_id
 154                         taxincluded currency cp_id intnotes id shipto_id
 155                         delivery_term_id));
 156
 157   IS->get_customer(\%myconfig, \%$form);
 158
 159   #quote all_customer Bug 133
 160   foreach my $ref (@{ $form->{all_customer} }) {
 161     $ref->{name} = $form->quote($ref->{name});
 162   }
 163
 164   $form->restore_vars(qw(id));
 165
 166   IS->retrieve_invoice(\%myconfig, \%$form);
 167   $form->restore_vars(qw(payment_id language_id taxzone_id currency intnotes
 168                          cp_id shipto_id delivery_term_id));
 169   $form->restore_vars(qw(taxincluded)) if $form->{id};
 170   $form->restore_vars(qw(salesman_id)) if $editing;
 171
 172
 173   # build vendor/customer drop down comatibility... don't ask
 174   if (@{ $form->{"all_customer"} }) {
 175     $form->{"selectcustomer"} = 1;
 176     $form->{customer}         = qq|$form->{customer}--$form->{"customer_id"}|;
 177   }
 178
 179   $form->{"oldcustomer"}  = $form->{customer};
 180
 181   if ($form->{"oldcustomer"} !~ m/--\d+$/ && $form->{"customer_id"}) {
 182     $form->{"oldcustomer"} .= qq|--$form->{"customer_id"}|
 183   }
 184
 185
 186 #  $form->{oldcustomer} = "$form->{customer}--$form->{customer_id}";
 187 #  $form->{selectcustomer} = 1;
 188
 189   $form->{employee} = "$form->{employee}--$form->{employee_id}";
 190
 191   # forex
 192   $form->{forex} = $form->{exchangerate};
 193   my $exchangerate = ($form->{exchangerate}) ? $form->{exchangerate} : 1;
 194
 195   foreach my $key (keys %{ $form->{AR_links} }) {
 196     foreach my $ref (@{ $form->{AR_links}{$key} }) {
 197       $form->{"select$key"} .= "<option>$ref->{accno}--$ref->{description}</option>\n";
 198     }
 199
 200     if ($key eq "AR_paid") {
 201       next unless $form->{acc_trans}{$key};
 202       for my $i (1 .. scalar @{ $form->{acc_trans}{$key} }) {
 203         $form->{"AR_paid_$i"}      = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 204
 205         $form->{"acc_trans_id_$i"}    = $form->{acc_trans}{$key}->[$i - 1]->{acc_trans_id};
 206         # reverse paid
 207         $form->{"paid_$i"}         = $form->{acc_trans}{$key}->[$i - 1]->{amount} * -1;
 208         $form->{"datepaid_$i"}     = $form->{acc_trans}{$key}->[$i - 1]->{transdate};
 209         $form->{"gldate_$i"}       = $form->{acc_trans}{$key}->[$i - 1]->{gldate};
 210         $form->{"exchangerate_$i"} = $form->{acc_trans}{$key}->[$i - 1]->{exchangerate};
 211         $form->{"forex_$i"}        = $form->{"exchangerate_$i"};
 212         $form->{"source_$i"}       = $form->{acc_trans}{$key}->[$i - 1]->{source};
 213         $form->{"memo_$i"}         = $form->{acc_trans}{$key}->[$i - 1]->{memo};
 214
 215         $form->{paidaccounts} = $i;
 216       }
 217     } else {
 218       $form->{$key} = "$form->{acc_trans}{$key}->[0]->{accno}--$form->{acc_trans}{$key}->[0]->{description}";
 219     }
 220   }
 221
 222   $form->{paidaccounts} = 1 unless (exists $form->{paidaccounts});
 223
 224   $form->{AR} = $form->{AR_1} unless $form->{id};
 225
 226   $form->{locked} = ($form->datetonum($form->{invdate},  \%myconfig)
 227                   <= $form->datetonum($form->{closedto}, \%myconfig));
 228
 229   $main::lxdebug->leave_sub();
 230 }
 231
 232 sub prepare_invoice {
 233   $main::lxdebug->enter_sub();
 234
 235   my $form     = $main::form;
 236   my %myconfig = %main::myconfig;
 237
 238   $main::auth->assert('invoice_edit');
 239
 240   if ($form->{type} eq "credit_note") {
 241     $form->{type}     = "credit_note";
 242     $form->{formname} = "credit_note";
 243   } else {
 244     $form->{type}     = "invoice";
 245     $form->{formname} = "invoice";
 246   }
 247
 248   if ($form->{id}) {
 249
 250     my $i = 0;
 251
 252     foreach my $ref (@{ $form->{invoice_details} }) {
 253       $i++;
 254
 255       map { $form->{"${_}_$i"} = $ref->{$_} } keys %{$ref};
 256
 257       $form->{"discount_$i"}   = $form->format_amount(\%myconfig, $form->{"discount_$i"} * 100);
 258       my ($dec)                = ($form->{"sellprice_$i"} =~ /\.(\d+)/);
 259       $dec                     = length $dec;
 260       my $decimalplaces        = ($dec > 2) ? $dec : 2;
 261
 262       $form->{"sellprice_$i"}  = $form->format_amount(\%myconfig, $form->{"sellprice_$i"}, $decimalplaces);
 263       (my $dec_qty)            = ($form->{"qty_$i"} =~ /\.(\d+)/);
 264       $dec_qty                 = length $dec_qty;
 265
 266       $form->{"lastcost_$i"}  = $form->format_amount(\%myconfig, $form->{"lastcost_$i"}, $decimalplaces);
 267
 268       $form->{"qty_$i"}        = $form->format_amount(\%myconfig, $form->{"qty_$i"}, $dec_qty);
 269
 270       $form->{"sellprice_pg_$i"} = join ('--', $form->{"sellprice_$i"}, $form->{"pricegroup_id_$i"});
 271
 272       $form->{rowcount}        = $i;
 273
 274     }
 275
 276     # get pricegroups for parts
 277     IS->get_pricegroups_for_parts(\%myconfig, \%$form);
 278
 279     # Problem: set_pricegroup resets the sellprice of old invoices to the price
 280     # currently defined in the pricegroup, which is a problem if the price has
 281     # changed, as the old invoice gets the new price
 282     # set_pricegroup must never be called, when an old invoice is initially loaded
 283
 284     # set_pricegroup($_) for 1 .. $form->{rowcount};
 285   }
 286   $main::lxdebug->leave_sub();
 287 }
 288
 289 sub form_header {
 290   $main::lxdebug->enter_sub();
 291
 292   my $form     = $main::form;
 293   my %myconfig = %main::myconfig;
 294   my $locale   = $main::locale;
 295   my $cgi      = $::request->{cgi};
 296
 297   $main::auth->assert('invoice_edit');
 298
 299   my %TMPL_VAR = ();
 300   my @custom_hiddens;
 301
 302   $form->{employee_id} = $form->{old_employee_id} if $form->{old_employee_id};
 303   $form->{salesman_id} = $form->{old_salesman_id} if $form->{old_salesman_id};
 304
 305   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 306
 307   my @old_project_ids = ($form->{"globalproject_id"});
 308   map { push @old_project_ids, $form->{"project_id_$_"} if $form->{"project_id_$_"}; } 1..$form->{"rowcount"};
 309
 310   $form->get_lists("projects"      => { "key"    => "ALL_PROJECTS",
 311                                         "all"    => 0,
 312                                         "old_id" => \@old_project_ids },
 313                    "taxzones"      => "ALL_TAXZONES",
 314                    "currencies"    => "ALL_CURRENCIES",
 315                    "customers"     => "ALL_CUSTOMERS",
 316                    "departments"   => "all_departments",
 317                    "price_factors" => "ALL_PRICE_FACTORS");
 318
 319   $TMPL_VAR{ALL_EMPLOYEES}         = SL::DB::Manager::Employee->get_all(query => [ or => [ id => $::form->{employee_id},  deleted => 0 ] ]);
 320   $TMPL_VAR{ALL_SALESMEN}          = SL::DB::Manager::Employee->get_all(query => [ or => [ id => $::form->{salesman_id},  deleted => 0 ] ]);
 321   $TMPL_VAR{ALL_SHIPTO}            = SL::DB::Manager::Shipto->get_all(query => [
 322     or => [ trans_id  => $::form->{"$::form->{vc}_id"} * 1, and => [ shipto_id => $::form->{shipto_id} * 1, trans_id => undef ] ]
 323   ]);
 324   $TMPL_VAR{ALL_CONTACTS}          = SL::DB::Manager::Contact->get_all(query => [
 325     or => [
 326       cp_cv_id => $::form->{"$::form->{vc}_id"} * 1,
 327       and      => [
 328         cp_cv_id => undef,
 329         cp_id    => $::form->{cp_id} * 1
 330       ]
 331     ]
 332   ]);
 333   $TMPL_VAR{department_labels}     = sub { "$_[0]->{description}--$_[0]->{id}" };
 334
 335   # customer
 336   $TMPL_VAR{vc_keys} = sub { "$_[0]->{name}--$_[0]->{id}" };
 337   $TMPL_VAR{vclimit} = $myconfig{vclimit};
 338   $TMPL_VAR{vc_select} = "customer_or_vendor_selection_window('customer', '', 0, 0)";
 339   push @custom_hiddens, "customer_id";
 340   push @custom_hiddens, "oldcustomer";
 341   push @custom_hiddens, "selectcustomer";
 342
 343   # currencies and exchangerate
 344   my @values = map { $_       } @{ $form->{ALL_CURRENCIES} };
 345   my %labels = map { $_ => $_ } @{ $form->{ALL_CURRENCIES} };
 346   $form->{currency}            = $form->{defaultcurrency} unless $form->{currency};
 347   $form->{show_exchangerate}   = $form->{currency} ne $form->{defaultcurrency};
 348   $TMPL_VAR{currencies}        = NTI($::request->{cgi}->popup_menu('-name' => 'currency', '-default' => $form->{"currency"},
 349                                                       '-values' => \@values, '-labels' => \%labels,
 350                                                       '-onchange' => "document.getElementById('update_button').click();"
 351                                      )) if scalar @values;
 352   push @custom_hiddens, "forex";
 353   push @custom_hiddens, "exchangerate" if $form->{forex};
 354
 355   $TMPL_VAR{creditwarning} = ($form->{creditlimit} != 0) && ($form->{creditremaining} < 0) && !$form->{update};
 356   $TMPL_VAR{is_credit_remaining_negativ} = $form->{creditremaining} =~ /-/;
 357
 358   my $follow_up_vc         =  $form->{customer};
 359   $follow_up_vc            =~ s/--\d*\s*$//;
 360   $TMPL_VAR{customer_name} = $follow_up_vc;
 361
 362 # set option selected
 363   foreach my $item (qw(AR)) {
 364     $form->{"select$item"} =~ s/ selected//;
 365     $form->{"select$item"} =~ s/option>\Q$form->{$item}\E/option selected>$form->{$item}/;
 366   }
 367
 368   $TMPL_VAR{is_type_credit_note} = $form->{type}   eq "credit_note";
 369   $TMPL_VAR{is_format_html}      = $form->{format} eq 'html';
 370   $TMPL_VAR{dateformat}          = $myconfig{dateformat};
 371   $TMPL_VAR{numberformat}        = $myconfig{numberformat};
 372
 373   # hiddens
 374   $TMPL_VAR{HIDDENS} = [qw(
 375     id action type media format queued printed emailed title vc discount
 376     title creditlimit creditremaining tradediscount business closedto locked shipped storno storno_id
 377     max_dunning_level dunning_amount
 378     shiptoname shiptostreet shiptozipcode shiptocity shiptocountry  shiptocontact shiptophone shiptofax
 379     shiptoemail shiptodepartment_1 shiptodepartment_2  shiptocp_gender message email subject cc bcc taxaccounts cursor_fokus
 380     convert_from_do_ids convert_from_oe_ids
 381   ), @custom_hiddens,
 382   map { $_.'_rate', $_.'_description', $_.'_taxnumber' } split / /, $form->{taxaccounts}];
 383
 384   $form->header();
 385
 386   print $form->parse_html_template("is/form_header", \%TMPL_VAR);
 387
 388   $main::lxdebug->leave_sub();
 389 }
 390
 391 sub form_footer {
 392   $main::lxdebug->enter_sub();
 393
 394   my $form     = $main::form;
 395   my %myconfig = %main::myconfig;
 396   my $locale   = $main::locale;
 397
 398   $main::auth->assert('invoice_edit');
 399
 400   $form->{invtotal}    = $form->{invsubtotal};
 401
 402   # note rows
 403   $form->{rows} = max 2,
 404     $form->numtextrows($form->{notes},    26, 8),
 405     $form->numtextrows($form->{intnotes}, 35, 8);
 406
 407
 408   # tax, total and subtotal calculations
 409   my ($tax, $subtotal);
 410   $form->{taxaccounts_array} = [ split(/ /, $form->{taxaccounts}) ];
 411
 412   if( $form->{customer_id} && !$form->{taxincluded_changed_by_user} ) {
 413     my $customer = SL::DB::Customer->new(id => $form->{customer_id})->load();
 414     $form->{taxincluded} = defined($customer->taxincluded_checked) ? $customer->taxincluded_checked : $myconfig{taxincluded_checked};
 415   }
 416
 417   foreach my $item (@{ $form->{taxaccounts_array} }) {
 418     if ($form->{"${item}_base"}) {
 419       if ($form->{taxincluded}) {
 420         $form->{"${item}_total"} = $form->round_amount( ($form->{"${item}_base"} * $form->{"${item}_rate"}
 421                                                                                  / (1 + $form->{"${item}_rate"})), 2);
 422         $form->{"${item}_netto"} = $form->round_amount( ($form->{"${item}_base"} - $form->{"${item}_total"}), 2);
 423       } else {
 424         $form->{"${item}_total"} = $form->round_amount( $form->{"${item}_base"} * $form->{"${item}_rate"}, 2);
 425         $form->{invtotal} += $form->{"${item}_total"};
 426       }
 427     }
 428   }
 429
 430   # follow ups
 431   if ($form->{id}) {
 432     $form->{follow_ups}            = FU->follow_ups('trans_id' => $form->{id}) || [];
 433     $form->{follow_ups_unfinished} = ( sum map { $_->{due} * 1 } @{ $form->{follow_ups} } ) || 0;
 434   }
 435
 436   # payments
 437   my $totalpaid = 0;
 438   $form->{paidaccounts}++ if ($form->{"paid_$form->{paidaccounts}"});
 439   $form->{paid_indices} = [ 1 .. $form->{paidaccounts} ];
 440
 441   # Standard Konto für Umlaufvermögen
 442   my $accno_arap = IS->get_standard_accno_current_assets(\%myconfig, \%$form);
 443
 444   for my $i (1 .. $form->{paidaccounts}) {
 445     $form->{"changeable_$i"} = 1;
 446     if (SL::DB::Default->get->payments_changeable == 0) {
 447       # never
 448       $form->{"changeable_$i"} = ($form->{"acc_trans_id_$i"})? 0 : 1;
 449     } elsif (SL::DB::Default->get->payments_changeable == 2) {
 450       # on the same day
 451       $form->{"changeable_$i"} = (($form->{"gldate_$i"} eq '') ||
 452                                   ($form->current_date(\%myconfig) eq $form->{"gldate_$i"}));
 453     }
 454
 455     $form->{"selectAR_paid_$i"} = $form->{selectAR_paid};
 456     if (!$form->{"AR_paid_$i"}) {
 457       $form->{"selectAR_paid_$i"} =~ s/option>$accno_arap--(.*?)</option selected>$accno_arap--$1</;
 458     } else {
 459       $form->{"selectAR_paid_$i"} =~ s/option>\Q$form->{"AR_paid_$i"}\E/option selected>$form->{"AR_paid_$i"}/;
 460     }
 461
 462     $totalpaid += $form->{"paid_$i"};
 463   }
 464
 465   $form->{oldinvtotal} = $form->{invtotal};
 466
 467   $form->{ALL_DELIVERY_TERMS} = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 468
 469   print $form->parse_html_template('is/form_footer', {
 470     is_type_credit_note => ($form->{type} eq "credit_note"),
 471     totalpaid           => $totalpaid,
 472     paid_missing        => $form->{invtotal} - $totalpaid,
 473     print_options       => print_options(inline => 1),
 474     show_storno         => $form->{id} && !$form->{storno} && !IS->has_storno(\%myconfig, $form, "ar") && !$totalpaid,
 475     show_delete         => ($::instance_conf->get_is_changeable == 2)
 476                              ? ($form->current_date(\%myconfig) eq $form->{gldate})
 477                              : ($::instance_conf->get_is_changeable == 1),
 478   });
 479 ##print $form->parse_html_template('is/_payments'); # parser
 480 ##print $form->parse_html_template('webdav/_list'); # parser
 481
 482   $main::lxdebug->leave_sub();
 483 }
 484
 485 sub mark_as_paid {
 486   $main::lxdebug->enter_sub();
 487
 488   my $form     = $main::form;
 489   my %myconfig = %main::myconfig;
 490
 491   $main::auth->assert('invoice_edit');
 492
 493   &mark_as_paid_common(\%myconfig,"ar");
 494
 495   $main::lxdebug->leave_sub();
 496 }
 497
 498 sub update {
 499   $main::lxdebug->enter_sub();
 500
 501   my $form     = $main::form;
 502   my %myconfig = %main::myconfig;
 503
 504   $main::auth->assert('invoice_edit');
 505
 506   my ($recursive_call) = @_;
 507
 508   $form->{print_and_post} = 0         if $form->{second_run};
 509   my $taxincluded         = $form->{taxincluded} ? "checked" : '';
 510   $form->{update} = 1;
 511
 512   &check_name("customer");
 513
 514   $form->{taxincluded} ||= $taxincluded;
 515
 516   if (!$form->{forex}) {        # read exchangerate from input field (not hidden)
 517     $form->{exchangerate} = $form->parse_amount(\%myconfig, $form->{exchangerate}) unless $recursive_call;
 518   }
 519   $form->{forex}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{invdate}, 'buy');
 520   $form->{exchangerate} = $form->{forex} if $form->{forex};
 521
 522   for my $i (1 .. $form->{paidaccounts}) {
 523     next unless $form->{"paid_$i"};
 524     map { $form->{"${_}_$i"} = $form->parse_amount(\%myconfig, $form->{"${_}_$i"}) } qw(paid exchangerate);
 525     if (!$form->{"forex_$i"}) {   #read exchangerate from input field (not hidden)
 526       $form->{exchangerate} = $form->{"exchangerate_$i"};
 527     }
 528     $form->{"forex_$i"}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'buy');
 529     $form->{"exchangerate_$i"} = $form->{"forex_$i"} if $form->{"forex_$i"};
 530   }
 531
 532   my $i            = $form->{rowcount};
 533   my $exchangerate = $form->{exchangerate} || 1;
 534
 535   # if last row empty, check the form otherwise retrieve new item
 536   if (   ($form->{"partnumber_$i"} eq "")
 537       && ($form->{"description_$i"} eq "")
 538       && ($form->{"partsgroup_$i"}  eq "")) {
 539
 540     $form->{creditremaining} += ($form->{oldinvtotal} - $form->{oldtotalpaid});
 541     &check_form;
 542
 543   } else {
 544
 545     IS->retrieve_item(\%myconfig, \%$form);
 546
 547     my $rows = scalar @{ $form->{item_list} };
 548
 549     # Falls kein Kundenrabatt vorhanden ist, den aktuellen Rabatt nicht mit 0% überschreiben,
 550     # da hier der Anwender schon manual einen Wert eingetragen haben könnte (analog zu qty) Bugfix: 1412
 551     if ($form->{customer_discount}){
 552       $form->{"discount_$i"} = $form->format_amount(\%myconfig, $form->{customer_discount} * 100);
 553     }
 554
 555     if ($rows) {
 556       $form->{"qty_$i"} = $form->parse_amount(\%myconfig, $form->{"qty_$i"});
 557       if( !$form->{"qty_$i"} ) {
 558         $form->{"qty_$i"} = 1;
 559       }
 560
 561       if ($rows > 1) {
 562
 563         select_item(mode => 'IS');
 564         ::end_of_request();
 565
 566       } else {
 567
 568         my $sellprice = $form->parse_amount(\%myconfig, $form->{"sellprice_$i"});
 569
 570         map { $form->{item_list}[$i]{$_} =~ s/\"/&quot;/g } qw(partnumber description unit);
 571         map { $form->{"${_}_$i"} = $form->{item_list}[0]{$_} } keys %{ $form->{item_list}[0] };
 572
 573         $form->{payment_id}    = $form->{"part_payment_id_$i"} if $form->{"part_payment_id_$i"} ne "";
 574         $form->{"discount_$i"} = 0                             if $form->{"not_discountable_$i"};
 575
 576         $form->{"marge_price_factor_$i"} = $form->{item_list}->[0]->{price_factor};
 577
 578         ($sellprice || $form->{"sellprice_$i"}) =~ /\.(\d+)/;
 579         my $decimalplaces = max 2, length $1;
 580
 581         if ($sellprice) {
 582           $form->{"sellprice_$i"} = $sellprice;
 583         } else {
 584           # if there is an exchange rate adjust sellprice
 585           $form->{"sellprice_$i"} *= (1 - $form->{tradediscount});
 586           $form->{"sellprice_$i"} /= $exchangerate;
 587         }
 588
 589         $form->{"listprice_$i"} /= $exchangerate;
 590
 591         my $amount = $form->{"sellprice_$i"} * $form->{"qty_$i"} * (1 - $form->{"discount_$i"} / 100);
 592         map { $form->{"${_}_base"} = 0 }                                 split / /, $form->{taxaccounts};
 593         map { $form->{"${_}_base"} += $amount }                          split / /, $form->{"taxaccounts_$i"};
 594         map { $amount += ($form->{"${_}_base"} * $form->{"${_}_rate"}) } split / /, $form->{"taxaccounts_$i"} if !$form->{taxincluded};
 595
 596         $form->{creditremaining} -= $amount;
 597
 598         map { $form->{"${_}_$i"} = $form->format_amount(\%myconfig, $form->{"${_}_$i"}, $decimalplaces) } qw(sellprice lastcost);
 599
 600         $form->{"qty_$i"} = $form->format_amount(\%myconfig, $form->{"qty_$i"});
 601
 602         # get pricegroups for parts
 603         IS->get_pricegroups_for_parts(\%myconfig, \%$form);
 604
 605         # build up html code for prices_$i
 606         &set_pricegroup($i);
 607       }
 608
 609       &display_form;
 610
 611     } else {
 612
 613       # ok, so this is a new part
 614       # ask if it is a part or service item
 615
 616       if (   $form->{"partsgroup_$i"}
 617           && ($form->{"partsnumber_$i"} eq "")
 618           && ($form->{"description_$i"} eq "")) {
 619         $form->{rowcount}--;
 620         $form->{"discount_$i"} = "";
 621         display_form();
 622
 623       } else {
 624         $form->{"id_$i"}   = 0;
 625         new_item();
 626       }
 627     }
 628   }
 629   $main::lxdebug->leave_sub();
 630 }
 631
 632 sub post_payment {
 633   $main::lxdebug->enter_sub();
 634
 635   my $form     = $main::form;
 636   my %myconfig = %main::myconfig;
 637   my $locale   = $main::locale;
 638
 639   $main::auth->assert('invoice_edit');
 640
 641   my $invdate = $form->datetonum($form->{invdate}, \%myconfig);
 642
 643   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 644   for my $i (1 .. $form->{paidaccounts}) {
 645     if ($form->{"paid_$i"}) {
 646       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 647
 648       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 649
 650
 651       if ($form->{currency} ne $form->{defaultcurrency}) {
 652         $form->{"exchangerate_$i"} = $form->{exchangerate}
 653           if ($invdate == $datepaid);
 654         $form->isblank("exchangerate_$i",
 655                        $locale->text('Exchangerate for payment missing!'));
 656       }
 657     }
 658   }
 659   # Abgeschlossene Zeiträume nur für den letzten (aktuellen) Zahlungseingang prüfen
 660   # Details s.a. Bug 1502
 661   # Das Problem ist jetzt, dass man Zahlungseingänge nachträglich ändern kann
 662   # Wobei dies für Installationen die sowieso nicht mit Bücherkontrolle arbeiten keinen
 663   # keinen Unterschied macht.
 664   # Optimal wäre, wenn gegen einen Zeitstempel des Zahlungsfelds geprüft würde ...
 665   # Das Problem hierbei ist, dass in IS.pm post_invoice IMMER alle Zahlungseingänge aus $form
 666   # erneut gespeichert werden. Prinzipiell wäre es besser NUR die Änderungen des Rechnungs-
 667   # belegs (neue Zahlung aber nichts anderes) zu speichern ...
 668   # Vielleicht könnte man ähnlich wie bei Rechnung löschen verfahren
 669   $form->error($locale->text('Cannot post payment for a closed period!'))
 670     if ($form->date_closed($form->{"datepaid_$form->{paidaccounts}"}, \%myconfig));
 671
 672   ($form->{AR})      = split /--/, $form->{AR};
 673   ($form->{AR_paid}) = split /--/, $form->{AR_paid};
 674   relink_accounts();
 675   $form->redirect($locale->text('Payment posted!'))
 676       if (IS->post_payment(\%myconfig, \%$form));
 677     $form->error($locale->text('Cannot post payment!'));
 678
 679
 680   $main::lxdebug->leave_sub();
 681 }
 682
 683 sub post {
 684   $main::lxdebug->enter_sub();
 685
 686   my $form     = $main::form;
 687   my %myconfig = %main::myconfig;
 688   my $locale   = $main::locale;
 689
 690   $main::auth->assert('invoice_edit');
 691
 692   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 693   $form->isblank("invdate",  $locale->text('Invoice Date missing!'));
 694   $form->isblank("customer", $locale->text('Customer missing!'));
 695   $form->error($locale->text('Cannot post invoice for a closed period!'))
 696         if ($form->date_closed($form->{"invdate"}, \%myconfig));
 697
 698   $form->{invnumber} =~ s/^\s*//g;
 699   $form->{invnumber} =~ s/\s*$//g;
 700
 701   # if oldcustomer ne customer redo form
 702   if (&check_name('customer')) {
 703     &update;
 704     ::end_of_request();
 705   }
 706
 707   if ($myconfig{mandatory_departments} && !$form->{department_id}) {
 708     $form->{saved_message} = $::locale->text('You have to specify a department.');
 709     update();
 710     exit;
 711   }
 712
 713   if ($form->{second_run}) {
 714     $form->{print_and_post} = 0;
 715   }
 716
 717   remove_emptied_rows();
 718   &validate_items;
 719
 720   my $closedto = $form->datetonum($form->{closedto}, \%myconfig);
 721   my $invdate  = $form->datetonum($form->{invdate},  \%myconfig);
 722
 723   $form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 724     if ($form->date_max_future($invdate, \%myconfig));
 725   $form->error($locale->text('Cannot post invoice for a closed period!'))
 726     if ($invdate <= $closedto);
 727
 728   $form->isblank("exchangerate", $locale->text('Exchangerate missing!'))
 729     if ($form->{currency} ne $form->{defaultcurrency});
 730
 731   for my $i (1 .. $form->{paidaccounts}) {
 732     if ($form->parse_amount(\%myconfig, $form->{"paid_$i"})) {
 733       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 734
 735       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 736
 737       $form->error($locale->text('Cannot post payment for a closed period!'))
 738         if ($form->date_closed($form->{"datepaid_$i"}, \%myconfig));
 739
 740       if ($form->{currency} ne $form->{defaultcurrency}) {
 741         $form->{"exchangerate_$i"} = $form->{exchangerate}
 742           if ($invdate == $datepaid);
 743         $form->isblank("exchangerate_$i",
 744                        $locale->text('Exchangerate for payment missing!'));
 745       }
 746     }
 747   }
 748
 749   ($form->{AR})        = split /--/, $form->{AR};
 750   ($form->{AR_paid})   = split /--/, $form->{AR_paid};
 751   $form->{storno}    ||= 0;
 752
 753   $form->{label} = $form->{type} eq 'credit_note' ? $locale->text('Credit Note') : $locale->text('Invoice');
 754
 755   $form->{id} = 0 if $form->{postasnew};
 756
 757   # get new invnumber in sequence if no invnumber is given or if posasnew was requested
 758   if ($form->{postasnew}) {
 759     if ($form->{type} eq "credit_note") {
 760       undef($form->{cnnumber});
 761     } else {
 762       undef($form->{invnumber});
 763     }
 764   }
 765
 766   relink_accounts();
 767   $form->error($locale->text('Cannot post invoice!'))
 768     unless IS->post_invoice(\%myconfig, \%$form);
 769   remove_draft() if $form->{remove_draft};
 770
 771   if(!exists $form->{addition}) {
 772     $form->{snumbers} =  'invnumber' .'_'. $form->{invnumber}; # ($form->{type} eq 'credit_note' ? 'cnnumber' : 'invnumber') .'_'. $form->{invnumber};
 773     $form->{addition} = $form->{print_and_post} ? "PRINTED AND POSTED" :
 774                         $form->{storno}         ? "STORNO"             :
 775                                                   "POSTED";
 776     $form->save_history;
 777   }
 778
 779   if (!$form->{no_redirect_after_post}) {
 780     $form->{action} = 'edit';
 781     $form->{script} = 'is.pl';
 782     $form->{saved_message} = $form->{label} . " $form->{invnumber} " . $locale->text('posted!');
 783     $form->{callback} = build_std_url(qw(action edit id saved_message));
 784     $form->redirect;
 785   }
 786
 787   $main::lxdebug->leave_sub();
 788 }
 789
 790 sub print_and_post {
 791   $main::lxdebug->enter_sub();
 792
 793   my $form     = $main::form;
 794
 795   $main::auth->assert('invoice_edit');
 796
 797   my $old_form                    = new Form;
 798   $form->{no_redirect_after_post} = 1;
 799   $form->{print_and_post}         = 1;
 800   &post();
 801
 802   &edit();
 803   $main::lxdebug->leave_sub();
 804
 805 }
 806
 807 sub use_as_new {
 808   $main::lxdebug->enter_sub();
 809
 810   my $form     = $main::form;
 811   my %myconfig = %main::myconfig;
 812
 813   $main::auth->assert('invoice_edit');
 814
 815   delete @{ $form }{qw(printed emailed queued invnumber invdate deliverydate id datepaid_1 gldate_1 acc_trans_id_1 source_1 memo_1 paid_1 exchangerate_1 AP_paid_1 storno locked)};
 816   $form->{paidaccounts} = 1;
 817   $form->{rowcount}--;
 818   $form->{invdate} = $form->current_date(\%myconfig);
 819   $form->{duedate} = $form->get_duedate(\%myconfig, $form->{invdate}) || $form->{invdate};
 820
 821   # remember pricegroups for "use as new"
 822   IS->get_pricegroups_for_parts(\%myconfig, \%$form);
 823   set_pricegroup($_) for 1 .. $form->{rowcount};
 824
 825   &display_form;
 826
 827   $main::lxdebug->leave_sub();
 828 }
 829
 830 sub storno {
 831   $main::lxdebug->enter_sub();
 832
 833   my $form     = $main::form;
 834   my %myconfig = %main::myconfig;
 835   my $locale   = $main::locale;
 836
 837   $main::auth->assert('invoice_edit');
 838
 839   if ($form->{storno}) {
 840     $form->error($locale->text('Cannot storno storno invoice!'));
 841   }
 842
 843   if (IS->has_storno(\%myconfig, $form, "ar")) {
 844     $form->error($locale->text("Invoice has already been storno'd!"));
 845   }
 846   if ($form->datetonum($form->{invdate},  \%myconfig) <= $form->datetonum($form->{closedto}, \%myconfig)) {
 847     $form->error($locale->text('Cannot storno invoice for a closed period!'));
 848   }
 849
 850   map({ my $key = $_; delete($form->{$key}) unless (grep({ $key eq $_ } qw(id login password type))); } keys(%{ $form }));
 851
 852   invoice_links();
 853   prepare_invoice();
 854   relink_accounts();
 855
 856   # Payments must not be recorded for the new storno invoice.
 857   $form->{paidaccounts} = 0;
 858   map { my $key = $_; delete $form->{$key} if grep { $key =~ /^$_/ } qw(datepaid_ gldate_ acc_trans_id_ source_ memo_ paid_ exchangerate_ AR_paid_) } keys %{ $form };
 859
 860   $form->{storno_id} = $form->{id};
 861   $form->{storno} = 1;
 862   $form->{id} = "";
 863   $form->{invnumber} = "Storno zu " . $form->{invnumber};
 864   $form->{invdate}   = DateTime->today->to_lxoffice;
 865   $form->{rowcount}++;
 866
 867   post();
 868   $main::lxdebug->leave_sub();
 869 }
 870
 871 sub preview {
 872   $main::lxdebug->enter_sub();
 873
 874   my $form     = $main::form;
 875
 876   $main::auth->assert('invoice_edit');
 877
 878   $form->{preview} = 1;
 879   my $old_form = new Form;
 880   for (keys %$form) { $old_form->{$_} = $form->{$_} }
 881
 882   &print_form($old_form);
 883   $main::lxdebug->leave_sub();
 884
 885 }
 886
 887 sub delete {
 888   $main::lxdebug->enter_sub();
 889
 890   my $form     = $main::form;
 891   my $locale   = $main::locale;
 892
 893   $main::auth->assert('invoice_edit');
 894
 895   if ($form->{second_run}) {
 896     $form->{print_and_post} = 0;
 897   }
 898   $form->header;
 899
 900   print qq|
 901 <form method="post" action="$form->{script}">
 902 |;
 903
 904   # delete action variable
 905   map { delete $form->{$_} } qw(action header);
 906
 907   foreach my $key (keys %$form) {
 908     next if (($key eq 'login') || ($key eq 'password') || ('' ne ref $form->{$key}));
 909     $form->{$key} =~ s/\"/&quot;/g;
 910     print qq|<input type="hidden" name="$key" value="$form->{$key}">\n|;
 911   }
 912
 913   print qq|
 914 <h2 class="confirm">| . $locale->text('Confirm!') . qq|</h2>
 915
 916 <h4>|
 917     . $locale->text('Are you sure you want to delete Invoice Number')
 918     . qq| $form->{invnumber}
 919 </h4>
 920
 921 <p>
 922 <input name="action" class="submit" type="submit" value="|
 923     . $locale->text('Yes') . qq|">
 924 </form>
 925 |;
 926
 927   $main::lxdebug->leave_sub();
 928 }
 929
 930 sub credit_note {
 931   $main::lxdebug->enter_sub();
 932
 933   my $form     = $main::form;
 934   my %myconfig = %main::myconfig;
 935   my $locale   = $main::locale;
 936
 937   $main::auth->assert('invoice_edit');
 938
 939   $form->{transdate} = $form->{invdate} = $form->current_date(\%myconfig);
 940   $form->{duedate} =
 941     $form->current_date(\%myconfig, $form->{invdate}, $form->{terms} * 1);
 942
 943   $form->{id}     = '';
 944   $form->{rowcount}--;
 945   $form->{shipto} = 1;
 946
 947
 948   $form->{title}  = $locale->text('Add Credit Note');
 949   $form->{script} = 'is.pl';
 950
 951   # Bei Gutschriften bezug zur Rechnungsnummer
 952   $form->{invnumber_for_credit_note} = $form->{invnumber};
 953   # bo creates the id, reset it
 954   map { delete $form->{$_} }
 955     qw(id invnumber subject message cc bcc printed emailed queued);
 956   $form->{ $form->{vc} } =~ s/--.*//g;
 957   $form->{type} = "credit_note";
 958
 959
 960   map { $form->{"select$_"} = "" } ($form->{vc}, 'currency');
 961
 962 #  map { $form->{$_} = $form->parse_amount(\%myconfig, $form->{$_}) }
 963 #    qw(creditlimit creditremaining);
 964
 965   for my $i (1 .. $form->{rowcount}) {
 966     for (qw(listprice)) {
 967       $form->{"${_}_${i}"} = $form->parse_amount(\%myconfig, $form->{"${_}_${i}"}) if $form->{"${_}_${i}"};
 968     }
 969   }
 970
 971   my $currency = $form->{currency};
 972   &invoice_links;
 973
 974   $form->{currency}     = $currency;
 975   $form->{forex}        = $form->check_exchangerate( \%myconfig, $form->{currency}, $form->{invdate}, 'buy');
 976   $form->{exchangerate} = $form->{forex} || '';
 977
 978   $form->{creditremaining} -= ($form->{oldinvtotal} - $form->{ordtotal});
 979
 980   # bei Gutschriften werden Zahlungseingänge aus Rechnung nicht übernommen
 981   for my $i (1 .. $form->{paidaccounts}) {
 982     delete $form->{"paid_$i"};
 983     delete $form->{"source_$i"};
 984     delete $form->{"memo_$i"};
 985     delete $form->{"datepaid_$i"};
 986     delete $form->{"gldate_$i"};
 987     delete $form->{"acc_trans_id_$i"};
 988     delete $form->{"AR_paid_$i"};
 989   };
 990   $form->{paidaccounts} = 1;
 991
 992   &prepare_invoice;
 993
 994
 995   &display_form;
 996
 997   $main::lxdebug->leave_sub();
 998 }
 999
1000 sub yes {
1001   $main::lxdebug->enter_sub();
1002
1003   my $form     = $main::form;
1004   my %myconfig = %main::myconfig;
1005   my $locale   = $main::locale;
1006
1007   $main::auth->assert('invoice_edit');
1008
1009   if (IS->delete_invoice(\%myconfig, \%$form)) {
1010     # saving the history
1011     if(!exists $form->{addition}) {
1012       $form->{snumbers} = 'invnumber' .'_'. $form->{invnumber}; # ($form->{type} eq 'credit_note' ? 'cnnumber' : 'invnumber') .'_'. $form->{invnumber};
1013       $form->{addition} = "DELETED";
1014       $form->save_history;
1015     }
1016     # /saving the history
1017     $form->redirect($locale->text('Invoice deleted!'));
1018   }
1019   $form->error($locale->text('Cannot delete invoice!'));
1020
1021   $main::lxdebug->leave_sub();
1022 }
1023
1024 sub e_mail {
1025   $main::lxdebug->enter_sub();
1026
1027   my $form     = $main::form;
1028
1029   $main::auth->assert('invoice_edit');
1030
1031   if (!$form->{id}) {
1032     $form->{no_redirect_after_post} = 1;
1033
1034     my $saved_form = save_form();
1035
1036     post();
1037
1038     restore_form($saved_form, 0, qw(id invnumber));
1039   }
1040
1041   edit_e_mail();
1042
1043   $main::lxdebug->leave_sub();
1044 }