scripts/task_server.pl

   1 #!/usr/bin/perl
   2
   3 use strict;
   4
   5 my $exe_dir;
   6
   7 BEGIN {
   8   use FindBin;
   9   use lib "$FindBin::Bin/..";
  10
  11   use SL::System::Process;
  12   $exe_dir = SL::System::Process::exe_dir;
  13
  14   unshift @INC, "${exe_dir}/modules/override"; # Use our own versions of various modules (e.g. YAML).
  15   push    @INC, "${exe_dir}/modules/fallback"; # Only use our own versions of modules if there's no system version.
  16   unshift @INC, $exe_dir;
  17
  18   chdir($exe_dir) || die "Cannot change directory to ${exe_dir}\n";
  19 }
  20
  21 use CGI qw( -no_xhtml);
  22 use Cwd;
  23 use Daemon::Generic;
  24 use Data::Dumper;
  25 use DateTime;
  26 use English qw(-no_match_vars);
  27 use File::Spec;
  28 use List::Util qw(first);
  29 use POSIX qw(setuid setgid);
  30 use SL::Auth;
  31 use SL::DB::BackgroundJob;
  32 use SL::BackgroundJob::ALL;
  33 use SL::Form;
  34 use SL::Helper::DateTime;
  35 use SL::InstanceConfiguration;
  36 use SL::LXDebug;
  37 use SL::LxOfficeConf;
  38 use SL::Locale;
  39 use SL::System::TaskServer;
  40
  41 our %lx_office_conf;
  42
  43 sub lxinit {
  44   my $login = $lx_office_conf{task_server}->{login};
  45
  46   package main;
  47
  48   $::lxdebug       = LXDebug->new;
  49   $::locale        = Locale->new($::lx_office_conf{system}->{language});
  50   $::form          = Form->new;
  51   $::auth          = SL::Auth->new;
  52   $::instance_conf = SL::InstanceConfiguration->new;
  53   $::request       = { cgi => CGI->new({}) };
  54
  55   die 'cannot reach auth db'               unless $::auth->session_tables_present;
  56
  57   $::auth->restore_session;
  58
  59   require "bin/mozilla/common.pl";
  60
  61   die "cannot find user $login"            unless %::myconfig = $::auth->read_user(login => $login);
  62   die "cannot find locale for user $login" unless $::locale   = Locale->new('de');
  63 }
  64
  65 sub drop_privileges {
  66   my $user = $lx_office_conf{task_server}->{run_as};
  67   return unless $user;
  68
  69   my ($uid, $gid);
  70   while (my @details = getpwent()) {
  71     next unless $details[0] eq $user;
  72     ($uid, $gid) = @details[2, 3];
  73     last;
  74   }
  75   endpwent();
  76
  77   if (!$uid) {
  78     print "Error: Cannot drop privileges to ${user}: user does not exist\n";
  79     exit 1;
  80   }
  81
  82   if (!setgid($gid)) {
  83     print "Error: Cannot drop group privileges to ${user} (group ID $gid): $!\n";
  84     exit 1;
  85   }
  86
  87   if (!setuid($uid)) {
  88     print "Error: Cannot drop user privileges to ${user} (user ID $uid): $!\n";
  89     exit 1;
  90   }
  91 }
  92
  93 sub gd_preconfig {
  94   my $self = shift;
  95
  96   SL::LxOfficeConf->read($self->{configfile});
  97
  98   die "Missing section [task_server] in config file"                unless $lx_office_conf{task_server};
  99   die "Missing key 'login' in section [task_server] in config file" unless $lx_office_conf{task_server}->{login};
 100
 101   drop_privileges();
 102   lxinit();
 103
 104   return ();
 105 }
 106
 107 sub gd_run {
 108   while (1) {
 109     my $ok = eval {
 110       $::lxdebug->message(0, "Retrieving jobs") if $lx_office_conf{task_server}->{debug};
 111
 112       my $jobs = SL::DB::Manager::BackgroundJob->get_all_need_to_run;
 113
 114       $::lxdebug->message(0, "  Found: " . join(' ', map { $_->package_name } @{ $jobs })) if $lx_office_conf{task_server}->{debug} && @{ $jobs };
 115
 116       foreach my $job (@{ $jobs }) {
 117         # Provide fresh global variables in case legacy code modifies
 118         # them somehow.
 119         $::locale = Locale->new($::lx_office_conf{system}->{language});
 120         $::form   = Form->new;
 121
 122         chdir $exe_dir;
 123
 124         $job->run;
 125       }
 126
 127       1;
 128     };
 129
 130     if ($lx_office_conf{task_server}->{debug}) {
 131       $::lxdebug->message(0, "Exception during execution: ${EVAL_ERROR}") if !$ok;
 132       $::lxdebug->message(0, "Sleeping");
 133     }
 134
 135     my $seconds = 60 - (localtime)[0];
 136     if (!eval {
 137       local $SIG{'ALRM'} = sub {
 138         $::lxdebug->message(0, "Got woken up by SIGALRM") if $lx_office_conf{task_server}->{debug};
 139         die "Alarm!\n"
 140       };
 141       sleep($seconds < 30 ? $seconds + 60 : $seconds);
 142       1;
 143     }) {
 144       die $@ unless $@ eq "Alarm!\n";
 145     }
 146   }
 147 }
 148
 149 chdir $exe_dir;
 150
 151 mkdir SL::System::TaskServer::PID_BASE() if !-d SL::System::TaskServer::PID_BASE();
 152
 153 my $file = first { -f } ("${exe_dir}/config/kivitendo.conf", "${exe_dir}/config/lx_office.conf", "${exe_dir}/config/kivitendo.conf.default");
 154
 155 die "No configuration file found." unless $file;
 156
 157 $file = File::Spec->abs2rel(Cwd::abs_path($file), Cwd::abs_path($exe_dir));
 158
 159 newdaemon(configfile => $file,
 160           progname   => 'kivitendo-background-jobs',
 161           pidbase    => SL::System::TaskServer::PID_BASE() . '/',
 162           );
 163
 164 1;