scripts/task_server.pl

   1 #!/usr/bin/perl
   2
   3 use strict;
   4
   5 my $exe_dir;
   6
   7 BEGIN {
   8   use FindBin;
   9   use lib "$FindBin::Bin/..";
  10
  11   use SL::System::Process;
  12   $exe_dir = SL::System::Process::exe_dir;
  13
  14   unshift @INC, "${exe_dir}/modules/override"; # Use our own versions of various modules (e.g. YAML).
  15   push    @INC, "${exe_dir}/modules/fallback"; # Only use our own versions of modules if there's no system version.
  16   unshift @INC, $exe_dir;
  17
  18   chdir($exe_dir) || die "Cannot change directory to ${exe_dir}\n";
  19 }
  20
  21 use CGI qw( -no_xhtml);
  22 use Cwd;
  23 use Daemon::Generic;
  24 use Data::Dumper;
  25 use DateTime;
  26 use English qw(-no_match_vars);
  27 use File::Spec;
  28 use List::Util qw(first);
  29 use POSIX qw(setuid setgid);
  30 use SL::Auth;
  31 use SL::DB::BackgroundJob;
  32 use SL::BackgroundJob::ALL;
  33 use SL::Form;
  34 use SL::Helper::DateTime;
  35 use SL::InstanceConfiguration;
  36 use SL::LXDebug;
  37 use SL::LxOfficeConf;
  38 use SL::Locale;
  39 use SL::System::TaskServer;
  40
  41 our %lx_office_conf;
  42
  43 sub debug {
  44   return if !$lx_office_conf{task_server}->{debug};
  45   $::lxdebug->message(0, @_);
  46 }
  47
  48 sub lxinit {
  49   my $login  = $lx_office_conf{task_server}->{login};
  50   my $client = $lx_office_conf{task_server}->{client};
  51
  52   package main;
  53
  54   $::lxdebug       = LXDebug->new;
  55   $::locale        = Locale->new($::lx_office_conf{system}->{language});
  56   $::form          = Form->new;
  57   $::auth          = SL::Auth->new;
  58   die "No client configured or no client found with the name/ID '$client'" unless $::auth->set_client($client);
  59   $::instance_conf = SL::InstanceConfiguration->new;
  60   $::request       = { cgi => CGI->new({}) };
  61
  62   die 'cannot reach auth db'               unless $::auth->session_tables_present;
  63
  64   $::auth->restore_session;
  65
  66   require "bin/mozilla/common.pl";
  67
  68   die "cannot find user $login"            unless %::myconfig = $::auth->read_user(login => $login);
  69   die "cannot find locale for user $login" unless $::locale   = Locale->new('de');
  70 }
  71
  72 sub drop_privileges {
  73   my $user = $lx_office_conf{task_server}->{run_as};
  74   return unless $user;
  75
  76   my ($uid, $gid);
  77   while (my @details = getpwent()) {
  78     next unless $details[0] eq $user;
  79     ($uid, $gid) = @details[2, 3];
  80     last;
  81   }
  82   endpwent();
  83
  84   if (!$uid) {
  85     print "Error: Cannot drop privileges to ${user}: user does not exist\n";
  86     exit 1;
  87   }
  88
  89   if (!setgid($gid)) {
  90     print "Error: Cannot drop group privileges to ${user} (group ID $gid): $!\n";
  91     exit 1;
  92   }
  93
  94   if (!setuid($uid)) {
  95     print "Error: Cannot drop user privileges to ${user} (user ID $uid): $!\n";
  96     exit 1;
  97   }
  98 }
  99
 100 sub gd_preconfig {
 101   my $self = shift;
 102
 103   SL::LxOfficeConf->read($self->{configfile});
 104
 105   die "Missing section [task_server] in config file"                 unless $lx_office_conf{task_server};
 106   die "Missing key 'login' in section [task_server] in config file"  unless $lx_office_conf{task_server}->{login};
 107   die "Missing key 'client' in section [task_server] in config file" unless $lx_office_conf{task_server}->{client};
 108
 109   drop_privileges();
 110   lxinit();
 111
 112   return ();
 113 }
 114
 115 sub gd_run {
 116   while (1) {
 117     my $ok = eval {
 118       debug("Retrieving jobs");
 119
 120       my $jobs = SL::DB::Manager::BackgroundJob->get_all_need_to_run;
 121
 122       debug("  Found: " . join(' ', map { $_->package_name } @{ $jobs })) if @{ $jobs };
 123
 124       foreach my $job (@{ $jobs }) {
 125         # Provide fresh global variables in case legacy code modifies
 126         # them somehow.
 127         $::locale = Locale->new($::lx_office_conf{system}->{language});
 128         $::form   = Form->new;
 129
 130         chdir $exe_dir;
 131
 132         $job->run;
 133       }
 134
 135       1;
 136     };
 137
 138     debug("Exception during execution: ${EVAL_ERROR}") if !$ok;
 139     debug("Sleeping");
 140
 141     my $seconds = 60 - (localtime)[0];
 142     if (!eval {
 143       local $SIG{'ALRM'} = sub {
 144         debug("Got woken up by SIGALRM");
 145         die "Alarm!\n"
 146       };
 147       sleep($seconds < 30 ? $seconds + 60 : $seconds);
 148       1;
 149     }) {
 150       die $@ unless $@ eq "Alarm!\n";
 151     }
 152   }
 153 }
 154
 155 chdir $exe_dir;
 156
 157 mkdir SL::System::TaskServer::PID_BASE() if !-d SL::System::TaskServer::PID_BASE();
 158
 159 my $file = first { -f } ("${exe_dir}/config/kivitendo.conf", "${exe_dir}/config/lx_office.conf", "${exe_dir}/config/kivitendo.conf.default");
 160
 161 die "No configuration file found." unless $file;
 162
 163 $file = File::Spec->abs2rel(Cwd::abs_path($file), Cwd::abs_path($exe_dir));
 164
 165 newdaemon(configfile => $file,
 166           progname   => 'kivitendo-background-jobs',
 167           pidbase    => SL::System::TaskServer::PID_BASE() . '/',
 168           );
 169
 170 1;