scripts/task_server.pl

   1 #!/usr/bin/perl
   2
   3
   4 use List::MoreUtils qw(any);
   5
   6 use strict;
   7
   8 my $exe_dir;
   9
  10 BEGIN {
  11   use FindBin;
  12   use lib "$FindBin::Bin/..";
  13
  14   use SL::System::Process;
  15   $exe_dir = SL::System::Process::exe_dir;
  16
  17   unshift @INC, "${exe_dir}/modules/override"; # Use our own versions of various modules (e.g. YAML).
  18   push    @INC, "${exe_dir}/modules/fallback"; # Only use our own versions of modules if there's no system version.
  19   unshift @INC, $exe_dir;
  20
  21   chdir($exe_dir) || die "Cannot change directory to ${exe_dir}\n";
  22 }
  23
  24 use CGI qw( -no_xhtml);
  25 use Cwd;
  26 use Daemon::Generic;
  27 use Data::Dumper;
  28 use DateTime;
  29 use Encode qw();
  30 use English qw(-no_match_vars);
  31 use File::Spec;
  32 use List::Util qw(first);
  33 use POSIX qw(setuid setgid);
  34 use SL::Auth;
  35 use SL::DB::BackgroundJob;
  36 use SL::BackgroundJob::ALL;
  37 use SL::Form;
  38 use SL::Helper::DateTime;
  39 use SL::InstanceConfiguration;
  40 use SL::LXDebug;
  41 use SL::LxOfficeConf;
  42 use SL::Locale;
  43 use SL::Mailer;
  44 use SL::System::TaskServer;
  45 use Template;
  46
  47 our %lx_office_conf;
  48
  49 sub debug {
  50   return if !$lx_office_conf{task_server}->{debug};
  51   $::lxdebug->message(0, @_);
  52 }
  53
  54 sub lxinit {
  55   my $login  = $lx_office_conf{task_server}->{login};
  56   my $client = $lx_office_conf{task_server}->{client};
  57
  58   package main;
  59
  60   $::lxdebug       = LXDebug->new;
  61   $::locale        = Locale->new($::lx_office_conf{system}->{language});
  62   $::form          = Form->new;
  63   $::auth          = SL::Auth->new;
  64   die "No client configured or no client found with the name/ID '$client'" unless $::auth->set_client($client);
  65   $::instance_conf = SL::InstanceConfiguration->new;
  66   $::request       = { cgi => CGI->new({}) };
  67
  68   die 'cannot reach auth db'               unless $::auth->session_tables_present;
  69
  70   $::auth->restore_session;
  71
  72   require "bin/mozilla/common.pl";
  73
  74   die "cannot find user $login"            unless %::myconfig = $::auth->read_user(login => $login);
  75   die "cannot find locale for user $login" unless $::locale   = Locale->new('de');
  76 }
  77
  78 sub per_job_initialization {
  79   $::locale        = Locale->new($::lx_office_conf{system}->{language});
  80   $::form          = Form->new;
  81   $::instance_conf = SL::InstanceConfiguration->new;
  82   $::request       = SL::Request->new(
  83     cgi            => CGI->new({}),
  84     layout         => SL::Layout::None->new,
  85   );
  86
  87   $::auth->restore_session;
  88
  89   $::form->{login} = $lx_office_conf{task_server}->{login};
  90   $::instance_conf->init;
  91 }
  92
  93 sub drop_privileges {
  94   my $user = $lx_office_conf{task_server}->{run_as};
  95   return unless $user;
  96
  97   my ($uid, $gid);
  98   while (my @details = getpwent()) {
  99     next unless $details[0] eq $user;
 100     ($uid, $gid) = @details[2, 3];
 101     last;
 102   }
 103   endpwent();
 104
 105   if (!$uid) {
 106     print "Error: Cannot drop privileges to ${user}: user does not exist\n";
 107     exit 1;
 108   }
 109
 110   if (!setgid($gid)) {
 111     print "Error: Cannot drop group privileges to ${user} (group ID $gid): $!\n";
 112     exit 1;
 113   }
 114
 115   if (!setuid($uid)) {
 116     print "Error: Cannot drop user privileges to ${user} (user ID $uid): $!\n";
 117     exit 1;
 118   }
 119 }
 120
 121 sub notify_on_failure {
 122   my (%params) = @_;
 123
 124   my $cfg = $lx_office_conf{'task_server/notify_on_failure'} || {};
 125
 126   return if any { !$cfg->{$_} } qw(send_email_to email_from email_subject email_template);
 127
 128   chdir $exe_dir;
 129
 130   return debug("Template " . $cfg->{email_template} . " missing!") unless -f $cfg->{email_template};
 131
 132   my $email_to = $cfg->{send_email_to};
 133   if ($email_to !~ m{\@}) {
 134     my %user = $::auth->read_user(login => $email_to);
 135     return debug("cannot find user for notification $email_to") unless %user;
 136
 137     $email_to = $user{email};
 138     return debug("user for notification " . $user{login} . " doesn't have a valid email address") unless $email_to =~ m{\@};
 139   }
 140
 141   my $template  = Template->new({
 142     INTERPOLATE => 0,
 143     EVAL_PERL   => 0,
 144     ABSOLUTE    => 1,
 145     CACHE_SIZE  => 0,
 146   });
 147
 148   return debug("Could not create Template instance") unless $template;
 149
 150   $params{client} = $::auth->client;
 151
 152   my $body;
 153   $template->process($cfg->{email_template}, \%params, \$body);
 154
 155   Mailer->new(
 156     from         => $cfg->{email_from},
 157     to           => $email_to,
 158     subject      => $cfg->{email_subject},
 159     content_type => 'text/plain',
 160     charset      => 'utf-8',
 161     message      => Encode::decode('utf-8', $body),
 162   )->send;
 163 }
 164
 165 sub gd_preconfig {
 166   my $self = shift;
 167
 168   SL::LxOfficeConf->read($self->{configfile});
 169
 170   die "Missing section [task_server] in config file"                 unless $lx_office_conf{task_server};
 171   die "Missing key 'login' in section [task_server] in config file"  unless $lx_office_conf{task_server}->{login};
 172   die "Missing key 'client' in section [task_server] in config file" unless $lx_office_conf{task_server}->{client};
 173
 174   drop_privileges();
 175   lxinit();
 176
 177   return ();
 178 }
 179
 180 sub gd_run {
 181   while (1) {
 182     my $ok = eval {
 183       debug("Retrieving jobs");
 184
 185       my $jobs = SL::DB::Manager::BackgroundJob->get_all_need_to_run;
 186
 187       debug("  Found: " . join(' ', map { $_->package_name } @{ $jobs })) if @{ $jobs };
 188
 189       foreach my $job (@{ $jobs }) {
 190         # Provide fresh global variables in case legacy code modifies
 191         # them somehow.
 192         per_job_initialization();
 193
 194         chdir $exe_dir;
 195
 196         my $history = $job->run;
 197
 198         notify_on_failure(history => $history) if $history && $history->has_failed;
 199       }
 200
 201       1;
 202     };
 203
 204     if (!$ok) {
 205       my $error = $EVAL_ERROR;
 206       debug("Exception during execution: ${error}");
 207       notify_on_failure(exception => $error);
 208     }
 209
 210     debug("Sleeping");
 211
 212     my $seconds = 60 - (localtime)[0];
 213     if (!eval {
 214       local $SIG{'ALRM'} = sub {
 215         debug("Got woken up by SIGALRM");
 216         die "Alarm!\n"
 217       };
 218       sleep($seconds < 30 ? $seconds + 60 : $seconds);
 219       1;
 220     }) {
 221       die $@ unless $@ eq "Alarm!\n";
 222     }
 223   }
 224 }
 225
 226 chdir $exe_dir;
 227
 228 mkdir SL::System::TaskServer::PID_BASE() if !-d SL::System::TaskServer::PID_BASE();
 229
 230 my $file = first { -f } ("${exe_dir}/config/kivitendo.conf", "${exe_dir}/config/lx_office.conf", "${exe_dir}/config/kivitendo.conf.default");
 231
 232 die "No configuration file found." unless $file;
 233
 234 $file = File::Spec->abs2rel(Cwd::abs_path($file), Cwd::abs_path($exe_dir));
 235
 236 newdaemon(configfile => $file,
 237           progname   => 'kivitendo-background-jobs',
 238           pidbase    => SL::System::TaskServer::PID_BASE() . '/',
 239           );
 240
 241 1;