bin/mozilla/is.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 1998-2002
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  28 #======================================================================
  29 #
  30 # Inventory invoicing module
  31 #
  32 #======================================================================
  33
  34 use SL::FU;
  35 use SL::IS;
  36 use SL::PE;
  37 use SL::OE;
  38 use Data::Dumper;
  39 use DateTime;
  40 use List::MoreUtils qw(uniq);
  41 use List::Util qw(max sum);
  42 use List::UtilsBy qw(sort_by);
  43 use English qw(-no_match_vars);
  44
  45 use SL::DB::Default;
  46 use SL::DB::Customer;
  47 use SL::DB::PaymentTerm;
  48
  49 require "bin/mozilla/io.pl";
  50 require "bin/mozilla/invoice_io.pl";
  51 require "bin/mozilla/arap.pl";
  52 require "bin/mozilla/drafts.pl";
  53
  54 use strict;
  55
  56 1;
  57
  58 # end of main
  59
  60 sub add {
  61   $main::lxdebug->enter_sub();
  62
  63   my $form     = $main::form;
  64   my $locale   = $main::locale;
  65
  66   $main::auth->assert('invoice_edit');
  67
  68   return $main::lxdebug->leave_sub() if (load_draft_maybe());
  69
  70   if ($form->{type} eq "credit_note") {
  71     $form->{title} = $locale->text('Add Credit Note');
  72
  73     if ($form->{storno}) {
  74       $form->{title} = $locale->text('Add Storno Credit Note');
  75     }
  76   } else {
  77     $form->{title} = $locale->text('Add Sales Invoice');
  78
  79   }
  80
  81
  82   $form->{callback} = "$form->{script}?action=add&type=$form->{type}" unless $form->{callback};
  83
  84   &invoice_links;
  85   &prepare_invoice;
  86   &display_form;
  87
  88   $main::lxdebug->leave_sub();
  89 }
  90
  91 sub edit {
  92   $main::lxdebug->enter_sub();
  93
  94   my $form     = $main::form;
  95   my $locale   = $main::locale;
  96
  97   $main::auth->assert('invoice_edit');
  98
  99   $form->{taxincluded_changed_by_user} = 1;
 100
 101   # show history button
 102   $form->{javascript} = qq|<script type="text/javascript" src="js/show_history.js"></script>|;
 103
 104   my ($language_id, $printer_id);
 105   if ($form->{print_and_post}) {
 106     $form->{action}   = "print";
 107     $form->{resubmit} = 1;
 108     $language_id = $form->{language_id};
 109     $printer_id = $form->{printer_id};
 110   }
 111
 112   &invoice_links;
 113   if ($form->{type} eq "credit_note") {
 114     $form->{title} = $locale->text('Edit Credit Note');
 115     $form->{title} = $locale->text('Edit Storno Credit Note') if $form->{storno};
 116   } else {
 117     $form->{title} = $locale->text('Edit Sales Invoice');
 118     $form->{title} = $locale->text('Edit Storno Invoice')     if $form->{storno};
 119   }
 120
 121   &prepare_invoice;
 122   if ($form->{print_and_post}) {
 123     $form->{language_id} = $language_id;
 124     $form->{printer_id} = $printer_id;
 125   }
 126
 127   &display_form;
 128
 129   $main::lxdebug->leave_sub();
 130 }
 131
 132 sub invoice_links {
 133   $main::lxdebug->enter_sub();
 134
 135   my $form     = $main::form;
 136   my %myconfig = %main::myconfig;
 137
 138   $main::auth->assert('invoice_edit');
 139
 140   $form->{vc} = 'customer';
 141
 142   # create links
 143   $form->{webdav}   = $::instance_conf->get_webdav;
 144
 145   $form->create_links("AR", \%myconfig, "customer");
 146
 147   if ($form->{all_customer}) {
 148     unless ($form->{customer_id}) {
 149       $form->{customer_id} = $form->{all_customer}->[0]->{id};
 150       $form->{salesman_id} = $form->{all_customer}->[0]->{salesman_id};
 151     }
 152   }
 153
 154   my $editing = $form->{id};
 155
 156   $form->backup_vars(qw(payment_id language_id taxzone_id salesman_id
 157                         taxincluded currency cp_id intnotes id shipto_id
 158                         delivery_term_id));
 159
 160   IS->get_customer(\%myconfig, \%$form);
 161
 162   #quote all_customer Bug 133
 163   foreach my $ref (@{ $form->{all_customer} }) {
 164     $ref->{name} = $form->quote($ref->{name});
 165   }
 166
 167   $form->restore_vars(qw(id));
 168
 169   IS->retrieve_invoice(\%myconfig, \%$form);
 170   $form->restore_vars(qw(payment_id language_id taxzone_id currency intnotes
 171                          cp_id shipto_id delivery_term_id));
 172   $form->restore_vars(qw(taxincluded)) if $form->{id};
 173   $form->restore_vars(qw(salesman_id)) if $editing;
 174
 175
 176   # build vendor/customer drop down compatibility... don't ask
 177   if (@{ $form->{"all_customer"} }) {
 178     $form->{"selectcustomer"} = 1;
 179     $form->{customer}         = qq|$form->{customer}--$form->{"customer_id"}|;
 180   }
 181
 182   $form->{"oldcustomer"}  = $form->{customer};
 183
 184   if ($form->{"oldcustomer"} !~ m/--\d+$/ && $form->{"customer_id"}) {
 185     $form->{"oldcustomer"} .= qq|--$form->{"customer_id"}|
 186   }
 187
 188
 189 #  $form->{oldcustomer} = "$form->{customer}--$form->{customer_id}";
 190 #  $form->{selectcustomer} = 1;
 191
 192   $form->{employee} = "$form->{employee}--$form->{employee_id}";
 193
 194   # forex
 195   $form->{forex} = $form->{exchangerate};
 196   my $exchangerate = ($form->{exchangerate}) ? $form->{exchangerate} : 1;
 197
 198   foreach my $key (keys %{ $form->{AR_links} }) {
 199     foreach my $ref (@{ $form->{AR_links}{$key} }) {
 200       $form->{"select$key"} .= "<option>$ref->{accno}--$ref->{description}</option>\n";
 201     }
 202
 203     if ($key eq "AR_paid") {
 204       next unless $form->{acc_trans}{$key};
 205       for my $i (1 .. scalar @{ $form->{acc_trans}{$key} }) {
 206         $form->{"AR_paid_$i"}      = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 207
 208         $form->{"acc_trans_id_$i"}    = $form->{acc_trans}{$key}->[$i - 1]->{acc_trans_id};
 209         # reverse paid
 210         $form->{"paid_$i"}         = $form->{acc_trans}{$key}->[$i - 1]->{amount} * -1;
 211         $form->{"datepaid_$i"}     = $form->{acc_trans}{$key}->[$i - 1]->{transdate};
 212         $form->{"gldate_$i"}       = $form->{acc_trans}{$key}->[$i - 1]->{gldate};
 213         $form->{"exchangerate_$i"} = $form->{acc_trans}{$key}->[$i - 1]->{exchangerate};
 214         $form->{"forex_$i"}        = $form->{"exchangerate_$i"};
 215         $form->{"source_$i"}       = $form->{acc_trans}{$key}->[$i - 1]->{source};
 216         $form->{"memo_$i"}         = $form->{acc_trans}{$key}->[$i - 1]->{memo};
 217
 218         $form->{paidaccounts} = $i;
 219       }
 220     } else {
 221       $form->{$key} = "$form->{acc_trans}{$key}->[0]->{accno}--$form->{acc_trans}{$key}->[0]->{description}";
 222     }
 223   }
 224
 225   $form->{paidaccounts} = 1 unless (exists $form->{paidaccounts});
 226
 227   $form->{AR} = $form->{AR_1} unless $form->{id};
 228
 229   $form->{locked} = ($form->datetonum($form->{invdate},  \%myconfig)
 230                   <= $form->datetonum($form->{closedto}, \%myconfig));
 231
 232   $main::lxdebug->leave_sub();
 233 }
 234
 235 sub prepare_invoice {
 236   $main::lxdebug->enter_sub();
 237
 238   my $form     = $main::form;
 239   my %myconfig = %main::myconfig;
 240
 241   $main::auth->assert('invoice_edit');
 242
 243   if ($form->{type} eq "credit_note") {
 244     $form->{type}     = "credit_note";
 245     $form->{formname} = "credit_note";
 246   } else {
 247     $form->{type}     = "invoice";
 248     $form->{formname} = "invoice";
 249   }
 250
 251   if ($form->{id}) {
 252
 253     my $i = 0;
 254
 255     foreach my $ref (@{ $form->{invoice_details} }) {
 256       $i++;
 257
 258       map { $form->{"${_}_$i"} = $ref->{$_} } keys %{$ref};
 259
 260       $form->{"discount_$i"}   = $form->format_amount(\%myconfig, $form->{"discount_$i"} * 100);
 261       my ($dec)                = ($form->{"sellprice_$i"} =~ /\.(\d+)/);
 262       $dec                     = length $dec;
 263       my $decimalplaces        = ($dec > 2) ? $dec : 2;
 264
 265       $form->{"sellprice_$i"}  = $form->format_amount(\%myconfig, $form->{"sellprice_$i"}, $decimalplaces);
 266       (my $dec_qty)            = ($form->{"qty_$i"} =~ /\.(\d+)/);
 267       $dec_qty                 = length $dec_qty;
 268
 269       $form->{"lastcost_$i"}  = $form->format_amount(\%myconfig, $form->{"lastcost_$i"}, $decimalplaces);
 270
 271       $form->{"qty_$i"}        = $form->format_amount(\%myconfig, $form->{"qty_$i"}, $dec_qty);
 272
 273       $form->{"sellprice_pg_$i"} = join ('--', $form->{"sellprice_$i"}, $form->{"pricegroup_id_$i"});
 274
 275       $form->{rowcount}        = $i;
 276
 277     }
 278   }
 279   $main::lxdebug->leave_sub();
 280 }
 281
 282 sub form_header {
 283   $main::lxdebug->enter_sub();
 284
 285   my $form     = $main::form;
 286   my %myconfig = %main::myconfig;
 287   my $locale   = $main::locale;
 288   my $cgi      = $::request->{cgi};
 289
 290   $main::auth->assert('invoice_edit');
 291
 292   my %TMPL_VAR = ();
 293   my @custom_hiddens;
 294
 295   if ($form->{id}) {
 296     require SL::DB::Invoice;
 297     $TMPL_VAR{invoice_obj} = SL::DB::Invoice->new(id => $form->{id})->load;
 298   }
 299   $form->{employee_id} = $form->{old_employee_id} if $form->{old_employee_id};
 300   $form->{salesman_id} = $form->{old_salesman_id} if $form->{old_salesman_id};
 301
 302   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 303
 304   $form->get_lists("taxzones"      => ($form->{id} ? "ALL_TAXZONES" : "ALL_ACTIVE_TAXZONES"),
 305                    "currencies"    => "ALL_CURRENCIES",
 306                    "customers"     => "ALL_CUSTOMERS",
 307                    "departments"   => "all_departments",
 308                    "price_factors" => "ALL_PRICE_FACTORS");
 309
 310   # Projects
 311   my @old_project_ids = uniq grep { $_ } map { $_ * 1 } ($form->{"globalproject_id"}, map { $form->{"project_id_$_"} } 1..$form->{"rowcount"});
 312   my @old_ids_cond    = @old_project_ids ? (id => \@old_project_ids) : ();
 313   my @customer_cond;
 314   if ($::instance_conf->get_customer_projects_only_in_sales) {
 315     @customer_cond = (
 316       or => [
 317         customer_id          => $::form->{customer_id},
 318         billable_customer_id => $::form->{customer_id},
 319       ]);
 320   }
 321   my @conditions = (
 322     or => [
 323       and => [ active => 1, @customer_cond ],
 324       @old_ids_cond,
 325     ]);
 326
 327   $TMPL_VAR{ALL_PROJECTS}          = SL::DB::Manager::Project->get_all_sorted(query => \@conditions);
 328   $form->{ALL_PROJECTS}            = $TMPL_VAR{ALL_PROJECTS}; # make projects available for second row drop-down in io.pl
 329   $TMPL_VAR{ALL_EMPLOYEES}         = SL::DB::Manager::Employee->get_all_sorted(query => [ or => [ id => $::form->{employee_id},  deleted => 0 ] ]);
 330   $TMPL_VAR{ALL_SALESMEN}          = SL::DB::Manager::Employee->get_all_sorted(query => [ or => [ id => $::form->{salesman_id},  deleted => 0 ] ]);
 331   $TMPL_VAR{ALL_SHIPTO}            = SL::DB::Manager::Shipto->get_all_sorted(query => [
 332     or => [ trans_id  => $::form->{"$::form->{vc}_id"} * 1, and => [ shipto_id => $::form->{shipto_id} * 1, trans_id => undef ] ]
 333   ]);
 334   $TMPL_VAR{ALL_CONTACTS}          = SL::DB::Manager::Contact->get_all_sorted(query => [
 335     or => [
 336       cp_cv_id => $::form->{"$::form->{vc}_id"} * 1,
 337       and      => [
 338         cp_cv_id => undef,
 339         cp_id    => $::form->{cp_id} * 1
 340       ]
 341     ]
 342   ]);
 343   $TMPL_VAR{department_labels}     = sub { "$_[0]->{description}--$_[0]->{id}" };
 344
 345   # customer
 346   $TMPL_VAR{vc_keys} = sub { "$_[0]->{name}--$_[0]->{id}" };
 347   $TMPL_VAR{vclimit} = $myconfig{vclimit};
 348   $TMPL_VAR{vc_select} = "customer_or_vendor_selection_window('customer', '', 0, 0)";
 349   push @custom_hiddens, "customer_id";
 350   push @custom_hiddens, "oldcustomer";
 351   push @custom_hiddens, "selectcustomer";
 352
 353   # currencies and exchangerate
 354   my @values = map { $_       } @{ $form->{ALL_CURRENCIES} };
 355   my %labels = map { $_ => $_ } @{ $form->{ALL_CURRENCIES} };
 356   $form->{currency}            = $form->{defaultcurrency} unless $form->{currency};
 357   $form->{show_exchangerate}   = $form->{currency} ne $form->{defaultcurrency};
 358   $TMPL_VAR{currencies}        = NTI($::request->{cgi}->popup_menu('-name' => 'currency', '-default' => $form->{"currency"},
 359                                                       '-values' => \@values, '-labels' => \%labels,
 360                                                       '-onchange' => "document.getElementById('update_button').click();"
 361                                      )) if scalar @values;
 362   push @custom_hiddens, "forex";
 363   push @custom_hiddens, "exchangerate" if $form->{forex};
 364
 365   $TMPL_VAR{creditwarning} = ($form->{creditlimit} != 0) && ($form->{creditremaining} < 0) && !$form->{update};
 366   $TMPL_VAR{is_credit_remaining_negativ} = $form->{creditremaining} =~ /-/;
 367
 368   my $follow_up_vc         =  $form->{customer};
 369   $follow_up_vc            =~ s/--\d*\s*$//;
 370   $TMPL_VAR{customer_name} = $follow_up_vc;
 371
 372 # set option selected
 373   foreach my $item (qw(AR)) {
 374     $form->{"select$item"} =~ s/ selected//;
 375     $form->{"select$item"} =~ s/option>\Q$form->{$item}\E/option selected>$form->{$item}/;
 376   }
 377
 378   $TMPL_VAR{is_type_credit_note} = $form->{type}   eq "credit_note";
 379   $TMPL_VAR{is_format_html}      = $form->{format} eq 'html';
 380   $TMPL_VAR{dateformat}          = $myconfig{dateformat};
 381   $TMPL_VAR{numberformat}        = $myconfig{numberformat};
 382
 383   # hiddens
 384   $TMPL_VAR{HIDDENS} = [qw(
 385     id action type media format queued printed emailed title vc discount
 386     title creditlimit creditremaining tradediscount business closedto locked shipped storno storno_id
 387     max_dunning_level dunning_amount dunning_description
 388     shiptoname shiptostreet shiptozipcode shiptocity shiptocountry  shiptocontact shiptophone shiptofax
 389     shiptoemail shiptodepartment_1 shiptodepartment_2  shiptocp_gender message email subject cc bcc taxaccounts cursor_fokus
 390     convert_from_do_ids convert_from_oe_ids convert_from_ar_ids useasnew
 391     invoice_id
 392     show_details
 393   ), @custom_hiddens,
 394   map { $_.'_rate', $_.'_description', $_.'_taxnumber' } split / /, $form->{taxaccounts}];
 395
 396   $::request->{layout}->use_javascript(map { "${_}.js" } qw(kivi.SalesPurchase ckeditor/ckeditor ckeditor/adapters/jquery kivi.io autocomplete_customer autocomplete_part client_js));
 397
 398   $TMPL_VAR{payment_terms_obj} = get_payment_terms_for_invoice();
 399   $form->{duedate}             = $TMPL_VAR{payment_terms_obj}->calc_date(reference_date => $form->{invdate}, due_date => $form->{due_due})->to_kivitendo if $TMPL_VAR{payment_terms_obj};
 400
 401   $form->header();
 402
 403   print $form->parse_html_template("is/form_header", \%TMPL_VAR);
 404
 405   $main::lxdebug->leave_sub();
 406 }
 407
 408 sub _sort_payments {
 409   my @fields   = qw(acc_trans_id gldate datepaid source memo paid AR_paid);
 410   my @payments =
 411     grep { $_->{paid} != 0 }
 412     map  {
 413       my $idx = $_;
 414       +{ map { ($_ => delete($::form->{"${_}_${idx}"})) } @fields }
 415     } (1..$::form->{paidaccounts});
 416
 417   @payments = sort_by { DateTime->from_kivitendo($_->{datepaid}) } @payments;
 418
 419   $::form->{paidaccounts} = max scalar(@payments), 1;
 420
 421   foreach my $idx (1 .. scalar(@payments)) {
 422     my $payment = $payments[$idx - 1];
 423     $::form->{"${_}_${idx}"} = $payment->{$_} for @fields;
 424   }
 425 }
 426
 427 sub form_footer {
 428   $main::lxdebug->enter_sub();
 429
 430   my $form     = $main::form;
 431   my %myconfig = %main::myconfig;
 432   my $locale   = $main::locale;
 433
 434   $main::auth->assert('invoice_edit');
 435
 436   $form->{invtotal}    = $form->{invsubtotal};
 437
 438   # note rows
 439   $form->{rows} = max 2,
 440     $form->numtextrows($form->{notes},    26, 8),
 441     $form->numtextrows($form->{intnotes}, 35, 8);
 442
 443
 444   # tax, total and subtotal calculations
 445   my ($tax, $subtotal);
 446   $form->{taxaccounts_array} = [ split(/ /, $form->{taxaccounts}) ];
 447
 448   if( $form->{customer_id} && !$form->{taxincluded_changed_by_user} ) {
 449     my $customer = SL::DB::Customer->new(id => $form->{customer_id})->load();
 450     $form->{taxincluded} = defined($customer->taxincluded_checked) ? $customer->taxincluded_checked : $myconfig{taxincluded_checked};
 451   }
 452
 453   foreach my $item (@{ $form->{taxaccounts_array} }) {
 454     if ($form->{"${item}_base"}) {
 455       if ($form->{taxincluded}) {
 456         $form->{"${item}_total"} = $form->round_amount( ($form->{"${item}_base"} * $form->{"${item}_rate"}
 457                                                                                  / (1 + $form->{"${item}_rate"})), 2);
 458         $form->{"${item}_netto"} = $form->round_amount( ($form->{"${item}_base"} - $form->{"${item}_total"}), 2);
 459       } else {
 460         $form->{"${item}_total"} = $form->round_amount( $form->{"${item}_base"} * $form->{"${item}_rate"}, 2);
 461         $form->{invtotal} += $form->{"${item}_total"};
 462       }
 463     }
 464   }
 465   $form->{invtotal} = $form->round_amount($form->{invtotal}, 2, 1);
 466
 467   # follow ups
 468   if ($form->{id}) {
 469     $form->{follow_ups}            = FU->follow_ups('trans_id' => $form->{id}) || [];
 470     $form->{follow_ups_unfinished} = ( sum map { $_->{due} * 1 } @{ $form->{follow_ups} } ) || 0;
 471   }
 472
 473   # payments
 474   _sort_payments();
 475
 476   my $totalpaid = 0;
 477   $form->{paidaccounts}++ if ($form->{"paid_$form->{paidaccounts}"});
 478   $form->{paid_indices} = [ 1 .. $form->{paidaccounts} ];
 479
 480   # Standard Konto für Umlaufvermögen
 481   my $accno_arap = IS->get_standard_accno_current_assets(\%myconfig, \%$form);
 482
 483   for my $i (1 .. $form->{paidaccounts}) {
 484     $form->{"changeable_$i"} = 1;
 485     if (SL::DB::Default->get->payments_changeable == 0) {
 486       # never
 487       $form->{"changeable_$i"} = ($form->{"acc_trans_id_$i"})? 0 : 1;
 488     } elsif (SL::DB::Default->get->payments_changeable == 2) {
 489       # on the same day
 490       $form->{"changeable_$i"} = (($form->{"gldate_$i"} eq '') ||
 491                                   ($form->current_date(\%myconfig) eq $form->{"gldate_$i"}));
 492     }
 493
 494     $form->{"selectAR_paid_$i"} = $form->{selectAR_paid};
 495     if (!$form->{"AR_paid_$i"}) {
 496       $form->{"selectAR_paid_$i"} =~ s/option>$accno_arap--(.*?)</option selected>$accno_arap--$1</;
 497     } else {
 498       $form->{"selectAR_paid_$i"} =~ s/option>\Q$form->{"AR_paid_$i"}\E/option selected>$form->{"AR_paid_$i"}/;
 499     }
 500
 501     $totalpaid += $form->{"paid_$i"};
 502   }
 503
 504   $form->{oldinvtotal} = $form->{invtotal};
 505
 506   $form->{ALL_DELIVERY_TERMS} = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 507
 508   print $form->parse_html_template('is/form_footer', {
 509     is_type_credit_note => ($form->{type} eq "credit_note"),
 510     totalpaid           => $totalpaid,
 511     paid_missing        => $form->{invtotal} - $totalpaid,
 512     print_options       => print_options(inline => 1),
 513     show_storno         => $form->{id} && !$form->{storno} && !IS->has_storno(\%myconfig, $form, "ar") && !$totalpaid,
 514     show_delete         => ($::instance_conf->get_is_changeable == 2)
 515                              ? ($form->current_date(\%myconfig) eq $form->{gldate})
 516                              : ($::instance_conf->get_is_changeable == 1),
 517     today               => DateTime->today,
 518   });
 519 ##print $form->parse_html_template('is/_payments'); # parser
 520 ##print $form->parse_html_template('webdav/_list'); # parser
 521
 522   $main::lxdebug->leave_sub();
 523 }
 524
 525 sub mark_as_paid {
 526   $main::lxdebug->enter_sub();
 527
 528   my $form     = $main::form;
 529   my %myconfig = %main::myconfig;
 530
 531   $main::auth->assert('invoice_edit');
 532
 533   &mark_as_paid_common(\%myconfig,"ar");
 534
 535   $main::lxdebug->leave_sub();
 536 }
 537
 538 sub update {
 539   $main::lxdebug->enter_sub();
 540
 541   my $form     = $main::form;
 542   my %myconfig = %main::myconfig;
 543
 544   $main::auth->assert('invoice_edit');
 545
 546   my ($recursive_call) = @_;
 547
 548   $form->{print_and_post} = 0         if $form->{second_run};
 549   my $taxincluded         = $form->{taxincluded} ? "checked" : '';
 550   $form->{update} = 1;
 551
 552   &check_name("customer");
 553
 554   $form->{taxincluded} ||= $taxincluded;
 555
 556   if (!$form->{forex}) {        # read exchangerate from input field (not hidden)
 557     $form->{exchangerate} = $form->parse_amount(\%myconfig, $form->{exchangerate}) unless $recursive_call;
 558   }
 559   $form->{forex}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{invdate}, 'buy');
 560   $form->{exchangerate} = $form->{forex} if $form->{forex};
 561
 562   for my $i (1 .. $form->{paidaccounts}) {
 563     next unless $form->{"paid_$i"};
 564     map { $form->{"${_}_$i"} = $form->parse_amount(\%myconfig, $form->{"${_}_$i"}) } qw(paid exchangerate);
 565     if (!$form->{"forex_$i"}) {   #read exchangerate from input field (not hidden)
 566       $form->{exchangerate} = $form->{"exchangerate_$i"};
 567     }
 568     $form->{"forex_$i"}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'buy');
 569     $form->{"exchangerate_$i"} = $form->{"forex_$i"} if $form->{"forex_$i"};
 570   }
 571
 572   my $i            = $form->{rowcount};
 573   my $exchangerate = $form->{exchangerate} || 1;
 574
 575   # if last row empty, check the form otherwise retrieve new item
 576   if (   ($form->{"partnumber_$i"} eq "")
 577       && ($form->{"description_$i"} eq "")
 578       && ($form->{"partsgroup_$i"}  eq "")) {
 579
 580     $form->{creditremaining} += ($form->{oldinvtotal} - $form->{oldtotalpaid});
 581     &check_form;
 582
 583   } else {
 584
 585     IS->retrieve_item(\%myconfig, \%$form);
 586
 587     my $rows = scalar @{ $form->{item_list} };
 588
 589     $form->{"discount_$i"}   = $form->parse_amount(\%myconfig, $form->{"discount_$i"}) / 100.0;
 590     $form->{"discount_$i"} ||= $form->{customer_discount};
 591
 592     if ($rows) {
 593       $form->{"qty_$i"} = $form->parse_amount(\%myconfig, $form->{"qty_$i"});
 594       if( !$form->{"qty_$i"} ) {
 595         $form->{"qty_$i"} = 1;
 596       }
 597
 598       if ($rows > 1) {
 599
 600         select_item(mode => 'IS', pre_entered_qty => $form->{"qty_$i"});
 601         ::end_of_request();
 602
 603       } else {
 604
 605         my $sellprice = $form->parse_amount(\%myconfig, $form->{"sellprice_$i"});
 606
 607         map { $form->{item_list}[$i]{$_} =~ s/\"/&quot;/g } qw(partnumber description unit);
 608         map { $form->{"${_}_$i"} = $form->{item_list}[0]{$_} } keys %{ $form->{item_list}[0] };
 609
 610         $form->{payment_id}    = $form->{"part_payment_id_$i"} if $form->{"part_payment_id_$i"} ne "";
 611         $form->{"discount_$i"} = 0                             if $form->{"not_discountable_$i"};
 612
 613         $form->{"marge_price_factor_$i"} = $form->{item_list}->[0]->{price_factor};
 614
 615         ($sellprice || $form->{"sellprice_$i"}) =~ /\.(\d+)/;
 616         my $decimalplaces = max 2, length $1;
 617
 618         if ($sellprice) {
 619           $form->{"sellprice_$i"} = $sellprice;
 620         } else {
 621           my $record        = _make_record();
 622           my $price_source  = SL::PriceSource->new(record_item => $record->items->[$i-1], record => $record);
 623           my $best_price    = $price_source->best_price;
 624           my $best_discount = $price_source->best_discount;
 625
 626           if ($best_price) {
 627             $::form->{"sellprice_$i"}           = $best_price->price;
 628             $::form->{"active_price_source_$i"} = $best_price->source;
 629           }
 630           if ($best_discount) {
 631             $::form->{"discount_$i"}               = $best_discount->discount;
 632             $::form->{"active_discount_source_$i"} = $best_discount->source;
 633           }
 634
 635           # if there is an exchange rate adjust sellprice
 636           $form->{"sellprice_$i"} /= $exchangerate;
 637         }
 638
 639         $form->{"listprice_$i"} /= $exchangerate;
 640
 641         my $amount = $form->{"sellprice_$i"} * $form->{"qty_$i"} * (1 - $form->{"discount_$i"});
 642         map { $form->{"${_}_base"} = 0 }                                 split / /, $form->{taxaccounts};
 643         map { $form->{"${_}_base"} += $amount }                          split / /, $form->{"taxaccounts_$i"};
 644         map { $amount += ($form->{"${_}_base"} * $form->{"${_}_rate"}) } split / /, $form->{"taxaccounts_$i"} if !$form->{taxincluded};
 645
 646         $form->{creditremaining} -= $amount;
 647
 648         map { $form->{"${_}_$i"} = $form->format_amount(\%myconfig, $form->{"${_}_$i"}, $decimalplaces) } qw(sellprice lastcost);
 649
 650         $form->{"qty_$i"}      = $form->format_amount(\%myconfig, $form->{"qty_$i"});
 651         $form->{"discount_$i"} = $form->format_amount(\%myconfig, $form->{"discount_$i"} * 100.0);
 652       }
 653
 654       &display_form;
 655
 656     } else {
 657
 658       # ok, so this is a new part
 659       # ask if it is a part or service item
 660
 661       if (   $form->{"partsgroup_$i"}
 662           && ($form->{"partsnumber_$i"} eq "")
 663           && ($form->{"description_$i"} eq "")) {
 664         $form->{rowcount}--;
 665         $form->{"discount_$i"} = "";
 666         display_form();
 667
 668       } else {
 669         $form->{"id_$i"}   = 0;
 670         new_item();
 671       }
 672     }
 673   }
 674   $main::lxdebug->leave_sub();
 675 }
 676
 677 sub post_payment {
 678   $main::lxdebug->enter_sub();
 679
 680   my $form     = $main::form;
 681   my %myconfig = %main::myconfig;
 682   my $locale   = $main::locale;
 683
 684   $main::auth->assert('invoice_edit');
 685
 686   $form->mtime_ischanged('ar') ;
 687   my $invdate = $form->datetonum($form->{invdate}, \%myconfig);
 688
 689   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 690   for my $i (1 .. $form->{paidaccounts}) {
 691     if ($form->{"paid_$i"}) {
 692       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 693
 694       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 695
 696
 697       if ($form->{currency} ne $form->{defaultcurrency}) {
 698         $form->{"exchangerate_$i"} = $form->{exchangerate}
 699           if ($invdate == $datepaid);
 700         $form->isblank("exchangerate_$i",
 701                        $locale->text('Exchangerate for payment missing!'));
 702       }
 703     }
 704   }
 705   # Abgeschlossene Zeiträume nur für den letzten (aktuellen) Zahlungseingang prüfen
 706   # Details s.a. Bug 1502
 707   # Das Problem ist jetzt, dass man Zahlungseingänge nachträglich ändern kann
 708   # Wobei dies für Installationen die sowieso nicht mit Bücherkontrolle arbeiten keinen
 709   # keinen Unterschied macht.
 710   # Optimal wäre, wenn gegen einen Zeitstempel des Zahlungsfelds geprüft würde ...
 711   # Das Problem hierbei ist, dass in IS.pm post_invoice IMMER alle Zahlungseingänge aus $form
 712   # erneut gespeichert werden. Prinzipiell wäre es besser NUR die Änderungen des Rechnungs-
 713   # belegs (neue Zahlung aber nichts anderes) zu speichern ...
 714   # Vielleicht könnte man ähnlich wie bei Rechnung löschen verfahren
 715   $form->error($locale->text('Cannot post payment for a closed period!'))
 716     if ($form->date_closed($form->{"datepaid_$form->{paidaccounts}"}, \%myconfig));
 717
 718   ($form->{AR})      = split /--/, $form->{AR};
 719   ($form->{AR_paid}) = split /--/, $form->{AR_paid};
 720   relink_accounts();
 721   if ( IS->post_payment(\%myconfig, \%$form) ) {
 722     $form->{snumbers}  = qq|invnumber_| . $form->{invnumber};
 723     $form->{what_done} = 'invoice';
 724     $form->{addition}  = "PAYMENT POSTED";
 725     $form->save_history;
 726     $form->redirect($locale->text('Payment posted!'))
 727   } else {
 728    $form->error($locale->text('Cannot post payment!'));
 729   };
 730
 731   $main::lxdebug->leave_sub();
 732 }
 733
 734 sub post {
 735   $main::lxdebug->enter_sub();
 736
 737   my $form     = $main::form;
 738   my %myconfig = %main::myconfig;
 739   my $locale   = $main::locale;
 740
 741   $main::auth->assert('invoice_edit');
 742   $form->mtime_ischanged('ar');
 743
 744   $form->{defaultcurrency} = $form->get_default_currency(\%myconfig);
 745   $form->isblank("invdate",  $locale->text('Invoice Date missing!'));
 746   $form->isblank("customer", $locale->text('Customer missing!'));
 747   $form->error($locale->text('Cannot post invoice for a closed period!'))
 748         if ($form->date_closed($form->{"invdate"}, \%myconfig));
 749
 750   $form->{invnumber} =~ s/^\s*//g;
 751   $form->{invnumber} =~ s/\s*$//g;
 752
 753   # if oldcustomer ne customer redo form
 754   if (&check_name('customer')) {
 755     &update;
 756     ::end_of_request();
 757   }
 758
 759   if ($myconfig{mandatory_departments} && !$form->{department_id}) {
 760     $form->{saved_message} = $::locale->text('You have to specify a department.');
 761     update();
 762     exit;
 763   }
 764
 765   if ($form->{second_run}) {
 766     $form->{print_and_post} = 0;
 767   }
 768
 769   remove_emptied_rows();
 770   &validate_items;
 771
 772   my $closedto = $form->datetonum($form->{closedto}, \%myconfig);
 773   my $invdate  = $form->datetonum($form->{invdate},  \%myconfig);
 774
 775   $form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 776     if ($form->date_max_future($invdate, \%myconfig));
 777   $form->error($locale->text('Cannot post invoice for a closed period!'))
 778     if ($invdate <= $closedto);
 779
 780   $form->isblank("exchangerate", $locale->text('Exchangerate missing!'))
 781     if ($form->{currency} ne $form->{defaultcurrency});
 782
 783   for my $i (1 .. $form->{paidaccounts}) {
 784     if ($form->parse_amount(\%myconfig, $form->{"paid_$i"})) {
 785       my $datepaid = $form->datetonum($form->{"datepaid_$i"}, \%myconfig);
 786
 787       $form->isblank("datepaid_$i", $locale->text('Payment date missing!'));
 788
 789       $form->error($locale->text('Cannot post payment for a closed period!'))
 790         if ($form->date_closed($form->{"datepaid_$i"}, \%myconfig));
 791
 792       if ($form->{currency} ne $form->{defaultcurrency}) {
 793         $form->{"exchangerate_$i"} = $form->{exchangerate}
 794           if ($invdate == $datepaid);
 795         $form->isblank("exchangerate_$i",
 796                        $locale->text('Exchangerate for payment missing!'));
 797       }
 798     }
 799   }
 800
 801   ($form->{AR})        = split /--/, $form->{AR};
 802   ($form->{AR_paid})   = split /--/, $form->{AR_paid};
 803   $form->{storno}    ||= 0;
 804
 805   $form->{label} = $form->{type} eq 'credit_note' ? $locale->text('Credit Note') : $locale->text('Invoice');
 806
 807   $form->{id} = 0 if $form->{postasnew};
 808
 809   # get new invnumber in sequence if no invnumber is given or if posasnew was requested
 810   if ($form->{postasnew}) {
 811     if ($form->{type} eq "credit_note") {
 812       undef($form->{cnnumber});
 813     } else {
 814       undef($form->{invnumber});
 815     }
 816   }
 817
 818   relink_accounts();
 819
 820   my $terms        = get_payment_terms_for_invoice();
 821   $form->{duedate} = $terms->calc_date(reference_date => $form->{invdate}, due_date => $form->{due_due})->to_kivitendo if $terms;
 822
 823   # If transfer_out is requested, get rose db handle and do post and
 824   # transfer out in one transaction. Otherwise just post the invoice.
 825   if ($::instance_conf->get_is_transfer_out && $form->{type} ne 'credit_note' && !$form->{storno}) {
 826     require SL::DB::Inventory;
 827     my $rose_db = SL::DB::Inventory->new->db;
 828     my @errors;
 829
 830     if (!$rose_db->with_transaction(sub {
 831       if (!eval {
 832         if (!IS->post_invoice(\%myconfig, \%$form, $rose_db->dbh)) {
 833           push @errors, $locale->text('Cannot post invoice!');
 834           die 'posting error';
 835         }
 836         my $err = IS->transfer_out(\%$form, $rose_db->dbh);
 837         if (@{ $err }) {
 838           push @errors, @{ $err };
 839           die 'transfer error';
 840         }
 841
 842         1;
 843       }) {
 844         push @errors, $EVAL_ERROR;
 845         die 'transaction error';
 846       }
 847
 848       1;
 849     })) {
 850       push @errors, $rose_db->error;
 851       $form->error($locale->text('Cannot post invoice and/or transfer out! Error message:') . "\n" . join("\n", @errors));
 852     }
 853   } else {
 854     if (!IS->post_invoice(\%myconfig, \%$form)) {
 855       $form->error($locale->text('Cannot post invoice!'));
 856     }
 857   }
 858
 859   remove_draft() if $form->{remove_draft};
 860
 861   if(!exists $form->{addition}) {
 862     $form->{snumbers}  =  'invnumber' .'_'. $form->{invnumber}; # ($form->{type} eq 'credit_note' ? 'cnnumber' : 'invnumber') .'_'. $form->{invnumber};
 863     $form->{what_done} = 'invoice';
 864     $form->{addition}  = $form->{print_and_post} ? "PRINTED AND POSTED" :
 865                          $form->{storno}         ? "STORNO"             :
 866                                                    "POSTED";
 867     $form->save_history;
 868   }
 869
 870   if (!$form->{no_redirect_after_post}) {
 871     $form->{action} = 'edit';
 872     $form->{script} = 'is.pl';
 873     $form->{saved_message} = $form->{label} . " $form->{invnumber} " . $locale->text('posted!');
 874     $form->{callback} = build_std_url(qw(action edit id callback saved_message));
 875     $form->redirect;
 876   }
 877
 878   $main::lxdebug->leave_sub();
 879 }
 880
 881 sub print_and_post {
 882   $main::lxdebug->enter_sub();
 883
 884   my $form     = $main::form;
 885
 886   $main::auth->assert('invoice_edit');
 887
 888   my $old_form                    = Form->new;
 889   $form->{no_redirect_after_post} = 1;
 890   $form->{print_and_post}         = 1;
 891   &post();
 892
 893   &edit();
 894   $main::lxdebug->leave_sub();
 895
 896 }
 897
 898 sub use_as_new {
 899   $main::lxdebug->enter_sub();
 900
 901   my $form     = $main::form;
 902   my %myconfig = %main::myconfig;
 903
 904   $main::auth->assert('invoice_edit');
 905
 906   delete @{ $form }{qw(printed emailed queued invnumber invdate exchangerate forex deliverydate id datepaid_1 gldate_1 acc_trans_id_1 source_1 memo_1 paid_1 exchangerate_1 AP_paid_1 storno locked)};
 907   $form->{rowcount}--;
 908   $form->{paidaccounts} = 1;
 909   $form->{invdate}      = $form->current_date(\%myconfig);
 910   my $terms             = get_payment_terms_for_invoice();
 911   $form->{duedate}      = $terms ? $terms->calc_date(reference_date => $form->{invdate})->to_kivitendo : $form->{invdate};
 912   $form->{employee_id}  = SL::DB::Manager::Employee->current->id;
 913   $form->{forex}        = $form->check_exchangerate(\%myconfig, $form->{currency}, $form->{invdate}, 'buy');
 914   $form->{exchangerate} = $form->{forex} if $form->{forex};
 915
 916   $form->{"converted_from_invoice_id_$_"} = delete $form->{"invoice_id_$_"} for 1 .. $form->{"rowcount"};
 917
 918   $form->{useasnew} = 1;
 919   &display_form;
 920
 921   $main::lxdebug->leave_sub();
 922 }
 923
 924 sub storno {
 925   $main::lxdebug->enter_sub();
 926
 927   my $form     = $main::form;
 928   my %myconfig = %main::myconfig;
 929   my $locale   = $main::locale;
 930
 931   $main::auth->assert('invoice_edit');
 932
 933   if ($form->{storno}) {
 934     $form->error($locale->text('Cannot storno storno invoice!'));
 935   }
 936
 937   if (IS->has_storno(\%myconfig, $form, "ar")) {
 938     $form->error($locale->text("Invoice has already been storno'd!"));
 939   }
 940   if ($form->datetonum($form->{invdate},  \%myconfig) <= $form->datetonum($form->{closedto}, \%myconfig)) {
 941     $form->error($locale->text('Cannot storno invoice for a closed period!'));
 942   }
 943
 944   # save the history of invoice being stornoed
 945   $form->{snumbers}  = qq|invnumber_| . $form->{invnumber};
 946   $form->{what_done} = 'invoice';
 947   $form->{addition}  = "STORNO";
 948   $form->save_history;
 949
 950   map({ my $key = $_; delete($form->{$key}) unless (grep({ $key eq $_ } qw(id login password type))); } keys(%{ $form }));
 951
 952   invoice_links();
 953   prepare_invoice();
 954   relink_accounts();
 955
 956   # Payments must not be recorded for the new storno invoice.
 957   $form->{paidaccounts} = 0;
 958   map { my $key = $_; delete $form->{$key} if grep { $key =~ /^$_/ } qw(datepaid_ gldate_ acc_trans_id_ source_ memo_ paid_ exchangerate_ AR_paid_) } keys %{ $form };
 959
 960   $form->{storno_id} = $form->{id};
 961   $form->{storno} = 1;
 962   $form->{id} = "";
 963   $form->{invnumber} = "Storno zu " . $form->{invnumber};
 964   $form->{invdate}   = DateTime->today->to_lxoffice;
 965   $form->{rowcount}++;
 966   # set new ids for storno invoice
 967   delete $form->{"invoice_id_$_"} for 1 .. $form->{"rowcount"};
 968
 969   post();
 970   $main::lxdebug->leave_sub();
 971 }
 972
 973 sub preview {
 974   $main::lxdebug->enter_sub();
 975
 976   my $form     = $main::form;
 977
 978   $main::auth->assert('invoice_edit');
 979
 980   $form->{preview} = 1;
 981   my $old_form = Form->new;
 982   for (keys %$form) { $old_form->{$_} = $form->{$_} }
 983
 984   &print_form($old_form);
 985   $main::lxdebug->leave_sub();
 986
 987 }
 988
 989 sub delete {
 990   $main::lxdebug->enter_sub();
 991
 992   my $form     = $main::form;
 993   my $locale   = $main::locale;
 994
 995   $main::auth->assert('invoice_edit');
 996
 997   if ($form->{second_run}) {
 998     $form->{print_and_post} = 0;
 999   }
1000   $form->header;
1001
1002   print qq|
1003 <form method="post" action="$form->{script}">
1004 |;
1005
1006   # delete action variable
1007   map { delete $form->{$_} } qw(action header);
1008
1009   foreach my $key (keys %$form) {
1010     next if (($key eq 'login') || ($key eq 'password') || ('' ne ref $form->{$key}));
1011     $form->{$key} =~ s/\"/&quot;/g;
1012     print qq|<input type="hidden" name="$key" value="$form->{$key}">\n|;
1013   }
1014
1015   print qq|
1016 <h2 class="confirm">| . $locale->text('Confirm!') . qq|</h2>
1017
1018 <h4>|
1019     . $locale->text('Are you sure you want to delete Invoice Number')
1020     . qq| $form->{invnumber}
1021 </h4>
1022
1023 <p>
1024 <input name="action" class="submit" type="submit" value="|
1025     . $locale->text('Yes') . qq|">
1026 </form>
1027 |;
1028
1029   $main::lxdebug->leave_sub();
1030 }
1031
1032 sub credit_note {
1033   $main::lxdebug->enter_sub();
1034
1035   my $form     = $main::form;
1036   my %myconfig = %main::myconfig;
1037   my $locale   = $main::locale;
1038
1039   $main::auth->assert('invoice_edit');
1040
1041   $form->{transdate} = $form->{invdate} = $form->current_date(\%myconfig);
1042   $form->{duedate} =
1043     $form->current_date(\%myconfig, $form->{invdate}, $form->{terms} * 1);
1044
1045   $form->{convert_from_ar_ids} = $form->{id};
1046   $form->{id}     = '';
1047   $form->{rowcount}--;
1048
1049
1050   $form->{title}  = $locale->text('Add Credit Note');
1051   $form->{script} = 'is.pl';
1052
1053   # Bei Gutschriften bezug zur Rechnungsnummer
1054   $form->{invnumber_for_credit_note} = $form->{invnumber};
1055   # bo creates the id, reset it
1056   map { delete $form->{$_} }
1057     qw(id invnumber subject message cc bcc printed emailed queued);
1058   $form->{ $form->{vc} } =~ s/--.*//g;
1059   $form->{type} = "credit_note";
1060
1061
1062   map { $form->{"select$_"} = "" } ($form->{vc}, 'currency');
1063
1064 #  map { $form->{$_} = $form->parse_amount(\%myconfig, $form->{$_}) }
1065 #    qw(creditlimit creditremaining);
1066
1067   # set new persistent ids for credit note and link previous invoice id
1068   $form->{"converted_from_invoice_id_$_"} = delete $form->{"invoice_id_$_"} for 1 .. $form->{"rowcount"};
1069
1070   my $currency = $form->{currency};
1071   &invoice_links;
1072
1073   $form->{currency}     = $currency;
1074   $form->{forex}        = $form->check_exchangerate( \%myconfig, $form->{currency}, $form->{invdate}, 'buy');
1075   $form->{exchangerate} = $form->{forex} || '';
1076
1077   $form->{creditremaining} -= ($form->{oldinvtotal} - $form->{ordtotal});
1078
1079   # bei Gutschriften werden Zahlungseingänge aus Rechnung nicht übernommen
1080   for my $i (1 .. $form->{paidaccounts}) {
1081     delete $form->{"paid_$i"};
1082     delete $form->{"source_$i"};
1083     delete $form->{"memo_$i"};
1084     delete $form->{"datepaid_$i"};
1085     delete $form->{"gldate_$i"};
1086     delete $form->{"acc_trans_id_$i"};
1087     delete $form->{"AR_paid_$i"};
1088   };
1089   $form->{paidaccounts} = 1;
1090
1091   &prepare_invoice;
1092
1093
1094   &display_form;
1095
1096   $main::lxdebug->leave_sub();
1097 }
1098
1099 sub yes {
1100   $main::lxdebug->enter_sub();
1101
1102   my $form     = $main::form;
1103   my %myconfig = %main::myconfig;
1104   my $locale   = $main::locale;
1105
1106   $main::auth->assert('invoice_edit');
1107
1108   if (IS->delete_invoice(\%myconfig, \%$form)) {
1109     # saving the history
1110     if(!exists $form->{addition}) {
1111       $form->{snumbers}  = 'invnumber' .'_'. $form->{invnumber}; # ($form->{type} eq 'credit_note' ? 'cnnumber' : 'invnumber') .'_'. $form->{invnumber};
1112       $form->{what_done} = 'invoice';
1113       $form->{addition}  = "DELETED";
1114       $form->save_history;
1115     }
1116     # /saving the history
1117     $form->redirect($locale->text('Invoice deleted!'));
1118   }
1119   $form->error($locale->text('Cannot delete invoice!'));
1120
1121   $main::lxdebug->leave_sub();
1122 }
1123
1124 sub post_and_e_mail {
1125   e_mail();
1126 };
1127
1128 sub e_mail {
1129   $main::lxdebug->enter_sub();
1130
1131   my $form     = $main::form;
1132
1133   $main::auth->assert('invoice_edit');
1134
1135   if (!$form->{id}) {
1136     $form->{no_redirect_after_post} = 1;
1137
1138     my $saved_form = save_form();
1139
1140     post();
1141
1142     restore_form($saved_form, 0, qw(id invnumber));
1143   }
1144
1145   edit_e_mail();
1146
1147   $main::lxdebug->leave_sub();
1148 }