scripts/installation_check.pl

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Getopt::Long;
   5 use Pod::Usage;
   6 use Term::ANSIColor;
   7 our $master_templates;
   8 BEGIN {
   9   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
  10   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
  11
  12   # this is a default dir. may be wrong in your installation, change it then
  13   $master_templates = './templates/print/';
  14 }
  15
  16 use SL::InstallationCheck;
  17
  18 my %check;
  19 Getopt::Long::Configure ("bundling");
  20 GetOptions(
  21   "v|verbose"   => \ my $v,
  22   "a|all"       => \ $check{a},
  23   "o|optional!" => \ $check{o},
  24   "d|devel!"    => \ $check{d},
  25   "l|latex!"    => \ $check{l},
  26   "r|required!" => \ $check{r},
  27   "h|help"      => sub { pod2usage(-verbose => 2) },
  28   "c|color!"    => \ ( my $c = 1 ),
  29 );
  30
  31 # if nothing is requested check "required"
  32 $check{r} = 1 unless defined $check{a} ||
  33                      defined $check{l} ||
  34                      defined $check{o} ||
  35                      defined $check{d};
  36 my $default_run ='1' if $check{r};  # no parameter, therefore print a note after default run
  37 if ($check{a}) {
  38   foreach my $check (keys %check) {
  39     $check{$check} = 1 unless defined $check{$check};
  40   }
  41 }
  42
  43
  44 $| = 1;
  45
  46 if ($check{r}) {
  47   print_header('Checking Required Modules');
  48   check_module($_, required => 1) for @SL::InstallationCheck::required_modules;
  49   print_header('Standard check for required modules done. See additional parameters for more checks (-- help)') if $default_run;
  50 }
  51 if ($check{o}) {
  52   print_header('Checking Optional Modules');
  53   check_module($_, optional => 1) for @SL::InstallationCheck::optional_modules;
  54 }
  55 if ($check{d}) {
  56   print_header('Checking Developer Modules');
  57   check_module($_, devel => 1) for @SL::InstallationCheck::developer_modules;
  58 }
  59 if ($check{l}) {
  60   check_latex();
  61 }
  62
  63 sub check_latex {
  64   my ($res) = check_kpsewhich();
  65   print_result("Looking for LaTeX kpsewhich", $res ? ('ok', 'green') : ('NOT ok', 'red'));
  66   if ($res) {
  67     check_template_dir($_) for SL::InstallationCheck::template_dirs($master_templates);
  68   }
  69 }
  70
  71 sub check_template_dir {
  72   my ($dir) = @_;
  73   my $path  = $master_templates . $dir;
  74
  75   print_header("Checking LaTeX Dependencies for Master Templates '$dir'");
  76   kpsewhich($path, 'cls', $_) for SL::InstallationCheck::classes_from_latex($path, '\documentclass');
  77   kpsewhich($path, 'sty', $_) for SL::InstallationCheck::classes_from_latex($path, '\usepackage');
  78 }
  79
  80 our $mastertemplate_path = './templates/print/';
  81
  82 sub check_kpsewhich {
  83   return 1 if SL::InstallationCheck::check_kpsewhich();
  84
  85   print STDERR <<EOL if $v;
  86 +------------------------------------------------------------------------------+
  87   Can't find kpsewhich, is there a proper installed LaTeX?
  88   On Debian you may run "aptitude install texlive-base-bin"
  89 +------------------------------------------------------------------------------+
  90 EOL
  91   return 0;
  92 }
  93
  94 sub kpsewhich {
  95   my ($dw, $type, $package) = @_;
  96   $package =~ s/[^-_0-9A-Za-z]//g;
  97   my $type_desc = $type eq 'cls' ? 'document class' : 'package';
  98
  99   eval { use String::ShellQuote; 1 } or warn "can't load String::ShellQuote" && return;
 100      $dw         = shell_quote $dw;
 101   my $e_package  = shell_quote $package;
 102   my $e_type     = shell_quote $type;
 103
 104   my $exit = system(qq|TEXINPUTS=".:$dw:" kpsewhich $e_package.$e_type > /dev/null|);
 105   my $res  = $exit > 0 ? 0 : 1;
 106
 107   print_result("Looking for LaTeX $type_desc $package", $res);
 108   if (!$res) {
 109     print STDERR <<EOL if $v;
 110 +------------------------------------------------------------------------------+
 111   LaTeX $type_desc $package could not be loaded.
 112
 113   On Debian you may find the needed *.deb package with:
 114     apt-file search $package.$type
 115
 116   Maybe you need to install apt-file first by:
 117     aptitude install apt-file && apt-file update
 118 +------------------------------------------------------------------------------+
 119 EOL
 120   }
 121 }
 122
 123 sub check_module {
 124   my ($module, %role) = @_;
 125
 126   my $line = "Looking for $module->{fullname}";
 127   my $res = SL::InstallationCheck::module_available($module->{"name"}, $module->{version});
 128   print_result($line, $res);
 129
 130   return if $res;
 131
 132   my $needed_text =
 133       $role{optional} ? 'It is OPTIONAL for Lx-Office but RECOMMENDED for improved functionality.'
 134     : $role{required} ? 'It is NEEDED by Lx-Office and must be installed.'
 135     : $role{devel}    ? 'It is OPTIONAL for Lx-Office and only useful for developers.'
 136     :                   'It is not listed as a dependancy yet. Please tell this the developers.';
 137
 138   my @source_texts = module_source_texts($module);
 139   local $" = $/;
 140   print STDERR <<EOL if $v;
 141 +------------------------------------------------------------------------------+
 142   $module->{fullname} could not be loaded.
 143
 144   This module is either too old or not available on your system.
 145   $needed_text
 146
 147   Here are some ideas how to get it:
 148
 149 @source_texts
 150 +------------------------------------------------------------------------------+
 151 EOL
 152 }
 153
 154 sub module_source_texts {
 155   my ($module) = @_;
 156   my @texts;
 157   push @texts, <<EOL;
 158   - You can get it from CPAN:
 159       perl -MCPAN -e "install $module->{name}"
 160 EOL
 161   push @texts, <<EOL if $module->{url};
 162   - You can download it from this URL and install it manually:
 163       $module->{url}
 164 EOL
 165   push @texts, <<EOL if $module->{debian};
 166   - On Debian, Ubuntu and other distros you can install it with apt-get:
 167       sudo apt-get install $module->{debian}
 168     Note: These may be out of date as well if your system is old.
 169 EOL
 170  # TODO: SuSE and Fedora packaging. Windows packaging.
 171
 172   return @texts;
 173 }
 174
 175 sub mycolor {
 176   return $_[0] unless $c;
 177   return colored(@_);
 178 }
 179
 180 sub print_result {
 181   my ($test, $exit) = @_;
 182   print $test, " ", ('.' x (72 - length $test));
 183   print $exit ? '.... '. mycolor('ok', 'green') : ' '. mycolor('NOT ok', 'red');
 184   print "\n";
 185   return;
 186 }
 187
 188 sub print_header {
 189   print $/;
 190   print "$_[0]:", $/;
 191 }
 192
 193 1;
 194
 195 __END__
 196
 197 =encoding UTF-8
 198
 199 =head1 NAME
 200
 201 scripts/installation_check.pl - check Lx-Office dependancies
 202
 203 =head1 SYNOPSIS
 204
 205   scripts/installation_check.pl [OPTION]
 206
 207 =head1 DESCRIPTION
 208
 209 Check dependencys. List all perl modules needed by Lx-Office, probes for them,
 210 and warns if one is not available.  List all LaTeX document classes and
 211 packages needed by Lx-Office master templates, probes for them, and warns if
 212 one is not available.
 213
 214
 215 =head1 OPTIONS
 216
 217 =over 4
 218
 219 =item C<-a, --all>
 220
 221 Probe for all perl modules and all LaTeX master templates.
 222
 223 =item C<-c, --color>
 224
 225 Color output. Default on.
 226
 227 =item C<--no-color>
 228
 229 No color output. Helpful to avoid terminal escape problems.
 230
 231 =item C<-d, --devel>
 232
 233 Probe for perl developer dependancies. (Used for console  and tags file)
 234
 235 =item C<--no-devel>
 236
 237 Don't probe for perl developer dependancies. (Useful in combination with --all)
 238
 239 =item C<-h, --help>
 240
 241 Display this help.
 242
 243 =item C<-o, --optional>
 244
 245 Probe for optional modules.
 246
 247 =item C<--no-optional>
 248
 249 Don't probe for optional perl modules. (Useful in combination with --all)
 250
 251 =item C<-r, --required>
 252
 253 Probe for required perl modules (default).
 254
 255 =item C<--no-required>
 256
 257 Don't probe for required perl modules. (Useful in combination with --all)
 258
 259 =item C<-l. --latex>
 260
 261 Probe for LaTeX documentclasses and packages in master templates.
 262
 263 =item C<--no-latex>
 264
 265 Don't probe for LaTeX document classes and packages in master templates. (Useful in combination with --all)
 266
 267 =item C<-v. --verbose>
 268
 269 Print additional info for missing dependancies
 270
 271 =back
 272
 273 =head1 BUGS, CAVEATS and TODO
 274
 275 =over 4
 276
 277 =item *
 278
 279 Fedora packages not listed yet.
 280
 281 =item *
 282
 283 Not possible yet to generate a combined cpan/apt-get string to install all needed.
 284
 285 =item *
 286
 287 Not able to handle devel cpan modules yet.
 288
 289 =item *
 290
 291 Version requirements not fully tested yet.
 292
 293 =back
 294
 295 =head1 AUTHOR
 296
 297   Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 298   Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 299   Wulf Coulmann E<lt>wulf@coulmann.deE<gt>
 300
 301 =cut