t/000setup_database.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4
   5 use lib 't';
   6
   7 use Data::Dumper;
   8 use Test::More;
   9
  10 use SL::Auth;
  11 use SL::DBConnect;
  12 use SL::Form;
  13 use SL::InstanceConfiguration;
  14 use SL::LXDebug;
  15 use SL::Layout::None;
  16 use SL::LxOfficeConf;
  17
  18 our ($db_cfg, $dbh);
  19
  20 sub dbg {
  21   # diag(@_);
  22 }
  23
  24 sub dbh_do {
  25   my ($dbh, $query, %params) = @_;
  26
  27   if (ref($query)) {
  28     return if $query->execute(@{ $params{bind} || [] });
  29     BAIL_OUT($dbh->errstr);
  30   }
  31
  32   return if $dbh->do($query, undef, @{ $params{bind} || [] });
  33
  34   BAIL_OUT($params{message} . ": " . $dbh->errstr) if $params{message};
  35   BAIL_OUT("Query failed: " . $dbh->errstr . " ; query: $query");
  36 }
  37
  38 sub verify_configuration {
  39   SL::LxOfficeConf->read;
  40
  41   my %config = %{ $::lx_office_conf{'testing/database'} || {} };
  42   my @unset  = sort grep { !$config{$_} } qw(host port db user template);
  43
  44   BAIL_OUT("Missing entries in configuration in section [testing/database]: " . join(' ', @unset)) if @unset;
  45 }
  46
  47 sub setup {
  48   package main;
  49
  50   $SIG{__DIE__}    = sub { Carp::confess( @_ ) } if $::lx_office_conf{debug}->{backtrace_on_die};
  51   $::lxdebug       = LXDebug->new(target => LXDebug::STDERR_TARGET);
  52   $::lxdebug->disable_sub_tracing;
  53   $::locale        = Locale->new($::lx_office_conf{system}->{language});
  54   $::form          = Form->new;
  55   $::auth          = SL::Auth->new(unit_tests_database => 1);
  56   $::locale        = Locale->new('de');
  57   $::instance_conf = SL::InstanceConfiguration->new;
  58   $db_cfg          = $::lx_office_conf{'testing/database'};
  59 }
  60
  61 sub drop_and_create_database {
  62   my @dbi_options = (
  63     'dbi:Pg:dbname=' . $db_cfg->{template} . ';host=' . $db_cfg->{host} . ';port=' . $db_cfg->{port},
  64     $db_cfg->{user},
  65     $db_cfg->{password},
  66     SL::DBConnect->get_options,
  67   );
  68
  69   $::auth->reset;
  70   my $dbh_template = SL::DBConnect->connect(@dbi_options) || BAIL_OUT("No database connection to the template database: " . $DBI::errstr);
  71   my $auth_dbh     = $::auth->dbconnect(1);
  72
  73   if ($auth_dbh) {
  74     dbg("Database exists; dropping");
  75     $auth_dbh->disconnect;
  76
  77     dbh_do($dbh_template, "DROP DATABASE \"" . $db_cfg->{db} . "\"", message => "Database could not be dropped");
  78
  79     $::auth->reset;
  80   }
  81
  82   dbg("Creating database");
  83
  84   dbh_do($dbh_template, "CREATE DATABASE \"" . $db_cfg->{db} . "\" TEMPLATE \"" . $db_cfg->{template} . "\" ENCODING 'UNICODE'", message => "Database could not be created");
  85   $dbh_template->disconnect;
  86 }
  87
  88 sub report_success {
  89   $dbh->disconnect;
  90   ok(1, "Database has been setup sucessfully.");
  91   done_testing();
  92 }
  93
  94 sub apply_dbupgrade {
  95   my ($dbupdater, $control_or_file) = @_;
  96
  97   my $file    = ref($control_or_file) ? ("sql/Pg-upgrade2" . ($dbupdater->{auth} ? "-auth" : "") . "/$control_or_file->{file}") : $control_or_file;
  98   my $control = ref($control_or_file) ? $control_or_file                                                                        : undef;
  99
 100   dbg("Applying $file");
 101
 102   my $error = $dbupdater->process_file($dbh, $file, $control);
 103
 104   BAIL_OUT("Error applying $file: $error") if $error;
 105 }
 106
 107 sub create_initial_schema {
 108   dbg("Creating initial schema");
 109
 110   my @dbi_options = (
 111     'dbi:Pg:dbname=' . $db_cfg->{db} . ';host=' . $db_cfg->{host} . ';port=' . $db_cfg->{port},
 112     $db_cfg->{user},
 113     $db_cfg->{password},
 114     SL::DBConnect->get_options(PrintError => 0, PrintWarn => 0),
 115   );
 116
 117   $dbh           = SL::DBConnect->connect(@dbi_options) || BAIL_OUT("Database connection failed: " . $DBI::errstr);
 118   $::auth->{dbh} = $dbh;
 119   my $dbupdater  = SL::DBUpgrade2->new(form => $::form, return_on_error => 1, silent => 1);
 120   my $coa        = 'Germany-DATEV-SKR03EU';
 121
 122   apply_dbupgrade($dbupdater, "sql/lx-office.sql");
 123   apply_dbupgrade($dbupdater, "sql/${coa}-chart.sql");
 124
 125   dbh_do($dbh, qq|UPDATE defaults SET coa = '${coa}', accounting_method = 'cash', profit_determination = 'income', inventory_system = 'periodic', curr = 'EUR'|);
 126   dbh_do($dbh, qq|CREATE TABLE schema_info (tag TEXT, login TEXT, itime TIMESTAMP DEFAULT now(), PRIMARY KEY (tag))|);
 127 }
 128
 129 sub create_initial_auth_schema {
 130   dbg("Creating initial auth schema");
 131
 132   my $dbupdater = SL::DBUpgrade2->new(form => $::form, return_on_error => 1, auth => 1);
 133   apply_dbupgrade($dbupdater, 'sql/auth_db.sql');
 134 }
 135
 136 sub apply_upgrades {
 137   my %params            = @_;
 138   my $dbupdater         = SL::DBUpgrade2->new(form => $::form, return_on_error => 1, auth => $params{auth});
 139   my @unapplied_scripts = $dbupdater->unapplied_upgrade_scripts($dbh);
 140
 141   apply_dbupgrade($dbupdater, $_) for @unapplied_scripts;
 142 }
 143
 144 sub create_client_user_and_employee {
 145   dbg("Creating client, user, group and employee");
 146
 147   dbh_do($dbh, qq|DELETE FROM auth.clients|);
 148   dbh_do($dbh, qq|INSERT INTO auth.clients (id, name, dbhost, dbport, dbname, dbuser, dbpasswd, is_default) VALUES (1, 'Unit-Tests', ?, ?, ?, ?, ?, TRUE)|,
 149          bind => [ @{ $db_cfg }{ qw(host port db user password) } ]);
 150   dbh_do($dbh, qq|INSERT INTO auth."user"         (id,        login)    VALUES (1, 'unittests')|);
 151   dbh_do($dbh, qq|INSERT INTO auth."group"        (id,        name)     VALUES (1, 'Vollzugriff')|);
 152   dbh_do($dbh, qq|INSERT INTO auth.clients_users  (client_id, user_id)  VALUES (1, 1)|);
 153   dbh_do($dbh, qq|INSERT INTO auth.clients_groups (client_id, group_id) VALUES (1, 1)|);
 154   dbh_do($dbh, qq|INSERT INTO auth.user_group     (user_id,   group_id) VALUES (1, 1)|);
 155
 156   my %config                 = (
 157     default_printer_id       => '',
 158     template_format          => '',
 159     default_media            => '',
 160     email                    => 'unit@tester',
 161     tel                      => '',
 162     dateformat               => 'dd.mm.yy',
 163     show_form_details        => '',
 164     name                     => 'Unit Tester',
 165     signature                => '',
 166     hide_cvar_search_options => '',
 167     numberformat             => '1.000,00',
 168     vclimit                  => 0,
 169     favorites                => '',
 170     copies                   => '',
 171     menustyle                => 'v3',
 172     fax                      => '',
 173     stylesheet               => 'lx-office-erp.css',
 174     mandatory_departments    => 0,
 175     countrycode              => 'de',
 176   );
 177
 178   my $sth = $dbh->prepare(qq|INSERT INTO auth.user_config (user_id, cfg_key, cfg_value) VALUES (1, ?, ?)|) || BAIL_OUT($dbh->errstr);
 179   dbh_do($dbh, $sth, bind => [ $_, $config{$_} ]) for sort keys %config;
 180   $sth->finish;
 181
 182   $sth = $dbh->prepare(qq|INSERT INTO auth.group_rights (group_id, "right", granted) VALUES (1, ?, TRUE)|) || BAIL_OUT($dbh->errstr);
 183   dbh_do($dbh, $sth, bind => [ $_ ]) for sort $::auth->all_rights;
 184   $sth->finish;
 185
 186   dbh_do($dbh, qq|INSERT INTO employee (id, login, name) VALUES (1, 'unittests', 'Unit Tester')|);
 187
 188   $::auth->set_client(1) || BAIL_OUT("\$::auth->set_client(1) failed");
 189   %::myconfig = $::auth->read_user(login => 'unittests');
 190 }
 191
 192 verify_configuration();
 193 setup();
 194 drop_and_create_database();
 195 create_initial_schema();
 196 create_initial_auth_schema();
 197 apply_upgrades(auth => 1);
 198 create_client_user_and_employee();
 199 apply_upgrades();
 200 report_success();
 201
 202 1;