bin/mozilla/sepa.pl

   1 use strict;
   2
   3 use List::MoreUtils qw(any none uniq);
   4 use List::Util qw(sum first);
   5 use POSIX qw(strftime);
   6
   7 use SL::BankAccount;
   8 use SL::Chart;
   9 use SL::CT;
  10 use SL::Form;
  11 use SL::GenericTranslations;
  12 use SL::ReportGenerator;
  13 use SL::SEPA;
  14 use SL::SEPA::XML;
  15
  16 require "bin/mozilla/common.pl";
  17 require "bin/mozilla/reportgenerator.pl";
  18
  19 sub bank_transfer_add {
  20   $main::lxdebug->enter_sub();
  21
  22   my $form          = $main::form;
  23   my $locale        = $main::locale;
  24   my $vc            = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
  25
  26   $form->{title}    = $vc eq 'customer' ? $::locale->text('Prepare bank collection via SEPA XML') : $locale->text('Prepare bank transfer via SEPA XML');
  27
  28   my $bank_accounts = SL::BankAccount->list();
  29
  30   if (!scalar @{ $bank_accounts }) {
  31     $form->error($locale->text('You have not added bank accounts yet.'));
  32   }
  33
  34   my $invoices = SL::SEPA->retrieve_open_invoices(vc => $vc);
  35
  36   if (!scalar @{ $invoices }) {
  37     $form->show_generic_information($locale->text('Either there are no open invoices, or you have already initiated bank transfers ' .
  38                                                   'with the open amounts for those that are still open.'));
  39     $main::lxdebug->leave_sub();
  40     return;
  41   }
  42
  43   # Only include those per default that require manual action from our
  44   # side. For sales invoices these are the ones for which direct debit
  45   # has been selected. For purchase invoices it's the other way
  46   # around: if direct debit is active then the vendor will collect
  47   # from us automatically and we don't have to send money manually.
  48   $_->{checked} = ($vc eq 'customer' ? $_->{direct_debit} : !$_->{direct_debit}) for @{ $invoices };
  49
  50   my $bank_account_label_sub = sub { $locale->text('Account number #1, bank code #2, #3', $_[0]->{account_number}, $_[0]->{bank_code}, $_[0]->{bank}) };
  51
  52   my $translation_list = GenericTranslations->list(translation_type => 'sepa_remittance_info_pfx');
  53   my %translations     = map { ( ($_->{language_id} || 'default') => $_->{translation} ) } @{ $translation_list };
  54
  55   foreach my $invoice (@{ $invoices }) {
  56     my $prefix                    = $translations{ $invoice->{language_id} } || $translations{default} || $::locale->text('Invoice');
  57     $prefix                      .= ' ' unless $prefix =~ m/ $/;
  58     $invoice->{reference_prefix}  = $prefix;
  59   }
  60
  61   $form->header();
  62   print $form->parse_html_template('sepa/bank_transfer_add',
  63                                    { 'INVOICES'           => $invoices,
  64                                      'BANK_ACCOUNTS'      => $bank_accounts,
  65                                      'bank_account_label' => $bank_account_label_sub,
  66                                      'vc'                 => $vc,
  67                                    });
  68
  69   $main::lxdebug->leave_sub();
  70 }
  71
  72 sub bank_transfer_create {
  73   $main::lxdebug->enter_sub();
  74
  75   my $form          = $main::form;
  76   my $locale        = $main::locale;
  77   my $myconfig      = \%main::myconfig;
  78   my $vc            = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
  79
  80   $form->{title}    = $vc eq 'customer' ? $::locale->text('Create bank collection via SEPA XML') : $locale->text('Create bank transfer via SEPA XML');
  81
  82   my $bank_accounts = SL::BankAccount->list();
  83
  84   if (!scalar @{ $bank_accounts }) {
  85     $form->error($locale->text('You have not added bank accounts yet.'));
  86   }
  87
  88   my $bank_account = first { $form->{bank_account}->{id} == $_->{id} } @{ $bank_accounts };
  89
  90   if (!$bank_account) {
  91     $form->error($locale->text('The selected bank account does not exist anymore.'));
  92   }
  93
  94   my $arap_id        = $vc eq 'customer' ? 'ar_id' : 'ap_id';
  95   my $invoices       = SL::SEPA->retrieve_open_invoices(vc => $vc);
  96
  97   my %invoices_map   = map { $_->{id} => $_ } @{ $invoices };
  98   my @bank_transfers =
  99     map  +{ %{ $invoices_map{ $_->{$arap_id} } }, %{ $_ } },
 100     grep  { $_->{selected} && (0 < $_->{amount}) && $invoices_map{ $_->{$arap_id} } }
 101     map   { $_->{amount} = $form->parse_amount($myconfig, $_->{amount}); $_ }
 102           @{ $form->{bank_transfers} || [] };
 103
 104   if (!scalar @bank_transfers) {
 105     $form->error($locale->text('You have selected none of the invoices.'));
 106   }
 107
 108   my $total_trans = sum map { $_->{open_amount} } @bank_transfers;
 109
 110   my ($vc_bank_info);
 111   my $error_message;
 112
 113   my @bank_columns    = qw(iban bic);
 114   push @bank_columns, qw(mandator_id mandate_date_of_signature) if $vc eq 'customer';
 115
 116   if ($form->{confirmation}) {
 117     $vc_bank_info = { map { $_->{id} => $_ } @{ $form->{vc_bank_info} || [] } };
 118
 119     foreach my $info (values %{ $vc_bank_info }) {
 120       if (any { !$info->{$_} } @bank_columns) {
 121         $error_message = $locale->text('The bank information must not be empty.');
 122         last;
 123       }
 124     }
 125   }
 126
 127   if ($error_message || !$form->{confirmation}) {
 128     my @vc_ids                 = uniq map { $_->{vc_id} } @bank_transfers;
 129     $vc_bank_info            ||= CT->get_bank_info('vc' => $vc,
 130                                                    'id' => \@vc_ids);
 131     my @vc_bank_info           = sort { lc $a->{name} cmp lc $b->{name} } values %{ $vc_bank_info };
 132
 133     my $bank_account_label_sub = sub { $locale->text('Account number #1, bank code #2, #3', $_[0]->{account_number}, $_[0]->{bank_code}, $_[0]->{bank}) };
 134
 135     $form->header();
 136     print $form->parse_html_template('sepa/bank_transfer_create',
 137                                      { 'BANK_TRANSFERS'     => \@bank_transfers,
 138                                        'BANK_ACCOUNTS'      => $bank_accounts,
 139                                        'VC_BANK_INFO'       => \@vc_bank_info,
 140                                        'bank_account'       => $bank_account,
 141                                        'bank_account_label' => $bank_account_label_sub,
 142                                        'error_message'      => $error_message,
 143                                        'vc'                 => $vc,
 144                                        'total_trans'        => $total_trans,
 145                                      });
 146
 147   } else {
 148     foreach my $bank_transfer (@bank_transfers) {
 149       foreach (@bank_columns) {
 150         $bank_transfer->{"vc_${_}"}  = $vc_bank_info->{ $bank_transfer->{vc_id} }->{$_};
 151         $bank_transfer->{"our_${_}"} = $bank_account->{$_};
 152       }
 153
 154       $bank_transfer->{chart_id} = $bank_account->{chart_id};
 155     }
 156
 157     my $id = SL::SEPA->create_export('employee'       => $form->{login},
 158                                      'bank_transfers' => \@bank_transfers,
 159                                      'vc'             => $vc);
 160
 161     $form->header();
 162     print $form->parse_html_template('sepa/bank_transfer_created', { 'id' => $id, 'vc' => $vc });
 163   }
 164
 165   $main::lxdebug->leave_sub();
 166 }
 167
 168 sub bank_transfer_search {
 169   $main::lxdebug->enter_sub();
 170
 171   my $form   = $main::form;
 172   my $locale = $main::locale;
 173   my $vc     = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
 174
 175   $form->{title}    = $vc eq 'customer' ? $::locale->text('List of bank collections') : $locale->text('List of bank transfers');
 176
 177   $form->header();
 178   print $form->parse_html_template('sepa/bank_transfer_search', { vc => $vc });
 179
 180   $main::lxdebug->leave_sub();
 181 }
 182
 183
 184 sub bank_transfer_list {
 185   $main::lxdebug->enter_sub();
 186
 187   my $form   = $main::form;
 188   my $locale = $main::locale;
 189   my $cgi    = $::request->{cgi};
 190   my $vc     = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
 191
 192   $form->{title}     = $vc eq 'customer' ? $::locale->text('List of bank collections') : $locale->text('List of bank transfers');
 193
 194   $form->{sort}    ||= 'id';
 195   $form->{sortdir}   = '1' if (!defined $form->{sortdir});
 196
 197   $form->{callback}  = build_std_url('action=bank_transfer_list', 'sort', 'sortdir', 'vc');
 198
 199   my %filter         = map  +( $_ => $form->{"f_${_}"} ),
 200                        grep  { $form->{"f_${_}"} }
 201                              (qw(vc invnumber),
 202                               map { ("${_}_date_from", "${_}_date_to") }
 203                                   qw(export requested_execution execution));
 204   $filter{executed}  = $form->{l_executed} ? 1 : 0 if ($form->{l_executed} != $form->{l_not_executed});
 205   $filter{closed}    = $form->{l_closed}   ? 1 : 0 if ($form->{l_open}     != $form->{l_closed});
 206
 207   my $exports        = SL::SEPA->list_exports('filter'    => \%filter,
 208                                               'sortorder' => $form->{sort},
 209                                               'sortdir'   => $form->{sortdir},
 210                                               'vc'        => $vc);
 211
 212   my $open_available = any { !$_->{closed} } @{ $exports };
 213
 214   my $report         = SL::ReportGenerator->new(\%main::myconfig, $form);
 215
 216   my @hidden_vars    = ('vc', grep { m/^[fl]_/ && $form->{$_} } keys %{ $form });
 217
 218   my $href           = build_std_url('action=bank_transfer_list', @hidden_vars);
 219
 220   my %column_defs = (
 221     'selected'    => { 'text' => $cgi->checkbox(-name => 'select_all', -id => 'select_all', -label => ''), },
 222     'id'          => { 'text' => $locale->text('Number'), },
 223     'export_date' => { 'text' => $locale->text('Export date'), },
 224     'employee'    => { 'text' => $locale->text('Employee'), },
 225     'executed'    => { 'text' => $locale->text('Executed'), },
 226     'closed'      => { 'text' => $locale->text('Closed'), },
 227   );
 228
 229   my @columns = qw(selected id export_date employee executed closed);
 230
 231   foreach my $name (qw(id export_date employee executed closed)) {
 232     my $sortdir                 = $form->{sort} eq $name ? 1 - $form->{sortdir} : $form->{sortdir};
 233     $column_defs{$name}->{link} = $href . "&sort=$name&sortdir=$sortdir";
 234   }
 235
 236   $column_defs{selected}->{visible} = $open_available                                ? 'HTML' : 0;
 237   $column_defs{executed}->{visible} = $form->{l_executed} && $form->{l_not_executed} ? 1 : 0;
 238   $column_defs{closed}->{visible}   = $form->{l_closed}   && $form->{l_open}         ? 1 : 0;
 239
 240   my @options = ();
 241   push @options, ($vc eq 'customer' ? $::locale->text('Customer') : $locale->text('Vendor')) . ' : ' . $form->{f_vc} if ($form->{f_vc});
 242   push @options, $locale->text('Invoice number')                . ' : ' . $form->{f_invnumber}                     if ($form->{f_invnumber});
 243   push @options, $locale->text('Export date from')              . ' : ' . $form->{f_export_date_from}              if ($form->{f_export_date_from});
 244   push @options, $locale->text('Export date to')                . ' : ' . $form->{f_export_date_to}                if ($form->{f_export_date_to});
 245   push @options, $locale->text('Requested execution date from') . ' : ' . $form->{f_requested_execution_date_from} if ($form->{f_requested_execution_date_from});
 246   push @options, $locale->text('Requested execution date to')   . ' : ' . $form->{f_requested_execution_date_to}   if ($form->{f_requested_execution_date_to});
 247   push @options, $locale->text('Execution date from')           . ' : ' . $form->{f_execution_date_from}           if ($form->{f_execution_date_from});
 248   push @options, $locale->text('Execution date to')             . ' : ' . $form->{f_execution_date_to}             if ($form->{f_execution_date_to});
 249   push @options, $form->{l_executed} ? $locale->text('executed') : $locale->text('not yet executed')               if ($form->{l_executed} != $form->{l_not_executed});
 250   push @options, $form->{l_closed}   ? $locale->text('closed')   : $locale->text('open')                           if ($form->{l_open}     != $form->{l_closed});
 251
 252   $report->set_options('top_info_text'         => join("\n", @options),
 253                        'raw_top_info_text'     => $form->parse_html_template('sepa/bank_transfer_list_top'),
 254                        'raw_bottom_info_text'  => $form->parse_html_template('sepa/bank_transfer_list_bottom', { 'show_buttons' => $open_available, vc => $vc }),
 255                        'std_column_visibility' => 1,
 256                        'output_format'         => 'HTML',
 257                        'title'                 => $form->{title},
 258                        'attachment_basename'   => $locale->text('banktransfers') . strftime('_%Y%m%d', localtime time),
 259     );
 260   $report->set_options_from_form();
 261   $locale->set_numberformat_wo_thousands_separator(\%::myconfig) if lc($report->{options}->{output_format}) eq 'csv';
 262
 263   $report->set_columns(%column_defs);
 264   $report->set_column_order(@columns);
 265   $report->set_export_options('bank_transfer_list', @hidden_vars);
 266   $report->set_sort_indicator($form->{sort}, $form->{sortdir});
 267
 268   my $edit_url = build_std_url('action=bank_transfer_edit', 'callback');
 269
 270   foreach my $export (@{ $exports }) {
 271     my $row = { map { $_ => { 'data' => $export->{$_} } } keys %{ $export } };
 272
 273     map { $row->{$_}->{data} = $export->{$_} ? $locale->text('yes') : $locale->text('no') } qw(executed closed);
 274
 275     $row->{id}->{link} = $edit_url . '&id=' . E($export->{id}) . '&vc=' . E($vc);
 276
 277     if (!$export->{closed}) {
 278       $row->{selected}->{raw_data} =
 279           $cgi->hidden(-name => "exports[+].id", -value => $export->{id})
 280         . $cgi->checkbox(-name => "exports[].selected", -value => 1, -label => '');
 281     }
 282
 283     $report->add_data($row);
 284   }
 285
 286   $report->generate_with_headers();
 287
 288   $main::lxdebug->leave_sub();
 289 }
 290
 291 sub bank_transfer_edit {
 292   $main::lxdebug->enter_sub();
 293
 294   my $form   = $main::form;
 295   my $locale = $main::locale;
 296   my $vc     = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
 297
 298   my @ids    = ();
 299   if (!$form->{mode} || ($form->{mode} eq 'single')) {
 300     push @ids, $form->{id};
 301   } else {
 302     @ids = map $_->{id}, grep { $_->{selected} } @{ $form->{exports} || [] };
 303
 304     if (!@ids) {
 305       $form->show_generic_error($locale->text('You have not selected any export.'), 'back_button' => 1);
 306     }
 307   }
 308
 309   my $export;
 310
 311   foreach my $id (@ids) {
 312     my $curr_export = SL::SEPA->retrieve_export('id' => $id, 'details' => 1, 'vc' => $vc);
 313
 314     foreach my $item (@{ $curr_export->{items} }) {
 315       map { $item->{"export_${_}"} = $curr_export->{$_} } grep { !ref $curr_export->{$_} } keys %{ $curr_export };
 316     }
 317
 318     if (!$export) {
 319       $export = $curr_export;
 320     } else {
 321       push @{ $export->{items} }, @{ $curr_export->{items} };
 322     }
 323   }
 324
 325   if ($form->{mode} && ($form->{mode} eq 'multi')) {
 326     $export->{items} = [ grep { !$_->{export_closed} && !$_->{executed} } @{ $export->{items} } ];
 327
 328     if (!@{ $export->{items} }) {
 329       $form->show_generic_error($locale->text('All the selected exports have already been closed, or all of their items have already been executed.'), 'back_button' => 1);
 330     }
 331
 332   } elsif (!$export) {
 333     $form->error($locale->text('That export does not exist.'));
 334   }
 335
 336   $form->{title}    = $locale->text('View SEPA export');
 337   $form->header();
 338   print $form->parse_html_template('sepa/bank_transfer_edit',
 339                                    { 'ids'                       => \@ids,
 340                                      'export'                    => $export,
 341                                      'current_date'              => $form->current_date(\%main::myconfig),
 342                                      'show_post_payments_button' => any { !$_->{export_closed} && !$_->{executed} } @{ $export->{items} },
 343                                    });
 344
 345   $main::lxdebug->leave_sub();
 346 }
 347
 348 sub bank_transfer_post_payments {
 349   $main::lxdebug->enter_sub();
 350
 351   my $form   = $main::form;
 352   my $locale = $main::locale;
 353   my $vc     = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
 354
 355   my @items  = grep { $_->{selected} } @{ $form->{items} || [] };
 356
 357   if (!@items) {
 358     $form->show_generic_error($locale->text('You have not selected any item.'), 'back_button' => 1);
 359   }
 360   my @export_ids    = uniq map { $_->{sepa_export_id} } @items;
 361   my %exports       = map { $_ => SL::SEPA->retrieve_export('id' => $_, 'details' => 1, vc => $vc) } @export_ids;
 362   my @items_to_post = ();
 363
 364   foreach my $item (@items) {
 365     my $export = $exports{ $item->{sepa_export_id} };
 366     next if (!$export || $export->{closed} || $export->{executed});
 367
 368     push @items_to_post, $item if (none { ($_->{id} == $item->{id}) && $_->{executed} } @{ $export->{items} });
 369   }
 370
 371   if (!@items_to_post) {
 372     $form->show_generic_error($locale->text('All the selected exports have already been closed, or all of their items have already been executed.'), 'back_button' => 1);
 373   }
 374
 375   if (any { !$_->{execution_date} } @items_to_post) {
 376     $form->show_generic_error($locale->text('You have to specify an execution date for each antry.'), 'back_button' => 1);
 377   }
 378
 379   SL::SEPA->post_payment('items' => \@items_to_post, vc => $vc);
 380
 381   $form->show_generic_information($locale->text('The payments have been posted.'));
 382
 383   $main::lxdebug->leave_sub();
 384 }
 385
 386 sub bank_transfer_payment_list_as_pdf {
 387   $main::lxdebug->enter_sub();
 388
 389   my $form       = $main::form;
 390   my %myconfig   = %main::myconfig;
 391   my $locale     = $main::locale;
 392   my $vc         = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
 393
 394   my @ids        = @{ $form->{items} || [] };
 395   my @export_ids = uniq map { $_->{export_id} } @ids;
 396
 397   $form->show_generic_error($locale->text('Multi mode not supported.'), 'back_button' => 1) if 1 != scalar @export_ids;
 398
 399   my $export = SL::SEPA->retrieve_export('id' => $export_ids[0], 'details' => 1, vc => $vc);
 400   my @items  = ();
 401
 402   foreach my $id (@ids) {
 403     my $item = first { $_->{id} == $id->{id} } @{ $export->{items} };
 404     push @items, $item if $item;
 405   }
 406
 407   $form->show_generic_error($locale->text('No transfers were executed in this export.'), 'back_button' => 1) if 1 > scalar @items;
 408
 409   my $report         =  SL::ReportGenerator->new(\%main::myconfig, $form);
 410
 411   my %column_defs    =  (
 412     'invnumber'      => { 'text' => $locale->text('Invoice'),                                                                  },
 413     'vc_name'        => { 'text' => $vc eq 'customer' ? $locale->text('Customer')         : $locale->text('Vendor'),           },
 414     'our_iban'       => { 'text' => $vc eq 'customer' ? $locale->text('Destination IBAN') : $locale->text('Source IBAN'),      },
 415     'our_bic'        => { 'text' => $vc eq 'customer' ? $locale->text('Destination BIC')  : $locale->text('Source BIC'),       },
 416     'vc_iban'        => { 'text' => $vc eq 'customer' ? $locale->text('Source IBAN')      : $locale->text('Destination IBAN'), },
 417     'vc_bic'         => { 'text' => $vc eq 'customer' ? $locale->text('Source BIC')       : $locale->text('Destination BIC'),  },
 418     'amount'         => { 'text' => $locale->text('Amount'),                                                                   },
 419     'reference'      => { 'text' => $locale->text('Reference'),                                                                },
 420     'execution_date' => { 'text' => $locale->text('Execution date'),                                                           },
 421   );
 422
 423   map { $column_defs{$_}->{align} = 'right' } qw(amount execution_date);
 424
 425   my @columns        =  qw(invnumber vc_name our_iban our_bic vc_iban vc_bic amount reference execution_date);
 426
 427   $report->set_options('std_column_visibility' => 1,
 428                        'output_format'         => 'PDF',
 429                        'title'                 =>  $vc eq 'customer' ? $locale->text('Bank collection payment list for export #1', $export->{id}) : $locale->text('Bank transfer payment list for export #1', $export->{id}),
 430                        'attachment_basename'   => ($vc eq 'customer' ? $locale->text('bank_collection_payment_list_#1', $export->{id}) : $locale->text('bank_transfer_payment_list_#1', $export->{id})) . strftime('_%Y%m%d', localtime time),
 431     );
 432
 433   $report->set_columns(%column_defs);
 434   $report->set_column_order(@columns);
 435
 436   foreach my $item (@items) {
 437     my $row                = { map { $_ => { 'data' => $item->{$_} } } @columns };
 438     $row->{amount}->{data} = $form->format_amount(\%myconfig, $item->{amount}, 2);
 439
 440     $report->add_data($row);
 441   }
 442
 443   $report->generate_with_headers();
 444
 445   $main::lxdebug->leave_sub();
 446 }
 447
 448 # TODO
 449 sub bank_transfer_download_sepa_xml {
 450   $main::lxdebug->enter_sub();
 451
 452   my $form     =  $main::form;
 453   my $myconfig = \%main::myconfig;
 454   my $locale   =  $main::locale;
 455   my $cgi      =  $::request->{cgi};
 456   my $vc       = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
 457   my $defaults = SL::DB::Default->get;
 458
 459   if (!$defaults->company) {
 460     $form->show_generic_error($locale->text('You have to enter a company name in the client configuration.'), 'back_button' => 1);
 461   }
 462
 463   if (($vc eq 'customer') && !$defaults->sepa_creditor_id) {
 464     $form->show_generic_error($locale->text('You have to enter the SEPA creditor ID in the client configuration.'), 'back_button' => 1);
 465   }
 466
 467   my @ids;
 468   if ($form->{mode} && ($form->{mode} eq 'multi')) {
 469      @ids = map $_->{id}, grep { $_->{selected} } @{ $form->{exports} || [] };
 470
 471   } else {
 472     @ids = ($form->{id});
 473   }
 474
 475   if (!@ids) {
 476     $form->show_generic_error($locale->text('You have not selected any export.'), 'back_button' => 1);
 477   }
 478
 479   my @items = ();
 480
 481   foreach my $id (@ids) {
 482     my $export = SL::SEPA->retrieve_export('id' => $id, 'details' => 1, vc => $vc);
 483     push @items, grep { !$_->{executed} } @{ $export->{items} } if ($export && !$export->{closed});
 484   }
 485
 486   if (!@items) {
 487     $form->show_generic_error($locale->text('All the selected exports have already been closed, or all of their items have already been executed.'), 'back_button' => 1);
 488   }
 489
 490   my $message_id = strftime('MSG%Y%m%d%H%M%S', localtime) . sprintf('%06d', $$);
 491
 492   my $sepa_xml   = SL::SEPA::XML->new('company'     => $defaults->company,
 493                                       'creditor_id' => $defaults->sepa_creditor_id,
 494                                       'src_charset' => 'UTF-8',
 495                                       'message_id'  => $message_id,
 496                                       'grouped'     => 1,
 497                                       'collection'  => $vc eq 'customer',
 498     );
 499
 500   foreach my $item (@items) {
 501     my $requested_execution_date;
 502     my $mandator_id;
 503     if ($item->{requested_execution_date}) {
 504       my ($yy, $mm, $dd)        = $locale->parse_date($myconfig, $item->{requested_execution_date});
 505       $requested_execution_date = sprintf '%04d-%02d-%02d', $yy, $mm, $dd;
 506     }
 507
 508     if ($vc eq 'customer') {
 509       my ($yy, $mm, $dd)      = $locale->parse_date($myconfig, $item->{reference_date});
 510       $item->{reference_date} = sprintf '%04d-%02d-%02d', $yy, $mm, $dd;
 511       $mandator_id = $item->{mandator_id};
 512       if ($item->{mandate_date_of_signature}) {
 513         ($yy, $mm, $dd)                    = $locale->parse_date($myconfig, $item->{mandate_date_of_signature});
 514         $item->{mandate_date_of_signature} = sprintf '%04d-%02d-%02d', $yy, $mm, $dd;
 515       }
 516     }
 517
 518     $sepa_xml->add_transaction({ 'src_iban'       => $item->{our_iban},
 519                                  'src_bic'        => $item->{our_bic},
 520                                  'dst_iban'       => $item->{vc_iban},
 521                                  'dst_bic'        => $item->{vc_bic},
 522                                  'company'        => $item->{vc_name},
 523                                  'company_number' => $item->{vc_number},
 524                                  'amount'         => $item->{amount},
 525                                  'reference'      => $item->{reference},
 526                                  'mandator_id'    => $mandator_id,
 527                                  'reference_date' => $item->{reference_date},
 528                                  'execution_date' => $requested_execution_date,
 529                                  'end_to_end_id'  => $item->{end_to_end_id},
 530                                  'date_of_signature' => $item->{mandate_date_of_signature}, });
 531   }
 532
 533   my $xml = $sepa_xml->to_xml();
 534
 535   print $cgi->header('-type'                => 'application/octet-stream',
 536                      '-content-disposition' => 'attachment; filename="SEPA_' . $message_id . ($vc eq 'customer' ? '.cdd' : '.cct') . '"',
 537                      '-content-length'      => length $xml);
 538   print $xml;
 539
 540   $main::lxdebug->leave_sub();
 541 }
 542
 543 sub bank_transfer_mark_as_closed_step1 {
 544   $main::lxdebug->enter_sub();
 545
 546   my $form       = $main::form;
 547   my $locale     = $main::locale;
 548   my $vc         = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
 549
 550   my @export_ids = map { $_->{id} } grep { $_->{selected} } @{ $form->{exports} || [] };
 551
 552   if (!@export_ids) {
 553     $form->show_generic_error($locale->text('You have not selected any export.'), 'back_button' => 1);
 554   }
 555
 556   my @open_export_ids = ();
 557   foreach my $id (@export_ids) {
 558     my $export = SL::SEPA->retrieve_export('id' => $id, vc => $vc);
 559     push @open_export_ids, $id if (!$export->{closed});
 560   }
 561
 562   if (!@open_export_ids) {
 563     $form->show_generic_error($locale->text('All of the exports you have selected were already closed.'), 'back_button' => 1);
 564   }
 565
 566   $form->{title} = $locale->text('Close SEPA exports');
 567   $form->header();
 568   print $form->parse_html_template('sepa/bank_transfer_mark_as_closed_step1', { 'OPEN_EXPORT_IDS' => \@open_export_ids, vc => $vc });
 569
 570   $main::lxdebug->leave_sub();
 571 }
 572
 573 sub bank_transfer_mark_as_closed_step2 {
 574   $main::lxdebug->enter_sub();
 575
 576   my $form       = $main::form;
 577   my $locale     = $main::locale;
 578
 579   map { SL::SEPA->close_export('id' => $_); } @{ $form->{open_export_ids} || [] };
 580
 581   $form->{title} = $locale->text('Close SEPA exports');
 582   $form->header();
 583   $form->show_generic_information($locale->text('The selected exports have been closed.'));
 584
 585   $main::lxdebug->leave_sub();
 586 }
 587
 588 sub dispatcher {
 589   my $form = $main::form;
 590
 591   foreach my $action (qw(bank_transfer_create bank_transfer_edit bank_transfer_list
 592                          bank_transfer_post_payments bank_transfer_download_sepa_xml
 593                          bank_transfer_mark_as_closed_step1 bank_transfer_mark_as_closed_step2
 594                          bank_transfer_payment_list_as_pdf)) {
 595     if ($form->{"action_${action}"}) {
 596       call_sub($action);
 597       return;
 598     }
 599   }
 600
 601   $form->error($main::locale->text('No action defined.'));
 602 }
 603
 604 1;