bin/mozilla/is.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 1998-2002
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  28 #======================================================================
  29 #
  30 # Inventory invoicing module
  31 #
  32 #======================================================================
  33
  34 use SL::FU;
  35 use SL::IS;
  36 use SL::PE;
  37 use SL::OE;
  38 use Data::Dumper;
  39 use DateTime;
  40 use List::MoreUtils qw(uniq);
  41 use List::Util qw(max sum);
  42 use English qw(-no_match_vars);
  43
  44 use SL::DB::Default;
  45 use SL::DB::Customer;
  46 use SL::DB::PaymentTerm;
  47
  48 require "bin/mozilla/io.pl";
  49 require "bin/mozilla/invoice_io.pl";
  50 require "bin/mozilla/arap.pl";
  51 require "bin/mozilla/drafts.pl";
  52
  53 use strict;
  54
  55 1;
  56
  57 # end of main
  58
  59 sub add {
  60   $main::lxdebug->enter_sub();
  61
  62   my $form     = $main::form;
  63   my $locale   = $main::locale;
  64
  65   $main::auth->assert('invoice_edit');
  66
  67   return $main::lxdebug->leave_sub() if (load_draft_maybe());
  68
  69   if ($form->{type} eq "credit_note") {
  70     $form->{title} = $locale->text('Add Credit Note');
  71
  72     if ($form->{storno}) {
  73       $form->{title} = $locale->text('Add Storno Credit Note');
  74     }
  75   } else {
  76     $form->{title} = $locale->text('Add Sales Invoice');
  77
  78   }
  79
  80
  81   $form->{callback} = "$form->{script}?action=add&type=$form->{type}" unless $form->{callback};
  82
  83   &invoice_links;
  84   &prepare_invoice;
  85   &display_form;
  86
  87   $main::lxdebug->leave_sub();
  88 }
  89
  90 sub edit {
  91   $main::lxdebug->enter_sub();
  92
  93   my $form     = $main::form;
  94   my $locale   = $main::locale;
  95
  96   $main::auth->assert('invoice_edit');
  97
  98   $form->{taxincluded_changed_by_user} = 1;
  99
 100   # show history button
 101   $form->{javascript} = qq|<script type="text/javascript" src="js/show_history.js"></script>|;
 102
 103   my ($language_id, $printer_id);
 104   if ($form->{print_and_post}) {
 105     $form->{action}   = "print";
 106     $form->{resubmit} = 1;
 107     $language_id = $form->{language_id};
 108     $printer_id = $form->{printer_id};
 109   }
 110
 111   &invoice_links;
 112   if ($form->{type} eq "credit_note") {
 113     $form->{title} = $locale->text('Edit Credit Note');
 114     $form->{title} = $locale->text('Edit Storno Credit Note') if $form->{storno};
 115   } else {
 116     $form->{title} = $locale->text('Edit Sales Invoice');
 117     $form->{title} = $locale->text('Edit Storno Invoice')     if $form->{storno};
 118   }
 119
 120   &prepare_invoice;
 121   if ($form->{print_and_post}) {
 122     $form->{language_id} = $language_id;
 123     $form->{printer_id} = $printer_id;
 124   }
 125
 126   &display_form;
 127
 128   $main::lxdebug->leave_sub();
 129 }
 130
 131 sub invoice_links {
 132   $main::lxdebug->enter_sub();
 133
 134   my $form     = $main::form;
 135   my %myconfig = %main::myconfig;
 136
 137   $main::auth->assert('invoice_edit');
 138
 139   $form->{vc} = 'customer';
 140
 141   # create links
 142   $form->{webdav}   = $::instance_conf->get_webdav;
 143
 144   $form->create_links("AR", \%myconfig, "customer");
 145
 146   if ($form->{all_customer}) {
 147     unless ($form->{customer_id}) {
 148       $form->{customer_id} = $form->{all_customer}->[0]->{id};
 149       $form->{salesman_id} = $form->{all_customer}->[0]->{salesman_id};
 150     }
 151   }
 152
 153   my $editing = $form->{id};
 154
 155   $form->backup_vars(qw(payment_id language_id taxzone_id salesman_id
 156                         taxincluded currency cp_id intnotes id shipto_id
 157                         delivery_term_id));
 158
 159   IS->get_customer(\%myconfig, \%$form);
 160
 161   #quote all_customer Bug 133
 162   foreach my $ref (@{ $form->{all_customer} }) {
 163     $ref->{name} = $form->quote($ref->{name});
 164   }
 165
 166   $form->restore_vars(qw(id));
 167
 168   IS->retrieve_invoice(\%myconfig, \%$form);
 169   $form->restore_vars(qw(payment_id language_id taxzone_id currency intnotes
 170                          cp_id shipto_id delivery_term_id));
 171   $form->restore_vars(qw(taxincluded)) if $form->{id};
 172   $form->restore_vars(qw(salesman_id)) if $editing;
 173
 174
 175   # build vendor/customer drop down compatibility... don't ask
 176   if (@{ $form->{"all_customer"} }) {
 177     $form->{"selectcustomer"} = 1;
 178     $form->{customer}         = qq|$form->{customer}--$form->{"customer_id"}|;
 179   }
 180
 181   $form->{"oldcustomer"}  = $form->{customer};
 182
 183   if ($form->{"oldcustomer"} !~ m/--\d+$/ && $form->{"customer_id"}) {
 184     $form->{"oldcustomer"} .= qq|--$form->{"customer_id"}|
 185   }
 186
 187
 188 #  $form->{oldcustomer} = "$form->{customer}--$form->{customer_id}";
 189 #  $form->{selectcustomer} = 1;
 190
 191   $form->{employee} = "$form->{employee}--$form->{employee_id}";
 192
 193   # forex
 194   $form->{forex} = $form->{exchangerate};
 195   my $exchangerate = ($form->{exchangerate}) ? $form->{exchangerate} : 1;
 196
 197   foreach my $key (keys %{ $form->{AR_links} }) {
 198     foreach my $ref (@{ $form->{AR_links}{$key} }) {
 199       $form->{"select$key"} .= "<option>$ref->{accno}--$ref->{description}</option>\n";
 200     }
 201
 202     if ($key eq "AR_paid") {
 203       next unless $form->{acc_trans}{$key};
 204       for my $i (1 .. scalar @{ $form->{acc_trans}{$key} }) {
 205         $form->{"AR_paid_$i"}      = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 206
 207         $form->{"acc_trans_id_$i"}    = $form->{acc_trans}{$key}->[$i - 1]->{acc_trans_id};
 208         # reverse paid
 209         $form->{"paid_$i"}         = $form->{acc_trans}{$key}->[$i - 1]->{amount} * -1;
 210         $form->{"datepaid_$i"}     = $form->{acc_trans}{$key}->[$i - 1]->{transdate};
 211         $form->{"gldate_$i"}       = $form->{acc_trans}{$key}->[$i - 1]->{gldate};
 212         $form->{"exchangerate_$i"} = $form->{acc_trans}{$key}->[$i - 1]->{exchangerate};
 213         $form->{"forex_$i"}        = $form->{"exchangerate_$i"};
 214         $form->{"source_$i"}       = $form->{acc_trans}{$key}->[$i - 1]->{source};
 215         $form->{"memo_$i"}         = $form->{acc_trans}{$key}->[$i - 1]->{memo};
 216
 217         $form->{paidaccounts} = $i;
 218       }
 219     } else {
 220       $form->{$key} = "$form->{acc_trans}{$key}->[0]->{accno}--$form->{acc_trans}{$key}->[0]->{description}";
 221     }
 222   }
 223
 224   $form->{paidaccounts} = 1 unless (exists $form->{paidaccounts});
 225
 226   $form->{AR} = $form->{AR_1} unless $form->{id};
 227
 228   $form->{locked} = ($form->datetonum($form->{invdate},  \%myconfig)
 229                   <= $form->datetonum($form->{closedto}, \%myconfig));
 230
 231   $main::lxdebug->leave_sub();
 232 }
 233
 234 sub prepare_invoice {
 235   $main::lxdebug->enter_sub();
 236
 237   my $form     = $main::form;
 238   my %myconfig = %main::myconfig;
 239
 240   $main::auth->assert('invoice_edit');
 241
 242   if ($form->{type} eq "credit_note") {
 243     $form->{type}     = "credit_note";
 244     $form->{formname} = "credit_note";
 245   } else {
 246     $form->{type}     = "invoice";
 247     $form->{formname} = "invoice";
 248   }
 249
 250   if ($form->{id}) {
 251
 252     my $i = 0;
 253
 254     foreach my $ref (@{ $form->{invoice_details} }) {
 255       $i++;
 256
 257       map { $form->{"${_}_$i"} = $ref->{$_} } keys %{$ref};
 258
 259       $form->{"discount_$i"}   = $form->format_amount(\%myconfig, $form->{"discount_$i"} * 100);
 260       my ($dec)                = ($form->{"sellprice_$i"} =~ /\.(\d+)/);
 261       $dec                     = length $dec;
 262       my $decimalplaces        = ($dec > 2) ? $dec : 2;
 263
 264       $form->{"sellprice_$i"}  = $form->format_amount(\%myconfig, $form->{"sellprice_$i"}, $decimalplaces);
 265       (my $dec_qty)            = ($form->{"qty_$i"} =~ /\.(\d+)/);
 266       $dec_qty                 = length $dec_qty;
 267
 268       $form->{"lastcost_$i"}  = $form->format_amount(\%myconfig, $form->{"lastcost_$i"}, $decimalplaces);
 269
 270       $form->{"qty_$i"}        = $form->format_amount(\%myconfig, $form->{"qty_$i"}, $dec_qty);
 271
 272       $form->{"sellprice_pg_$i"} = join ('--', $form->{"sellprice_$i"}, $form->{"pricegroup_id_$i"});
 273
 274       $form->{rowcount}        = $i;
 275
 276     }
 277   }
 278   $main::lxdebug->leave_sub();
 279 }
 280
 281 sub form_header {
 282   $main::lxdebug->enter_sub();
 283
 284   my $form     = $main::form;
 285   my %myconfig = %main::myconfig;
 286   my $locale   = $main::locale;
 287   my $cgi      = $::request->{cgi};
 288
 289   $main::auth->assert('invoice_edit');
 290
 291   my %TMPL_VAR = ();
 292   my @custom_hiddens;
 293
 294   $form->{employee_id} = $form->{old_employee_id} if $form->{old_employee_id};
 295   $form->{salesman_id} = $form->{old_salesman_id} if $form->{old_salesman_id};
 296
 297   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 298
 299   $form->get_lists("taxzones"      => ($form->{id} ? "ALL_TAXZONES" : "ALL_ACTIVE_TAXZONES"),
 300                    "currencies"    => "ALL_CURRENCIES",
 301                    "customers"     => "ALL_CUSTOMERS",
 302                    "departments"   => "all_departments",
 303                    "price_factors" => "ALL_PRICE_FACTORS");
 304
 305   # Projects
 306   my @old_project_ids = uniq grep { $_ } map { $_ * 1 } ($form->{"globalproject_id"}, map { $form->{"project_id_$_"} } 1..$form->{"rowcount"});
 307   my @old_ids_cond    = @old_project_ids ? (id => \@old_project_ids) : ();
 308   my @customer_cond;
 309   if ($::instance_conf->get_customer_projects_only_in_sales) {
 310     @customer_cond = (
 311       or => [
 312         customer_id          => $::form->{customer_id},
 313         billable_customer_id => $::form->{customer_id},
 314       ]);
 315   }
 316   my @conditions = (
 317     or => [
 318       and => [ active => 1, @customer_cond ],
 319       @old_ids_cond,
 320     ]);
 321
 322   $TMPL_VAR{ALL_PROJECTS}          = SL::DB::Manager::Project->get_all_sorted(query => \@conditions);
 323   $TMPL_VAR{ALL_EMPLOYEES}         = SL::DB::Manager::Employee->get_all_sorted(query => [ or => [ id => $::form->{employee_id},  deleted => 0 ] ]);
 324   $TMPL_VAR{ALL_SALESMEN}          = SL::DB::Manager::Employee->get_all_sorted(query => [ or => [ id => $::form->{salesman_id},  deleted => 0 ] ]);
 325   $TMPL_VAR{ALL_SHIPTO}            = SL::DB::Manager::Shipto->get_all_sorted(query => [
 326     or => [ trans_id  => $::form->{"$::form->{vc}_id"} * 1, and => [ shipto_id => $::form->{shipto_id} * 1, trans_id => undef ] ]
 327   ]);
 328   $TMPL_VAR{ALL_CONTACTS}          = SL::DB::Manager::Contact->get_all_sorted(query => [
 329     or => [
 330       cp_cv_id => $::form->{"$::form->{vc}_id"} * 1,
 331       and      => [
 332         cp_cv_id => undef,
 333         cp_id    => $::form->{cp_id} * 1
 334       ]
 335     ]
 336   ]);
 337   $TMPL_VAR{department_labels}     = sub { "$_[0]->{description}--$_[0]->{id}" };
 338
 339   # customer
 340   $TMPL_VAR{vc_keys} = sub { "$_[0]->{name}--$_[0]->{id}" };
 341   $TMPL_VAR{vclimit} = $myconfig{vclimit};
 342   $TMPL_VAR{vc_select} = "customer_or_vendor_selection_window('customer', '', 0, 0)";
 343   push @custom_hiddens, "customer_id";
 344   push @custom_hiddens, "oldcustomer";
 345   push @custom_hiddens, "selectcustomer";
 346
 347   # currencies and exchangerate
 348   my @values = map { $_       } @{ $form->{ALL_CURRENCIES} };
 349   my %labels = map { $_ => $_ } @{ $form->{ALL_CURRENCIES} };
 350   $form->{currency}            = $form->{defaultcurrency} unless $form->{currency};
 351   $form->{show_exchangerate}   = $form->{currency} ne $form->{defaultcurrency};
 352   $TMPL_VAR{currencies}        = NTI($::request->{cgi}->popup_menu('-name' => 'currency', '-default' => $form->{"currency"},
 353                                                       '-values' => \@values, '-labels' => \%labels,
 354                                                       '-onchange' => "document.getElementById('update_button').click();"
 355                                      )) if scalar @values;
 356   push @custom_hiddens, "forex";
 357   push @custom_hiddens, "exchangerate" if $form->{forex};
 358
 359   $TMPL_VAR{creditwarning} = ($form->{creditlimit} != 0) && ($form->{creditremaining} < 0) && !$form->{update};
 360   $TMPL_VAR{is_credit_remaining_negativ} = $form->{creditremaining} =~ /-/;
 361
 362   my $follow_up_vc         =  $form->{customer};
 363   $follow_up_vc            =~ s/--\d*\s*$//;
 364   $TMPL_VAR{customer_name} = $follow_up_vc;
 365
 366 # set option selected
 367   foreach my $item (qw(AR)) {
 368     $form->{"select$item"} =~ s/ selected//;
 369     $form->{"select$item"} =~ s/option>\Q$form->{$item}\E/option selected>$form->{$item}/;
 370   }
 371
 372   $TMPL_VAR{is_type_credit_note} = $form->{type}   eq "credit_note";
 373   $TMPL_VAR{is_format_html}      = $form->{format} eq 'html';
 374   $TMPL_VAR{dateformat}          = $myconfig{dateformat};
 375   $TMPL_VAR{numberformat}        = $myconfig{numberformat};
 376
 377   # hiddens
 378   $TMPL_VAR{HIDDENS} = [qw(
 379     id action type media format queued printed emailed title vc discount
 380     title creditlimit creditremaining tradediscount business closedto locked shipped storno storno_id
 381     max_dunning_level dunning_amount
 382     shiptoname shiptostreet shiptozipcode shiptocity shiptocountry  shiptocontact shiptophone shiptofax
 383     shiptoemail shiptodepartment_1 shiptodepartment_2  shiptocp_gender message email subject cc bcc taxaccounts cursor_fokus
 384     convert_from_do_ids convert_from_oe_ids convert_from_ar_ids useasnew
 385     invoice_id
 386     show_details
 387   ), @custom_hiddens,
 388   map { $_.'_rate', $_.'_description', $_.'_taxnumber' } split / /, $form->{taxaccounts}];
 389
 390   $::request->{layout}->use_javascript(map { "${_}.js" } qw(kivi.SalesPurchase ckeditor/ckeditor ckeditor/adapters/jquery kivi.io autocomplete_customer autocomplete_part client_js));
 391
 392   $TMPL_VAR{payment_terms_obj} = get_payment_terms_for_invoice();
 393   $form->{duedate}             = $TMPL_VAR{payment_terms_obj}->calc_date(reference_date => $form->{invdate}, due_date => $form->{due_due})->to_kivitendo if $TMPL_VAR{payment_terms_obj};
 394
 395   $form->header();
 396
 397   print $form->parse_html_template("is/form_header", \%TMPL_VAR);
 398
 399   $main::lxdebug->leave_sub();
 400 }
 401
 402 sub form_footer {
 403   $main::lxdebug->enter_sub();
 404
 405   my $form     = $main::form;
 406   my %myconfig = %main::myconfig;
 407   my $locale   = $main::locale;
 408
 409   $main::auth->assert('invoice_edit');
 410
 411   $form->{invtotal}    = $form->{invsubtotal};
 412
 413   # note rows
 414   $form->{rows} = max 2,
 415     $form->numtextrows($form->{notes},    26, 8),
 416     $form->numtextrows($form->{intnotes}, 35, 8);
 417
 418
 419   # tax, total and subtotal calculations
 420   my ($tax, $subtotal);
 421   $form->{taxaccounts_array} = [ split(/ /, $form->{taxaccounts}) ];
 422
 423   if( $form->{customer_id} && !$form->{taxincluded_changed_by_user} ) {
 424     my $customer = SL::DB::Customer->new(id => $form->{customer_id})->load();
 425     $form->{taxincluded} = defined($customer->taxincluded_checked) ? $customer->taxincluded_checked : $myconfig{taxincluded_checked};
 426   }
 427
 428   foreach my $item (@{ $form->{taxaccounts_array} }) {
 429     if ($form->{"${item}_base"}) {
 430       if ($form->{taxincluded}) {
 431         $form->{"${item}_total"} = $form->round_amount( ($form->{"${item}_base"} * $form->{"${item}_rate"}
 432                                                                                  / (1 + $form->{"${item}_rate"})), 2);
 433         $form->{"${item}_netto"} = $form->round_amount( ($form->{"${item}_base"} - $form->{"${item}_total"}), 2);
 434       } else {
 435         $form->{"${item}_total"} = $form->round_amount( $form->{"${item}_base"} * $form->{"${item}_rate"}, 2);
 436         $form->{invtotal} += $form->{"${item}_total"};
 437       }
 438     }
 439   }
 440
 441   # follow ups
 442   if ($form->{id}) {
 443     $form->{follow_ups}            = FU->follow_ups('trans_id' => $form->{id}) || [];
 444     $form->{follow_ups_unfinished} = ( sum map { $_->{due} * 1 } @{ $form->{follow_ups} } ) || 0;
 445   }
 446
 447   # payments
 448   my $totalpaid = 0;
 449   $form->{paidaccounts}++ if ($form->{"paid_$form->{paidaccounts}"});
 450   $form->{paid_indices} = [ 1 .. $form->{paidaccounts} ];
 451
 452   # Standard Konto für Umlaufvermögen
 453   my $accno_arap = IS->get_standard_accno_current_assets(\%myconfig, \%$form);
 454
 455   for my $i (1 .. $form->{paidaccounts}) {
 456     $form->{"changeable_$i"} = 1;
 457     if (SL::DB::Default->get->payments_changeable == 0) {
 458       # never
 459       $form->{"changeable_$i"} = ($form->{"acc_trans_id_$i"})? 0 : 1;
 460     } elsif (SL::DB::Default->get->payments_changeable == 2) {
 461       # on the same day
 462       $form->{"changeable_$i"} = (($form->{"gldate_$i"} eq '') ||
 463                                   ($form->current_date(\%myconfig) eq $form->{"gldate_$i"}));
 464     }
 465
 466     $form->{"selectAR_paid_$i"} = $form->{selectAR_paid};
 467     if (!$form->{"AR_paid_$i"}) {
 468       $form->{"selectAR_paid_$i"} =~ s/option>$accno_arap--(.*?)</option selected>$accno_arap--$1</;
 469     } else {
 470       $form->{"selectAR_paid_$i"} =~ s/option>\Q$form->{"AR_paid_$i"}\E/option selected>$form->{"AR_paid_$i"}/;
 471     }
 472
 473     $totalpaid += $form->{"paid_$i"};
 474   }
 475
 476   $form->{oldinvtotal} = $form->{invtotal};
 477
 478   $form->{ALL_DELIVERY_TERMS} = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 479
 480   print $form->parse_html_template('is/form_footer', {
 481     is_type_credit_note => ($form->{type} eq "credit_note"),
 482     totalpaid           => $totalpaid,
 483     paid_missing        => $form->{invtotal} - $totalpaid,
 484     print_options       => print_options(inline => 1),
 485     show_storno         => $form->{id} && !$form->{storno} && !IS->has_storno(\%myconfig, $form, "ar") && !$totalpaid,
 486     show_delete         => ($::instance_conf->get_is_changeable == 2)
 487                              ? ($form->current_date(\%myconfig) eq $form->{gldate})
 488                              : ($::instance_conf->get_is_changeable == 1),
 489   });
 490 ##print $form->parse_html_template('is/_payments'); # parser
 491 ##print $form->parse_html_template('webdav/_list'); # parser
 492
 493   $main::lxdebug->leave_sub();
 494 }
 495
 496 sub mark_as_paid {
 497   $main::lxdebug->enter_sub();
 498
 499   my $form     = $main::form;
 500   my %myconfig = %main::myconfig;
 501
 502   $main::auth->assert('invoice_edit');
 503
 504   &mark_as_paid_common(\%myconfig,"ar");
 505
 506   $main::lxdebug->leave_sub();
 507 }
 508
 509 sub update {
 510   $main::lxdebug->enter_sub();
 511
 512   my $form     = $main::form;
 513   my %myconfig = %main::myconfig;
 514
 515   $main::auth->assert('invoice_edit');
 516
 517   my ($recursive_call) = @_;
 518
 519   $form->{print_and_post} = 0         if $form->{second_run};
 520   my $taxincluded         = $form->{taxincluded} ? "checked" : '';
 521   $form->{update} = 1;
 522
 523   &check_name("customer");
 524
 525   $form->{taxincluded} ||= $taxincluded;
 526
 527   if (!$form->{forex}) {        # read exchangerate from input field (not hidden)
 528     $form->{exchangerate} = $form->parse_amount(\%myconfig, $form->{exchangerate}) unless $recursive_call;
 529   }
 530   $form->{forex}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{invdate}, 'buy');
 531   $form->{exchangerate} = $form->{forex} if $form->{forex};
 532
 533   for my $i (1 .. $form->{paidaccounts}) {
 534     next unless $form->{"paid_$i"};
 535     map { $form->{"${_}_$i"} = $form->parse_amount(\%myconfig, $form->{"${_}_$i"}) } qw(paid exchangerate);
 536     if (!$form->{"forex_$i"}) {   #read exchangerate from input field (not hidden)
 537       $form->{exchangerate} = $form->{"exchangerate_$i"};
 538     }
 539     $form->{"forex_$i"}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'buy');
 540     $form->{"exchangerate_$i"} = $form->{"forex_$i"} if $form->{"forex_$i"};
 541   }
 542
 543   my $i            = $form->{rowcount};
 544   my $exchangerate = $form->{exchangerate} || 1;
 545
 546   # if last row empty, check the form otherwise retrieve new item
 547   if (   ($form->{"partnumber_$i"} eq "")
 548       && ($form->{"description_$i"} eq "")
 549       && ($form->{"partsgroup_$i"}  eq "")) {
 550
 551     $form->{creditremaining} += ($form->{oldinvtotal} - $form->{oldtotalpaid});
 552     &check_form;
 553
 554   } else {
 555
 556     IS->retrieve_item(\%myconfig, \%$form);
 557
 558     my $rows = scalar @{ $form->{item_list} };
 559
 560     $form->{"discount_$i"}   = $form->parse_amount(\%myconfig, $form->{"discount_$i"}) / 100.0;
 561     $form->{"discount_$i"} ||= $form->{customer_discount};
 562
 563     if ($rows) {
 564       $form->{"qty_$i"} = $form->parse_amount(\%myconfig, $form->{"qty_$i"});
 565       if( !$form->{"qty_$i"} ) {
 566         $form->{"qty_$i"} = 1;
 567       }
 568
 569       if ($rows > 1) {
 570
 571         select_item(mode => 'IS', pre_entered_qty => $form->{"qty_$i"});
 572         ::end_of_request();
 573
 574       } else {
 575
 576         my $sellprice = $form->parse_amount(\%myconfig, $form->{"sellprice_$i"});
 577
 578         map { $form->{item_list}[$i]{$_} =~ s/\"/&quot;/g } qw(partnumber description unit);
 579         map { $form->{"${_}_$i"} = $form->{item_list}[0]{$_} } keys %{ $form->{item_list}[0] };
 580
 581         $form->{payment_id}    = $form->{"part_payment_id_$i"} if $form->{"part_payment_id_$i"} ne "";
 582         $form->{"discount_$i"} = 0                             if $form->{"not_discountable_$i"};
 583
 584         $form->{"marge_price_factor_$i"} = $form->{item_list}->[0]->{price_factor};
 585
 586         ($sellprice || $form->{"sellprice_$i"}) =~ /\.(\d+)/;
 587         my $decimalplaces = max 2, length $1;
 588
 589         if ($sellprice) {
 590           $form->{"sellprice_$i"} = $sellprice;
 591         } else {
 592           my $record        = _make_record();
 593           my $price_source  = SL::PriceSource->new(record_item => $record->items->[$i-1], record => $record);
 594           my $best_price    = $price_source->best_price;
 595           my $best_discount = $price_source->best_discount;
 596
 597           if ($best_price) {
 598             $::form->{"sellprice_$i"}           = $best_price->price;
 599             $::form->{"active_price_source_$i"} = $best_price->source;
 600           }
 601           if ($best_discount) {
 602             $::form->{"discount_$i"}               = $best_discount->discount;
 603             $::form->{"active_discount_source_$i"} = $best_discount->source;
 604           }
 605
 606           # if there is an exchange rate adjust sellprice
 607           $form->{"sellprice_$i"} /= $exchangerate;
 608         }
 609
 610         $form->{"listprice_$i"} /= $exchangerate;
 611
 612         my $amount = $form->{"sellprice_$i"} * $form->{"qty_$i"} * (1 - $form->{"discount_$i"});
 613         map { $form->{"${_}_base"} = 0 }                                 split / /, $form->{taxaccounts};
 614         map { $form->{"${_}_base"} += $amount }                          split / /, $form->{"taxaccounts_$i"};
 615         map { $amount += ($form->{"${_}_base"} * $form->{"${_}_rate"}) } split / /, $form->{"taxaccounts_$i"} if !$form->{taxincluded};
 616
 617         $form->{creditremaining} -= $amount;
 618
 619         map { $form->{"${_}_$i"} = $form->format_amount(\%myconfig, $form->{"${_}_$i"}, $decimalplaces) } qw(sellprice lastcost);
 620
 621         $form->{"qty_$i"}      = $form->format_amount(\%myconfig, $form->{"qty_$i"});
 622         $form->{"discount_$i"} = $form->format_amount(\%myconfig, $form->{"discount_$i"} * 100.0);
 623       }
 624
 625       &display_form;
 626
 627     } else {
 628
 629       # ok, so this is a new part
 630       # ask if it is a part or service item
 631
 632       if (   $form->{"partsgroup_$i"}
 633           && ($form->{"partsnumber_$i"} eq "")
 634           && ($form->{"description_$i"} eq "")) {
 635         $form->{rowcount}--;
 636         $form->{"discount_$i"} = "";
 637         display_form();
 638
 639       } else {
 640         $form->{"id_$i"}   = 0;
 641         new_item();
 642       }
 643     }
 644   }
 645   $main::lxdebug->leave_sub();
 646 }
 647
 648 sub post_payment {
 649   $main::lxdebug->enter_sub();
 650
 651   my $form     = $main::form;
 652   my %myconfig = %main::myconfig;
 653   my $locale   = $main::locale;
 654
 655   $main::auth->assert('invoice_edit');
 656
 657   my $invdate = $form->datetonum($form->{invdate}, \%myconfig);
 658
 659   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 660   for my $i (1 .. $form->{paidaccounts}) {
 661     if ($form->{"paid_$i"}) {
 662       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 663
 664       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 665
 666
 667       if ($form->{currency} ne $form->{defaultcurrency}) {
 668         $form->{"exchangerate_$i"} = $form->{exchangerate}
 669           if ($invdate == $datepaid);
 670         $form->isblank("exchangerate_$i",
 671                        $locale->text('Exchangerate for payment missing!'));
 672       }
 673     }
 674   }
 675   # Abgeschlossene Zeiträume nur für den letzten (aktuellen) Zahlungseingang prüfen
 676   # Details s.a. Bug 1502
 677   # Das Problem ist jetzt, dass man Zahlungseingänge nachträglich ändern kann
 678   # Wobei dies für Installationen die sowieso nicht mit Bücherkontrolle arbeiten keinen
 679   # keinen Unterschied macht.
 680   # Optimal wäre, wenn gegen einen Zeitstempel des Zahlungsfelds geprüft würde ...
 681   # Das Problem hierbei ist, dass in IS.pm post_invoice IMMER alle Zahlungseingänge aus $form
 682   # erneut gespeichert werden. Prinzipiell wäre es besser NUR die Änderungen des Rechnungs-
 683   # belegs (neue Zahlung aber nichts anderes) zu speichern ...
 684   # Vielleicht könnte man ähnlich wie bei Rechnung löschen verfahren
 685   $form->error($locale->text('Cannot post payment for a closed period!'))
 686     if ($form->date_closed($form->{"datepaid_$form->{paidaccounts}"}, \%myconfig));
 687
 688   ($form->{AR})      = split /--/, $form->{AR};
 689   ($form->{AR_paid}) = split /--/, $form->{AR_paid};
 690   relink_accounts();
 691   if ( IS->post_payment(\%myconfig, \%$form) ) {
 692     $form->{snumbers}  = qq|invnumber_| . $form->{invnumber};
 693     $form->{what_done} = 'invoice';
 694     $form->{addition}  = "PAYMENT POSTED";
 695     $form->save_history;
 696     $form->redirect($locale->text('Payment posted!'))
 697   } else {
 698    $form->error($locale->text('Cannot post payment!'));
 699   };
 700
 701   $main::lxdebug->leave_sub();
 702 }
 703
 704 sub post {
 705   $main::lxdebug->enter_sub();
 706
 707   my $form     = $main::form;
 708   my %myconfig = %main::myconfig;
 709   my $locale   = $main::locale;
 710
 711   $main::auth->assert('invoice_edit');
 712
 713   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 714   $form->isblank("invdate",  $locale->text('Invoice Date missing!'));
 715   $form->isblank("customer", $locale->text('Customer missing!'));
 716   $form->error($locale->text('Cannot post invoice for a closed period!'))
 717         if ($form->date_closed($form->{"invdate"}, \%myconfig));
 718
 719   $form->{invnumber} =~ s/^\s*//g;
 720   $form->{invnumber} =~ s/\s*$//g;
 721
 722   # if oldcustomer ne customer redo form
 723   if (&check_name('customer')) {
 724     &update;
 725     ::end_of_request();
 726   }
 727
 728   if ($myconfig{mandatory_departments} && !$form->{department_id}) {
 729     $form->{saved_message} = $::locale->text('You have to specify a department.');
 730     update();
 731     exit;
 732   }
 733
 734   if ($form->{second_run}) {
 735     $form->{print_and_post} = 0;
 736   }
 737
 738   remove_emptied_rows();
 739   &validate_items;
 740
 741   my $closedto = $form->datetonum($form->{closedto}, \%myconfig);
 742   my $invdate  = $form->datetonum($form->{invdate},  \%myconfig);
 743
 744   $form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 745     if ($form->date_max_future($invdate, \%myconfig));
 746   $form->error($locale->text('Cannot post invoice for a closed period!'))
 747     if ($invdate <= $closedto);
 748
 749   $form->isblank("exchangerate", $locale->text('Exchangerate missing!'))
 750     if ($form->{currency} ne $form->{defaultcurrency});
 751
 752   for my $i (1 .. $form->{paidaccounts}) {
 753     if ($form->parse_amount(\%myconfig, $form->{"paid_$i"})) {
 754       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 755
 756       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 757
 758       $form->error($locale->text('Cannot post payment for a closed period!'))
 759         if ($form->date_closed($form->{"datepaid_$i"}, \%myconfig));
 760
 761       if ($form->{currency} ne $form->{defaultcurrency}) {
 762         $form->{"exchangerate_$i"} = $form->{exchangerate}
 763           if ($invdate == $datepaid);
 764         $form->isblank("exchangerate_$i",
 765                        $locale->text('Exchangerate for payment missing!'));
 766       }
 767     }
 768   }
 769
 770   ($form->{AR})        = split /--/, $form->{AR};
 771   ($form->{AR_paid})   = split /--/, $form->{AR_paid};
 772   $form->{storno}    ||= 0;
 773
 774   $form->{label} = $form->{type} eq 'credit_note' ? $locale->text('Credit Note') : $locale->text('Invoice');
 775
 776   $form->{id} = 0 if $form->{postasnew};
 777
 778   # get new invnumber in sequence if no invnumber is given or if posasnew was requested
 779   if ($form->{postasnew}) {
 780     if ($form->{type} eq "credit_note") {
 781       undef($form->{cnnumber});
 782     } else {
 783       undef($form->{invnumber});
 784     }
 785   }
 786
 787   relink_accounts();
 788
 789   my $terms        = get_payment_terms_for_invoice();
 790   $form->{duedate} = $terms->calc_date(reference_date => $form->{invdate}, due_date => $form->{due_due})->to_kivitendo if $terms;
 791
 792   # If transfer_out is requested, get rose db handle and do post and
 793   # transfer out in one transaction. Otherwise just post the invoice.
 794   if ($::instance_conf->get_is_transfer_out && $form->{type} ne 'credit_note' && !$form->{storno}) {
 795     require SL::DB::Inventory;
 796     my $rose_db = SL::DB::Inventory->new->db;
 797     my @errors;
 798
 799     if (!$rose_db->with_transaction(sub {
 800       if (!eval {
 801         if (!IS->post_invoice(\%myconfig, \%$form, $rose_db->dbh)) {
 802           push @errors, $locale->text('Cannot post invoice!');
 803           die 'posting error';
 804         }
 805         my $err = IS->transfer_out(\%$form, $rose_db->dbh);
 806         if (@{ $err }) {
 807           push @errors, @{ $err };
 808           die 'transfer error';
 809         }
 810
 811         1;
 812       }) {
 813         push @errors, $EVAL_ERROR;
 814         die 'transaction error';
 815       }
 816
 817       1;
 818     })) {
 819       push @errors, $rose_db->error;
 820       $form->error($locale->text('Cannot post invoice and/or transfer out! Error message:') . "\n" . join("\n", @errors));
 821     }
 822   } else {
 823     if (!IS->post_invoice(\%myconfig, \%$form)) {
 824       $form->error($locale->text('Cannot post invoice!'));
 825     }
 826   }
 827
 828   remove_draft() if $form->{remove_draft};
 829
 830   if(!exists $form->{addition}) {
 831     $form->{snumbers}  =  'invnumber' .'_'. $form->{invnumber}; # ($form->{type} eq 'credit_note' ? 'cnnumber' : 'invnumber') .'_'. $form->{invnumber};
 832     $form->{what_done} = 'invoice';
 833     $form->{addition}  = $form->{print_and_post} ? "PRINTED AND POSTED" :
 834                          $form->{storno}         ? "STORNO"             :
 835                                                    "POSTED";
 836     $form->save_history;
 837   }
 838
 839   if (!$form->{no_redirect_after_post}) {
 840     $form->{action} = 'edit';
 841     $form->{script} = 'is.pl';
 842     $form->{saved_message} = $form->{label} . " $form->{invnumber} " . $locale->text('posted!');
 843     $form->{callback} = build_std_url(qw(action edit id callback saved_message));
 844     $form->redirect;
 845   }
 846
 847   $main::lxdebug->leave_sub();
 848 }
 849
 850 sub print_and_post {
 851   $main::lxdebug->enter_sub();
 852
 853   my $form     = $main::form;
 854
 855   $main::auth->assert('invoice_edit');
 856
 857   my $old_form                    = Form->new;
 858   $form->{no_redirect_after_post} = 1;
 859   $form->{print_and_post}         = 1;
 860   &post();
 861
 862   &edit();
 863   $main::lxdebug->leave_sub();
 864
 865 }
 866
 867 sub use_as_new {
 868   $main::lxdebug->enter_sub();
 869
 870   my $form     = $main::form;
 871   my %myconfig = %main::myconfig;
 872
 873   $main::auth->assert('invoice_edit');
 874
 875   delete @{ $form }{qw(printed emailed queued invnumber invdate exchangerate forex deliverydate id datepaid_1 gldate_1 acc_trans_id_1 source_1 memo_1 paid_1 exchangerate_1 AP_paid_1 storno locked)};
 876   $form->{rowcount}--;
 877   $form->{paidaccounts} = 1;
 878   $form->{invdate}      = $form->current_date(\%myconfig);
 879   my $terms             = get_payment_terms_for_invoice();
 880   $form->{duedate}      = $terms ? $terms->calc_date(reference_date => $form->{invdate})->to_kivitendo : $form->{invdate};
 881   $form->{employee_id}  = SL::DB::Manager::Employee->current->id;
 882   $form->{forex}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{invdate}, 'buy');
 883   $form->{exchangerate} = $form->{forex} if $form->{forex};
 884
 885   $form->{"converted_from_invoice_id_$_"} = delete $form->{"invoice_id_$_"} for 1 .. $form->{"rowcount"};
 886
 887   $form->{useasnew} = 1;
 888   &display_form;
 889
 890   $main::lxdebug->leave_sub();
 891 }
 892
 893 sub storno {
 894   $main::lxdebug->enter_sub();
 895
 896   my $form     = $main::form;
 897   my %myconfig = %main::myconfig;
 898   my $locale   = $main::locale;
 899
 900   $main::auth->assert('invoice_edit');
 901
 902   if ($form->{storno}) {
 903     $form->error($locale->text('Cannot storno storno invoice!'));
 904   }
 905
 906   if (IS->has_storno(\%myconfig, $form, "ar")) {
 907     $form->error($locale->text("Invoice has already been storno'd!"));
 908   }
 909   if ($form->datetonum($form->{invdate},  \%myconfig) <= $form->datetonum($form->{closedto}, \%myconfig)) {
 910     $form->error($locale->text('Cannot storno invoice for a closed period!'));
 911   }
 912
 913   # save the history of invoice being stornoed
 914   $form->{snumbers}  = qq|invnumber_| . $form->{invnumber};
 915   $form->{what_done} = 'invoice';
 916   $form->{addition}  = "STORNO";
 917   $form->save_history;
 918
 919   map({ my $key = $_; delete($form->{$key}) unless (grep({ $key eq $_ } qw(id login password type))); } keys(%{ $form }));
 920
 921   invoice_links();
 922   prepare_invoice();
 923   relink_accounts();
 924
 925   # Payments must not be recorded for the new storno invoice.
 926   $form->{paidaccounts} = 0;
 927   map { my $key = $_; delete $form->{$key} if grep { $key =~ /^$_/ } qw(datepaid_ gldate_ acc_trans_id_ source_ memo_ paid_ exchangerate_ AR_paid_) } keys %{ $form };
 928
 929   $form->{storno_id} = $form->{id};
 930   $form->{storno} = 1;
 931   $form->{id} = "";
 932   $form->{invnumber} = "Storno zu " . $form->{invnumber};
 933   $form->{invdate}   = DateTime->today->to_lxoffice;
 934   $form->{rowcount}++;
 935   # set new ids for storno invoice
 936   delete $form->{"invoice_id_$_"} for 1 .. $form->{"rowcount"};
 937
 938   post();
 939   $main::lxdebug->leave_sub();
 940 }
 941
 942 sub preview {
 943   $main::lxdebug->enter_sub();
 944
 945   my $form     = $main::form;
 946
 947   $main::auth->assert('invoice_edit');
 948
 949   $form->{preview} = 1;
 950   my $old_form = Form->new;
 951   for (keys %$form) { $old_form->{$_} = $form->{$_} }
 952
 953   &print_form($old_form);
 954   $main::lxdebug->leave_sub();
 955
 956 }
 957
 958 sub delete {
 959   $main::lxdebug->enter_sub();
 960
 961   my $form     = $main::form;
 962   my $locale   = $main::locale;
 963
 964   $main::auth->assert('invoice_edit');
 965
 966   if ($form->{second_run}) {
 967     $form->{print_and_post} = 0;
 968   }
 969   $form->header;
 970
 971   print qq|
 972 <form method="post" action="$form->{script}">
 973 |;
 974
 975   # delete action variable
 976   map { delete $form->{$_} } qw(action header);
 977
 978   foreach my $key (keys %$form) {
 979     next if (($key eq 'login') || ($key eq 'password') || ('' ne ref $form->{$key}));
 980     $form->{$key} =~ s/\"/&quot;/g;
 981     print qq|<input type="hidden" name="$key" value="$form->{$key}">\n|;
 982   }
 983
 984   print qq|
 985 <h2 class="confirm">| . $locale->text('Confirm!') . qq|</h2>
 986
 987 <h4>|
 988     . $locale->text('Are you sure you want to delete Invoice Number')
 989     . qq| $form->{invnumber}
 990 </h4>
 991
 992 <p>
 993 <input name="action" class="submit" type="submit" value="|
 994     . $locale->text('Yes') . qq|">
 995 </form>
 996 |;
 997
 998   $main::lxdebug->leave_sub();
 999 }
