sql/Pg-upgrade2/steuerfilterung.pl

   1 # @tag: steuerfilterung
   2 # @description: Steuern in Dialogbuchungen filtern.
   3 # @depends: release_3_0_0 tax_constraints
   4 package SL::DBUpgrade2::steuerfilterung;
   5
   6 use strict;
   7 use utf8;
   8 use List::Util qw(first);
   9
  10 use parent qw(SL::DBUpgrade2::Base);
  11
  12 sub run {
  13   my ($self) = @_;
  14
  15   my $categories;
  16   my $tax_id;
  17
  18   my $query = qq|ALTER TABLE tax ADD chart_categories TEXT|;
  19   $self->db_query($query);
  20
  21   if ( $::form->{continued_tax} ) {
  22     my $update_query;
  23     foreach my $i (1 .. $::form->{rowcount}) {
  24       $tax_id = $::form->{"tax_id_$i"};
  25       $categories = '';
  26       $categories .= 'A' if $::form->{"asset_$i"};
  27       $categories .= 'L' if $::form->{"liability_$i"};
  28       $categories .= 'Q' if $::form->{"equity_$i"};
  29       $categories .= 'C' if $::form->{"costs_$i"};
  30       $categories .= 'I' if $::form->{"revenue_$i"};
  31       $categories .= 'E' if $::form->{"expense_$i"};
  32       $update_query = qq|UPDATE tax SET chart_categories = '$categories' WHERE id=$tax_id;|;
  33       $self->db_query($update_query);
  34     }
  35     $update_query = qq|ALTER TABLE tax ALTER COLUMN chart_categories SET NOT NULL|;
  36     $self->db_query($update_query);
  37     return 1;
  38   }
  39
  40   my @well_known_taxes = (
  41       { taxkey => 0,  rate => 0,    taxdescription => qr{keine.*steuer}i,                       categories => 'ALQCIE' },
  42       { taxkey => 1,  rate => 0,    taxdescription => qr{frei}i,                                categories => 'ALQCIE' },
  43       { taxkey => 2,  rate => 0.07, taxdescription => qr{umsatzsteuer}i,                        categories => 'I' },
  44       { taxkey => 3,  rate => 0.16, taxdescription => qr{umsatzsteuer}i,                        categories => 'I' },
  45       { taxkey => 3,  rate => 0.19, taxdescription => qr{umsatzsteuer}i,                        categories => 'I' },
  46       { taxkey => 5,  rate => 0.16, taxdescription => qr{umsatzsteuer}i,                        categories => 'I' },
  47       { taxkey => 7,  rate => 0.16, taxdescription => qr{vorsteuer}i,                           categories => 'E' },
  48       { taxkey => 8,  rate => 0.07, taxdescription => qr{vorsteuer}i,                           categories => 'E' },
  49       { taxkey => 9,  rate => 0.16, taxdescription => qr{vorsteuer}i,                           categories => 'E' },
  50       { taxkey => 9,  rate => 0.19, taxdescription => qr{vorsteuer}i,                           categories => 'E' },
  51       { taxkey => 10, rate => 0,    taxdescription => qr{andere.*steuerpflichtige.*lieferung}i, categories => 'I' },
  52       { taxkey => 11, rate => 0,    taxdescription => qr{frei.*innergem.*mit}i,                 categories => 'I' },
  53       { taxkey => 12, rate => 0.07, taxdescription => qr{steuerpflichtig.*lieferung.*erm}i,     categories => 'I' },
  54       { taxkey => 13, rate => 0.16, taxdescription => qr{steuerpflichtig.*lieferung.*voll}i,    categories => 'I' },
  55       { taxkey => 13, rate => 0.19, taxdescription => qr{steuerpflichtig.*lieferung.*voll}i,    categories => 'I' },
  56       { taxkey => 15, rate => 0.16, taxdescription => qr{steuerpflicht.*eg.*lieferung}i,        categories => 'I' },
  57       { taxkey => 17, rate => 0.16, taxdescription => qr{steuerpflicht.*eg.*erwerb}i,           categories => 'E' },
  58       { taxkey => 18, rate => 0.07, taxdescription => qr{innergem.*erwerb.*erm}i,               categories => 'E' },
  59       { taxkey => 19, rate => 0.16, taxdescription => qr{innergem.*erwerb.*voll}i,              categories => 'E' },
  60       { taxkey => 19, rate => 0.19, taxdescription => qr{innergem.*erwerb.*voll}i,              categories => 'E' },
  61       );
  62
  63   $query = qq|SELECT taxkey, taxdescription, rate, id AS tax_id FROM tax order by taxkey, rate;|;
  64
  65   my $sth = $self->dbh->prepare($query);
  66   $sth->execute || $::form->dberror($query);
  67
  68   my $well_known_tax;
  69
  70   $::form->{PARTS} = [];
  71   while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
  72     $well_known_tax = first {
  73       ($ref->{taxkey} == $_->{taxkey})
  74       && ($ref->{rate} == $_->{rate})
  75       && ($ref->{taxdescription} =~ $_->{taxdescription})
  76     } @well_known_taxes;
  77     if ($well_known_tax) {
  78       $categories = $well_known_tax->{categories};
  79       $tax_id = $ref->{tax_id};
  80       $query = qq|UPDATE tax SET chart_categories = '$categories' WHERE id=$tax_id;|;
  81       $self->db_query($query);
  82     } else {
  83       $ref->{rate} = $::form->format_amount(\%::myconfig, $::form->round_amount($ref->{rate} * 100));
  84       push @{ $::form->{PARTS} }, $ref;
  85     }
  86   }
  87
  88   if (scalar @{ $::form->{PARTS} } > 0){
  89     &print_message;
  90     return 2;
  91   } else {
  92     $query = qq|ALTER TABLE tax ALTER COLUMN chart_categories SET NOT NULL|;
  93     $self->db_query($query);
  94     return 1;
  95   }
  96 } # end run
  97
  98 sub print_message {
  99   print $::form->parse_html_template("dbupgrade/steuerfilterung");
 100 }
 101
 102 1;