scripts/installation_check.pl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Getopt::Long;
   5 use Pod::Usage;
   6 use Term::ANSIColor;
   7 our $master_templates;
   8 BEGIN {
   9   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
  10   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
  11
  12   # this is a default dir. may be wrong in your installation, change it then
  13   $master_templates = './templates/print/';
  14 }
  15
  16 use SL::InstallationCheck;
  17
  18 my %check;
  19 Getopt::Long::Configure ("bundling");
  20 GetOptions(
  21   "v|verbose"   => \ my $v,
  22   "a|all"       => \ $check{a},
  23   "o|optional!" => \ $check{o},
  24   "d|devel!"    => \ $check{d},
  25   "l|latex!"    => \ $check{l},
  26   "r|required!" => \ $check{r},
  27   "h|help"      => sub { pod2usage(-verbose => 2) },
  28   "c|color!"    => \ ( my $c = 1 ),
  29 );
  30
  31 # if notihing is requested check "required"
  32 $check{r} = 1 unless defined $check{a} ||
  33                      defined $check{l} ||
  34                      defined $check{o} ||
  35                      defined $check{d};
  36
  37 if ($check{a}) {
  38   foreach my $check (keys %check) {
  39     $check{$check} = 1 unless defined $check{$check};
  40   }
  41 }
  42
  43
  44 $| = 1;
  45
  46 if ($check{r}) {
  47   print_header('Checking Required Modules');
  48   check_module($_, required => 1) for @SL::InstallationCheck::required_modules;
  49 }
  50 if ($check{o}) {
  51   print_header('Checking Optional Modules');
  52   check_module($_, optional => 1) for @SL::InstallationCheck::optional_modules;
  53 }
  54 if ($check{d}) {
  55   print_header('Checking Developer Modules');
  56   check_module($_, devel => 1) for @SL::InstallationCheck::developer_modules;
  57 }
  58 if ($check{l}) {
  59   check_latex();
  60 }
  61
  62 sub check_latex {
  63   my ($res) = check_kpsewhich();
  64   print_result("Looking for LaTeX kpsewhich", $res ? ('ok', 'green') : ('NOT ok', 'red'));
  65   if ($res) {
  66     check_template_dir($_) for SL::InstallationCheck::template_dirs($master_templates);
  67   }
  68 }
  69
  70 sub check_template_dir {
  71   my ($dir) = @_;
  72   my $path  = $master_templates . $dir;
  73
  74   print_header("Checking LaTeX Dependencies for Master Templates '$dir'");
  75   kpsewhich($path, 'cls', $_) for SL::InstallationCheck::classes_from_latex($path, '\documentclass');
  76   kpsewhich($path, 'sty', $_) for SL::InstallationCheck::classes_from_latex($path, '\usepackage');
  77 }
  78
  79 our $mastertemplate_path = './templates/print/';
  80
  81 sub check_kpsewhich {
  82   return 1 if SL::InstallationCheck::check_kpsewhich();
  83
  84   print STDERR <<EOL if $v;
  85 +------------------------------------------------------------------------------+
  86   Can't find kpsewhich, is there a proper installed LaTeX?
  87   On Debian you may run "aptitude install texlive-base-bin"
  88 +------------------------------------------------------------------------------+
  89 EOL
  90   return 0;
  91 }
  92
  93 sub kpsewhich {
  94   my ($dw, $type, $package) = @_;
  95   $package =~ s/[^-_0-9A-Za-z]//g;
  96   my $type_desc = $type eq 'cls' ? 'document class' : 'package';
  97
  98   eval { use String::ShellQuote; 1 } or warn "can't load String::ShellQuote" && return;
  99      $dw         = shell_quote $dw;
 100   my $e_package  = shell_quote $package;
 101   my $e_type     = shell_quote $type;
 102
 103   my $exit = system(qq|TEXINPUTS=".:$dw:" kpsewhich $e_package.$e_type > /dev/null|);
 104   my $res  = $exit > 0 ? 0 : 1;
 105
 106   print_result("Looking for LaTeX $type_desc $package", $res);
 107   if (!$res) {
 108     print STDERR <<EOL if $v;
 109 +------------------------------------------------------------------------------+
 110   LaTeX $type_desc $package could not be loaded.
 111
 112   On Debian you may find the needed *.deb package with:
 113     apt-file search $package.$type
 114
 115   Maybe you need to install apt-file first by:
 116     aptitude install apt-file && apt-file update
 117 +------------------------------------------------------------------------------+
 118 EOL
 119   }
 120 }
 121
 122 sub check_module {
 123   my ($module, %role) = @_;
 124
 125   my $line = "Looking for $module->{fullname}";
 126   my ($res, $ver) = SL::InstallationCheck::module_available($module->{"name"}, $module->{version});
 127   if ($res) {
 128     print_line($line, $ver || 'no version', 'green');
 129   } else {
 130     print_result($line, $res);
 131   }
 132
 133
 134   return if $res;
 135
 136   my $needed_text =
 137       $role{optional} ? 'It is OPTIONAL for Lx-Office but RECOMMENDED for improved functionality.'
 138     : $role{required} ? 'It is NEEDED by Lx-Office and must be installed.'
 139     : $role{devel}    ? 'It is OPTIONAL for Lx-Office and only useful for developers.'
 140     :                   'It is not listed as a dependancy yet. Please tell this the developers.';
 141
 142   my @source_texts = module_source_texts($module);
 143   local $" = $/;
 144   print STDERR <<EOL if $v;
 145 +------------------------------------------------------------------------------+
 146   $module->{fullname} could not be loaded.
 147
 148   This module is either too old or not available on your system.
 149   $needed_text
 150
 151   Here are some ideas how to get it:
 152
 153 @source_texts
 154 +------------------------------------------------------------------------------+
 155 EOL
 156 }
 157
 158 sub module_source_texts {
 159   my ($module) = @_;
 160   my @texts;
 161   push @texts, <<EOL;
 162   - You can get it from CPAN:
 163       perl -MCPAN -e "install $module->{name}"
 164 EOL
 165   push @texts, <<EOL if $module->{url};
 166   - You can download it from this URL and install it manually:
 167       $module->{url}
 168 EOL
 169   push @texts, <<EOL if $module->{debian};
 170   - On Debian, Ubuntu and other distros you can install it with apt-get:
 171       sudo apt-get install $module->{debian}
 172     Note: These may be out of date as well if your system is old.
 173 EOL
 174  # TODO: SuSE and Fedora packaging. Windows packaging.
 175
 176   return @texts;
 177 }
 178
 179 sub mycolor {
 180   return $_[0] unless $c;
 181   return colored(@_);
 182 }
 183
 184 sub print_result {
 185   my ($test, $exit) = @_;
 186   if ($exit) {
 187     print_line($test, 'ok', 'green');
 188   } else {
 189     print_line($test, 'NOT ok', 'red');
 190   }
 191 }
 192
 193 sub print_line {
 194   my ($text, $res, $color) = @_;
 195   print $text, " ", ('.' x (78 - length($text) - length($res)));
 196   print mycolor($res, $color);
 197   print "\n";
 198   return;
 199 }
 200
 201 sub print_header {
 202   print $/;
 203   print "$_[0]:", $/;
 204 }
 205
 206 1;
 207
 208 __END__
 209
 210 =encoding UTF-8
 211
 212 =head1 NAME
 213
 214 scripts/installation_check.pl - check Lx-Office dependancies
 215
 216 =head1 SYNOPSIS
 217
 218   scripts/installation_check.pl [OPTION]
 219
 220 =head1 DESCRIPTION
 221
 222 Check dependencys. List all perl modules needed by Lx-Office, probes for them,
 223 and warns if one is not available.  List all LaTeX document classes and
 224 packages needed by Lx-Office master templates, probes for them, and warns if
 225 one is not available.
 226
 227
 228 =head1 OPTIONS
 229
 230 =over 4
 231
 232 =item C<-a, --all>
 233
 234 Probe for all perl modules and all LaTeX master templates.
 235
 236 =item C<-c, --color>
 237
 238 Color output. Default on.
 239
 240 =item C<--no-color>
 241
 242 No color output. Helpful to avoid terminal escape problems.
 243
 244 =item C<-d, --devel>
 245
 246 Probe for perl developer dependancies. (Used for console  and tags file)
 247
 248 =item C<--no-devel>
 249
 250 Don't probe for perl developer dependancies. (Useful in combination with --all)
 251
 252 =item C<-h, --help>
 253
 254 Display this help.
 255
 256 =item C<-o, --optional>
 257
 258 Probe for optional modules.
 259
 260 =item C<--no-optional>
 261
 262 Don't probe for optional perl modules. (Useful in combination with --all)
 263
 264 =item C<-r, --required>
 265
 266 Probe for required perl modules (default).
 267
 268 =item C<--no-required>
 269
 270 Don't probe for required perl modules. (Useful in combination with --all)
 271
 272 =item C<-l. --latex>
 273
 274 Probe for LaTeX documentclasses and packages in master templates.
 275
 276 =item C<--no-latex>
 277
 278 Don't probe for LaTeX document classes and packages in master templates. (Useful in combination with --all)
 279
 280 =item C<-v. --verbose>
 281
 282 Print additional info for missing dependancies
 283
 284 =back
 285
 286 =head1 BUGS, CAVEATS and TODO
 287
 288 =over 4
 289
 290 =item *
 291
 292 Fedora packages not listed yet.
 293
 294 =item *
 295
 296 Not possible yet to generate a combined cpan/apt-get string to install all needed.
 297
 298 =item *
 299
 300 Not able to handle devel cpan modules yet.
 301
 302 =item *
 303
 304 Version requirements not fully tested yet.
 305
 306 =back
 307
 308 =head1 AUTHOR
 309
 310   Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 311   Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 312   Wulf Coulmann E<lt>wulf@coulmann.deE<gt>
 313
 314 =cut