bin/mozilla/menu.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 ######################################################################
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 1998-2002
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #  Contributors: Christopher Browne
  16 #
  17 # This program is free software; you can redistribute it and/or modify
  18 # it under the terms of the GNU General Public License as published by
  19 # the Free Software Foundation; either version 2 of the License, or
  20 # (at your option) any later version.
  21 #
  22 # This program is distributed in the hope that it will be useful,
  23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 # GNU General Public License for more details.
  26 # You should have received a copy of the GNU General Public License
  27 # along with this program; if not, write to the Free Software
  28 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  29 #######################################################################
  30 #
  31 # the frame layout with refractured menu
  32 #
  33 # CHANGE LOG:
  34 #   DS. 2002-03-25  Created
  35 #  2004-12-14 - New Optik - Marco Welter <mawe@linux-studio.de>
  36 #  2010-08-19 - Icons for sub entries and single click behavior, unlike XUL-Menu
  37 #               JS switchable HTML-menu - Sven Donath <lxo@dexo.de>
  38 #######################################################################
  39
  40 use strict;
  41
  42 use SL::Menu;
  43 use Data::Dumper;
  44 use URI;
  45
  46 use List::MoreUtils qw(apply);
  47
  48 my $menufile = "menu.ini";
  49 my $nbsp     = '&nbsp;';
  50 my $mainlevel;
  51
  52 # end of main
  53
  54 sub display {
  55   $::lxdebug->enter_sub;
  56
  57   my $callback  = $::form->unescape($::form->{callback});
  58   $callback     = URI->new($callback)->rel($callback) if $callback;
  59   $callback     = "login.pl?action=company_logo"      if $callback =~ /^(\.\/)?$/;
  60   my $framesize = _calc_framesize();
  61
  62   $::form->header;
  63
  64   print qq|
  65 <frameset rows="28px,*" cols="*" framespacing="0" frameborder="0">
  66   <frame  src="kopf.pl" name="kopf"  scrolling="NO">
  67   <frameset cols="$framesize,*" framespacing="0" frameborder="0" border="0" id="menuframe" name="menuframe">
  68     <frame src="$::form->{script}?action=acc_menu" name="acc_menu"  scrolling="auto" noresize marginwidth="0">
  69     <frame src="$callback" name="main_window" scrolling="auto">
  70   </frameset>
  71   <noframes>
  72   You need a browser that can read frames to see this page.
  73   </noframes>
  74 </frameset>
  75 </HTML>
  76 |;
  77
  78   $::lxdebug->leave_sub;
  79 }
  80
  81 sub acc_menu {
  82   $::lxdebug->enter_sub;
  83
  84   my $framesize    = _calc_framesize() - 2;
  85   my $menu         = Menu->new($::menufile);
  86   $mainlevel       = $::form->{level};
  87   $::form->{title} = $::locale->text('Lx-Office');
  88   $::form->header;
  89
  90   print qq|
  91 <body class="menu">
  92
  93 <div align="left">\n<table width="$framesize" border="0">\n|;
  94
  95   section_menu($menu);
  96
  97   print qq|</table></div>
  98 </body>
  99 </html>
 100 |;
 101
 102   $::lxdebug->leave_sub;
 103 }
 104
 105 sub section_menu {
 106   $::lxdebug->enter_sub;
 107   my ($menu, $level) = @_;
 108
 109   # build tiered menus
 110   my @menuorder = $menu->access_control(\%::myconfig, $level);
 111   for my $item (@menuorder) {
 112     my $menuitem   = $menu->{$item};
 113     my $label      = apply { s/.*--// } $item;
 114     my $ml         = apply { s/--.*// } $item;
 115     my $show       = $ml eq $mainlevel;
 116     my $spacer     = $nbsp x (($item =~ s/--/--/g) * 2);
 117     my $label_icon = $level . "--" . $label . ".png";
 118
 119     $label         = $::locale->text($label);
 120
 121     $menuitem->{target} ||= "main_window";
 122
 123     my $anchor     = $menu->menuitem(\%::myconfig, $::form, $item, $level);
 124
 125     next if $menuitem->{HIDDEN};
 126
 127     # multi line hack, sschoeling jul06
 128     # if a label is too long, try to split it at whitespaces, then join it to chunks of less
 129     # than 20 chars and store it in an array.
 130     # use this array later instead of the &nbsp;-ed label
 131     my @chunks;
 132     my $l = 20;
 133     for (split / /, $label) {
 134       $l += length $_;
 135       if ($l < 20) {
 136         $chunks[-1] .= " $_";
 137       } else {
 138         $l = length $_;
 139         push @chunks, $_;
 140       }
 141     }
 142     # end multi line
 143
 144     if ($menuitem->{submenu}) {
 145       if ($::form->{level} && $item =~ /^\Q$::form->{level}\E/) {
 146         my $image = make_image(submenu => 1);
 147         print "<tr><td style='vertical-align:bottom'><b>$spacer$image$label</b></td></tr>\n" if $show;
 148
 149         # remove same level items
 150         $menu->{$_}{HIDDEN} = 1 for grep /^$item/, @menuorder;
 151         section_menu($menu, $item);
 152       } else {
 153         print "<tr><td>$anchor$label&nbsp;...</a></td></tr>\n" if $show;
 154
 155         # remove same level items
 156         $menu->{$_}{HIDDEN} = 1 for grep /^$item/, @menuorder;
 157       }
 158     } elsif ($menuitem->{module}) {
 159       if ($::form->{$item} && $::form->{level} eq $item) {
 160         my $image = make_image();
 161         print qq|<tr><td valign=bottom>$spacer$image$anchor$label</a></td></tr>\n| if $show;
 162
 163         # remove same level items
 164         $menu->{$_}{HIDDEN} = 1 for grep /^$item/, @menuorder;
 165         section_menu($menu, $item);
 166       } elsif ($show) {
 167         my $image1 = make_image(label => $label, icon => $label_icon);
 168         my $image2 = make_image(hidden => 1);
 169         print "<tr><td class='hover' height='16'>$spacer$anchor$image1$chunks[0]</a></td></tr>\n";
 170         print "<tr style='vertical-align:top'><td class='hover'>$spacer$image2$anchor$chunks[$_]</a></td></tr>\n"
 171           for 1..$#chunks;
 172       }
 173     } else {
 174       my $ml_    = $::form->escape($ml);
 175       my $image  = make_image(icon => $item . '.png', size => 24, label => $label, valign => 'middle');
 176       my $anchor = "<a href='menu.pl?action=acc_menu&level=$ml_' class='nohover' title='$label'>";
 177       print qq|<tr><td class="bg" height="24" align="left" valign="middle">$anchor$image$label</a></td></tr>\n|;
 178
 179       &section_menu($menu, $item);
 180     }
 181   }
 182   $::lxdebug->leave_sub;
 183 }
 184
 185 sub _calc_framesize {
 186   my $is_lynx_browser   = $ENV{HTTP_USER_AGENT} =~ /links/i;
 187   my $is_mobile_browser = $ENV{HTTP_USER_AGENT} =~ /mobile/i;
 188   my $is_mobile_style   = $::form->{stylesheet} =~ /mobile/i;
 189
 190   return  $is_mobile_browser && $is_mobile_style ?  130
 191         : $is_lynx_browser                       ?  240
 192         :                                           200;
 193 }
 194
 195 sub _show_images {
 196   # don't show images in links
 197   _calc_framesize() != 240;
 198 }
 199
 200 sub make_image {
 201   my (%params) = @_;
 202
 203   my $label  = $params{label};
 204   my $icon   = $params{icon};
 205   my $hidden = $params{hidden};
 206   my $size   = $params{size}   || 16;
 207   my $valign = $params{valign} || 'text-top';
 208
 209   return unless _show_images();
 210
 211   my $icon_found = $icon && -f _icon_path($icon, $size);
 212
 213   my $image_url = $icon_found ? _icon_path($icon, $size) : "image/unterpunkt.png";
 214   my $style     = $hidden     ? "visibility:hidden"      : "vertical-align:$valign";
 215   my $width     = $hidden     ? "width='$size'"          : '';
 216
 217   my $padding   = $size == 16 && $icon_found || $hidden ? $nbsp x 2
 218                 : $size == 24                           ? $nbsp
 219                 :                                         '';
 220
 221   return "<img src='$image_url' border='0' style='$style' title='$label' $width>$padding";
 222 }
 223
 224 sub _icon_path {
 225   my ($label, $size) = @_;
 226
 227   $size ||= 16;
 228
 229   return "image/icons/${size}x${size}/$label";
 230 }
 231
 232 1;
 233
 234 __END__