bin/mozilla/vk.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 2001
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  28 #======================================================================
  29 #
  30 # Sales report
  31 #
  32 #======================================================================
  33
  34 use POSIX qw(strftime);
  35 use List::Util qw(sum first);
  36
  37 use SL::AM;
  38 use SL::VK;
  39 use SL::IS;
  40 use SL::ReportGenerator;
  41 use Data::Dumper;
  42
  43 require "bin/mozilla/arap.pl";
  44 require "bin/mozilla/common.pl";
  45 require "bin/mozilla/drafts.pl";
  46 require "bin/mozilla/reportgenerator.pl";
  47
  48 use strict;
  49
  50 sub search_invoice {
  51   $main::lxdebug->enter_sub();
  52   $main::auth->assert('general_ledger | invoice_edit');
  53
  54   my $form     = $main::form;
  55   my %myconfig = %main::myconfig;
  56   my $locale   = $main::locale;
  57
  58   my ($customer, $department);
  59
  60   # setup customer selection
  61   $form->all_vc(\%myconfig, "customer", "AR");
  62
  63   $form->{title}    = $locale->text('Sales Report');
  64   $form->{jsscript} = 1;
  65
  66   $form->get_lists("projects"        => { "key" => "ALL_PROJECTS", "all" => 1 },
  67                    "departments"     => "ALL_DEPARTMENTS",
  68                    "business_types"  => "ALL_BUSINESS_TYPES",
  69                    "salesmen"        => "ALL_SALESMEN",
  70                    'employees'       => 'ALL_EMPLOYEES',
  71                    'partsgroup'      => 'ALL_PARTSGROUPS',
  72                    "customers"       => "ALL_VC");
  73   $form->{CUSTOM_VARIABLES_IC}                  = CVar->get_configs('module' => 'IC');
  74   ($form->{CUSTOM_VARIABLES_FILTER_CODE_IC},
  75    $form->{CUSTOM_VARIABLES_INCLUSION_CODE_IC}) = CVar->render_search_options('variables'      => $form->{CUSTOM_VARIABLES_IC},
  76                                                                            'include_prefix' => 'l_',
  77                                                                            'include_value'  => 'Y');
  78
  79   $form->{CUSTOM_VARIABLES_CT}                  = CVar->get_configs('module' => 'CT');
  80   ($form->{CUSTOM_VARIABLES_FILTER_CODE_CT},
  81    $form->{CUSTOM_VARIABLES_INCLUSION_CODE_CT}) = CVar->render_search_options('variables'      => $form->{CUSTOM_VARIABLES_CT},
  82                                                                            'include_prefix' => 'l_',
  83                                                                            'include_value'  => 'Y');
  84   $form->{vc_keys}   = sub { "$_[0]->{name}--$_[0]->{id}" };
  85   $form->{employee_labels} = sub { $_[0]->{"name"} || $_[0]->{"login"} };
  86   $form->{salesman_labels} = $form->{employee_labels};
  87
  88   $form->header;
  89   print $form->parse_html_template('vk/search_invoice', { %myconfig });
  90
  91   $main::lxdebug->leave_sub();
  92 }
  93
  94 sub invoice_transactions {
  95   $main::lxdebug->enter_sub();
  96
  97   $main::auth->assert('general_ledger | invoice_edit');
  98
  99   my $form     = $main::form;
 100   my %myconfig = %main::myconfig;
 101   my $locale   = $main::locale;
 102
 103   my ($callback, $href, @columns);
 104
 105   # can't currently be configured from report, empty line between main sortings
 106   my $addemptylines = 1;
 107
 108   if ( $form->{customer} =~ /--/ ) {
 109     # Felddaten kommen aus Dropdownbox
 110     ($form->{customername}, $form->{customer_id}) = split(/--/, $form->{customer});
 111   } elsif ($form->{customer}) {
 112     # es wurde ein Wert im Freitextfeld übergeben, auf Eindeutigkeit überprüfen
 113
 114     # check_name wird mit no_select => 1 ausgeführt, ist die Abfrage nicht eindeutig kommt ein Fehler
 115     # und die Abfrage muß erneut ausgeführt werden
 116
 117     # Ohne no_select kommt bei Auswahl des Kunden ein Aufruf von update der ins
 118     # Nichts führt, daher diese Zwischenlösung
 119
 120     &check_name('customer', no_select => 1);
 121
 122     # $form->{customer_id} wurde schon von check_name gesetzt
 123     $form->{customername} = $form->{customer};
 124   };
 125   # ist $form->{customer} leer passiert hier nichts weiter
 126
 127   # decimalplaces überprüfen oder auf Default 2 setzen
 128   $form->{decimalplaces} = 2 unless $form->{decimalplaces} > 0 && $form->{decimalplaces} < 6;
 129
 130   my $cvar_configs_ct = CVar->get_configs('module' => 'CT');
 131   my $cvar_configs_ic = CVar->get_configs('module' => 'IC');
 132
 133 #  report_generator_set_default_sort('transdate', 1);
 134
 135   VK->invoice_transactions(\%myconfig, \%$form);
 136
 137
 138   if ( $form->{mainsort} eq 'month' or $form->{subsort} eq 'month' ) {
 139
 140     # Data already comes out of SELECT statement in correct month order, but
 141     # remove whitespaces (month names are padded) and translate them as early
 142     # as possible
 143
 144     foreach (@{ $form->{AR} }) {
 145       $_->{month} =~ s/\s//g;
 146       $_->{month} = $locale->text($_->{month});
 147     };
 148   };
 149
 150   $form->{title} = $locale->text('Sales Report');
 151
 152   @columns =
 153     qw(description invnumber transdate customernumber customername partnumber partsgroup country business transdate qty parts_unit weight sellprice sellprice_total discount lastcost lastcost_total marge_total marge_percent employee salesman);
 154
 155   my @includeable_custom_variables = grep { $_->{includeable} } @{ $cvar_configs_ic }, @{ $cvar_configs_ct };
 156   my @searchable_custom_variables  = grep { $_->{searchable} }  @{ $cvar_configs_ic }, @{ $cvar_configs_ct };
 157   my %column_defs_cvars            = map { +"cvar_$_->{name}" => { 'text' => $_->{description} } } @includeable_custom_variables;
 158
 159   push @columns, map { "cvar_$_->{name}" } @includeable_custom_variables;
 160
 161
 162   # hidden variables für pdf/csv export übergeben
 163   # einmal mit l_ um zu bestimmen welche Spalten ausgegeben werden sollen
 164   # einmal optionen für die Überschrift (z.B. transdatefrom, partnumber, ...)
 165   my @hidden_variables  = (qw(l_headers_mainsort l_headers_subsort l_subtotal_mainsort l_subtotal_subsort l_total l_parts l_customername l_customernumber transdatefrom transdateto decimalplaces customer customername customer_id department partnumber partsgroup country business description project_id customernumber salesman employee salesman_id employee_id business_id partsgroup_id mainsort subsort),
 166       "$form->{db}number",
 167       map({ "cvar_$_->{name}" } @searchable_custom_variables),
 168       map { "l_$_" } @columns
 169       );
 170   my @hidden_nondefault = grep({ $form->{$_} } @hidden_variables);
 171   # Variablen werden dann als Hidden Variable mitgegeben, z.B.
 172   # <input type="hidden" name="report_generator_hidden_transdateto" value="21.05.2010">
 173
 174   $href = build_std_url('action=invoice_transactions', grep { $form->{$_} } @hidden_variables);
 175   # href = vk.pl?action=invoice_transactions&l_headers=Y&l_subtotal=Y&l_total=Y&transdatefrom=04.03.2010 ...
 176
 177   my %column_defs = (
 178     'description'             => { 'text' => $locale->text('Description'), },
 179     'partnumber'              => { 'text' => $locale->text('Part Number'), },
 180     'partsgroup'              => { 'text' => $locale->text('Group'), },
 181     'country'                 => { 'text' => $locale->text('Country'), },
 182     'business'                => { 'text' => $locale->text('Customer type'), },
 183     'employee'                => { 'text' => $locale->text('Employee'), },
 184     'salesman'                => { 'text' => $locale->text('Salesperson'), },
 185     'invnumber'               => { 'text' => $locale->text('Invoice Number'), },
 186     'transdate'               => { 'text' => $locale->text('Invoice Date'), },
 187     'qty'                     => { 'text' => $locale->text('Quantity'), },
 188     'parts_unit'              => { 'text' => $locale->text('Base unit'), },
 189     'weight'                  => { 'text' => $locale->text('Weight'), },
 190     'sellprice'               => { 'text' => $locale->text('Sales price'), },
 191     'sellprice_total'         => { 'text' => $locale->text('Sales net amount'), },
 192     'lastcost_total'          => { 'text' => $locale->text('Purchase net amount'), },
 193     'discount'                => { 'text' => $locale->text('Discount'), },
 194     'lastcost'                => { 'text' => $locale->text('Purchase price'), },
 195     'marge_total'             => { 'text' => $locale->text('Sales margin'), },
 196     'marge_percent'           => { 'text' => $locale->text('Sales margin %'), },
 197     'customernumber'          => { 'text' => $locale->text('Customer Number'), },
 198     'customername'            => { 'text' => $locale->text('Customer Name'), },
 199 # add 3 more column_defs so we have a translation for top_info_text
 200     'customer'                => { 'text' => $locale->text('Customer'), },
 201     'part'                    => { 'text' => $locale->text('Part'), },
 202     'month'                   => { 'text' => $locale->text('Month'), },
 203     %column_defs_cvars,
 204   );
 205
 206   map { $column_defs{$_}->{visible} = $form->{"l_$_"} eq 'Y' } @columns;
 207
 208   my %column_alignment = map { $_ => 'right' } qw(lastcost sellprice sellprice_total lastcost_total parts_unit discount marge_total marge_percent qty weight);
 209
 210
 211   # so now the check-box "Description" is only used as switch for part description in invoice-mode
 212   # always fill the column "Description" if we are in Zwischensummenmode
 213   $form->{"l_description"} = "Y" if not defined $form->{"l_parts"};;
 214   map { $column_defs{$_}->{visible} = $form->{"l_${_}"} ? 1 : 0 } @columns;
 215
 216   my @options;
 217
 218   push @options, $locale->text('Description')             . " : $form->{description}"                                                       if $form->{description};
 219   push @options, $locale->text('Customer')                . " : $form->{customername}"                                                      if $form->{customer};
 220   push @options, $locale->text('Customer Number')         . " : $form->{customernumber}"                                                    if $form->{customernumber};
 221   # TODO: es wird nur id übergeben
 222   push @options, $locale->text('Department')              . " : " . (split /--/, $form->{department})[0]                                    if $form->{department};
 223   push @options, $locale->text('Invoice Number')          . " : $form->{invnumber}"                                                         if $form->{invnumber};
 224   push @options, $locale->text('Invoice Date')            . " : $form->{invdate}"                                                           if $form->{invdate};
 225   push @options, $locale->text('Part Number')             . " : $form->{partnumber}"                                                        if $form->{partnumber};
 226   push @options, $locale->text('Group')                   . " : " . SL::DB::PartsGroup->new(id => $form->{partsgroup_id})->load->partsgroup if $form->{partsgroup_id};
 227   push @options, $locale->text('Country')                 . " : $form->{country}"                                                           if $form->{country};
 228   push @options, $locale->text('Employee')                . ' : ' . SL::DB::Employee->new(id => $form->{employee_id})->load->name           if $form->{employee_id};
 229   push @options, $locale->text('Salesman')                . ' : ' . SL::DB::Employee->new(id => $form->{salesman_id})->load->name           if $form->{salesman_id};
 230   push @options, $locale->text('Customer type')           . ' : ' . SL::DB::Business->new(id => $form->{business_id})->load->description    if $form->{business_id};
 231   push @options, $locale->text('Order Number')            . " : $form->{ordnumber}"                                                         if $form->{ordnumber};
 232   push @options, $locale->text('Notes')                   . " : $form->{notes}"                                                             if $form->{notes};
 233   push @options, $locale->text('Transaction description') . " : $form->{transaction_description}"                                           if $form->{transaction_description};
 234   push @options, $locale->text('From')                    . " " . $locale->date(\%myconfig, $form->{transdatefrom}, 1)                      if $form->{transdatefrom};
 235   push @options, $locale->text('Bis')                     . " " . $locale->date(\%myconfig, $form->{transdateto}, 1)                        if $form->{transdateto};
 236
 237   my $report = SL::ReportGenerator->new(\%myconfig, $form);
 238
 239   $report->set_options('top_info_text'        => join("\n", $locale->text('Main sorting') . ' : ' . $column_defs{$form->{mainsort}}->{text} , $locale->text('Secondary sorting') . ' : ' . $column_defs{$form->{'subsort'}}->{text}, @options),
 240                        'output_format'        => 'HTML',
 241                        'title'                => $form->{title},
 242                        'attachment_basename'  => $locale->text('Sales Report') . strftime('_%Y%m%d', localtime time),
 243     );
 244   $report->set_options_from_form();
 245   $locale->set_numberformat_wo_thousands_separator(\%myconfig) if lc($report->{options}->{output_format}) eq 'csv';
 246
 247   $report->set_columns(%column_defs);
 248   $report->set_column_order(@columns);
 249
 250   $report->set_export_options('invoice_transactions', @hidden_variables, qw(mainsort sortdir));
 251
 252   $report->set_sort_indicator($form->{mainsort}, $form->{sortdir});
 253
 254   CVar->add_custom_variables_to_report('module'         => 'CT',
 255       'trans_id_field' => 'customerid',
 256       'configs'        => $cvar_configs_ct,
 257       'column_defs'    => \%column_defs,
 258       'data'           => $form->{AR}
 259   );
 260
 261   CVar->add_custom_variables_to_report('module'         => 'IC',
 262       'trans_id_field' => 'parts_id',
 263       'configs'        => $cvar_configs_ic,
 264       'column_defs'    => \%column_defs,
 265       'data'           => $form->{AR}
 266   );
 267
 268   my $num_visible_columns = scalar $report->get_visible_columns;
 269   my %empty_row           = (
 270     description           => {
 271       data                => '',
 272       class               => 'listrowempty',
 273       colspan             => $num_visible_columns,
 274     },
 275   );
 276
 277   # add sort and escape callback, this one we use for the add sub
 278   $form->{callback} = $href .= "&sort=$form->{mainsort}";
 279
 280   # escape callback for href
 281   $callback = $form->escape($href);
 282
 283   my @subtotal_columns = qw(qty weight sellprice sellprice_total lastcost lastcost_total marge_total marge_percent discount);
 284   # Gesamtsumme:
 285   # Summe von sellprice_total, lastcost_total und marge_total
 286   # Durchschnitt von marge_percent
 287   my @total_columns = qw(sellprice_total lastcost_total marge_total marge_percent );
 288
 289   my %totals     = map { $_ => 0 } @total_columns;
 290   my %subtotals1 = map { $_ => 0 } @subtotal_columns;
 291   my %subtotals2 = map { $_ => 0 } @subtotal_columns;
 292
 293   my $idx = 0;
 294
 295   my $basefactor;
 296   my $all_units = AM->retrieve_all_units();
 297
 298   foreach my $ar (@{ $form->{AR} }) {
 299     $basefactor = $all_units->{$ar->{unit}}->{factor} / $all_units->{$ar->{parts_unit}}->{factor};
 300     $basefactor = 1 unless $basefactor;
 301
 302     $ar->{price_factor} = 1 unless $ar->{price_factor};
 303     # calculate individual sellprice
 304     # discount was already accounted for in db sellprice
 305     $ar->{sellprice}       = $ar->{sellprice}  / $ar->{price_factor} / $basefactor;
 306     $ar->{lastcost}        = $ar->{lastcost}   / $ar->{price_factor} / $basefactor;
 307     $ar->{sellprice_total} = $form->round_amount( $ar->{qty} * ( $ar->{fxsellprice} * ( 1 - $ar->{discount} ) ) / $ar->{price_factor}, $form->{"decimalplaces"});
 308     $ar->{lastcost_total}  = $form->round_amount( $ar->{qty} * $ar->{lastcost} * $basefactor, $form->{"decimalplaces"});
 309     # marge_percent wird neu berechnet, da Wert in invoice leer ist (Bug)
 310     $ar->{marge_percent} = $ar->{sellprice_total} ? (($ar->{sellprice_total}-$ar->{lastcost_total}) / $ar->{sellprice_total} * 100) : 0;
 311     # marge_total neu berechnen
 312     $ar->{marge_total} = $ar->{sellprice_total} ? $ar->{sellprice_total}-$ar->{lastcost_total}  : 0;
 313     $ar->{discount} *= 100;  # für Ausgabe formatieren, 10% stored as 0.1 in db
 314
 315     #adapt qty to the chosen unit
 316     $ar->{qty} *= $basefactor;
 317
 318     #weight is the still the weight per part, but here we want the total weight
 319     $ar->{weight} *= $ar->{qty};
 320
 321     # Anfangshauptüberschrift
 322     if ( $form->{l_headers_mainsort} eq "Y" && ( $idx == 0 or $ar->{ $form->{'mainsort'} } ne $form->{AR}->[$idx - 1]->{ $form->{'mainsort'} } )) {
 323       my $headerrow = {
 324         # use $emptyname for mainsort header if mainsort is empty
 325         data    => $ar->{$form->{'mainsort'}} || $locale->text('empty'),
 326         class   => "listmainsortheader",
 327         colspan => $num_visible_columns,
 328       };
 329       $report->add_data([ { description => $headerrow } ]);
 330
 331       # add empty row after main header
 332 #      my $emptyheaderrow->{description}->{data} = "";
 333 #      $emptyheaderrow->{description}->{class} = "listmainsortheader";
 334 #      my $emptyheaderrow_set = [ $emptyheaderrow ];
 335 #      $report->add_data($emptyheaderrow_set) if $form->{l_headers} eq "Y";
 336     };
 337
 338     # subsort überschriften
 339     # special case: subsort headers only makes (aesthetical) sense if we show individual parts
 340     if ((   $idx == 0
 341          or $ar->{ $form->{'subsort'} }  ne $form->{AR}->[$idx - 1]->{ $form->{'subsort'} }
 342          or $ar->{ $form->{'mainsort'} } ne $form->{AR}->[$idx - 1]->{ $form->{'mainsort'} })
 343         && ($form->{l_headers_subsort} eq "Y")
 344         && $form->{l_parts}
 345     ) {
 346       my $headerrow = {
 347         # if subsort name is defined, use that name in header, otherwise use $emptyname
 348         data    => $ar->{$form->{'subsort'}} || $locale->text('empty'),
 349         class   => "listsubsortheader",
 350         colspan => $num_visible_columns,
 351       };
 352       $report->add_data([ { description => $headerrow } ]);
 353     };
 354
 355     map { $subtotals1{$_} += $ar->{$_};
 356           $subtotals2{$_} += $ar->{$_};
 357         } @subtotal_columns;
 358
 359     map { $totals{$_}    += $ar->{$_} } @total_columns;
 360
 361     if ( $subtotals1{qty} != 0 ) {
 362       # calculate averages for subtotals1 and subtotals2
 363       # credited positions reduce both total and qty and thus don't influence average prices
 364       $subtotals1{sellprice} = $subtotals1{sellprice_total} / $subtotals1{qty};
 365       $subtotals1{lastcost}  = $subtotals1{lastcost_total}  / $subtotals1{qty};
 366     } else {
 367       # qty is zero, so we have a special case where each position in subtotal
 368       # group has a corresponding credit note so that the total qty is zero in
 369       # this case we also want the total amounts to be zero, so overwrite them,
 370       # rather than leaving the last value in sellprice/lastcost
 371
 372       $subtotals1{sellprice} = 0;
 373       $subtotals1{lastcost}  = 0;
 374     };
 375
 376     if ( $subtotals2{qty} != 0 ) {
 377       $subtotals2{sellprice} = $subtotals2{sellprice_total} / $subtotals2{qty};
 378       $subtotals2{lastcost}  = $subtotals2{lastcost_total}  / $subtotals2{qty};
 379     } else {
 380       $subtotals2{sellprice} = 0;
 381       $subtotals2{lastcost}  = 0;
 382     };
 383
 384     # Ertrag prozentual in den Summen: (summe VK - summe Ertrag) / summe VK
 385     $subtotals1{marge_percent} = $subtotals1{sellprice_total} ? (($subtotals1{sellprice_total} - $subtotals1{lastcost_total}) / $subtotals1{sellprice_total}) * 100 : 0;
 386     $subtotals2{marge_percent} = $subtotals2{sellprice_total} ? (($subtotals2{sellprice_total} - $subtotals2{lastcost_total}) / $subtotals2{sellprice_total}) *100 : 0;
 387
 388     # Ertrag prozentual:  (Summe VK betrag - Summe EK betrag) / Summe VK betrag
 389     # wird laufend bei jeder Position neu berechnet
 390     $totals{marge_percent}    = $totals{sellprice_total}    ? ( ($totals{sellprice_total} - $totals{lastcost_total}) / $totals{sellprice_total}   ) * 100 : 0;
 391
 392     map { $ar->{$_} = $form->format_amount(\%myconfig, $ar->{$_}, 2) } qw(marge_percent qty);
 393     map { $ar->{$_} = $form->format_amount(\%myconfig, $ar->{$_}, 3) } qw(weight);
 394     map { $ar->{$_} = $form->format_amount(\%myconfig, $ar->{$_}, $form->{"decimalplaces"} )} qw(lastcost sellprice sellprice_total lastcost_total marge_total);
 395
 396     # Einzelzeilen nur zeigen wenn l_parts gesetzt ist, nützlich, wenn man nur
 397     # Subtotals und Totals sehen möchte
 398     if ($form->{l_parts}) {
 399       my %row = (
 400         map { ($_ => { data => $ar->{$_}, align => $column_alignment{$_} }) } @columns
 401       );
 402
 403       $row{invnumber}->{link} = build_std_url("script=is.pl", 'action=edit') . "&id=" . E($ar->{id}) . "&callback=${callback}";
 404
 405       $report->add_data(\%row);
 406     }
 407
 408     # hier wird bei l_subtotal nicht differenziert zwischen mainsort und subsort
 409     # macht man l_subtotal_mainsort aus wird l_subtotal_subsort auch nicht ausgeführt
 410     if (   ($form->{l_subtotal_mainsort} eq 'Y')
 411         && ($form->{l_subtotal_subsort}  eq 'Y')
 412         && (($idx == (scalar @{ $form->{AR} } - 1))   # last element always has a subtotal
 413           || ($ar->{ $form->{'subsort'} } ne $form->{AR}->[$idx + 1]->{ $form->{'subsort'}   })
 414           || ($ar->{ $form->{'mainsort'} } ne $form->{AR}->[$idx + 1]->{ $form->{'mainsort'} })
 415           )) {   # if value that is sorted by changes, print subtotal
 416
 417       $report->add_data(create_subtotal_row_invoice(\%subtotals2, \@columns, \%column_alignment, \@subtotal_columns, $form->{l_parts} ? 'listsubtotal' : undef, $ar->{ $form->{'subsort'} }));
 418       $report->add_data({ %empty_row }) if $form->{l_parts} and $addemptylines;
 419     }
 420
 421     # if last mainsort is reached or mainsort has changed, add mainsort subtotal and empty row
 422     if (   ($form->{l_subtotal_mainsort} eq 'Y')
 423         && ($form->{l_subtotal_mainsort} eq 'Y')
 424         && ($form->{mainsort}            ne $form->{subsort})
 425         && (($idx == (scalar @{ $form->{AR} } - 1))   # last element always has a subtotal
 426             || ($ar->{ $form->{'mainsort'} } ne $form->{AR}->[$idx + 1]->{ $form->{'mainsort'} })
 427             )) {   # if value that is sorted by changes, print subtotal
 428         # subtotal is overriden if mainsort and subsort are equal, don't print
 429         # subtotal line even if it is selected
 430       $report->add_data(create_subtotal_row_invoice(\%subtotals1, \@columns, \%column_alignment, \@subtotal_columns, 'listsubtotal', $ar->{$form->{mainsort}}));
 431       $report->add_data({ %empty_row }) if $addemptylines; # insert empty row after mainsort
 432     }
 433
 434     $idx++;
 435   }
 436   if ( $form->{l_total} eq "Y" ) {
 437     $report->add_separator();
 438     $report->add_data(create_subtotal_row_invoice(\%totals, \@columns, \%column_alignment, \@total_columns, 'listtotal', 'l_total'))
 439   };
 440
 441   $report->generate_with_headers();
 442   $main::lxdebug->leave_sub();
 443 }
 444
 445 sub create_subtotal_row_invoice {
 446   $main::lxdebug->enter_sub();
 447
 448   my ($totals, $columns, $column_alignment, $subtotal_columns, $class, $name) = @_;
 449
 450   my $form     = $main::form;
 451   my %myconfig = %main::myconfig;
 452   my $locale   = $main::locale;
 453
 454   my $row = { map { $_ => { data => '', class => $class, align => $column_alignment->{$_}, } } @{ $columns } };
 455
 456   # set name as "empty" if no value is given, except if we are dealing with the
 457   # absolute total, then just write "Total sum"
 458   # here we assume that no name will be called 'l_total'
 459   $name = $locale->text('empty') unless $name;
 460   if ( $name eq 'l_total' ) {
 461     $row->{description}->{data} = $locale->text('Total sum');
 462   } else {
 463     $row->{description}->{data} = $locale->text('Total') . ' ' . $name;
 464   };
 465
 466   map { $row->{$_}->{data} = $form->format_amount(\%myconfig, $totals->{$_}, 2) } qw(marge_total marge_percent qty);
 467   map { $row->{$_}->{data} = $form->format_amount(\%myconfig, $totals->{$_}, 3) } qw(weight);
 468   map { $row->{$_}->{data} = $form->format_amount(\%myconfig, $totals->{$_}, $form->{decimalplaces}) } qw(lastcost sellprice sellprice_total lastcost_total);
 469
 470
 471   map { $totals->{$_} = 0 } @{ $subtotal_columns };
 472
 473   $main::lxdebug->leave_sub();
 474
 475   return $row;
 476 }
 477
 478 1;