bin/mozilla/vk.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 2001
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
  28 # MA 02110-1335, USA.
  29 #======================================================================
  30 #
  31 # Sales report
  32 #
  33 #======================================================================
  34
  35 use POSIX qw(strftime);
  36 use List::Util qw(sum first);
  37
  38 use SL::AM;
  39 use SL::DB::Employee;
  40 use SL::VK;
  41 use SL::IS;
  42 use SL::ReportGenerator;
  43 use Data::Dumper;
  44
  45 require "bin/mozilla/common.pl";
  46 require "bin/mozilla/reportgenerator.pl";
  47
  48 use strict;
  49
  50 sub search_invoice {
  51   $main::lxdebug->enter_sub();
  52   $main::auth->assert('ar_transactions | ap_transactions | invoice_edit');
  53
  54   my $form     = $main::form;
  55   my %myconfig = %main::myconfig;
  56   my $locale   = $main::locale;
  57
  58   my ($customer);
  59
  60   $::request->layout->add_javascripts("autocomplete_project.js");
  61
  62   $form->{title}    = $locale->text('Sales Report');
  63
  64   $form->get_lists("departments"     => "ALL_DEPARTMENTS",
  65                    "business_types"  => "ALL_BUSINESS_TYPES",
  66                    "salesmen"        => "ALL_SALESMEN",
  67                    'partsgroup'      => 'ALL_PARTSGROUPS');
  68
  69   $form->{ALL_EMPLOYEES} = SL::DB::Manager::Employee->get_all_sorted;
  70
  71   $form->{CUSTOM_VARIABLES_IC}                  = CVar->get_configs('module' => 'IC');
  72   ($form->{CUSTOM_VARIABLES_FILTER_CODE_IC},
  73    $form->{CUSTOM_VARIABLES_INCLUSION_CODE_IC}) = CVar->render_search_options('variables'      => $form->{CUSTOM_VARIABLES_IC},
  74                                                                            'include_prefix' => 'l_',
  75                                                                            'include_value'  => 'Y');
  76
  77   $form->{CUSTOM_VARIABLES_CT}                  = CVar->get_configs('module' => 'CT');
  78   ($form->{CUSTOM_VARIABLES_FILTER_CODE_CT},
  79    $form->{CUSTOM_VARIABLES_INCLUSION_CODE_CT}) = CVar->render_search_options('variables'      => $form->{CUSTOM_VARIABLES_CT},
  80                                                                            'include_prefix' => 'l_',
  81                                                                            'include_value'  => 'Y');
  82   $form->header;
  83   print $form->parse_html_template('vk/search_invoice', { %myconfig });
  84
  85   $main::lxdebug->leave_sub();
  86 }
  87
  88 sub invoice_transactions {
  89   $main::lxdebug->enter_sub();
  90
  91   $main::auth->assert('ar_transactions | ap_transactions | invoice_edit');
  92
  93   my $form     = $main::form;
  94   my %myconfig = %main::myconfig;
  95   my $locale   = $main::locale;
  96
  97   my ($callback, $href, @columns);
  98
  99   # can't currently be configured from report, empty line between main sortings
 100   my $addemptylines = 1;
 101
 102   # don't add empty lines between mainsort subtotals when only subtotal_mainsort is selected
 103   if ($form->{l_subtotal_mainsort} eq "Y" and not defined $form->{l_headers_mainsort} and not defined $form->{l_headers_subsort} and not defined $form->{l_subtotal_subsort} ) {
 104     $addemptylines = 0
 105   };
 106
 107   if ( $form->{customer} =~ /--/ ) {
 108     # Felddaten kommen aus Dropdownbox
 109     my $dummy;
 110     ($dummy, $form->{customer_id}) = split(/--/, $form->{customer});
 111   }
 112   # if $form->{customer} is empty nothing further happens here
 113
 114   # test for decimalplaces or set to default of 2
 115   $form->{decimalplaces} = 2 unless $form->{decimalplaces} > 0 && $form->{decimalplaces} < 6;
 116
 117   my $cvar_configs_ct = CVar->get_configs('module' => 'CT');
 118   my $cvar_configs_ic = CVar->get_configs('module' => 'IC');
 119
 120 #  report_generator_set_default_sort('transdate', 1);
 121
 122   VK->invoice_transactions(\%myconfig, \%$form);
 123
 124
 125   if ( $form->{mainsort} eq 'month' or $form->{subsort} eq 'month' ) {
 126
 127     # Data already comes out of SELECT statement in correct month order, but
 128     # remove whitespaces (month names are padded) and translate them as early
 129     # as possible
 130
 131     foreach (@{ $form->{AR} }) {
 132       $_->{month} =~ s/\s//g;
 133       $_->{month} = $locale->text($_->{month});
 134     };
 135   };
 136
 137   $form->{title} = $locale->text('Sales Report');
 138
 139   @columns =
 140     qw(description invnumber transdate shipvia customernumber customername partnumber partsgroup country business transdate qty parts_unit weight sellprice sellprice_total discount lastcost lastcost_total marge_total marge_percent employee salesman);
 141
 142   my @includeable_custom_variables = grep { $_->{includeable} } @{ $cvar_configs_ic }, @{ $cvar_configs_ct };
 143   my @searchable_custom_variables  = grep { $_->{searchable} }  @{ $cvar_configs_ic }, @{ $cvar_configs_ct };
 144   my %column_defs_cvars            = map { +"cvar_$_->{name}" => { 'text' => $_->{description} } } @includeable_custom_variables;
 145
 146   push @columns, map { "cvar_$_->{name}" } @includeable_custom_variables;
 147
 148
 149   # pass hidden variables for pdf/csv export
 150   # first with l_ to determine which columns to show
 151   # then with the options for headings (such as transdatefrom, partnumber, ...)
 152   my @hidden_variables  = (qw(l_headers_mainsort l_headers_subsort l_subtotal_mainsort l_subtotal_subsort l_total l_parts l_customername l_customernumber transdatefrom transdateto decimalplaces customer customer_id department_id partnumber partsgroup country business description project_id customernumber salesman employee salesman_id employee_id business_id partsgroup_id mainsort subsort),
 153       "$form->{db}number",
 154       map({ "cvar_$_->{name}" } @searchable_custom_variables),
 155       map { "l_$_" } @columns
 156       );
 157   my @hidden_nondefault = grep({ $form->{$_} } @hidden_variables);
 158   # variables are passed as hiddens, e.g.
 159   # <input type="hidden" name="report_generator_hidden_transdateto" value="21.05.2010">
 160
 161   $href = build_std_url('action=invoice_transactions', grep { $form->{$_} } @hidden_variables);
 162   # href = vk.pl?action=invoice_transactions&l_headers=Y&l_subtotal=Y&l_total=Y&transdatefrom=04.03.2010 ...
 163
 164   my %column_defs = (
 165     'description'             => { 'text' => $locale->text('Description'), },
 166     'partnumber'              => { 'text' => $locale->text('Part Number'), },
 167     'partsgroup'              => { 'text' => $locale->text('Partsgroup'), },
 168     'country'                 => { 'text' => $locale->text('Country'), },
 169     'business'                => { 'text' => $locale->text('Customer type'), },
 170     'employee'                => { 'text' => $locale->text('Employee'), },
 171     'salesman'                => { 'text' => $locale->text('Salesperson'), },
 172     'invnumber'               => { 'text' => $locale->text('Invoice Number'), },
 173     'transdate'               => { 'text' => $locale->text('Invoice Date'), },
 174     'shipvia'                 => { 'text' => $locale->text('Ship via'), },
 175     'qty'                     => { 'text' => $locale->text('Quantity'), },
 176     'parts_unit'              => { 'text' => $locale->text('Base unit'), },
 177     'weight'                  => { 'text' => $locale->text('Weight'), },
 178     'sellprice'               => { 'text' => $locale->text('Sales price'), },
 179     'sellprice_total'         => { 'text' => $locale->text('Sales net amount'), },
 180     'lastcost_total'          => { 'text' => $locale->text('Purchase net amount'), },
 181     'discount'                => { 'text' => $locale->text('Discount'), },
 182     'lastcost'                => { 'text' => $locale->text('Purchase price'), },
 183     'marge_total'             => { 'text' => $locale->text('Sales margin'), },
 184     'marge_percent'           => { 'text' => $locale->text('Sales margin %'), },
 185     'customernumber'          => { 'text' => $locale->text('Customer Number'), },
 186     'customername'            => { 'text' => $locale->text('Customer Name'), },
 187 # add 3 more column_defs so we have a translation for top_info_text
 188     'customer'                => { 'text' => $locale->text('Customer'), },
 189     'part'                    => { 'text' => $locale->text('Part'), },
 190     'month'                   => { 'text' => $locale->text('Month'), },
 191     %column_defs_cvars,
 192   );
 193
 194   map { $column_defs{$_}->{visible} = $form->{"l_$_"} eq 'Y' } @columns;
 195
 196   my %column_alignment = map { $_ => 'right' } qw(lastcost sellprice sellprice_total lastcost_total parts_unit discount marge_total marge_percent qty weight);
 197
 198
 199   # so now the check-box "Description" is only used as switch for part description in invoice-mode
 200   # always fill the column "Description" if we are in Zwischensummenmode
 201   $form->{"l_description"} = "Y" if not defined $form->{"l_parts"};;
 202   map { $column_defs{$_}->{visible} = $form->{"l_${_}"} ? 1 : 0 } @columns;
 203
 204   my @options;
 205
 206   push @options, $locale->text('Description')             . " : $form->{description}"                                                       if $form->{description};
 207   push @options, $locale->text('Customer')                . " : $form->{customer}"                                                          if $form->{customer};
 208   push @options, $locale->text('Customer Number')         . " : $form->{customernumber}"                                                    if $form->{customernumber};
 209   # TODO: only customer id is passed
 210   push @options, $locale->text('Department')              . " : " . SL::DB::Department->new(id => $form->{department_id})->load->description if $form->{department_id};
 211   push @options, $locale->text('Invoice Number')          . " : $form->{invnumber}"                                                         if $form->{invnumber};
 212   push @options, $locale->text('Invoice Date')            . " : $form->{invdate}"                                                           if $form->{invdate};
 213   push @options, $locale->text('Ship via')                . " : $form->{shipvia}"                                                         if $form->{shipvia};
 214   push @options, $locale->text('Part Number')             . " : $form->{partnumber}"                                                        if $form->{partnumber};
 215   push @options, $locale->text('Partsgroup')              . " : " . SL::DB::PartsGroup->new(id => $form->{partsgroup_id})->load->partsgroup if $form->{partsgroup_id};
 216   push @options, $locale->text('Country')                 . " : $form->{country}"                                                           if $form->{country};
 217   push @options, $locale->text('Employee')                . ' : ' . SL::DB::Employee->new(id => $form->{employee_id})->load->name           if $form->{employee_id};
 218   push @options, $locale->text('Salesman')                . ' : ' . SL::DB::Employee->new(id => $form->{salesman_id})->load->name           if $form->{salesman_id};
 219   push @options, $locale->text('Customer type')           . ' : ' . SL::DB::Business->new(id => $form->{business_id})->load->description    if $form->{business_id};
 220   push @options, $locale->text('Order Number')            . " : $form->{ordnumber}"                                                         if $form->{ordnumber};
 221   push @options, $locale->text('Notes')                   . " : $form->{notes}"                                                             if $form->{notes};
 222   push @options, $locale->text('Transaction description') . " : $form->{transaction_description}"                                           if $form->{transaction_description};
 223   push @options, $locale->text('From')                    . " " . $locale->date(\%myconfig, $form->{transdatefrom}, 1)                      if $form->{transdatefrom};
 224   push @options, $locale->text('Bis')                     . " " . $locale->date(\%myconfig, $form->{transdateto}, 1)                        if $form->{transdateto};
 225
 226   my $report = SL::ReportGenerator->new(\%myconfig, $form);
 227
 228   $report->set_options('top_info_text'        => join("\n", $locale->text('Main sorting') . ' : ' . $column_defs{$form->{mainsort}}->{text} , $locale->text('Secondary sorting') . ' : ' . $column_defs{$form->{'subsort'}}->{text}, @options),
 229                        'output_format'        => 'HTML',
 230                        'title'                => $form->{title},
 231                        'attachment_basename'  => $locale->text('Sales Report') . strftime('_%Y%m%d', localtime time),
 232     );
 233   $report->set_options_from_form();
 234   $locale->set_numberformat_wo_thousands_separator(\%myconfig) if lc($report->{options}->{output_format}) eq 'csv';
 235
 236   $report->set_columns(%column_defs);
 237   $report->set_column_order(@columns);
 238
 239   $report->set_export_options('invoice_transactions', @hidden_variables, qw(mainsort sortdir));
 240
 241   $report->set_sort_indicator($form->{mainsort}, $form->{sortdir});
 242
 243   CVar->add_custom_variables_to_report('module'         => 'CT',
 244       'trans_id_field' => 'customerid',
 245       'configs'        => $cvar_configs_ct,
 246       'column_defs'    => \%column_defs,
 247       'data'           => $form->{AR}
 248   );
 249
 250   CVar->add_custom_variables_to_report('module'         => 'IC',
 251       'trans_id_field' => 'parts_id',
 252       'configs'        => $cvar_configs_ic,
 253       'column_defs'    => \%column_defs,
 254       'data'           => $form->{AR}
 255   );
 256
 257   my $num_visible_columns = scalar $report->get_visible_columns;
 258   my %empty_row           = (
 259     description           => {
 260       data                => '',
 261       class               => 'listrowempty',
 262       colspan             => $num_visible_columns,
 263     },
 264   );
 265
 266   # add sort and escape callback, this one we use for the add sub
 267   $form->{callback} = $href .= "&sort=$form->{mainsort}";
 268
 269   # escape callback for href
 270   $callback = $form->escape($href);
 271
 272   my @subtotal_columns = qw(qty weight sellprice sellprice_total lastcost lastcost_total marge_total marge_percent discount);
 273   # Total sum:
 274   # sum of sellprice_total, lastcost_total and marge_total
 275   # average of marge_percent
 276   my @total_columns = qw(sellprice_total lastcost_total marge_total marge_percent );
 277
 278   my %totals     = map { $_ => 0 } @total_columns;
 279   my %subtotals1 = map { $_ => 0 } @subtotal_columns;
 280   my %subtotals2 = map { $_ => 0 } @subtotal_columns;
 281
 282   my $idx = 0;
 283
 284   my $basefactor;
 285   my $all_units = AM->retrieve_all_units();
 286
 287   foreach my $ar (@{ $form->{AR} }) {
 288     $basefactor = $all_units->{$ar->{unit}}->{factor} / $all_units->{$ar->{parts_unit}}->{factor};
 289     $basefactor = 1 unless $basefactor;
 290
 291     $ar->{price_factor} = 1 unless $ar->{price_factor};
 292
 293     # calculate individual sellprice, discount is already accounted for in column sellprice in db
 294
 295     # The sellprice total can be calculated from sellprice or fxsellprice (the
 296     # value that was actually entered in the sellprice field and is always
 297     # stored separately).  However, for fxsellprice this method only works when
 298     # the tax is not included, because otherwise fxsellprice includes the tax
 299     # and there is no simple way to extract the tax rate of the article from
 300     # the big query.
 301     #
 302     # Using fxsellprice is potentially more accurate (certainly for tax
 303     # included), because we can use the same method as is used while the
 304     # invoice is generated.
 305     #
 306     # sellprice however has already been converted to the net value (but
 307     # rounded in the process, which leads to rounding errors when calculating
 308     # the linetotal from the rounded sellprice in the report.  These rounding
 309     # errors can quickly amount to several cents when qty is large)
 310     #
 311     # For calculating sellprice_total from fxsellprice, you would use:
 312     # sellprice_total_including_tax = qty * fxsellprice * (1-discount) /  price_factor * exchangerate
 313     # $ar->{sellprice_total_including_tax} =  $form->round_amount( $ar->{qty} * ( $ar->{fxsellprice} * ( 1 - $ar->{discount} ) ) / $ar->{price_factor}, $form->{"decimalplaces"});
 314
 315     my $sellprice_orig     = $ar->{sellprice};
 316     my $qty_orig           = $ar->{qty};
 317     # adjust sellprice so it reflects the unit sellprice according to price_factor and basefactor
 318     $ar->{sellprice}       = $ar->{sellprice}  / $ar->{price_factor} / $basefactor;
 319     # for sellprice_total use the original amounts
 320     $ar->{sellprice_total} = $form->round_amount( $qty_orig * $sellprice_orig / $ar->{price_factor}, $form->{"decimalplaces"});
 321
 322     my $lastcost_orig      = $ar->{lastcost};
 323     $ar->{lastcost}        = $ar->{lastcost}   / $ar->{price_factor} / $basefactor;
 324     $ar->{lastcost_total}  = $form->round_amount( $qty_orig * $lastcost_orig / $ar->{price_factor}, $form->{"decimalplaces"});
 325
 326     # marge_percent is recalculated, because the value in invoice used to be empty
 327     $ar->{marge_percent} = $ar->{sellprice_total} ? (($ar->{sellprice_total}-$ar->{lastcost_total}) / $ar->{sellprice_total} * 100) : 0;
 328     # also recalculate marge_total
 329     $ar->{marge_total} = $ar->{sellprice_total} ? $ar->{sellprice_total}-$ar->{lastcost_total}  : 0;
 330     $ar->{discount} *= 100;  # format discount value for output, 10% is stored as 0.1 in db
 331
 332     # adjust qty to reflect the qty of the base unit
 333     $ar->{qty} *= $basefactor;
 334
 335     # now $ar->{sellprice} * $ar->{qty} should be the same as $qty_orig * $ar->{qty}
 336
 337     # weight is the still the weight per part, but here we want the total weight
 338     $ar->{weight} *= $ar->{qty};
 339
 340     # Main header
 341     if ( $form->{l_headers_mainsort} eq "Y" && ( $idx == 1 or $ar->{ $form->{'mainsort'} } ne $form->{AR}->[$idx - 1]->{ $form->{'mainsort'} } )) {
 342       my $headerrow = {
 343         # use $emptyname for mainsort header if mainsort is empty
 344         data    => $ar->{$form->{'mainsort'}} || $locale->text('empty'),
 345         class   => "listmainsortheader",
 346         colspan => $num_visible_columns,
 347       };
 348       $report->add_data([ { description => $headerrow } ]);
 349
 350       # add empty row after main header
 351 #      my $emptyheaderrow->{description}->{data} = "";
 352 #      $emptyheaderrow->{description}->{class} = "listmainsortheader";
 353 #      my $emptyheaderrow_set = [ $emptyheaderrow ];
 354 #      $report->add_data($emptyheaderrow_set) if $form->{l_headers} eq "Y";
 355     };
 356
 357     # subsort headers
 358     # special case: subsort headers only makes (aesthetical) sense if we show individual parts
 359     if ((   $idx == 0
 360          or $ar->{ $form->{'subsort'} }  ne $form->{AR}->[$idx - 1]->{ $form->{'subsort'} }
 361          or $ar->{ $form->{'mainsort'} } ne $form->{AR}->[$idx - 1]->{ $form->{'mainsort'} })
 362         && ($form->{l_headers_subsort} eq "Y")
 363         && $form->{l_parts}
 364     ) {
 365       my $headerrow = {
 366         # if subsort name is defined, use that name in header, otherwise use $emptyname
 367         data    => $ar->{$form->{'subsort'}} || $locale->text('empty'),
 368         class   => "listsubsortheader",
 369         colspan => $num_visible_columns,
 370       };
 371       $report->add_data([ { description => $headerrow } ]);
 372     };
 373
 374     map { $subtotals1{$_} += $ar->{$_};
 375           $subtotals2{$_} += $ar->{$_};
 376         } @subtotal_columns;
 377
 378     map { $totals{$_}    += $ar->{$_} } @total_columns;
 379
 380     if ( $subtotals1{qty} != 0 ) {
 381       # calculate averages for subtotals1 and subtotals2
 382       # credited positions reduce both total and qty and thus don't influence average prices
 383       $subtotals1{sellprice} = $subtotals1{sellprice_total} / $subtotals1{qty};
 384       $subtotals1{lastcost}  = $subtotals1{lastcost_total}  / $subtotals1{qty};
 385     } else {
 386       # qty is zero, so we have a special case where each position in subtotal
 387       # group has a corresponding credit note so that the total qty is zero in
 388       # this case we also want the total amounts to be zero, so overwrite them,
 389       # rather than leaving the last value in sellprice/lastcost
 390
 391       $subtotals1{sellprice} = 0;
 392       $subtotals1{lastcost}  = 0;
 393     };
 394
 395     if ( $subtotals2{qty} != 0 ) {
 396       $subtotals2{sellprice} = $subtotals2{sellprice_total} / $subtotals2{qty};
 397       $subtotals2{lastcost}  = $subtotals2{lastcost_total}  / $subtotals2{qty};
 398     } else {
 399       $subtotals2{sellprice} = 0;
 400       $subtotals2{lastcost}  = 0;
 401     };
 402
 403     # marge percent as sums: (sum VK - sum Ertrag) / sum VK
 404     $subtotals1{marge_percent} = $subtotals1{sellprice_total} ? (($subtotals1{sellprice_total} - $subtotals1{lastcost_total}) / $subtotals1{sellprice_total}) * 100 : 0;
 405     $subtotals2{marge_percent} = $subtotals2{sellprice_total} ? (($subtotals2{sellprice_total} - $subtotals2{lastcost_total}) / $subtotals2{sellprice_total}) *100 : 0;
 406
 407     # total marge percent:  (sum VK betrag - sum EK betrag) / sum VK betrag
 408     # is recalculated after each position
 409     $totals{marge_percent}    = $totals{sellprice_total}    ? ( ($totals{sellprice_total} - $totals{lastcost_total}) / $totals{sellprice_total}   ) * 100 : 0;
 410
 411     map { $ar->{$_} = $form->format_amount(\%myconfig, $ar->{$_}, 2) } qw(marge_percent qty);
 412     map { $ar->{$_} = $form->format_amount(\%myconfig, $ar->{$_}, 3) } qw(weight);
 413     map { $ar->{$_} = $form->format_amount(\%myconfig, $ar->{$_}, $form->{"decimalplaces"} )} qw(lastcost sellprice sellprice_total lastcost_total marge_total);
 414
 415     # only show individual lines when l_parts is set, this is useful, if you
 416     # only want to see subtotals and totals
 417
 418     if ($form->{l_parts}) {
 419       my %row = (
 420         map { ($_ => { data => $ar->{$_}, align => $column_alignment{$_} }) } @columns
 421       );
 422
 423       $row{invnumber}->{link} = build_std_url("script=is.pl", 'action=edit') . "&id=" . E($ar->{id}) . "&callback=${callback}";
 424
 425       # use partdescription according to invoice in article mode
 426       $row{description}->{data} = $ar->{invoice_description};
 427
 428       $report->add_data(\%row);
 429     }
 430
 431     # choosing l_subtotal doesn't make a distinction between mainsort and subsort
 432     # if l_subtotal_mainsort is not selected l_subtotal_subsort isn't run either
 433     if (   ($form->{l_subtotal_mainsort} eq 'Y')
 434         && ($form->{l_subtotal_subsort}  eq 'Y')
 435         && (($idx == (scalar @{ $form->{AR} } - 1))   # last element always has a subtotal
 436           || ($ar->{ $form->{'subsort'} } ne $form->{AR}->[$idx + 1]->{ $form->{'subsort'}   })
 437           || ($ar->{ $form->{'mainsort'} } ne $form->{AR}->[$idx + 1]->{ $form->{'mainsort'} })
 438           )) {   # if value that is sorted by changes, print subtotal
 439
 440       $report->add_data(create_subtotal_row_invoice(\%subtotals2, \@columns, \%column_alignment, \@subtotal_columns, $form->{l_parts} ? 'listsubtotal' : undef, $ar->{ $form->{'subsort'} }));
 441       $report->add_data({ %empty_row }) if $form->{l_parts} and $addemptylines;
 442     }
 443
 444     # if last mainsort is reached or mainsort has changed, add mainsort subtotal and empty row
 445     if (   ($form->{l_subtotal_mainsort} eq 'Y')
 446         && ($form->{l_subtotal_mainsort} eq 'Y')
 447         && ($form->{mainsort}            ne $form->{subsort})
 448         && (($idx == (scalar @{ $form->{AR} } - 1))   # last element always has a subtotal
 449             || ($ar->{ $form->{'mainsort'} } ne $form->{AR}->[$idx + 1]->{ $form->{'mainsort'} })
 450             )) {   # if value that is sorted by changes, print subtotal
 451         # subtotal is overridden if mainsort and subsort are equal, don't print
 452         # subtotal line even if it is selected
 453       $report->add_data(create_subtotal_row_invoice(\%subtotals1, \@columns, \%column_alignment, \@subtotal_columns, 'listsubtotal', $ar->{$form->{mainsort}}));
 454       $report->add_data({ %empty_row }) if $addemptylines; # insert empty row after mainsort
 455     }
 456
 457     $idx++;
 458   }
 459   if ( $form->{l_total} eq "Y" ) {
 460     $report->add_separator();
 461     $report->add_data(create_subtotal_row_invoice(\%totals, \@columns, \%column_alignment, \@total_columns, 'listtotal', 'l_total'))
 462   };
 463
 464   $report->generate_with_headers();
 465   $main::lxdebug->leave_sub();
 466 }
 467
 468 sub create_subtotal_row_invoice {
 469   $main::lxdebug->enter_sub();
 470
 471   my ($totals, $columns, $column_alignment, $subtotal_columns, $class, $name) = @_;
 472
 473   my $form     = $main::form;
 474   my %myconfig = %main::myconfig;
 475   my $locale   = $main::locale;
 476
 477   my $row = { map { $_ => { data => '', class => $class, align => $column_alignment->{$_}, } } @{ $columns } };
 478
 479   # set name as "empty" if no value is given, except if we are dealing with the
 480   # absolute total, then just write "Total sum"
 481   # here we assume that no name will be called 'l_total'
 482   $name = $locale->text('empty') unless $name;
 483   if ( $name eq 'l_total' ) {
 484     $row->{description}->{data} = $locale->text('Total sum');
 485   } else {
 486     $row->{description}->{data} = $locale->text('Total') . ' ' . $name;
 487   };
 488
 489   map { $row->{$_}->{data} = $form->format_amount(\%myconfig, $totals->{$_}, 2) } qw(marge_total marge_percent qty);
 490   map { $row->{$_}->{data} = $form->format_amount(\%myconfig, $totals->{$_}, 3) } qw(weight);
 491   map { $row->{$_}->{data} = $form->format_amount(\%myconfig, $totals->{$_}, $form->{decimalplaces}) } qw(lastcost sellprice sellprice_total lastcost_total);
 492
 493
 494   map { $totals->{$_} = 0 } @{ $subtotal_columns };
 495
 496   $main::lxdebug->leave_sub();
 497
 498   return $row;
 499 }
 500
 501 1;