bin/mozilla/is.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 1998-2002
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  28 #======================================================================
  29 #
  30 # Inventory invoicing module
  31 #
  32 #======================================================================
  33
  34 use SL::FU;
  35 use SL::IS;
  36 use SL::PE;
  37 use SL::OE;
  38 use Data::Dumper;
  39 use DateTime;
  40 use List::MoreUtils qw(uniq);
  41 use List::Util qw(max sum);
  42
  43 use SL::DB::Default;
  44 use SL::DB::Customer;
  45
  46 require "bin/mozilla/io.pl";
  47 require "bin/mozilla/invoice_io.pl";
  48 require "bin/mozilla/arap.pl";
  49 require "bin/mozilla/drafts.pl";
  50
  51 use strict;
  52
  53 1;
  54
  55 # end of main
  56
  57 sub add {
  58   $main::lxdebug->enter_sub();
  59
  60   my $form     = $main::form;
  61   my $locale   = $main::locale;
  62
  63   $main::auth->assert('invoice_edit');
  64
  65   return $main::lxdebug->leave_sub() if (load_draft_maybe());
  66
  67   if ($form->{type} eq "credit_note") {
  68     $form->{title} = $locale->text('Add Credit Note');
  69
  70     if ($form->{storno}) {
  71       $form->{title} = $locale->text('Add Storno Credit Note');
  72     }
  73   } else {
  74     $form->{title} = $locale->text('Add Sales Invoice');
  75
  76   }
  77
  78
  79   $form->{callback} = "$form->{script}?action=add&type=$form->{type}" unless $form->{callback};
  80
  81   &invoice_links;
  82   &prepare_invoice;
  83   &display_form;
  84
  85   $main::lxdebug->leave_sub();
  86 }
  87
  88 sub edit {
  89   $main::lxdebug->enter_sub();
  90
  91   my $form     = $main::form;
  92   my $locale   = $main::locale;
  93
  94   $main::auth->assert('invoice_edit');
  95
  96   $form->{taxincluded_changed_by_user} = 1;
  97
  98   # show history button
  99   $form->{javascript} = qq|<script type="text/javascript" src="js/show_history.js"></script>|;
 100   #/show hhistory button
 101
 102   my ($language_id, $printer_id);
 103   if ($form->{print_and_post}) {
 104     $form->{action}   = "print";
 105     $form->{resubmit} = 1;
 106     $language_id = $form->{language_id};
 107     $printer_id = $form->{printer_id};
 108   }
 109
 110   &invoice_links;
 111   if ($form->{type} eq "credit_note") {
 112     $form->{title} = $locale->text('Edit Credit Note');
 113     $form->{title} = $locale->text('Edit Storno Credit Note') if $form->{storno};
 114   } else {
 115     $form->{title} = $locale->text('Edit Sales Invoice');
 116     $form->{title} = $locale->text('Edit Storno Invoice')     if $form->{storno};
 117   }
 118
 119   &prepare_invoice;
 120   if ($form->{print_and_post}) {
 121     $form->{language_id} = $language_id;
 122     $form->{printer_id} = $printer_id;
 123   }
 124
 125   &display_form;
 126
 127   $main::lxdebug->leave_sub();
 128 }
 129
 130 sub invoice_links {
 131   $main::lxdebug->enter_sub();
 132
 133   my $form     = $main::form;
 134   my %myconfig = %main::myconfig;
 135
 136   $main::auth->assert('invoice_edit');
 137
 138   $form->{vc} = 'customer';
 139
 140   # create links
 141   $form->{webdav}   = $::instance_conf->get_webdav;
 142
 143   $form->create_links("AR", \%myconfig, "customer");
 144
 145   if ($form->{all_customer}) {
 146     unless ($form->{customer_id}) {
 147       $form->{customer_id} = $form->{all_customer}->[0]->{id};
 148       $form->{salesman_id} = $form->{all_customer}->[0]->{salesman_id};
 149     }
 150   }
 151
 152   my $editing = $form->{id};
 153
 154   $form->backup_vars(qw(payment_id language_id taxzone_id salesman_id
 155                         taxincluded currency cp_id intnotes id shipto_id
 156                         delivery_term_id));
 157
 158   IS->get_customer(\%myconfig, \%$form);
 159
 160   #quote all_customer Bug 133
 161   foreach my $ref (@{ $form->{all_customer} }) {
 162     $ref->{name} = $form->quote($ref->{name});
 163   }
 164
 165   $form->restore_vars(qw(id));
 166
 167   IS->retrieve_invoice(\%myconfig, \%$form);
 168   $form->restore_vars(qw(payment_id language_id taxzone_id currency intnotes
 169                          cp_id shipto_id delivery_term_id));
 170   $form->restore_vars(qw(taxincluded)) if $form->{id};
 171   $form->restore_vars(qw(salesman_id)) if $editing;
 172
 173
 174   # build vendor/customer drop down comatibility... don't ask
 175   if (@{ $form->{"all_customer"} }) {
 176     $form->{"selectcustomer"} = 1;
 177     $form->{customer}         = qq|$form->{customer}--$form->{"customer_id"}|;
 178   }
 179
 180   $form->{"oldcustomer"}  = $form->{customer};
 181
 182   if ($form->{"oldcustomer"} !~ m/--\d+$/ && $form->{"customer_id"}) {
 183     $form->{"oldcustomer"} .= qq|--$form->{"customer_id"}|
 184   }
 185
 186
 187 #  $form->{oldcustomer} = "$form->{customer}--$form->{customer_id}";
 188 #  $form->{selectcustomer} = 1;
 189
 190   $form->{employee} = "$form->{employee}--$form->{employee_id}";
 191
 192   # forex
 193   $form->{forex} = $form->{exchangerate};
 194   my $exchangerate = ($form->{exchangerate}) ? $form->{exchangerate} : 1;
 195
 196   foreach my $key (keys %{ $form->{AR_links} }) {
 197     foreach my $ref (@{ $form->{AR_links}{$key} }) {
 198       $form->{"select$key"} .= "<option>$ref->{accno}--$ref->{description}</option>\n";
 199     }
 200
 201     if ($key eq "AR_paid") {
 202       next unless $form->{acc_trans}{$key};
 203       for my $i (1 .. scalar @{ $form->{acc_trans}{$key} }) {
 204         $form->{"AR_paid_$i"}      = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 205
 206         $form->{"acc_trans_id_$i"}    = $form->{acc_trans}{$key}->[$i - 1]->{acc_trans_id};
 207         # reverse paid
 208         $form->{"paid_$i"}         = $form->{acc_trans}{$key}->[$i - 1]->{amount} * -1;
 209         $form->{"datepaid_$i"}     = $form->{acc_trans}{$key}->[$i - 1]->{transdate};
 210         $form->{"gldate_$i"}       = $form->{acc_trans}{$key}->[$i - 1]->{gldate};
 211         $form->{"exchangerate_$i"} = $form->{acc_trans}{$key}->[$i - 1]->{exchangerate};
 212         $form->{"forex_$i"}        = $form->{"exchangerate_$i"};
 213         $form->{"source_$i"}       = $form->{acc_trans}{$key}->[$i - 1]->{source};
 214         $form->{"memo_$i"}         = $form->{acc_trans}{$key}->[$i - 1]->{memo};
 215
 216         $form->{paidaccounts} = $i;
 217       }
 218     } else {
 219       $form->{$key} = "$form->{acc_trans}{$key}->[0]->{accno}--$form->{acc_trans}{$key}->[0]->{description}";
 220     }
 221   }
 222
 223   $form->{paidaccounts} = 1 unless (exists $form->{paidaccounts});
 224
 225   $form->{AR} = $form->{AR_1} unless $form->{id};
 226
 227   $form->{locked} = ($form->datetonum($form->{invdate},  \%myconfig)
 228                   <= $form->datetonum($form->{closedto}, \%myconfig));
 229
 230   $main::lxdebug->leave_sub();
 231 }
 232
 233 sub prepare_invoice {
 234   $main::lxdebug->enter_sub();
 235
 236   my $form     = $main::form;
 237   my %myconfig = %main::myconfig;
 238
 239   $main::auth->assert('invoice_edit');
 240
 241   if ($form->{type} eq "credit_note") {
 242     $form->{type}     = "credit_note";
 243     $form->{formname} = "credit_note";
 244   } else {
 245     $form->{type}     = "invoice";
 246     $form->{formname} = "invoice";
 247   }
 248
 249   if ($form->{id}) {
 250
 251     my $i = 0;
 252
 253     foreach my $ref (@{ $form->{invoice_details} }) {
 254       $i++;
 255
 256       map { $form->{"${_}_$i"} = $ref->{$_} } keys %{$ref};
 257
 258       $form->{"discount_$i"}   = $form->format_amount(\%myconfig, $form->{"discount_$i"} * 100);
 259       my ($dec)                = ($form->{"sellprice_$i"} =~ /\.(\d+)/);
 260       $dec                     = length $dec;
 261       my $decimalplaces        = ($dec > 2) ? $dec : 2;
 262
 263       $form->{"sellprice_$i"}  = $form->format_amount(\%myconfig, $form->{"sellprice_$i"}, $decimalplaces);
 264       (my $dec_qty)            = ($form->{"qty_$i"} =~ /\.(\d+)/);
 265       $dec_qty                 = length $dec_qty;
 266
 267       $form->{"lastcost_$i"}  = $form->format_amount(\%myconfig, $form->{"lastcost_$i"}, $decimalplaces);
 268
 269       $form->{"qty_$i"}        = $form->format_amount(\%myconfig, $form->{"qty_$i"}, $dec_qty);
 270
 271       $form->{"sellprice_pg_$i"} = join ('--', $form->{"sellprice_$i"}, $form->{"pricegroup_id_$i"});
 272
 273       $form->{rowcount}        = $i;
 274
 275     }
 276   }
 277   $main::lxdebug->leave_sub();
 278 }
 279
 280 sub form_header {
 281   $main::lxdebug->enter_sub();
 282
 283   my $form     = $main::form;
 284   my %myconfig = %main::myconfig;
 285   my $locale   = $main::locale;
 286   my $cgi      = $::request->{cgi};
 287
 288   $main::auth->assert('invoice_edit');
 289
 290   my %TMPL_VAR = ();
 291   my @custom_hiddens;
 292
 293   $form->{employee_id} = $form->{old_employee_id} if $form->{old_employee_id};
 294   $form->{salesman_id} = $form->{old_salesman_id} if $form->{old_salesman_id};
 295
 296   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 297
 298   $form->get_lists("taxzones"      => ($form->{id} ? "ALL_TAXZONES" : "ALL_ACTIVE_TAXZONES"),
 299                    "currencies"    => "ALL_CURRENCIES",
 300                    "customers"     => "ALL_CUSTOMERS",
 301                    "departments"   => "all_departments",
 302                    "price_factors" => "ALL_PRICE_FACTORS");
 303
 304   # Projects
 305   my @old_project_ids = uniq grep { $_ } map { $_ * 1 } ($form->{"globalproject_id"}, map { $form->{"project_id_$_"} } 1..$form->{"rowcount"});
 306   my @old_ids_cond    = @old_project_ids ? (id => \@old_project_ids) : ();
 307   my @customer_cond;
 308   if ($::instance_conf->get_customer_projects_only_in_sales) {
 309     @customer_cond = (
 310       or => [
 311         customer_id          => $::form->{customer_id},
 312         billable_customer_id => $::form->{customer_id},
 313       ]);
 314   }
 315   my @conditions = (
 316     or => [
 317       and => [ active => 1, @customer_cond ],
 318       @old_ids_cond,
 319     ]);
 320
 321   $TMPL_VAR{ALL_PROJECTS}          = SL::DB::Manager::Project->get_all(query => \@conditions);
 322   $TMPL_VAR{ALL_EMPLOYEES}         = SL::DB::Manager::Employee->get_all_sorted(query => [ or => [ id => $::form->{employee_id},  deleted => 0 ] ]);
 323   $TMPL_VAR{ALL_SALESMEN}          = SL::DB::Manager::Employee->get_all_sorted(query => [ or => [ id => $::form->{salesman_id},  deleted => 0 ] ]);
 324   $TMPL_VAR{ALL_SHIPTO}            = SL::DB::Manager::Shipto->get_all_sorted(query => [
 325     or => [ trans_id  => $::form->{"$::form->{vc}_id"} * 1, and => [ shipto_id => $::form->{shipto_id} * 1, trans_id => undef ] ]
 326   ]);
 327   $TMPL_VAR{ALL_CONTACTS}          = SL::DB::Manager::Contact->get_all_sorted(query => [
 328     or => [
 329       cp_cv_id => $::form->{"$::form->{vc}_id"} * 1,
 330       and      => [
 331         cp_cv_id => undef,
 332         cp_id    => $::form->{cp_id} * 1
 333       ]
 334     ]
 335   ]);
 336   $TMPL_VAR{department_labels}     = sub { "$_[0]->{description}--$_[0]->{id}" };
 337
 338   # customer
 339   $TMPL_VAR{vc_keys} = sub { "$_[0]->{name}--$_[0]->{id}" };
 340   $TMPL_VAR{vclimit} = $myconfig{vclimit};
 341   $TMPL_VAR{vc_select} = "customer_or_vendor_selection_window('customer', '', 0, 0)";
 342   push @custom_hiddens, "customer_id";
 343   push @custom_hiddens, "oldcustomer";
 344   push @custom_hiddens, "selectcustomer";
 345
 346   # currencies and exchangerate
 347   my @values = map { $_       } @{ $form->{ALL_CURRENCIES} };
 348   my %labels = map { $_ => $_ } @{ $form->{ALL_CURRENCIES} };
 349   $form->{currency}            = $form->{defaultcurrency} unless $form->{currency};
 350   $form->{show_exchangerate}   = $form->{currency} ne $form->{defaultcurrency};
 351   $TMPL_VAR{currencies}        = NTI($::request->{cgi}->popup_menu('-name' => 'currency', '-default' => $form->{"currency"},
 352                                                       '-values' => \@values, '-labels' => \%labels,
 353                                                       '-onchange' => "document.getElementById('update_button').click();"
 354                                      )) if scalar @values;
 355   push @custom_hiddens, "forex";
 356   push @custom_hiddens, "exchangerate" if $form->{forex};
 357
 358   $TMPL_VAR{creditwarning} = ($form->{creditlimit} != 0) && ($form->{creditremaining} < 0) && !$form->{update};
 359   $TMPL_VAR{is_credit_remaining_negativ} = $form->{creditremaining} =~ /-/;
 360
 361   my $follow_up_vc         =  $form->{customer};
 362   $follow_up_vc            =~ s/--\d*\s*$//;
 363   $TMPL_VAR{customer_name} = $follow_up_vc;
 364
 365 # set option selected
 366   foreach my $item (qw(AR)) {
 367     $form->{"select$item"} =~ s/ selected//;
 368     $form->{"select$item"} =~ s/option>\Q$form->{$item}\E/option selected>$form->{$item}/;
 369   }
 370
 371   $TMPL_VAR{is_type_credit_note} = $form->{type}   eq "credit_note";
 372   $TMPL_VAR{is_format_html}      = $form->{format} eq 'html';
 373   $TMPL_VAR{dateformat}          = $myconfig{dateformat};
 374   $TMPL_VAR{numberformat}        = $myconfig{numberformat};
 375
 376   # hiddens
 377   $TMPL_VAR{HIDDENS} = [qw(
 378     id action type media format queued printed emailed title vc discount
 379     title creditlimit creditremaining tradediscount business closedto locked shipped storno storno_id
 380     max_dunning_level dunning_amount
 381     shiptoname shiptostreet shiptozipcode shiptocity shiptocountry  shiptocontact shiptophone shiptofax
 382     shiptoemail shiptodepartment_1 shiptodepartment_2  shiptocp_gender message email subject cc bcc taxaccounts cursor_fokus
 383     convert_from_do_ids convert_from_oe_ids convert_from_ar_ids
 384     show_details
 385   ), @custom_hiddens,
 386   map { $_.'_rate', $_.'_description', $_.'_taxnumber' } split / /, $form->{taxaccounts}];
 387
 388   $::request->{layout}->use_javascript(map { "${_}.js" } qw(kivi.SalesPurchase ckeditor/ckeditor ckeditor/adapters/jquery));
 389
 390   $form->header();
 391
 392   print $form->parse_html_template("is/form_header", \%TMPL_VAR);
 393
 394   $main::lxdebug->leave_sub();
 395 }
 396
 397 sub form_footer {
 398   $main::lxdebug->enter_sub();
 399
 400   my $form     = $main::form;
 401   my %myconfig = %main::myconfig;
 402   my $locale   = $main::locale;
 403
 404   $main::auth->assert('invoice_edit');
 405
 406   $form->{invtotal}    = $form->{invsubtotal};
 407
 408   # note rows
 409   $form->{rows} = max 2,
 410     $form->numtextrows($form->{notes},    26, 8),
 411     $form->numtextrows($form->{intnotes}, 35, 8);
 412
 413
 414   # tax, total and subtotal calculations
 415   my ($tax, $subtotal);
 416   $form->{taxaccounts_array} = [ split(/ /, $form->{taxaccounts}) ];
 417
 418   if( $form->{customer_id} && !$form->{taxincluded_changed_by_user} ) {
 419     my $customer = SL::DB::Customer->new(id => $form->{customer_id})->load();
 420     $form->{taxincluded} = defined($customer->taxincluded_checked) ? $customer->taxincluded_checked : $myconfig{taxincluded_checked};
 421   }
 422
 423   foreach my $item (@{ $form->{taxaccounts_array} }) {
 424     if ($form->{"${item}_base"}) {
 425       if ($form->{taxincluded}) {
 426         $form->{"${item}_total"} = $form->round_amount( ($form->{"${item}_base"} * $form->{"${item}_rate"}
 427                                                                                  / (1 + $form->{"${item}_rate"})), 2);
 428         $form->{"${item}_netto"} = $form->round_amount( ($form->{"${item}_base"} - $form->{"${item}_total"}), 2);
 429       } else {
 430         $form->{"${item}_total"} = $form->round_amount( $form->{"${item}_base"} * $form->{"${item}_rate"}, 2);
 431         $form->{invtotal} += $form->{"${item}_total"};
 432       }
 433     }
 434   }
 435
 436   # follow ups
 437   if ($form->{id}) {
 438     $form->{follow_ups}            = FU->follow_ups('trans_id' => $form->{id}) || [];
 439     $form->{follow_ups_unfinished} = ( sum map { $_->{due} * 1 } @{ $form->{follow_ups} } ) || 0;
 440   }
 441
 442   # payments
 443   my $totalpaid = 0;
 444   $form->{paidaccounts}++ if ($form->{"paid_$form->{paidaccounts}"});
 445   $form->{paid_indices} = [ 1 .. $form->{paidaccounts} ];
 446
 447   # Standard Konto für Umlaufvermögen
 448   my $accno_arap = IS->get_standard_accno_current_assets(\%myconfig, \%$form);
 449
 450   for my $i (1 .. $form->{paidaccounts}) {
 451     $form->{"changeable_$i"} = 1;
 452     if (SL::DB::Default->get->payments_changeable == 0) {
 453       # never
 454       $form->{"changeable_$i"} = ($form->{"acc_trans_id_$i"})? 0 : 1;
 455     } elsif (SL::DB::Default->get->payments_changeable == 2) {
 456       # on the same day
 457       $form->{"changeable_$i"} = (($form->{"gldate_$i"} eq '') ||
 458                                   ($form->current_date(\%myconfig) eq $form->{"gldate_$i"}));
 459     }
 460
 461     $form->{"selectAR_paid_$i"} = $form->{selectAR_paid};
 462     if (!$form->{"AR_paid_$i"}) {
 463       $form->{"selectAR_paid_$i"} =~ s/option>$accno_arap--(.*?)</option selected>$accno_arap--$1</;
 464     } else {
 465       $form->{"selectAR_paid_$i"} =~ s/option>\Q$form->{"AR_paid_$i"}\E/option selected>$form->{"AR_paid_$i"}/;
 466     }
 467
 468     $totalpaid += $form->{"paid_$i"};
 469   }
 470
 471   $form->{oldinvtotal} = $form->{invtotal};
 472
 473   $form->{ALL_DELIVERY_TERMS} = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 474
 475   print $form->parse_html_template('is/form_footer', {
 476     is_type_credit_note => ($form->{type} eq "credit_note"),
 477     totalpaid           => $totalpaid,
 478     paid_missing        => $form->{invtotal} - $totalpaid,
 479     print_options       => print_options(inline => 1),
 480     show_storno         => $form->{id} && !$form->{storno} && !IS->has_storno(\%myconfig, $form, "ar") && !$totalpaid,
 481     show_delete         => ($::instance_conf->get_is_changeable == 2)
 482                              ? ($form->current_date(\%myconfig) eq $form->{gldate})
 483                              : ($::instance_conf->get_is_changeable == 1),
 484   });
 485 ##print $form->parse_html_template('is/_payments'); # parser
 486 ##print $form->parse_html_template('webdav/_list'); # parser
 487
 488   $main::lxdebug->leave_sub();
 489 }
 490
 491 sub mark_as_paid {
 492   $main::lxdebug->enter_sub();
 493
 494   my $form     = $main::form;
 495   my %myconfig = %main::myconfig;
 496
 497   $main::auth->assert('invoice_edit');
 498
 499   &mark_as_paid_common(\%myconfig,"ar");
 500
 501   $main::lxdebug->leave_sub();
 502 }
 503
 504 sub update {
 505   $main::lxdebug->enter_sub();
 506
 507   my $form     = $main::form;
 508   my %myconfig = %main::myconfig;
 509
 510   $main::auth->assert('invoice_edit');
 511
 512   my ($recursive_call) = @_;
 513
 514   $form->{print_and_post} = 0         if $form->{second_run};
 515   my $taxincluded         = $form->{taxincluded} ? "checked" : '';
 516   $form->{update} = 1;
 517
 518   &check_name("customer");
 519
 520   $form->{taxincluded} ||= $taxincluded;
 521
 522   if (!$form->{forex}) {        # read exchangerate from input field (not hidden)
 523     $form->{exchangerate} = $form->parse_amount(\%myconfig, $form->{exchangerate}) unless $recursive_call;
 524   }
 525   $form->{forex}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{invdate}, 'buy');
 526   $form->{exchangerate} = $form->{forex} if $form->{forex};
 527
 528   for my $i (1 .. $form->{paidaccounts}) {
 529     next unless $form->{"paid_$i"};
 530     map { $form->{"${_}_$i"} = $form->parse_amount(\%myconfig, $form->{"${_}_$i"}) } qw(paid exchangerate);
 531     if (!$form->{"forex_$i"}) {   #read exchangerate from input field (not hidden)
 532       $form->{exchangerate} = $form->{"exchangerate_$i"};
 533     }
 534     $form->{"forex_$i"}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'buy');
 535     $form->{"exchangerate_$i"} = $form->{"forex_$i"} if $form->{"forex_$i"};
 536   }
 537
 538   my $i            = $form->{rowcount};
 539   my $exchangerate = $form->{exchangerate} || 1;
 540
 541   # if last row empty, check the form otherwise retrieve new item
 542   if (   ($form->{"partnumber_$i"} eq "")
 543       && ($form->{"description_$i"} eq "")
 544       && ($form->{"partsgroup_$i"}  eq "")) {
 545
 546     $form->{creditremaining} += ($form->{oldinvtotal} - $form->{oldtotalpaid});
 547     &check_form;
 548
 549   } else {
 550
 551     IS->retrieve_item(\%myconfig, \%$form);
 552
 553     my $rows = scalar @{ $form->{item_list} };
 554
 555     # Falls kein Kundenrabatt vorhanden ist, den aktuellen Rabatt nicht mit 0% überschreiben,
 556     # da hier der Anwender schon manual einen Wert eingetragen haben könnte (analog zu qty) Bugfix: 1412
 557     if ($form->{customer_discount}){
 558       $form->{"discount_$i"} = $form->format_amount(\%myconfig, $form->{customer_discount} * 100);
 559     }
 560
 561     if ($rows) {
 562       $form->{"qty_$i"} = $form->parse_amount(\%myconfig, $form->{"qty_$i"});
 563       if( !$form->{"qty_$i"} ) {
 564         $form->{"qty_$i"} = 1;
 565       }
 566
 567       if ($rows > 1) {
 568
 569         select_item(mode => 'IS');
 570         ::end_of_request();
 571
 572       } else {
 573
 574         my $sellprice = $form->parse_amount(\%myconfig, $form->{"sellprice_$i"});
 575
 576         map { $form->{item_list}[$i]{$_} =~ s/\"/&quot;/g } qw(partnumber description unit);
 577         map { $form->{"${_}_$i"} = $form->{item_list}[0]{$_} } keys %{ $form->{item_list}[0] };
 578
 579         $form->{payment_id}    = $form->{"part_payment_id_$i"} if $form->{"part_payment_id_$i"} ne "";
 580         $form->{"discount_$i"} = 0                             if $form->{"not_discountable_$i"};
 581
 582         $form->{"marge_price_factor_$i"} = $form->{item_list}->[0]->{price_factor};
 583
 584         ($sellprice || $form->{"sellprice_$i"}) =~ /\.(\d+)/;
 585         my $decimalplaces = max 2, length $1;
 586
 587         if ($sellprice) {
 588           $form->{"sellprice_$i"} = $sellprice;
 589         } else {
 590           # if there is an exchange rate adjust sellprice
 591           $form->{"sellprice_$i"} *= (1 - $form->{tradediscount});
 592           $form->{"sellprice_$i"} /= $exchangerate;
 593         }
 594
 595         $form->{"listprice_$i"} /= $exchangerate;
 596
 597         my $amount = $form->{"sellprice_$i"} * $form->{"qty_$i"} * (1 - $form->{"discount_$i"} / 100);
 598         map { $form->{"${_}_base"} = 0 }                                 split / /, $form->{taxaccounts};
 599         map { $form->{"${_}_base"} += $amount }                          split / /, $form->{"taxaccounts_$i"};
 600         map { $amount += ($form->{"${_}_base"} * $form->{"${_}_rate"}) } split / /, $form->{"taxaccounts_$i"} if !$form->{taxincluded};
 601
 602         $form->{creditremaining} -= $amount;
 603
 604         map { $form->{"${_}_$i"} = $form->format_amount(\%myconfig, $form->{"${_}_$i"}, $decimalplaces) } qw(sellprice lastcost);
 605
 606         $form->{"qty_$i"} = $form->format_amount(\%myconfig, $form->{"qty_$i"});
 607       }
 608
 609       &display_form;
 610
 611     } else {
 612
 613       # ok, so this is a new part
 614       # ask if it is a part or service item
 615
 616       if (   $form->{"partsgroup_$i"}
 617           && ($form->{"partsnumber_$i"} eq "")
 618           && ($form->{"description_$i"} eq "")) {
 619         $form->{rowcount}--;
 620         $form->{"discount_$i"} = "";
 621         display_form();
 622
 623       } else {
 624         $form->{"id_$i"}   = 0;
 625         new_item();
 626       }
 627     }
 628   }
 629   $main::lxdebug->leave_sub();
 630 }
 631
 632 sub post_payment {
 633   $main::lxdebug->enter_sub();
 634
 635   my $form     = $main::form;
 636   my %myconfig = %main::myconfig;
 637   my $locale   = $main::locale;
 638
 639   $main::auth->assert('invoice_edit');
 640
 641   my $invdate = $form->datetonum($form->{invdate}, \%myconfig);
 642
 643   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 644   for my $i (1 .. $form->{paidaccounts}) {
 645     if ($form->{"paid_$i"}) {
 646       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 647
 648       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 649
 650
 651       if ($form->{currency} ne $form->{defaultcurrency}) {
 652         $form->{"exchangerate_$i"} = $form->{exchangerate}
 653           if ($invdate == $datepaid);
 654         $form->isblank("exchangerate_$i",
 655                        $locale->text('Exchangerate for payment missing!'));
 656       }
 657     }
 658   }
 659   # Abgeschlossene Zeiträume nur für den letzten (aktuellen) Zahlungseingang prüfen
 660   # Details s.a. Bug 1502
 661   # Das Problem ist jetzt, dass man Zahlungseingänge nachträglich ändern kann
 662   # Wobei dies für Installationen die sowieso nicht mit Bücherkontrolle arbeiten keinen
 663   # keinen Unterschied macht.
 664   # Optimal wäre, wenn gegen einen Zeitstempel des Zahlungsfelds geprüft würde ...
 665   # Das Problem hierbei ist, dass in IS.pm post_invoice IMMER alle Zahlungseingänge aus $form
 666   # erneut gespeichert werden. Prinzipiell wäre es besser NUR die Änderungen des Rechnungs-
 667   # belegs (neue Zahlung aber nichts anderes) zu speichern ...
 668   # Vielleicht könnte man ähnlich wie bei Rechnung löschen verfahren
 669   $form->error($locale->text('Cannot post payment for a closed period!'))
 670     if ($form->date_closed($form->{"datepaid_$form->{paidaccounts}"}, \%myconfig));
 671
 672   ($form->{AR})      = split /--/, $form->{AR};
 673   ($form->{AR_paid}) = split /--/, $form->{AR_paid};
 674   relink_accounts();
 675   $form->redirect($locale->text('Payment posted!'))
 676       if (IS->post_payment(\%myconfig, \%$form));
 677     $form->error($locale->text('Cannot post payment!'));
 678
 679
 680   $main::lxdebug->leave_sub();
 681 }
 682
 683 sub post {
 684   $main::lxdebug->enter_sub();
 685
 686   my $form     = $main::form;
 687   my %myconfig = %main::myconfig;
 688   my $locale   = $main::locale;
 689
 690   $main::auth->assert('invoice_edit');
 691
 692   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 693   $form->isblank("invdate",  $locale->text('Invoice Date missing!'));
 694   $form->isblank("customer", $locale->text('Customer missing!'));
 695   $form->error($locale->text('Cannot post invoice for a closed period!'))
 696         if ($form->date_closed($form->{"invdate"}, \%myconfig));
 697
 698   $form->{invnumber} =~ s/^\s*//g;
 699   $form->{invnumber} =~ s/\s*$//g;
 700
 701   # if oldcustomer ne customer redo form
 702   if (&check_name('customer')) {
 703     &update;
 704     ::end_of_request();
 705   }
 706
 707   if ($myconfig{mandatory_departments} && !$form->{department_id}) {
 708     $form->{saved_message} = $::locale->text('You have to specify a department.');
 709     update();
 710     exit;
 711   }
 712
 713   if ($form->{second_run}) {
 714     $form->{print_and_post} = 0;
 715   }
 716
 717   remove_emptied_rows();
 718   &validate_items;
 719
 720   my $closedto = $form->datetonum($form->{closedto}, \%myconfig);
 721   my $invdate  = $form->datetonum($form->{invdate},  \%myconfig);
 722
 723   $form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 724     if ($form->date_max_future($invdate, \%myconfig));
 725   $form->error($locale->text('Cannot post invoice for a closed period!'))
 726     if ($invdate <= $closedto);
 727
 728   $form->isblank("exchangerate", $locale->text('Exchangerate missing!'))
 729     if ($form->{currency} ne $form->{defaultcurrency});
 730
 731   for my $i (1 .. $form->{paidaccounts}) {
 732     if ($form->parse_amount(\%myconfig, $form->{"paid_$i"})) {
 733       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 734
 735       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 736
 737       $form->error($locale->text('Cannot post payment for a closed period!'))
 738         if ($form->date_closed($form->{"datepaid_$i"}, \%myconfig));
 739
 740       if ($form->{currency} ne $form->{defaultcurrency}) {
 741         $form->{"exchangerate_$i"} = $form->{exchangerate}
 742           if ($invdate == $datepaid);
 743         $form->isblank("exchangerate_$i",
 744                        $locale->text('Exchangerate for payment missing!'));
 745       }
 746     }
 747   }
 748
 749   ($form->{AR})        = split /--/, $form->{AR};
 750   ($form->{AR_paid})   = split /--/, $form->{AR_paid};
 751   $form->{storno}    ||= 0;
 752
 753   $form->{label} = $form->{type} eq 'credit_note' ? $locale->text('Credit Note') : $locale->text('Invoice');
 754
 755   $form->{id} = 0 if $form->{postasnew};
 756
 757   # get new invnumber in sequence if no invnumber is given or if posasnew was requested
 758   if ($form->{postasnew}) {
 759     if ($form->{type} eq "credit_note") {
 760       undef($form->{cnnumber});
 761     } else {
 762       undef($form->{invnumber});
 763     }
 764   }
 765
 766   relink_accounts();
 767   $form->error($locale->text('Cannot post invoice!'))
 768     unless IS->post_invoice(\%myconfig, \%$form);
 769   remove_draft() if $form->{remove_draft};
 770
 771   if(!exists $form->{addition}) {
 772     $form->{snumbers} =  'invnumber' .'_'. $form->{invnumber}; # ($form->{type} eq 'credit_note' ? 'cnnumber' : 'invnumber') .'_'. $form->{invnumber};
 773     $form->{addition} = $form->{print_and_post} ? "PRINTED AND POSTED" :
 774                         $form->{storno}         ? "STORNO"             :
 775                                                   "POSTED";
 776     $form->save_history;
 777   }
 778
 779   if (!$form->{no_redirect_after_post}) {
 780     $form->{action} = 'edit';
 781     $form->{script} = 'is.pl';
 782     $form->{saved_message} = $form->{label} . " $form->{invnumber} " . $locale->text('posted!');
 783     $form->{callback} = build_std_url(qw(action edit id saved_message));
 784     $form->redirect;
 785   }
 786
 787   $main::lxdebug->leave_sub();
 788 }
 789
 790 sub print_and_post {
 791   $main::lxdebug->enter_sub();
 792
 793   my $form     = $main::form;
 794
 795   $main::auth->assert('invoice_edit');
 796
 797   my $old_form                    = new Form;
 798   $form->{no_redirect_after_post} = 1;
 799   $form->{print_and_post}         = 1;
 800   &post();
 801
 802   &edit();
 803   $main::lxdebug->leave_sub();
 804
 805 }
 806
 807 sub use_as_new {
 808   $main::lxdebug->enter_sub();
 809
 810   my $form     = $main::form;
 811   my %myconfig = %main::myconfig;
 812
 813   $main::auth->assert('invoice_edit');
 814
 815   delete @{ $form }{qw(printed emailed queued invnumber invdate exchangerate forex deliverydate id datepaid_1 gldate_1 acc_trans_id_1 source_1 memo_1 paid_1 exchangerate_1 AP_paid_1 storno locked)};
 816   $form->{rowcount}--;
 817   $form->{paidaccounts} = 1;
 818   $form->{invdate}      = $form->current_date(\%myconfig);
 819   $form->{duedate}      = $form->get_duedate(\%myconfig, $form->{invdate}) || $form->{invdate};
 820   $form->{employee_id}  = SL::DB::Manager::Employee->current->id;
 821   $form->{forex}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{invdate}, 'buy');
 822   $form->{exchangerate} = $form->{forex} if $form->{forex};
 823
 824   &display_form;
 825
 826   $main::lxdebug->leave_sub();
 827 }
 828
 829 sub storno {
 830   $main::lxdebug->enter_sub();
 831
 832   my $form     = $main::form;
 833   my %myconfig = %main::myconfig;
 834   my $locale   = $main::locale;
 835
 836   $main::auth->assert('invoice_edit');
 837
 838   if ($form->{storno}) {
 839     $form->error($locale->text('Cannot storno storno invoice!'));
 840   }
 841
 842   if (IS->has_storno(\%myconfig, $form, "ar")) {
 843     $form->error($locale->text("Invoice has already been storno'd!"));
 844   }
 845   if ($form->datetonum($form->{invdate},  \%myconfig) <= $form->datetonum($form->{closedto}, \%myconfig)) {
 846     $form->error($locale->text('Cannot storno invoice for a closed period!'));
 847   }
 848
 849   map({ my $key = $_; delete($form->{$key}) unless (grep({ $key eq $_ } qw(id login password type))); } keys(%{ $form }));
 850
 851   invoice_links();
 852   prepare_invoice();
 853   relink_accounts();
 854
 855   # Payments must not be recorded for the new storno invoice.
 856   $form->{paidaccounts} = 0;
 857   map { my $key = $_; delete $form->{$key} if grep { $key =~ /^$_/ } qw(datepaid_ gldate_ acc_trans_id_ source_ memo_ paid_ exchangerate_ AR_paid_) } keys %{ $form };
 858
 859   $form->{storno_id} = $form->{id};
 860   $form->{storno} = 1;
 861   $form->{id} = "";
 862   $form->{invnumber} = "Storno zu " . $form->{invnumber};
 863   $form->{invdate}   = DateTime->today->to_lxoffice;
 864   $form->{rowcount}++;
 865
 866   post();
 867   $main::lxdebug->leave_sub();
 868 }
 869
 870 sub preview {
 871   $main::lxdebug->enter_sub();
 872
 873   my $form     = $main::form;
 874
 875   $main::auth->assert('invoice_edit');
 876
 877   $form->{preview} = 1;
 878   my $old_form = new Form;
 879   for (keys %$form) { $old_form->{$_} = $form->{$_} }
 880
 881   &print_form($old_form);
 882   $main::lxdebug->leave_sub();
 883
 884 }
 885
 886 sub delete {
 887   $main::lxdebug->enter_sub();
 888
 889   my $form     = $main::form;
 890   my $locale   = $main::locale;
 891
 892   $main::auth->assert('invoice_edit');
 893
 894   if ($form->{second_run}) {
 895     $form->{print_and_post} = 0;
 896   }
 897   $form->header;
 898
 899   print qq|
 900 <form method="post" action="$form->{script}">
 901 |;
 902
 903   # delete action variable
 904   map { delete $form->{$_} } qw(action header);
 905
 906   foreach my $key (keys %$form) {
 907     next if (($key eq 'login') || ($key eq 'password') || ('' ne ref $form->{$key}));
 908     $form->{$key} =~ s/\"/&quot;/g;
 909     print qq|<input type="hidden" name="$key" value="$form->{$key}">\n|;
 910   }
 911
 912   print qq|
 913 <h2 class="confirm">| . $locale->text('Confirm!') . qq|</h2>
 914
 915 <h4>|
 916     . $locale->text('Are you sure you want to delete Invoice Number')
 917     . qq| $form->{invnumber}
 918 </h4>
 919
 920 <p>
 921 <input name="action" class="submit" type="submit" value="|
 922     . $locale->text('Yes') . qq|">
 923 </form>
 924 |;
 925
 926   $main::lxdebug->leave_sub();
 927 }
 928
 929 sub credit_note {
 930   $main::lxdebug->enter_sub();
 931
 932   my $form     = $main::form;
 933   my %myconfig = %main::myconfig;
 934   my $locale   = $main::locale;
 935
 936   $main::auth->assert('invoice_edit');
 937
 938   $form->{transdate} = $form->{invdate} = $form->current_date(\%myconfig);
 939   $form->{duedate} =
 940     $form->current_date(\%myconfig, $form->{invdate}, $form->{terms} * 1);
 941
 942   $form->{convert_from_ar_ids} = $form->{id};
 943   $form->{id}     = '';
 944   $form->{rowcount}--;
 945
 946
 947   $form->{title}  = $locale->text('Add Credit Note');
 948   $form->{script} = 'is.pl';
 949
 950   # Bei Gutschriften bezug zur Rechnungsnummer
 951   $form->{invnumber_for_credit_note} = $form->{invnumber};
 952   # bo creates the id, reset it
 953   map { delete $form->{$_} }
 954     qw(id invnumber subject message cc bcc printed emailed queued);
 955   $form->{ $form->{vc} } =~ s/--.*//g;
 956   $form->{type} = "credit_note";
 957
 958
 959   map { $form->{"select$_"} = "" } ($form->{vc}, 'currency');
 960
 961 #  map { $form->{$_} = $form->parse_amount(\%myconfig, $form->{$_}) }
 962 #    qw(creditlimit creditremaining);
 963
 964   for my $i (1 .. $form->{rowcount}) {
 965     for (qw(listprice)) {
 966       $form->{"${_}_${i}"} = $form->parse_amount(\%myconfig, $form->{"${_}_${i}"}) if $form->{"${_}_${i}"};
 967     }
 968   }
 969
 970   my $currency = $form->{currency};
 971   &invoice_links;
 972
 973   $form->{currency}     = $currency;
 974   $form->{forex}        = $form->check_exchangerate( \%myconfig, $form->{currency}, $form->{invdate}, 'buy');
 975   $form->{exchangerate} = $form->{forex} || '';
 976
 977   $form->{creditremaining} -= ($form->{oldinvtotal} - $form->{ordtotal});
 978
 979   # bei Gutschriften werden Zahlungseingänge aus Rechnung nicht übernommen
 980   for my $i (1 .. $form->{paidaccounts}) {
 981     delete $form->{"paid_$i"};
 982     delete $form->{"source_$i"};
 983     delete $form->{"memo_$i"};
 984     delete $form->{"datepaid_$i"};
 985     delete $form->{"gldate_$i"};
 986     delete $form->{"acc_trans_id_$i"};
 987     delete $form->{"AR_paid_$i"};
 988   };
 989   $form->{paidaccounts} = 1;
 990
 991   &prepare_invoice;
 992
 993
 994   &display_form;
 995
 996   $main::lxdebug->leave_sub();
 997 }
 998
 999 sub yes {
1000   $main::lxdebug->enter_sub();
1001
1002   my $form     = $main::form;
1003   my %myconfig = %main::myconfig;
1004   my $locale   = $main::locale;
1005
1006   $main::auth->assert('invoice_edit');
1007
1008   if (IS->delete_invoice(\%myconfig, \%$form)) {
1009     # saving the history
1010     if(!exists $form->{addition}) {
1011       $form->{snumbers} = 'invnumber' .'_'. $form->{invnumber}; # ($form->{type} eq 'credit_note' ? 'cnnumber' : 'invnumber') .'_'. $form->{invnumber};
1012       $form->{addition} = "DELETED";
1013       $form->save_history;
1014     }
1015     # /saving the history
1016     $form->redirect($locale->text('Invoice deleted!'));
1017   }
1018   $form->error($locale->text('Cannot delete invoice!'));
1019
1020   $main::lxdebug->leave_sub();
1021 }
1022
1023 sub post_and_e_mail {
1024   e_mail();
1025 };
1026
1027 sub e_mail {
1028   $main::lxdebug->enter_sub();
1029
1030   my $form     = $main::form;
1031
1032   $main::auth->assert('invoice_edit');
1033
1034   if (!$form->{id}) {
1035     $form->{no_redirect_after_post} = 1;
1036
1037     my $saved_form = save_form();
1038
1039     post();
1040
1041     restore_form($saved_form, 0, qw(id invnumber));
1042   }
1043
1044   edit_e_mail();
1045
1046   $main::lxdebug->leave_sub();
1047 }