bin/mozilla/sepa.pl

   1 use strict;
   2
   3 use List::MoreUtils qw(any none uniq);
   4 use List::Util qw(first);
   5 use POSIX qw(strftime);
   6
   7 use SL::BankAccount;
   8 use SL::Chart;
   9 use SL::CT;
  10 use SL::Form;
  11 use SL::GenericTranslations;
  12 use SL::ReportGenerator;
  13 use SL::SEPA;
  14 use SL::SEPA::XML;
  15
  16 require "bin/mozilla/common.pl";
  17 require "bin/mozilla/reportgenerator.pl";
  18
  19 sub bank_transfer_add {
  20   $main::lxdebug->enter_sub();
  21
  22   my $form          = $main::form;
  23   my $locale        = $main::locale;
  24   my $vc            = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
  25
  26   $form->{title}    = $vc eq 'customer' ? $::locale->text('Prepare bank collection via SEPA XML') : $locale->text('Prepare bank transfer via SEPA XML');
  27
  28   my $bank_accounts = SL::BankAccount->list();
  29
  30   if (!scalar @{ $bank_accounts }) {
  31     $form->error($locale->text('You have not added bank accounts yet.'));
  32   }
  33
  34   my $invoices = SL::SEPA->retrieve_open_invoices(vc => $vc);
  35
  36   if (!scalar @{ $invoices }) {
  37     $form->show_generic_information($locale->text('Either there are no open invoices, or you have already initiated bank transfers ' .
  38                                                   'with the open amounts for those that are still open.'));
  39     $main::lxdebug->leave_sub();
  40     return;
  41   }
  42
  43   my $bank_account_label_sub = sub { $locale->text('Account number #1, bank code #2, #3', $_[0]->{account_number}, $_[0]->{bank_code}, $_[0]->{bank}) };
  44
  45   my $translation_list = GenericTranslations->list(translation_type => 'sepa_remittance_info_pfx');
  46   my %translations     = map { ( ($_->{language_id} || 'default') => $_->{translation} ) } @{ $translation_list };
  47
  48   foreach my $invoice (@{ $invoices }) {
  49     my $prefix                    = $translations{ $invoice->{language_id} } || $translations{default} || $::locale->text('Invoice');
  50     $prefix                      .= ' ' unless $prefix =~ m/ $/;
  51     $invoice->{reference_prefix}  = $prefix;
  52   }
  53
  54   $form->header();
  55   print $form->parse_html_template('sepa/bank_transfer_add',
  56                                    { 'INVOICES'           => $invoices,
  57                                      'BANK_ACCOUNTS'      => $bank_accounts,
  58                                      'bank_account_label' => $bank_account_label_sub,
  59                                      'vc'                 => $vc,
  60                                    });
  61
  62   $main::lxdebug->leave_sub();
  63 }
  64
  65 sub bank_transfer_create {
  66   $main::lxdebug->enter_sub();
  67
  68   my $form          = $main::form;
  69   my $locale        = $main::locale;
  70   my $myconfig      = \%main::myconfig;
  71   my $vc            = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
  72
  73   $form->{title}    = $vc eq 'customer' ? $::locale->text('Create bank collection via SEPA XML') : $locale->text('Create bank transfer via SEPA XML');
  74
  75   my $bank_accounts = SL::BankAccount->list();
  76
  77   if (!scalar @{ $bank_accounts }) {
  78     $form->error($locale->text('You have not added bank accounts yet.'));
  79   }
  80
  81   my $bank_account = first { $form->{bank_account}->{id} == $_->{id} } @{ $bank_accounts };
  82
  83   if (!$bank_account) {
  84     $form->error($locale->text('The selected bank account does not exist anymore.'));
  85   }
  86
  87   my $arap_id        = $vc eq 'customer' ? 'ar_id' : 'ap_id';
  88   my $invoices       = SL::SEPA->retrieve_open_invoices(vc => $vc);
  89
  90   my %invoices_map   = map { $_->{id} => $_ } @{ $invoices };
  91   my @bank_transfers =
  92     map  +{ %{ $invoices_map{ $_->{$arap_id} } }, %{ $_ } },
  93     grep  { $_->{selected} && (0 < $_->{amount}) && $invoices_map{ $_->{$arap_id} } }
  94     map   { $_->{amount} = $form->parse_amount($myconfig, $_->{amount}); $_ }
  95           @{ $form->{bank_transfers} || [] };
  96
  97   if (!scalar @bank_transfers) {
  98     $form->error($locale->text('You have selected none of the invoices.'));
  99   }
 100
 101   my ($vc_bank_info);
 102   my $error_message;
 103
 104   if ($form->{confirmation}) {
 105     $vc_bank_info = { map { $_->{id} => $_ } @{ $form->{vc_bank_info} || [] } };
 106
 107     foreach my $info (values %{ $vc_bank_info }) {
 108       if (any { !$info->{$_} } qw(iban bic)) {
 109         $error_message = $locale->text('The bank information must not be empty.');
 110         last;
 111       }
 112     }
 113   }
 114
 115   if ($error_message || !$form->{confirmation}) {
 116     my @vc_ids                 = uniq map { $_->{"${vc}_id"} } @bank_transfers;
 117     $vc_bank_info            ||= CT->get_bank_info('vc' => $vc,
 118                                                    'id' => \@vc_ids);
 119     my @vc_bank_info           = sort { lc $a->{name} cmp lc $b->{name} } values %{ $vc_bank_info };
 120
 121     my $bank_account_label_sub = sub { $locale->text('Account number #1, bank code #2, #3', $_[0]->{account_number}, $_[0]->{bank_code}, $_[0]->{bank}) };
 122
 123     $form->{jsscript}          = 1;
 124
 125     $form->header();
 126     print $form->parse_html_template('sepa/bank_transfer_create',
 127                                      { 'BANK_TRANSFERS'     => \@bank_transfers,
 128                                        'BANK_ACCOUNTS'      => $bank_accounts,
 129                                        'VC_BANK_INFO'       => \@vc_bank_info,
 130                                        'bank_account'       => $bank_account,
 131                                        'bank_account_label' => $bank_account_label_sub,
 132                                        'error_message'      => $error_message,
 133                                        'vc'                 => $vc,
 134                                      });
 135
 136   } else {
 137     foreach my $bank_transfer (@bank_transfers) {
 138       foreach (qw(iban bic)) {
 139         $bank_transfer->{"vc_${_}"}  = $vc_bank_info->{ $bank_transfer->{"${vc}_id"} }->{$_};
 140         $bank_transfer->{"our_${_}"} = $bank_account->{$_};
 141       }
 142
 143       $bank_transfer->{chart_id} = $bank_account->{chart_id};
 144     }
 145
 146     my $id = SL::SEPA->create_export('employee'       => $form->{login},
 147                                      'bank_transfers' => \@bank_transfers,
 148                                      'vc'             => $vc);
 149
 150     $form->header();
 151     print $form->parse_html_template('sepa/bank_transfer_created', { 'id' => $id, 'vc' => $vc });
 152   }
 153
 154   $main::lxdebug->leave_sub();
 155 }
 156
 157 sub bank_transfer_search {
 158   $main::lxdebug->enter_sub();
 159
 160   my $form   = $main::form;
 161   my $locale = $main::locale;
 162   my $vc     = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
 163
 164   $form->{title}    = $vc eq 'customer' ? $::locale->text('List of bank collections') : $locale->text('List of bank transfers');
 165   $form->{jsscript} = 1;
 166
 167   $form->header();
 168   print $form->parse_html_template('sepa/bank_transfer_search', { vc => $vc });
 169
 170   $main::lxdebug->leave_sub();
 171 }
 172
 173
 174 sub bank_transfer_list {
 175   $main::lxdebug->enter_sub();
 176
 177   my $form   = $main::form;
 178   my $locale = $main::locale;
 179   my $cgi    = $main::cgi;
 180   my $vc     = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
 181
 182   $form->{title}     = $vc eq 'customer' ? $::locale->text('List of bank collections') : $locale->text('List of bank transfers');
 183
 184   $form->{sort}    ||= 'id';
 185   $form->{sortdir}   = '1' if (!defined $form->{sortdir});
 186
 187   $form->{callback}  = build_std_url('action=bank_transfer_list', 'sort', 'sortdir', 'vc');
 188
 189   my %filter         = map  +( $_ => $form->{"f_${_}"} ),
 190                        grep  { $form->{"f_${_}"} }
 191                              (qw(vc invnumber),
 192                               map { ("${_}_date_from", "${_}_date_to") }
 193                                   qw(export requested_execution execution));
 194   $filter{executed}  = $form->{l_executed} ? 1 : 0 if ($form->{l_executed} != $form->{l_not_executed});
 195   $filter{closed}    = $form->{l_closed}   ? 1 : 0 if ($form->{l_open}     != $form->{l_closed});
 196
 197   my $exports        = SL::SEPA->list_exports('filter'    => \%filter,
 198                                               'sortorder' => $form->{sort},
 199                                               'sortdir'   => $form->{sortdir},
 200                                               'vc'        => $vc);
 201
 202   my $open_available = any { !$_->{closed} } @{ $exports };
 203
 204   my $report         = SL::ReportGenerator->new(\%main::myconfig, $form);
 205
 206   my @hidden_vars    = ('vc', grep { m/^[fl]_/ && $form->{$_} } keys %{ $form });
 207
 208   my $href           = build_std_url('action=bank_transfer_list', @hidden_vars);
 209
 210   my %column_defs = (
 211     'selected'    => { 'text' => $cgi->checkbox(-name => 'select_all', -id => 'select_all', -label => ''), },
 212     'id'          => { 'text' => $locale->text('Number'), },
 213     'export_date' => { 'text' => $locale->text('Export date'), },
 214     'employee'    => { 'text' => $locale->text('Employee'), },
 215     'executed'    => { 'text' => $locale->text('Executed'), },
 216     'closed'      => { 'text' => $locale->text('Closed'), },
 217   );
 218
 219   my @columns = qw(selected id export_date employee executed closed);
 220
 221   foreach my $name (qw(id export_date employee executed closed)) {
 222     my $sortdir                 = $form->{sort} eq $name ? 1 - $form->{sortdir} : $form->{sortdir};
 223     $column_defs{$name}->{link} = $href . "&sort=$name&sortdir=$sortdir";
 224   }
 225
 226   $column_defs{selected}->{visible} = $open_available                                ? 'HTML' : 0;
 227   $column_defs{executed}->{visible} = $form->{l_executed} && $form->{l_not_executed} ? 1 : 0;
 228   $column_defs{closed}->{visible}   = $form->{l_closed}   && $form->{l_open}         ? 1 : 0;
 229
 230   my @options = ();
 231   push @options, ($vc eq 'customer' ? $::locale->text('Customer') : $locale->text('Vendor')) . ' : ' . $form->{f_vc} if ($form->{f_vc});
 232   push @options, $locale->text('Invoice number')                . ' : ' . $form->{f_invnumber}                     if ($form->{f_invnumber});
 233   push @options, $locale->text('Export date from')              . ' : ' . $form->{f_export_date_from}              if ($form->{f_export_date_from});
 234   push @options, $locale->text('Export date to')                . ' : ' . $form->{f_export_date_to}                if ($form->{f_export_date_to});
 235   push @options, $locale->text('Requested execution date from') . ' : ' . $form->{f_requested_execution_date_from} if ($form->{f_requested_execution_date_from});
 236   push @options, $locale->text('Requested execution date to')   . ' : ' . $form->{f_requested_execution_date_to}   if ($form->{f_requested_execution_date_to});
 237   push @options, $locale->text('Execution date from')           . ' : ' . $form->{f_execution_date_from}           if ($form->{f_execution_date_from});
 238   push @options, $locale->text('Execution date to')             . ' : ' . $form->{f_execution_date_to}             if ($form->{f_execution_date_to});
 239   push @options, $form->{l_executed} ? $locale->text('executed') : $locale->text('not yet executed')               if ($form->{l_executed} != $form->{l_not_executed});
 240   push @options, $form->{l_closed}   ? $locale->text('closed')   : $locale->text('open')                           if ($form->{l_open}     != $form->{l_closed});
 241
 242   $report->set_options('top_info_text'         => join("\n", @options),
 243                        'raw_top_info_text'     => $form->parse_html_template('sepa/bank_transfer_list_top'),
 244                        'raw_bottom_info_text'  => $form->parse_html_template('sepa/bank_transfer_list_bottom', { 'show_buttons' => $open_available, vc => $vc }),
 245                        'std_column_visibility' => 1,
 246                        'output_format'         => 'HTML',
 247                        'title'                 => $form->{title},
 248                        'attachment_basename'   => $locale->text('banktransfers') . strftime('_%Y%m%d', localtime time),
 249     );
 250   $report->set_options_from_form();
 251
 252   $report->set_columns(%column_defs);
 253   $report->set_column_order(@columns);
 254   $report->set_export_options('bank_transfer_list', @hidden_vars);
 255   $report->set_sort_indicator($form->{sort}, $form->{sortdir});
 256
 257   my $edit_url = build_std_url('action=bank_transfer_edit', 'callback');
 258
 259   foreach my $export (@{ $exports }) {
 260     my $row = { map { $_ => { 'data' => $export->{$_} } } keys %{ $export } };
 261
 262     map { $row->{$_}->{data} = $export->{$_} ? $locale->text('yes') : $locale->text('no') } qw(executed closed);
 263
 264     $row->{id}->{link} = $edit_url . '&id=' . E($export->{id}) . '&vc=' . E($vc);
 265
 266     if (!$export->{closed}) {
 267       $row->{selected}->{raw_data} =
 268           $cgi->hidden(-name => "exports[+].id", -value => $export->{id})
 269         . $cgi->checkbox(-name => "exports[].selected", -value => 1, -label => '');
 270     }
 271
 272     $report->add_data($row);
 273   }
 274
 275   $report->generate_with_headers();
 276
 277   $main::lxdebug->leave_sub();
 278 }
 279
 280 sub bank_transfer_edit {
 281   $main::lxdebug->enter_sub();
 282
 283   my $form   = $main::form;
 284   my $locale = $main::locale;
 285   my $vc     = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
 286
 287   my @ids    = ();
 288   if (!$form->{mode} || ($form->{mode} eq 'single')) {
 289     push @ids, $form->{id};
 290   } else {
 291     @ids = map $_->{id}, grep { $_->{selected} } @{ $form->{exports} || [] };
 292
 293     if (!@ids) {
 294       $form->show_generic_error($locale->text('You have not selected any export.'), 'back_button' => 1);
 295     }
 296   }
 297
 298   my $export;
 299
 300   foreach my $id (@ids) {
 301     my $curr_export = SL::SEPA->retrieve_export('id' => $id, 'details' => 1, 'vc' => $vc);
 302
 303     foreach my $item (@{ $curr_export->{items} }) {
 304       map { $item->{"export_${_}"} = $curr_export->{$_} } grep { !ref $curr_export->{$_} } keys %{ $curr_export };
 305     }
 306
 307     if (!$export) {
 308       $export = $curr_export;
 309     } else {
 310       push @{ $export->{items} }, @{ $curr_export->{items} };
 311     }
 312   }
 313
 314   if ($form->{mode} && ($form->{mode} eq 'multi')) {
 315     $export->{items} = [ grep { !$_->{export_closed} && !$_->{executed} } @{ $export->{items} } ];
 316
 317     if (!@{ $export->{items} }) {
 318       $form->show_generic_error($locale->text('All the selected exports have already been closed, or all of their items have already been executed.'), 'back_button' => 1);
 319     }
 320
 321   } elsif (!$export) {
 322     $form->error($locale->text('That export does not exist.'));
 323   }
 324
 325   $form->{jsscript} = 1;
 326   $form->{title}    = $locale->text('View SEPA export');
 327   $form->header();
 328   print $form->parse_html_template('sepa/bank_transfer_edit',
 329                                    { 'ids'                       => \@ids,
 330                                      'export'                    => $export,
 331                                      'current_date'              => $form->current_date(\%main::myconfig),
 332                                      'show_post_payments_button' => any { !$_->{export_closed} && !$_->{executed} } @{ $export->{items} },
 333                                    });
 334
 335   $main::lxdebug->leave_sub();
 336 }
 337
 338 sub bank_transfer_post_payments {
 339   $main::lxdebug->enter_sub();
 340
 341   my $form   = $main::form;
 342   my $locale = $main::locale;
 343   my $vc     = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
 344
 345   my @items  = grep { $_->{selected} } @{ $form->{items} || [] };
 346
 347   if (!@items) {
 348     $form->show_generic_error($locale->text('You have not selected any item.'), 'back_button' => 1);
 349   }
 350   my @export_ids    = uniq map { $_->{sepa_export_id} } @items;
 351   my %exports       = map { $_ => SL::SEPA->retrieve_export('id' => $_, 'details' => 1, vc => $vc) } @export_ids;
 352   my @items_to_post = ();
 353
 354   foreach my $item (@items) {
 355     my $export = $exports{ $item->{sepa_export_id} };
 356     next if (!$export || $export->{closed} || $export->{executed});
 357
 358     push @items_to_post, $item if (none { ($_->{id} == $item->{id}) && $_->{executed} } @{ $export->{items} });
 359   }
 360
 361   if (!@items_to_post) {
 362     $form->show_generic_error($locale->text('All the selected exports have already been closed, or all of their items have already been executed.'), 'back_button' => 1);
 363   }
 364
 365   if (any { !$_->{execution_date} } @items_to_post) {
 366     $form->show_generic_error($locale->text('You have to specify an execution date for each antry.'), 'back_button' => 1);
 367   }
 368
 369   SL::SEPA->post_payment('items' => \@items_to_post, vc => $vc);
 370
 371   $form->show_generic_information($locale->text('The payments have been posted.'));
 372
 373   $main::lxdebug->leave_sub();
 374 }
 375
 376 sub bank_transfer_payment_list_as_pdf {
 377   $main::lxdebug->enter_sub();
 378
 379   my $form       = $main::form;
 380   my %myconfig   = %main::myconfig;
 381   my $locale     = $main::locale;
 382   my $vc         = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
 383
 384   my @ids        = @{ $form->{items} || [] };
 385   my @export_ids = uniq map { $_->{export_id} } @ids;
 386
 387   $form->show_generic_error($locale->text('Multi mode not supported.'), 'back_button' => 1) if 1 != scalar @export_ids;
 388
 389   my $export = SL::SEPA->retrieve_export('id' => $export_ids[0], 'details' => 1, vc => $vc);
 390   my @items  = ();
 391
 392   foreach my $id (@ids) {
 393     my $item = first { $_->{id} == $id->{id} } @{ $export->{items} };
 394     push @items, $item if $item;
 395   }
 396
 397   $form->show_generic_error($locale->text('No transfers were executed in this export.'), 'back_button' => 1) if 1 > scalar @items;
 398
 399   my $report         =  SL::ReportGenerator->new(\%main::myconfig, $form);
 400
 401   my %column_defs    =  (
 402     'invnumber'      => { 'text' => $locale->text('Invoice'),                                                                  },
 403     'vc_name'        => { 'text' => $vc eq 'customer' ? $locale->text('Customer')         : $locale->text('Vendor'),           },
 404     'our_iban'       => { 'text' => $vc eq 'customer' ? $locale->text('Destination IBAN') : $locale->text('Source IBAN'),      },
 405     'our_bic'        => { 'text' => $vc eq 'customer' ? $locale->text('Destination BIC')  : $locale->text('Source BIC'),       },
 406     'vc_iban'        => { 'text' => $vc eq 'customer' ? $locale->text('Source IBAN')      : $locale->text('Destination IBAN'), },
 407     'vc_bic'         => { 'text' => $vc eq 'customer' ? $locale->text('Source BIC')       : $locale->text('Destination BIC'),  },
 408     'amount'         => { 'text' => $locale->text('Amount'),                                                                   },
 409     'reference'      => { 'text' => $locale->text('Reference'),                                                                },
 410     'execution_date' => { 'text' => $locale->text('Execution date'),                                                           },
 411   );
 412
 413   map { $column_defs{$_}->{align} = 'right' } qw(amount execution_date);
 414
 415   my @columns        =  qw(invnumber vc_name our_iban our_bic vc_iban vc_bic amount reference execution_date);
 416
 417   $report->set_options('std_column_visibility' => 1,
 418                        'output_format'         => 'PDF',
 419                        'title'                 =>  $vc eq 'customer' ? $locale->text('Bank collection payment list for export #1', $export->{id}) : $locale->text('Bank transfer payment list for export #1', $export->{id}),
 420                        'attachment_basename'   => ($vc eq 'customer' ? $locale->text('bank_collection_payment_list_#1', $export->{id}) : $locale->text('bank_transfer_payment_list_#1', $export->{id})) . strftime('_%Y%m%d', localtime time),
 421     );
 422
 423   $report->set_columns(%column_defs);
 424   $report->set_column_order(@columns);
 425
 426   foreach my $item (@items) {
 427     my $row                = { map { $_ => { 'data' => $item->{$_} } } @columns };
 428     $row->{amount}->{data} = $form->format_amount(\%myconfig, $item->{amount}, 2);
 429
 430     $report->add_data($row);
 431   }
 432
 433   $report->generate_with_headers();
 434
 435   $main::lxdebug->leave_sub();
 436 }
 437
 438 # TODO
 439 sub bank_transfer_download_sepa_xml {
 440   $main::lxdebug->enter_sub();
 441
 442   my $form     =  $main::form;
 443   my $myconfig = \%main::myconfig;
 444   my $locale   =  $main::locale;
 445   my $cgi      =  $main::cgi;
 446   my $vc       = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
 447
 448   if (!$myconfig->{company}) {
 449     $form->show_generic_error($locale->text('You have to enter a company name in your user preferences (see the "Program" menu, "Preferences").'), 'back_button' => 1);
 450   }
 451
 452   if (($vc eq 'customer') && !$myconfig->{sepa_creditor_id}) {
 453     $form->show_generic_error($locale->text('You have to enter the SEPA creditor ID in your user preferences (see the "Program" menu, "Preferences").'), 'back_button' => 1);
 454   }
 455
 456   my @ids;
 457   if ($form->{mode} && ($form->{mode} eq 'multi')) {
 458      @ids = map $_->{id}, grep { $_->{selected} } @{ $form->{exports} || [] };
 459
 460   } else {
 461     @ids = ($form->{id});
 462   }
 463
 464   if (!@ids) {
 465     $form->show_generic_error($locale->text('You have not selected any export.'), 'back_button' => 1);
 466   }
 467
 468   my @items = ();
 469
 470   foreach my $id (@ids) {
 471     my $export = SL::SEPA->retrieve_export('id' => $id, 'details' => 1, vc => $vc);
 472     push @items, grep { !$_->{executed} } @{ $export->{items} } if ($export && !$export->{closed});
 473   }
 474
 475   if (!@items) {
 476     $form->show_generic_error($locale->text('All the selected exports have already been closed, or all of their items have already been executed.'), 'back_button' => 1);
 477   }
 478
 479   my $message_id = strftime('MSG%Y%m%d%H%M%S', localtime) . sprintf('%06d', $$);
 480
 481   my $sepa_xml   = SL::SEPA::XML->new('company'     => $myconfig->{company},
 482                                       'creditor_id' => $myconfig->{sepa_creditor_id},
 483                                       'src_charset' => $main::dbcharset || 'ISO-8859-15',
 484                                       'message_id'  => $message_id,
 485                                       'grouped'     => 1,
 486                                       'collection'  => $vc eq 'customer',
 487     );
 488
 489   foreach my $item (@items) {
 490     my $requested_execution_date;
 491     if ($item->{requested_execution_date}) {
 492       my ($yy, $mm, $dd)        = $locale->parse_date($myconfig, $item->{requested_execution_date});
 493       $requested_execution_date = sprintf '%04d-%02d-%02d', $yy, $mm, $dd;
 494     }
 495
 496     if ($vc eq 'customer') {
 497       my ($yy, $mm, $dd)      = $locale->parse_date($myconfig, $item->{reference_date});
 498       $item->{reference_date} = sprintf '%04d-%02d-%02d', $yy, $mm, $dd;
 499     }
 500
 501     $sepa_xml->add_transaction({ 'src_iban'       => $item->{our_iban},
 502                                  'src_bic'        => $item->{our_bic},
 503                                  'dst_iban'       => $item->{vc_iban},
 504                                  'dst_bic'        => $item->{vc_bic},
 505                                  'company'        => $item->{vc_name},
 506                                  'amount'         => $item->{amount},
 507                                  'reference'      => $item->{reference},
 508                                  'reference_date' => $item->{reference_date},
 509                                  'execution_date' => $requested_execution_date,
 510                                  'end_to_end_id'  => $item->{end_to_end_id} });
 511   }
 512
 513   my $xml = $sepa_xml->to_xml();
 514
 515   print $cgi->header('-type'                => 'application/octet-stream',
 516                      '-content-disposition' => 'attachment; filename="SEPA_' . $message_id . ($vc eq 'customer' ? '.cdd' : '.cct') . '"',
 517                      '-content-length'      => length $xml);
 518   print $xml;
 519
 520   $main::lxdebug->leave_sub();
 521 }
 522
 523 sub bank_transfer_mark_as_closed_step1 {
 524   $main::lxdebug->enter_sub();
 525
 526   my $form       = $main::form;
 527   my $locale     = $main::locale;
 528   my $vc         = $form->{vc} eq 'customer' ? 'customer' : 'vendor';
 529
 530   my @export_ids = map { $_->{id} } grep { $_->{selected} } @{ $form->{exports} || [] };
 531
 532   if (!@export_ids) {
 533     $form->show_generic_error($locale->text('You have not selected any export.'), 'back_button' => 1);
 534   }
 535
 536   my @open_export_ids = ();
 537   foreach my $id (@export_ids) {
 538     my $export = SL::SEPA->retrieve_export('id' => $id, vc => $vc);
 539     push @open_export_ids, $id if (!$export->{closed});
 540   }
 541
 542   if (!@open_export_ids) {
 543     $form->show_generic_error($locale->text('All of the exports you have selected were already closed.'), 'back_button' => 1);
 544   }
 545
 546   $form->{title} = $locale->text('Close SEPA exports');
 547   $form->header();
 548   print $form->parse_html_template('sepa/bank_transfer_mark_as_closed_step1', { 'OPEN_EXPORT_IDS' => \@open_export_ids, vc => $vc });
 549
 550   $main::lxdebug->leave_sub();
 551 }
 552
 553 sub bank_transfer_mark_as_closed_step2 {
 554   $main::lxdebug->enter_sub();
 555
 556   my $form       = $main::form;
 557   my $locale     = $main::locale;
 558
 559   map { SL::SEPA->close_export('id' => $_); } @{ $form->{open_export_ids} || [] };
 560
 561   $form->{title} = $locale->text('Close SEPA exports');
 562   $form->header();
 563   $form->show_generic_information($locale->text('The selected exports have been closed.'));
 564
 565   $main::lxdebug->leave_sub();
 566 }
 567
 568 sub dispatcher {
 569   my $form = $main::form;
 570
 571   foreach my $action (qw(bank_transfer_create bank_transfer_edit bank_transfer_list
 572                          bank_transfer_post_payments bank_transfer_download_sepa_xml
 573                          bank_transfer_mark_as_closed_step1 bank_transfer_mark_as_closed_step2
 574                          bank_transfer_payment_list_as_pdf)) {
 575     if ($form->{"action_${action}"}) {
 576       call_sub($action);
 577       return;
 578     }
 579   }
 580
 581   $form->error($main::locale->text('No action defined.'));
 582 }
 583
 584 1;