bin/mozilla/wh.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #############################################################################
   7 # SQL-Ledger, Accounting
   8 # Copyright (c) 1998-2002
   9 #
  10 #  Author: Dieter Simader
  11 #   Email: dsimader@sql-ledger.org
  12 #     Web: http://www.sql-ledger.org
  13 #
  14 #
  15 # This program is free software; you can redistribute it and/or modify
  16 # it under the terms of the GNU General Public License as published by
  17 # the Free Software Foundation; either version 2 of the License, or
  18 # (at your option) any later version.
  19 #
  20 # This program is distributed in the hope that it will be useful,
  21 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 # GNU General Public License for more details.
  24 # You should have received a copy of the GNU General Public License
  25 # along with this program; if not, write to the Free Software
  26 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  27 #
  28 #######################################################################
  29 #
  30 # warehouse and packinglist
  31 #
  32 #######################################################################
  33
  34 use List::Util qw(min max first);
  35 use POSIX qw(strftime);
  36
  37 use SL::Form;
  38 use SL::User;
  39
  40 use SL::AM;
  41 use SL::CT;
  42 use SL::IC;
  43 use SL::WH;
  44 use SL::OE;
  45 use SL::ReportGenerator;
  46
  47 use SL::DB::Part;
  48
  49 use Data::Dumper;
  50
  51 require "bin/mozilla/common.pl";
  52 require "bin/mozilla/reportgenerator.pl";
  53
  54 use strict;
  55
  56 # parserhappy(R):
  57
  58 # contents of the "transfer_type" table:
  59 #  $locale->text('back')
  60 #  $locale->text('correction')
  61 #  $locale->text('disposed')
  62 #  $locale->text('found')
  63 #  $locale->text('missing')
  64 #  $locale->text('stock')
  65 #  $locale->text('shipped')
  66 #  $locale->text('transfer')
  67 #  $locale->text('used')
  68 #  $locale->text('return_material')
  69 #  $locale->text('release_material')
  70 #  $locale->text('assembled')
  71
  72 # --------------------------------------------------------------------
  73 # Transfer
  74 # --------------------------------------------------------------------
  75
  76 sub transfer_warehouse_selection {
  77   $main::lxdebug->enter_sub();
  78
  79   $main::auth->assert('warehouse_management');
  80
  81   my $form     = $main::form;
  82   my %myconfig = %main::myconfig;
  83   my $locale   = $main::locale;
  84
  85   $form->get_lists('warehouses' => { 'key'    => 'WAREHOUSES',
  86                                      'bins'   => 'BINS', });
  87
  88   show_no_warehouses_error() if (!scalar @{ $form->{WAREHOUSES} });
  89
  90   my $units      = AM->retrieve_units(\%myconfig, $form);
  91
  92   my $part = 0;
  93   if ( $form->{parts_id} ) {
  94     $part = SL::DB::Part->new();
  95     $part->id($form->{parts_id});
  96     $part->load();
  97   }
  98
  99   # der zweite Parameter von unit_select_data gibt den default-Namen (selected) vor
 100   $form->{UNITS} = AM->unit_select_data($units, $form->{unit}, 0, $part ? $part->unit : 0);
 101
 102   if (scalar @{ $form->{WAREHOUSES} }) {
 103     $form->{warehouse_id} ||= $form->{WAREHOUSES}->[0]->{id};
 104     $form->{bin_id}       ||= $form->{WAREHOUSES}->[0]->{BINS}->[0]->{id};
 105   }
 106
 107   my $content;
 108
 109   if ($form->{trans_type} eq 'removal') {
 110     $form->{nextsub} = "removal_parts_selection";
 111     $form->{title}   = $locale->text('Removal from Warehouse');
 112     $content         = $form->parse_html_template('wh/warehouse_selection');
 113
 114   } elsif ($form->{trans_type} eq 'stock') {
 115     $form->{title} = $locale->text('Stock');
 116     $content       = $form->parse_html_template('wh/warehouse_selection_stock');
 117
 118   } elsif (!$form->{trans_type} || ($form->{trans_type} eq 'transfer')) {
 119     $form->{nextsub} = "transfer_parts_selection";
 120     $form->{title}   = $locale->text('Transfer');
 121     $content         = $form->parse_html_template('wh/warehouse_selection');
 122
 123   } elsif ($form->{trans_type} eq 'assembly') {
 124     $form->{title} = $locale->text('Produce Assembly');
 125     $content       = $form->parse_html_template('wh/warehouse_selection_assembly');
 126   }
 127
 128   $form->header();
 129   print $content;
 130
 131   $main::lxdebug->leave_sub();
 132 }
 133
 134 sub transfer_parts_selection {
 135   $main::lxdebug->enter_sub();
 136
 137   $main::auth->assert('warehouse_management');
 138
 139   my $form     = $main::form;
 140   my %myconfig = %main::myconfig;
 141   my $locale   = $main::locale;
 142
 143   transfer_or_removal_prepare_contents('direction' => 'transfer');
 144
 145   $form->{title} = $locale->text('Transfer');
 146   $form->header();
 147   print $form->parse_html_template("wh/transfer_parts_selection");
 148
 149   $main::lxdebug->leave_sub();
 150 }
 151
 152 sub transfer_or_removal_prepare_contents {
 153   $main::lxdebug->enter_sub();
 154
 155   $main::auth->assert('warehouse_management');
 156
 157   my %args = @_;
 158
 159   my $form     = $main::form;
 160   my %myconfig = %main::myconfig;
 161   my $locale   = $main::locale;
 162
 163   $form->get_lists('warehouses' => { 'key'    => 'WAREHOUSES',
 164                                      'bins'   => 'BINS', });
 165
 166   my $warehouse_idx = get_warehouse_idx($form->{warehouse_id});
 167   $form->show_generic_error($locale->text("The selected warehouse does not exist.")) if (-1 == $warehouse_idx);
 168
 169   my $warehouse = $form->{WAREHOUSES}->[$warehouse_idx];
 170
 171   $form->{initial_warehouse_idx} = $warehouse_idx;
 172   $form->{warehouse_description} = $warehouse->{description};
 173   $warehouse->{selected}         = 1;
 174
 175   $form->show_generic_error($locale->text("The source warehouse does not contain any bins.")) if (0 == scalar @{ $warehouse->{BINS} });
 176
 177   map { $form->{"l_$_"} = 'Y' } qw(parts_id qty warehouseid binid partnumber partdescription bindescription chargenumber bestbefore partunit ean);
 178
 179   $form->{sort} = 'bindescription';
 180   my @contents  = WH->get_warehouse_report("warehouse_id" => $form->{warehouse_id},
 181                                            "bin_id"       => $form->{bin_id},
 182                                            "chargenumber" => $form->{chargenumber},
 183                                            "bestbefore"   => $form->{bestbefore},
 184                                            "partnumber"   => $form->{partnumber},
 185                                            "ean"          => $form->{ean},
 186                                            "description"  => $form->{description});
 187
 188   if (0 == scalar(@contents)) {
 189     $form->show_generic_error($locale->text("The selected warehouse is empty, or no stocked items where found that match the filter settings."));
 190   }
 191
 192   my $all_units = AM->retrieve_units(\%myconfig, $form);
 193
 194   foreach (@contents) {
 195     $_->{qty} = $form->format_amount_units('amount'     => $_->{qty},
 196                                            'part_unit'  => $_->{partunit},
 197                                            'conv_units' => 'convertible');
 198     my $this_unit = $_->{partunit};
 199
 200     if ($all_units->{$_->{partunit}} && ($all_units->{g}->{base_unit} eq $all_units->{$_->{partunit}}->{base_unit})) {
 201       $this_unit = "kg";
 202     }
 203
 204     $_->{UNITS} = AM->unit_select_data($all_units, $this_unit, 0, $_->{partunit});
 205   }
 206
 207   my $transfer_types = WH->retrieve_transfer_types($args{direction});
 208   map { $_->{description} = $locale->text($_->{description}) } @{ $transfer_types };
 209
 210   $form->{CONTENTS}       = \@contents;
 211   $form->{TRANSFER_TYPES} = $transfer_types;
 212
 213   $main::lxdebug->leave_sub();
 214 }
 215
 216
 217 sub transfer_parts {
 218   $main::lxdebug->enter_sub();
 219
 220   $main::auth->assert('warehouse_management');
 221
 222   my $form     = $main::form;
 223   my %myconfig = %main::myconfig;
 224   my $locale   = $main::locale;
 225
 226   $form->get_lists('warehouses' => { 'key' => 'WAREHOUSES', 'bins' => 'BINS' });
 227
 228   my $warehouse_idx = get_warehouse_idx($form->{warehouse_id});
 229   $form->show_generic_error($locale->text("The selected warehouse does not exist.")) if (-1 == $warehouse_idx);
 230
 231   my $warehouse = $form->{WAREHOUSES}->[$warehouse_idx];
 232
 233   $form->show_generic_error($locale->text("The source warehouse does not contain any bins.")) if (0 == scalar @{ $warehouse->{BINS} });
 234
 235   map { $form->{"l_$_"} = 'Y' } qw(parts_id qty warehouseid binid partnumber partdescription bindescription chargenumber bestbefore partunit);
 236
 237   $form->{sort} = 'bindescription';
 238   my @contents  = WH->get_warehouse_report("warehouse_id" => $form->{warehouse_id});
 239   my $all_units = AM->retrieve_units(\%myconfig, $form);
 240
 241   my @transfers;
 242
 243   foreach my $row (1 .. $form->{rowcount}) {
 244     $form->{"qty_$row"} =~ s/^\s*//;
 245     $form->{"qty_$row"} =~ s/\s*$//;
 246     next if (!$form->{"qty_$row"});
 247
 248     my $bin_idx = get_bin_idx($warehouse_idx, $form->{"src_bin_id_$row"});
 249     $form->show_generic_error($locale->text("The selected bin does not exist.")) if (-1 == $bin_idx);
 250     my $bin     = $warehouse->{BINS}->[$bin_idx];
 251
 252     my $orig_qty = $form->{"qty_$row"} . " " . $form->{"unit_$row"};
 253
 254     my $transfer = {
 255       'src_warehouse_id' => $form->{warehouse_id},
 256       'transfer_type_id' => $form->{transfer_type_id},
 257     };
 258
 259     map { $transfer->{$_} = $form->{"${_}_${row}"} } qw(src_bin_id chargenumber bestbefore parts_id qty dst_warehouse_id dst_bin_id);
 260
 261     my $entry;
 262
 263     foreach (@contents) {
 264       if (($_->{binid} == $transfer->{src_bin_id}) && ($_->{parts_id} == $transfer->{parts_id}) && ($_->{chargenumber} eq $transfer->{chargenumber}) && $_->{bestbefore} eq $transfer->{bestbefore}) {
 265         $entry = $_;
 266         last;
 267       }
 268     }
 269
 270     if (!$entry) {
 271       $form->error($locale->text("There is not enough left of '#1' in bin '#2' for the removal of #3.",
 272                                  $form->{"partdescription_$row"}, $bin->{description}, $orig_qty));
 273     }
 274
 275     $transfer->{qty}  = $form->parse_amount(\%myconfig, $transfer->{qty}) * $all_units->{$form->{"unit_$row"}}->{factor};
 276     $transfer->{qty} /= $all_units->{$entry->{partunit}}->{factor} || 1;
 277
 278     if (($entry->{qty} < $transfer->{qty}) || (0 >= $transfer->{qty})) {
 279       $form->error($locale->text("There is not enough left of '#1' in bin '#2' for the removal of #3.",
 280                                  $form->{"partdescription_$row"}, $bin->{description}, $orig_qty));
 281     }
 282
 283     $transfer->{comment} = $form->{comment};
 284     $transfer->{change_default_bin} = $form->{change_default_bin};
 285
 286     push @transfers, $transfer;
 287
 288     $entry->{qty} -= $transfer->{qty};
 289   }
 290
 291   if (!scalar @transfers) {
 292     $form->show_generic_information($locale->text('Nothing has been selected for transfer.'));
 293     ::end_of_request();
 294   }
 295
 296   WH->transfer(@transfers);
 297
 298   $form->{trans_type}    = 'transfer';
 299   $form->{saved_message} = $locale->text('The parts have been transferred.');
 300
 301   transfer_warehouse_selection();
 302
 303   $main::lxdebug->leave_sub();
 304 }
 305
 306 # --------------------------------------------------------------------
 307 # Transfer: stock
 308 # --------------------------------------------------------------------
 309
 310 sub transfer_stock_update_part {
 311   $main::lxdebug->enter_sub();
 312
 313   my $form     = $main::form;
 314   my %myconfig = %main::myconfig;
 315   my $locale   = $main::locale;
 316
 317   $form->{trans_type} = 'stock';
 318   $form->{qty}        = $form->parse_amount(\%myconfig, $form->{qty});
 319
 320   if (!$form->{partnumber} && !$form->{description} && !$form->{ean}) {
 321     delete @{$form}{qw(parts_id partunit ean)};
 322     transfer_warehouse_selection();
 323
 324   } elsif (($form->{partnumber} && ($form->{partnumber} ne $form->{old_partnumber})) || $form->{description} || $form->{ean}) {
 325
 326 #    $form->{no_services}   = 1; # services may now be transfered. fix for Bug 1383.
 327     $form->{no_assemblies} = 0; # assemblies duerfen eingelagert werden (z.B. bei retouren)
 328
 329     my $parts = Common->retrieve_parts(\%myconfig, $form, 'description', 1);
 330
 331     if (!scalar @{ $parts }) {
 332       new_item(action => "transfer_stock_update_part");
 333     } elsif (scalar @{ $parts } == 1) {
 334       @{$form}{qw(parts_id partnumber description ean warehouse_id bin_id)} = @{$parts->[0]}{qw(id partnumber description ean warehouse_id bin_id)};
 335       transfer_stock_get_partunit();
 336       transfer_warehouse_selection();
 337
 338     } else {
 339       select_part('transfer_stock_part_selected', @{ $parts });
 340     }
 341
 342   } else {
 343     transfer_stock_get_partunit();
 344     transfer_warehouse_selection();
 345   }
 346
 347   $main::lxdebug->leave_sub();
 348 }
 349
 350 # --------------------------------------------------------------------
 351 # Transfer: assemblies
 352 # Dies ist die Auswahlmaske für ein assembly.
 353 # Die ist einfach von transfer_assembly_update_part kopiert und nur um den trans_type (assembly) korrigiert worden
 354 # Es wäre schön, hier nochmal check_assembly_max_create auf, um die max. Fertigungszahl herauszufinden.
 355 # Ich lass das mal als auskommentierte Idee bestehen jb 18.3.09
 356 # --------------------------------------------------------------------
 357
 358 sub transfer_assembly_update_part {
 359   $main::lxdebug->enter_sub();
 360
 361   my $form     = $main::form;
 362   my %myconfig = %main::myconfig;
 363   my $locale   = $main::locale;
 364
 365   $form->{trans_type} = 'assembly';
 366   $form->{qty}        = $form->parse_amount(\%myconfig, $form->{qty});
 367
 368   if (!$form->{partnumber} && !$form->{description}) {
 369     delete @{$form}{qw(parts_id partunit)};
 370     transfer_warehouse_selection();
 371
 372   } elsif (($form->{partnumber} && ($form->{partnumber} ne $form->{old_partnumber})) || $form->{description}) {
 373     $form->{assemblies} = 1;
 374     $form->{no_assemblies} = 0;
 375     my $parts = Common->retrieve_parts(\%myconfig, $form, 'description', 1);
 376     if (scalar @{ $parts } == 1) {
 377       @{$form}{qw(parts_id partnumber description)} = @{$parts->[0]}{qw(id partnumber description)};
 378       transfer_stock_get_partunit();
 379       transfer_warehouse_selection();
 380     } else {
 381       select_part('transfer_stock_part_selected', @{ $parts });
 382     }
 383
 384   } else {
 385     transfer_stock_get_partunit();
 386     transfer_warehouse_selection();
 387   }
 388
 389 # hier die oben benannte idee
 390 #    my $maxcreate = Common->check_assembly_max_create(assembly_id => $form->{parts_id}, dbh => $my_dbh);
 391   $main::lxdebug->leave_sub();
 392 }
 393
 394 sub transfer_stock_part_selected {
 395   $main::lxdebug->enter_sub();
 396
 397   my $part = shift;
 398
 399   my $form     = $main::form;
 400
 401   @{$form}{qw(parts_id partnumber description ean warehouse_id bin_id)} = @{$part}{qw(id partnumber description ean warehouse_id bin_id)};
 402
 403   transfer_stock_get_partunit();
 404   transfer_warehouse_selection();
 405
 406   $main::lxdebug->leave_sub();
 407 }
 408
 409 sub transfer_stock_get_partunit {
 410   $main::lxdebug->enter_sub();
 411
 412   my $form     = $main::form;
 413
 414   if ($form->{parts_id}) {
 415     my $part_info     = IC->get_basic_part_info('id' => $form->{parts_id});
 416     $form->{partunit} = $part_info->{unit};
 417   }
 418
 419   $main::lxdebug->leave_sub();
 420 }
 421
 422 # vorüberlegung jb 22.2.2009
 423 # wir benötigen für diese funktion, die anzahl die vom erzeugnis hergestellt werden soll. vielleicht direkt per js fehleingaben verhindern?
 424 # ferner dann nochmal mit check_asssembly_max_create gegenprüfen und dann transaktionssicher wegbuchen.
 425 # wir brauchen eine hilfsfunktion, die nee. brauchen wir nicht. der algorithmus läuft genau wie bei check max_create, nur dass hier auch eine lagerbewegung (verbraucht) stattfindet
 426 # Manko ist derzeit noch, dass unterschiedliche Lagerplätze, bzw. das Quelllager an sich nicht ausgewählt werden können.
 427 # Laut Absprache in KW11 09 übernimmt mb hier den rest im April ... jb 18.3.09
 428
 429 sub create_assembly {
 430   $main::lxdebug->enter_sub();
 431
 432   my $form     = $main::form;
 433   my %myconfig = %main::myconfig;
 434   my $locale   = $main::locale;
 435
 436   $form->{qty} = $form->parse_amount(\%myconfig, $form->{qty});
 437   if ($form->{qty} <= 0) {
 438     $form->show_generic_error($locale->text('Invalid quantity.'), 'back_button' => 1);
 439   }
 440   # TODO Es wäre schön, hier schon die maximale Anzahl der zu fertigenden Erzeugnisse zu haben
 441   #else { if ($form->{qty} > $maxcreate) { #s.o.
 442   #     $form->show_generic_error($locale->text('Can not create that quantity with current stock'), 'back_button' => 1);
 443   #     $form->show_generic_error('Maximale Stückzahl' . $maxcreate , 'back_button' => 1);
 444   #   }
 445   #  }
 446
 447   if (!$form->{warehouse_id} || !$form->{bin_id}) {
 448     $form->error($locale->text('The warehouse or the bin is missing.'));
 449   }
 450
 451   if (!$::instance_conf->get_show_bestbefore) {
 452       $form->{bestbefore} = '';
 453   }
 454
 455   # WIESO war das nicht vorher schon ein %HASH?? ein hash ist ein hash! das hat mich mehr als eine Stunde gekostet herauszufinden. grr. jb 3.3.2009
 456   # Anm. jb 18.3. vielleicht auch nur meine unwissenheit in perl-datenstrukturen
 457   my %TRANSFER = (
 458     'transfer_type'    => 'assembly',
 459     'login'            => $::myconfig{login},
 460     'dst_warehouse_id' => $form->{warehouse_id},
 461     'dst_bin_id'       => $form->{bin_id},
 462     'chargenumber'     => $form->{chargenumber},
 463     'bestbefore'       => $form->{bestbefore},
 464     'assembly_id'      => $form->{parts_id},
 465     'qty'              => $form->{qty},
 466     'unit'             => $form->{unit},
 467     'comment'          => $form->{comment}
 468   );
 469
 470   my $ret = WH->transfer_assembly (%TRANSFER);
 471   # Frage: Ich pack in den return-wert auch gleich die Fehlermeldung. Irgendwelche Nummern als Fehlerkonstanten definieren find ich auch nicht besonders schick...
 472   # Ideen? jb 18.3.09
 473   if ($ret ne "1"){
 474     # Die locale-Funktion kann keine Double-Quotes escapen, deswegen hier erstmal so (ein wahrscheinlich immerwährender Hotfix) s.a. Frage davor jb 25.4.09
 475     $form->show_generic_error($ret, 'back_button' => 1);
 476   }
 477
 478   delete @{$form}{qw(parts_id partnumber description qty unit chargenumber bestbefore comment)};
 479
 480   $form->{saved_message} = $locale->text('The assembly has been created.');
 481   $form->{trans_type}    = 'assembly';
 482
 483   transfer_warehouse_selection();
 484
 485   $main::lxdebug->leave_sub();
 486 }
 487
 488 sub transfer_stock {
 489   $main::lxdebug->enter_sub();
 490
 491   my $form     = $main::form;
 492   my %myconfig = %main::myconfig;
 493   my $locale   = $main::locale;
 494
 495   $form->{qty} = $form->parse_amount(\%myconfig, $form->{qty});
 496
 497   if ($form->{qty} <= 0) {
 498     $form->show_generic_error($locale->text('Invalid quantity.'), 'back_button' => 1);
 499   }
 500
 501   if (!$form->{warehouse_id} || !$form->{bin_id}) {
 502     $form->error($locale->text('The warehouse or the bin is missing.'));
 503   }
 504
 505   my $transfer = {
 506     'transfer_type'    => 'stock',
 507     'dst_warehouse_id' => $form->{warehouse_id},
 508     'dst_bin_id'       => $form->{bin_id},
 509     'chargenumber'     => $form->{chargenumber},
 510     'bestbefore'       => $form->{bestbefore},
 511     'parts_id'         => $form->{parts_id},
 512     'qty'              => $form->{qty},
 513     'unit'             => $form->{unit},
 514     'comment'          => $form->{comment},
 515   };
 516
 517   WH->transfer($transfer);
 518
 519   delete @{$form}{qw(parts_id partnumber description qty unit chargenumber bestbefore comment ean)};
 520
 521   $form->{saved_message} = $locale->text('The parts have been stocked.');
 522   $form->{trans_type}    = 'stock';
 523
 524   transfer_warehouse_selection();
 525
 526   $main::lxdebug->leave_sub();
 527 }
 528
 529 # --------------------------------------------------------------------
 530 # Transfer: removal
 531 # --------------------------------------------------------------------
 532
 533 sub removal_parts_selection {
 534   $main::lxdebug->enter_sub();
 535
 536   $main::auth->assert('warehouse_management');
 537
 538   my $form     = $main::form;
 539   my %myconfig = %main::myconfig;
 540   my $locale   = $main::locale;
 541
 542   transfer_or_removal_prepare_contents('direction' => 'out');
 543
 544   $form->{title} = $locale->text('Removal');
 545   $form->header();
 546   print $form->parse_html_template("wh/removal_parts_selection");
 547
 548   $main::lxdebug->leave_sub();
 549 }
 550
 551 sub remove_parts {
 552   $main::lxdebug->enter_sub();
 553
 554   $main::auth->assert('warehouse_management');
 555
 556   my $form     = $main::form;
 557   my %myconfig = %main::myconfig;
 558   my $locale   = $main::locale;
 559
 560   $form->get_lists('warehouses' => { 'key'    => 'WAREHOUSES',
 561                                      'bins'   => 'BINS', });
 562
 563   my $warehouse_idx = get_warehouse_idx($form->{warehouse_id});
 564   $form->show_generic_error($locale->text("The selected warehouse does not exist.")) if (-1 == $warehouse_idx);
 565
 566   my $warehouse = $form->{WAREHOUSES}->[$warehouse_idx];
 567
 568   $form->show_generic_error($locale->text("The warehouse does not contain any bins.")) if (0 == scalar @{ $warehouse->{BINS} });
 569
 570   map { $form->{"l_$_"} = 'Y' } qw(parts_id qty warehouseid binid partnumber partdescription bindescription chargenumber bestbefore partunit);
 571
 572   $form->{sort} = 'bindescription';
 573   my @contents  = WH->get_warehouse_report("warehouse_id" => $form->{warehouse_id});
 574   my $all_units = AM->retrieve_units(\%myconfig, $form);
 575
 576   my @transfers;
 577
 578   foreach my $row (1 .. $form->{rowcount}) {
 579     $form->{"qty_$row"} =~ s/^\s*//;
 580     $form->{"qty_$row"} =~ s/\s*$//;
 581     next if (!$form->{"qty_$row"});
 582
 583     my $bin_idx = get_bin_idx($warehouse_idx, $form->{"src_bin_id_$row"});
 584     $form->show_generic_error($locale->text("The selected bin does not exist.")) if (-1 == $bin_idx);
 585     my $bin     = $warehouse->{BINS}->[$bin_idx];
 586
 587     my $orig_qty = $form->{"qty_$row"} . " " . $form->{"unit_$row"};
 588
 589     my $transfer = {
 590       'src_warehouse_id' => $form->{warehouse_id},
 591       'transfer_type_id' => $form->{transfer_type_id},
 592     };
 593
 594     map { $transfer->{$_} = $form->{"${_}_${row}"} } qw(src_bin_id chargenumber bestbefore parts_id qty);
 595
 596     my $entry;
 597
 598     foreach (@contents) {
 599       if (($_->{binid} == $transfer->{src_bin_id}) && ($_->{parts_id} == $transfer->{parts_id}) && ($_->{chargenumber} eq $transfer->{chargenumber}) && ($_->{bestbefore} eq $transfer->{bestbefore})) {
 600         $entry = $_;
 601         last;
 602       }
 603     }
 604
 605     if (!$entry) {
 606       $form->error($locale->text("There is not enough left of '#1' in bin '#2' for the removal of #3.",
 607                                  $form->{"partdescription_$row"}, $bin->{description}, $orig_qty));
 608     }
 609
 610     $transfer->{qty}  = $form->parse_amount(\%myconfig, $transfer->{qty}) * $all_units->{$form->{"unit_$row"}}->{factor};
 611     $transfer->{qty} /= $all_units->{$entry->{partunit}}->{factor} || 1;
 612
 613     if (($entry->{qty} < $transfer->{qty}) || (0 >= $transfer->{qty})) {
 614       $form->error($locale->text("There is not enough left of '#1' in bin '#2' for the removal of #3.",
 615                                  $form->{"partdescription_$row"}, $bin->{description}, $orig_qty));
 616     }
 617
 618     $transfer->{comment} = $form->{comment};
 619
 620     push @transfers, $transfer;
 621
 622     $entry->{qty} -= $transfer->{qty};
 623   }
 624
 625   if (!scalar @transfers) {
 626     $form->show_generic_information($locale->text('Nothing has been selected for removal.'));
 627     ::end_of_request();
 628   }
 629
 630   WH->transfer(@transfers);
 631
 632   $form->{trans_type}    = 'removal';
 633   $form->{saved_message} = $locale->text('The parts have been removed.');
 634
 635   transfer_warehouse_selection();
 636
 637   $main::lxdebug->leave_sub();
 638 }
 639
 640 # --------------------------------------------------------------------
 641 # Journal
 642 # --------------------------------------------------------------------
 643
 644 sub journal {
 645   $main::lxdebug->enter_sub();
 646
 647   $main::auth->assert('warehouse_management');
 648
 649   my $form     = $main::form;
 650   my %myconfig = %main::myconfig;
 651   my $locale   = $main::locale;
 652
 653   $form->{title} = $locale->text('Report about warehouse transactions');
 654   $form->get_lists('warehouses' => { 'key'  => 'WAREHOUSES',
 655                                      'bins' => 'BINS', });
 656
 657   show_no_warehouses_error() if (!scalar @{ $form->{WAREHOUSES} });
 658
 659   $form->header();
 660   print $form->parse_html_template("wh/journal_filter", { "UNITS" => AM->unit_select_data(AM->retrieve_units(\%myconfig, $form)) });
 661
 662   $main::lxdebug->leave_sub();
 663 }
 664
 665 sub generate_journal {
 666   $main::lxdebug->enter_sub();
 667
 668   $main::auth->assert('warehouse_management');
 669
 670   my $form     = $main::form;
 671   my %myconfig = %main::myconfig;
 672   my $locale   = $main::locale;
 673
 674   $form->{title}   = $locale->text("WHJournal");
 675   $form->{sort}  ||= 'date';
 676
 677   my %filter;
 678   my @columns = qw(trans_id date warehouse_from bin_from warehouse_to bin_to partnumber partdescription chargenumber bestbefore trans_type comment qty employee oe_id projectnumber);
 679
 680   # filter stuff
 681   map { $filter{$_} = $form->{$_} if ($form->{$_}) } qw(warehouse_id bin_id partnumber description chargenumber bestbefore);
 682
 683   $filter{qty_op} = WH->convert_qty_op($form->{qty_op});
 684   if ($filter{qty_op}) {
 685     $form->isblank("qty",      $locale->text('Quantity missing.'));
 686     $form->isblank("qty_unit", $locale->text('Unit missing.'));
 687
 688     $filter{qty}      = $form->{qty};
 689     $filter{qty_unit} = $form->{qty_unit};
 690   }
 691   # /filter stuff
 692
 693   my $report = SL::ReportGenerator->new(\%myconfig, $form);
 694
 695   my @hidden_variables = map { "l_${_}" } @columns;
 696   push @hidden_variables, qw(warehouse_id bin_id partnumber description chargenumber bestbefore qty_op qty qty_unit fromdate todate);
 697
 698   my %column_defs = (
 699     'date'            => { 'text' => $locale->text('Date'), },
 700     'trans_id'        => { 'text' => $locale->text('Trans Id'), },
 701     'trans_type'      => { 'text' => $locale->text('Trans Type'), },
 702     'comment'         => { 'text' => $locale->text('Comment'), },
 703     'warehouse_from'  => { 'text' => $locale->text('Warehouse From'), },
 704     'warehouse_to'    => { 'text' => $locale->text('Warehouse To'), },
 705     'bin_from'        => { 'text' => $locale->text('Bin From'), },
 706     'bin_to'          => { 'text' => $locale->text('Bin To'), },
 707     'partnumber'      => { 'text' => $locale->text('Part Number'), },
 708     'partdescription' => { 'text' => $locale->text('Part Description'), },
 709     'chargenumber'    => { 'text' => $locale->text('Charge Number'), },
 710     'bestbefore'      => { 'text' => $locale->text('Best Before'), },
 711     'qty'             => { 'text' => $locale->text('Qty'), },
 712     'employee'        => { 'text' => $locale->text('Employee'), },
 713     'projectnumber'   => { 'text' => $locale->text('Project Number'), },
 714     'oe_id'           => { 'text' => $locale->text('Document'), },
 715   );
 716
 717   my $href = build_std_url('action=generate_journal', grep { $form->{$_} } @hidden_variables);
 718   map { $column_defs{$_}->{link} = $href . "&sort=${_}&order=" . Q($_ eq $form->{sort} ? 1 - $form->{order} : $form->{order}) } @columns;
 719
 720   my %column_alignment = map { $_ => 'right' } qw(qty);
 721
 722   map { $column_defs{$_}->{visible} = $form->{"l_${_}"} ? 1 : 0 } @columns;
 723
 724   $report->set_columns(%column_defs);
 725   $report->set_column_order(@columns);
 726
 727   $report->set_export_options('generate_journal', @hidden_variables, qw(sort order));
 728
 729   $report->set_sort_indicator($form->{sort}, $form->{order});
 730
 731   $report->set_options('output_format'        => 'HTML',
 732                        'title'                => $form->{title},
 733                        'attachment_basename'  => strftime($locale->text('warehouse_journal_list') . '_%Y%m%d', localtime time));
 734   $report->set_options_from_form();
 735   $locale->set_numberformat_wo_thousands_separator(\%myconfig) if lc($report->{options}->{output_format}) eq 'csv';
 736
 737   my $all_units = AM->retrieve_units(\%myconfig, $form);
 738   my @contents  = WH->get_warehouse_journal(%filter);
 739
 740   my %doc_types = ( 'sales_quotation'         => { script => 'oe', title => $locale->text('Sales quotation') },
 741                     'sales_order'             => { script => 'oe', title => $locale->text('Sales Order') },
 742                     'request_quotation'       => { script => 'oe', title => $locale->text('Request quotation') },
 743                     'purchase_order'          => { script => 'oe', title => $locale->text('Purchase Order') },
 744                     'sales_delivery_order'    => { script => 'do', title => $locale->text('Sales delivery order') },
 745                     'purchase_delivery_order' => { script => 'do', title => $locale->text('Purchase delivery order') },
 746                     'sales_invoice'           => { script => 'is', title => $locale->text('Sales Invoice') },
 747                     'purchase_invoice'        => { script => 'ir', title => $locale->text('Purchase Invoice') },
 748                   );
 749
 750   foreach my $entry (@contents) {
 751     $entry->{qty}        = $form->format_amount_units('amount'     => $entry->{qty},
 752                                                       'part_unit'  => $entry->{partunit},
 753                                                       'conv_units' => 'convertible');
 754     $entry->{trans_type} = $locale->text($entry->{trans_type});
 755
 756     my $row = { };
 757
 758     foreach my $column (@columns) {
 759       $row->{$column} = {
 760         'data'  => $entry->{$column},
 761         'align' => $column_alignment{$column},
 762       };
 763     }
 764
 765     $row->{trans_type}->{raw_data} = $entry->{trans_type};
 766
 767     if ($form->{l_oe_id}) {
 768       $row->{oe_id}->{data} = '';
 769       my $info              = $entry->{oe_id_info};
 770
 771       if ($info && $info->{id} && $info->{type} && $doc_types{$info->{type}}) {
 772         $row->{oe_id} = { data => $doc_types{ $info->{type} }->{title} . ' ' . $info->{number},
 773                           link => build_std_url('script=' . $doc_types{ $info->{type} }->{script} . '.pl', 'action=edit', 'id=' . $info->{id}, 'type=' . $info->{type}) };
 774       }
 775     }
 776
 777     $report->add_data($row);
 778   }
 779
 780   $report->generate_with_headers();
 781
 782   $main::lxdebug->leave_sub();
 783 }
 784
 785 # --------------------------------------------------------------------
 786 # Report
 787 # --------------------------------------------------------------------
 788
 789 sub report {
 790   $main::lxdebug->enter_sub();
 791
 792   $main::auth->assert('warehouse_contents | warehouse_management');
 793
 794   my $form     = $main::form;
 795   my %myconfig = %main::myconfig;
 796   my $locale   = $main::locale;
 797
 798   $form->get_lists('warehouses' => { 'key'    => 'WAREHOUSES',
 799                                      'bins'   => 'BINS', });
 800
 801   show_no_warehouses_error() if (!scalar @{ $form->{WAREHOUSES} });
 802
 803   $form->{title}   = $locale->text("Report about warehouse contents");
 804
 805   $form->header();
 806   print $form->parse_html_template("wh/report_filter",
 807                                    { "nextsub"    => "generate_report",
 808                                      "WAREHOUSES" => $form->{WAREHOUSES},
 809                                      "UNITS"      => AM->unit_select_data(AM->retrieve_units(\%myconfig, $form)) });
 810
 811   $main::lxdebug->leave_sub();
 812 }
 813
 814 sub generate_report {
 815   $main::lxdebug->enter_sub();
 816
 817   $main::auth->assert('warehouse_contents | warehouse_management');
 818
 819   my $form     = $main::form;
 820   my %myconfig = %main::myconfig;
 821   my $locale   = $main::locale;
 822
 823   $form->{title}   = $locale->text("Report about warehouse contents");
 824   $form->{sort}  ||= 'partnumber';
 825   my $sort_col     = $form->{sort};
 826
 827   my %filter;
 828   my @columns = qw(warehousedescription bindescription partnumber partdescription chargenumber bestbefore qty stock_value);
 829
 830   # filter stuff
 831   map { $filter{$_} = $form->{$_} if ($form->{$_}) } qw(warehouse_id bin_id partnumber description chargenumber bestbefore date include_invalid_warehouses);
 832
 833   # show filter stuff also in report
 834   my @options;
 835   # dispatch all options
 836   my $dispatch_options = {
 837    warehouse_id   => sub { push @options, $locale->text('Warehouse') . " : " .
 838                                             SL::DB::Manager::Warehouse->find_by(id => $form->{warehouse_id})->description},
 839    bin_id         => sub { push @options, $locale->text('Bin') . " : " .
 840                                             SL::DB::Manager::Bin->find_by(id => $form->{bin_id})->description},
 841    partnumber     => sub { push @options, $locale->text('Partnumber')     . " : $form->{partnumber}"},
 842    description    => sub { push @options, $locale->text('Description')    . " : $form->{description}"},
 843    chargenumber   => sub { push @options, $locale->text('Charge Number')  . " : $form->{chargenumber}"},
 844    bestbefore     => sub { push @options, $locale->text('Best Before')    . " : $form->{bestbefore}"},
 845    date           => sub { push @options, $locale->text('Date')           . " : $form->{date}"},
 846    include_invalid_warehouses    => sub { push @options, $locale->text('Include invalid warehouses ')},
 847   };
 848   foreach (keys %filter) {
 849    $dispatch_options->{$_}->() if $dispatch_options->{$_};
 850   }
 851   # / end show filter stuff also in report
 852
 853   $filter{qty_op} = WH->convert_qty_op($form->{qty_op});
 854   if ($filter{qty_op}) {
 855     $form->isblank("qty",      $locale->text('Quantity missing.'));
 856     $form->isblank("qty_unit", $locale->text('Unit missing.'));
 857
 858     $filter{qty}      = $form->{qty};
 859     $filter{qty_unit} = $form->{qty_unit};
 860   }
 861   # /filter stuff
 862
 863   $form->{subtotal} = '' if (!first { $_ eq $sort_col } qw(partnumber partdescription));
 864
 865   my $report = SL::ReportGenerator->new(\%myconfig, $form);
 866
 867   my @hidden_variables = map { "l_${_}" } @columns;
 868   push @hidden_variables, qw(warehouse_id bin_id partnumber description chargenumber bestbefore qty_op qty qty_unit l_warehousedescription l_bindescription);
 869   push @hidden_variables, qw(include_empty_bins subtotal include_invalid_warehouses date);
 870
 871   my %column_defs = (
 872     'warehousedescription' => { 'text' => $locale->text('Warehouse'), },
 873     'bindescription'       => { 'text' => $locale->text('Bin'), },
 874     'partnumber'           => { 'text' => $locale->text('Part Number'), },
 875     'partdescription'      => { 'text' => $locale->text('Part Description'), },
 876     'chargenumber'         => { 'text' => $locale->text('Charge Number'), },
 877     'bestbefore'           => { 'text' => $locale->text('Best Before'), },
 878     'qty'                  => { 'text' => $locale->text('Qty'), },
 879     'stock_value'          => { 'text' => $locale->text('Stock value'), },
 880   );
 881
 882   my $href = build_std_url('action=generate_report', grep { $form->{$_} } @hidden_variables);
 883   map { $column_defs{$_}->{link} = $href . "&sort=${_}&order=" . Q($_ eq $sort_col ? 1 - $form->{order} : $form->{order}) } @columns;
 884
 885   my %column_alignment = map { $_ => 'right' } qw(qty stock_value);
 886
 887   map { $column_defs{$_}->{visible} = $form->{"l_${_}"} ? 1 : 0 } @columns;
 888
 889   $report->set_columns(%column_defs);
 890   $report->set_column_order(@columns);
 891
 892   $report->set_export_options('generate_report', @hidden_variables, qw(sort order));
 893
 894   $report->set_sort_indicator($sort_col, $form->{order});
 895
 896   $report->set_options('top_info_text'        => join("\n", @options),
 897                        'output_format'        => 'HTML',
 898                        'title'                => $form->{title},
 899                        'attachment_basename'  => strftime($locale->text('warehouse_report_list') . '_%Y%m%d', localtime time));
 900   $report->set_options_from_form();
 901   $locale->set_numberformat_wo_thousands_separator(\%myconfig) if lc($report->{options}->{output_format}) eq 'csv';
 902
 903   my $all_units = AM->retrieve_units(\%myconfig, $form);
 904   my @contents  = WH->get_warehouse_report(%filter);
 905
 906   my $idx       = 0;
 907
 908   my @subtotals_columns = qw(qty stock_value);
 909   my %subtotals         = map { $_ => 0 } @subtotals_columns;
 910
 911   my $total_stock_value = 0;
 912
 913   foreach my $entry (@contents) {
 914     map { $subtotals{$_} += $entry->{$_} } @subtotals_columns;
 915     $total_stock_value   += $entry->{stock_value} * 1;
 916
 917     $entry->{qty}         = $form->format_amount_units('amount'     => $entry->{qty},
 918                                                        'part_unit'  => $entry->{partunit},
 919                                                        'conv_units' => 'convertible');
 920     $entry->{stock_value} = $form->format_amount(\%myconfig, $entry->{stock_value} * 1, 2);
 921
 922     my $row_set = [ { map { $_ => { 'data' => $entry->{$_}, 'align' => $column_alignment{$_} } } @columns } ];
 923
 924     if ( ($form->{subtotal} eq 'Y' && !$form->{report_generator_csv_options_for_import} )
 925         && (($idx == (scalar @contents - 1))
 926             || ($entry->{$sort_col} ne $contents[$idx + 1]->{$sort_col}))) {
 927
 928       my $row = { map { $_ => { 'data' => '', 'class' => 'listsubtotal', 'align' => $column_alignment{$_}, } } @columns };
 929       $row->{qty}->{data}         = $form->format_amount_units('amount'     => $subtotals{qty} * 1,
 930                                                                'part_unit'  => $entry->{partunit},
 931                                                                'conv_units' => 'convertible');
 932       $row->{stock_value}->{data} = $form->format_amount(\%myconfig, $subtotals{stock_value} * 1, 2);
 933
 934       %subtotals                  = map { $_ => 0 } @subtotals_columns;
 935
 936       push @{ $row_set }, $row;
 937     }
 938
 939     $report->add_data($row_set);
 940
 941     $idx++;
 942   }
 943
 944   if ( $column_defs{stock_value}->{visible} && !$form->{report_generator_csv_options_for_import} ) {
 945     $report->add_separator();
 946
 947     my $row                      = { map { $_ => { 'data' => '', 'class' => 'listsubtotal', } } @columns };
 948
 949     my $left_col                 = first { $column_defs{$_}->{visible} } @columns;
 950
 951     $row->{$left_col}->{data}    = $locale->text('Total stock value');
 952     $row->{stock_value}->{data}  = $form->format_amount(\%myconfig, $total_stock_value, 2);
 953     $row->{stock_value}->{align} = 'right';
 954
 955     $report->add_data($row);
 956   }
 957
 958   $report->generate_with_headers();
 959
 960   $main::lxdebug->leave_sub();
 961 }
 962
 963 # --------------------------------------------------------------------
 964 # Utility functions
 965 # --------------------------------------------------------------------
 966
 967 sub show_no_warehouses_error {
 968   $main::lxdebug->enter_sub();
 969
 970   my $form     = $main::form;
 971   my %myconfig = %main::myconfig;
 972   my $locale   = $main::locale;
 973
 974   my $msg = $locale->text('No warehouse has been created yet or the quantity of the bins is not configured yet.') . ' ';
 975
 976   if ($main::auth->check_right($::myconfig{login}, 'config')) {
 977     $msg .= $locale->text('You can create warehouses and bins via the menu "System -> Warehouses".');
 978   } else {
 979     $msg .= $locale->text('Please ask your administrator to create warehouses and bins.');
 980   }
 981
 982   $form->show_generic_error($msg);
 983
 984   $main::lxdebug->leave_sub();
 985 }
 986
 987 sub get_warehouse_idx {
 988   my ($warehouse_id) = @_;
 989
 990   my $form     = $main::form;
 991
 992   for (my $i = 0; $i < scalar @{$form->{WAREHOUSES}}; $i++) {
 993     return $i if ($form->{WAREHOUSES}->[$i]->{id} == $warehouse_id);
 994   }
 995
 996   return -1;
 997 }
 998
 999 sub get_bin_idx {
1000   my ($warehouse_index, $bin_id) = @_;
1001
1002   my $form     = $main::form;
1003
1004   my $warehouse = $form->{WAREHOUSES}->[$warehouse_index];
1005
1006   return -1 if (!$warehouse);
1007
1008   for (my $i = 0; $i < scalar @{ $warehouse->{BINS} }; $i++) {
1009     return $i if ($warehouse->{BINS}->[$i]->{id} == $bin_id);
1010   }
1011
1012   return -1;
1013 }
1014
1015 sub new_item {
1016   $main::lxdebug->enter_sub();
1017   my %params = @_;
1018
1019   my $form     = $main::form;
1020
1021   # change callback
1022   $form->{old_callback} = $form->escape($form->{callback}, 1);
1023   $form->{callback}     = $form->escape("$form->{script}?action=$params{action}", 1);
1024
1025   # save all form variables except action in a previousform variable
1026   my $previousform = join '&', map { my $value = $form->{$_}; $value =~ s/&/%26/; "$_=$value" } grep { !/action/ } keys %$form;
1027   my @HIDDENS = ();
1028
1029 #  push @HIDDENS,      { 'name' => 'previousform', 'value' => $form->escape($previousform, 1) };
1030   push @HIDDENS, map +{ 'name' => $_,             'value' => $form->{$_} }, qw(partnumber description unit vc sellprice ean);
1031   push @HIDDENS,      { 'name' => 'taxaccount2',  'value' => $form->{taxaccounts} };
1032   push @HIDDENS,      { 'name' => 'notes',        'value' => $form->{longdescription} };
1033
1034   $form->header();
1035   print $form->parse_html_template("generic/new_item", { HIDDENS => [ sort { $a->{name} cmp $b->{name} } @HIDDENS ] } );
1036
1037   $main::lxdebug->leave_sub();
1038 }
1039
1040 sub update {
1041   my $form     = $main::form;
1042   call_sub($form->{update_nextsub} || $form->{nextsub});
1043 }
1044
1045 sub continue {
1046   my $form     = $main::form;
1047   call_sub($form->{continue_nextsub} || $form->{nextsub});
1048 }
1049
1050 sub stock {
1051   my $form     = $main::form;
1052   call_sub($form->{stock_nextsub} || $form->{nextsub});
1053 }
1054
1055 1;
1056
1057 __END__
1058
1059 =head1 NAME
1060
1061 bin/mozilla/wh.pl - Warehouse frontend.
1062
1063 =head1 FUNCTIONS
1064
1065 =over 4
1066
1067 =item new_item
1068
1069 call new item dialogue from warehouse masks.
1070
1071 PARAMS:
1072   action  => name of sub to be called when new item is done
1073
1074 =back
1075
1076 =cut