1000
1001 sub credit_note {
1002   $main::lxdebug->enter_sub();
1003
1004   my $form     = $main::form;
1005   my %myconfig = %main::myconfig;
1006   my $locale   = $main::locale;
1007
1008   $main::auth->assert('invoice_edit');
1009
1010   $form->{transdate} = $form->{invdate} = $form->current_date(\%myconfig);
1011   $form->{duedate} =
1012     $form->current_date(\%myconfig, $form->{invdate}, $form->{terms} * 1);
1013
1014   $form->{convert_from_ar_ids} = $form->{id};
1015   $form->{id}     = '';
1016   $form->{rowcount}--;
1017
1018
1019   $form->{title}  = $locale->text('Add Credit Note');
1020   $form->{script} = 'is.pl';
1021
1022   # Bei Gutschriften bezug zur Rechnungsnummer
1023   $form->{invnumber_for_credit_note} = $form->{invnumber};
1024   # bo creates the id, reset it
1025   map { delete $form->{$_} }
1026     qw(id invnumber subject message cc bcc printed emailed queued);
1027   $form->{ $form->{vc} } =~ s/--.*//g;
1028   $form->{type} = "credit_note";
1029
1030
1031   map { $form->{"select$_"} = "" } ($form->{vc}, 'currency');
1032
1033 #  map { $form->{$_} = $form->parse_amount(\%myconfig, $form->{$_}) }
1034 #    qw(creditlimit creditremaining);
1035
1036   # set new persistent ids for credit note and link previous invoice id
1037   $form->{"converted_from_invoice_id_$_"} = delete $form->{"invoice_id_$_"} for 1 .. $form->{"rowcount"};
1038
1039   my $currency = $form->{currency};
1040   &invoice_links;
1041
1042   $form->{currency}     = $currency;
1043   $form->{forex}        = $form->check_exchangerate( \%myconfig, $form->{currency}, $form->{invdate}, 'buy');
1044   $form->{exchangerate} = $form->{forex} || '';
1045
1046   $form->{creditremaining} -= ($form->{oldinvtotal} - $form->{ordtotal});
1047
1048   # bei Gutschriften werden Zahlungseingänge aus Rechnung nicht übernommen
1049   for my $i (1 .. $form->{paidaccounts}) {
1050     delete $form->{"paid_$i"};
1051     delete $form->{"source_$i"};
1052     delete $form->{"memo_$i"};
1053     delete $form->{"datepaid_$i"};
1054     delete $form->{"gldate_$i"};
1055     delete $form->{"acc_trans_id_$i"};
1056     delete $form->{"AR_paid_$i"};
1057   };
1058   $form->{paidaccounts} = 1;
1059
1060   &prepare_invoice;
1061
1062
1063   &display_form;
1064
1065   $main::lxdebug->leave_sub();
1066 }
1067
1068 sub yes {
1069   $main::lxdebug->enter_sub();
1070
1071   my $form     = $main::form;
1072   my %myconfig = %main::myconfig;
1073   my $locale   = $main::locale;
1074
1075   $main::auth->assert('invoice_edit');
1076
1077   if (IS->delete_invoice(\%myconfig, \%$form)) {
1078     # saving the history
1079     if(!exists $form->{addition}) {
1080       $form->{snumbers}  = 'invnumber' .'_'. $form->{invnumber}; # ($form->{type} eq 'credit_note' ? 'cnnumber' : 'invnumber') .'_'. $form->{invnumber};
1081       $form->{what_done} = 'invoice';
1082       $form->{addition}  = "DELETED";
1083       $form->save_history;
1084     }
1085     # /saving the history
1086     $form->redirect($locale->text('Invoice deleted!'));
1087   }
1088   $form->error($locale->text('Cannot delete invoice!'));
1089
1090   $main::lxdebug->leave_sub();
1091 }
1092
1093 sub post_and_e_mail {
1094   e_mail();
1095 };
1096
1097 sub e_mail {
1098   $main::lxdebug->enter_sub();
1099
1100   my $form     = $main::form;
1101
1102   $main::auth->assert('invoice_edit');
1103
1104   if (!$form->{id}) {
1105     $form->{no_redirect_after_post} = 1;
1106
1107     my $saved_form = save_form();
1108
1109     post();
1110
1111     restore_form($saved_form, 0, qw(id invnumber));
1112   }
1113
1114   edit_e_mail();
1115
1116   $main::lxdebug->leave_sub();
1117 }