t/bank/bank_transactions.t

   1 use Test::More tests => 75;
   2
   3 use strict;
   4
   5 use lib 't';
   6 use utf8;
   7
   8 use Carp;
   9 use Support::TestSetup;
  10 use Test::Exception;
  11 use List::Util qw(sum);
  12
  13 use SL::DB::Buchungsgruppe;
  14 use SL::DB::Currency;
  15 use SL::DB::Customer;
  16 use SL::DB::Vendor;
  17 use SL::DB::Invoice;
  18 use SL::DB::Unit;
  19 use SL::DB::Part;
  20 use SL::DB::TaxZone;
  21 use SL::DB::BankAccount;
  22 use SL::DB::PaymentTerm;
  23 use SL::DB::PurchaseInvoice;
  24 use SL::DB::BankTransaction;
  25 use SL::Controller::BankTransaction;
  26 use SL::Dev::ALL;
  27 use Data::Dumper;
  28
  29 my ($customer, $vendor, $currency_id, $unit, $tax, $tax7, $tax_9, $payment_terms, $bank_account);
  30 my ($transdate1, $transdate2, $currency);
  31 my ($ar_chart,$bank,$ar_amount_chart, $ap_chart, $ap_amount_chart);
  32 my ($ar_transaction, $ap_transaction);
  33
  34 sub clear_up {
  35
  36   SL::DB::Manager::BankTransaction->delete_all(all => 1);
  37   SL::DB::Manager::InvoiceItem->delete_all(all => 1);
  38   SL::DB::Manager::InvoiceItem->delete_all(all => 1);
  39   SL::DB::Manager::Invoice->delete_all(all => 1);
  40   SL::DB::Manager::PurchaseInvoice->delete_all(all => 1);
  41   SL::DB::Manager::Part->delete_all(all => 1);
  42   SL::DB::Manager::Customer->delete_all(all => 1);
  43   SL::DB::Manager::Vendor->delete_all(all => 1);
  44   SL::DB::Manager::BankAccount->delete_all(all => 1);
  45   SL::DB::Manager::PaymentTerm->delete_all(all => 1);
  46   SL::DB::Manager::Currency->delete_all(where => [ name => 'CUR' ]);
  47 };
  48
  49 sub save_btcontroller_to_string {
  50   my $output;
  51   open(my $outputFH, '>', \$output) or die;
  52   my $oldFH = select $outputFH;
  53
  54   my $bt_controller = SL::Controller::BankTransaction->new;
  55   $bt_controller->action_save_invoices;
  56
  57   select $oldFH;
  58   close $outputFH;
  59   return $output;
  60 }
  61
  62 # starting test:
  63 Support::TestSetup::login();
  64
  65 clear_up();
  66 reset_state(); # initialise customers/vendors/bank/currency/...
  67
  68 test1();
  69 test_overpayment_with_partialpayment();
  70 test_overpayment();
  71 test_skonto_exact();
  72 test_two_invoices();
  73 test_partial_payment();
  74 test_credit_note();
  75 test_neg_ap_transaction();
  76
  77 # remove all created data at end of test
  78 clear_up();
  79
  80 done_testing();
  81
  82 ###### functions for setting up data
  83
  84 sub reset_state {
  85   my %params = @_;
  86
  87   $params{$_} ||= {} for qw(unit customer tax vendor);
  88
  89   clear_up();
  90
  91   $transdate1 = DateTime->today;
  92   $transdate2 = DateTime->today->add(days => 5);
  93
  94   $tax             = SL::DB::Manager::Tax->find_by(taxkey => 3, rate => 0.19, %{ $params{tax} }) || croak "No tax";
  95   $tax7            = SL::DB::Manager::Tax->find_by(taxkey => 2, rate => 0.07)                    || croak "No tax for 7\%";
  96   $tax_9           = SL::DB::Manager::Tax->find_by(taxkey => 9, rate => 0.19, %{ $params{tax} }) || croak "No tax";
  97
  98   $currency_id     = $::instance_conf->get_currency_id;
  99
 100   $bank_account     =  SL::DB::BankAccount->new(
 101     account_number  => '123',
 102     bank_code       => '123',
 103     iban            => '123',
 104     bic             => '123',
 105     bank            => '123',
 106     chart_id        => SL::DB::Manager::Chart->find_by(description => 'Bank')->id,
 107     name            => SL::DB::Manager::Chart->find_by(description => 'Bank')->description,
 108   )->save;
 109
 110   $customer = SL::Dev::CustomerVendor::create_customer(
 111     name                      => 'Test Customer',
 112     iban                      => 'DE12500105170648489890',
 113     bic                       => 'TESTBIC',
 114     account_number            => '648489890',
 115     mandate_date_of_signature => $transdate1,
 116     mandator_id               => 'foobar',
 117     bank                      => 'Geizkasse',
 118     bank_code                 => 'G1235',
 119     depositor                 => 'Test Customer',
 120   )->save;
 121
 122   $payment_terms = SL::Dev::Payment::create_payment_terms;
 123
 124   $vendor = SL::Dev::CustomerVendor::create_vendor(
 125     name           => 'Test Vendor',
 126     payment_id     => $payment_terms->id,
 127     iban           => 'DE12500105170648489890',
 128     bic            => 'TESTBIC',
 129     account_number => '648489890',
 130     bank           => 'Geizkasse',
 131     bank_code      => 'G1235',
 132     depositor      => 'Test Vendor',
 133   )->save;
 134
 135   $ar_chart        = SL::DB::Manager::Chart->find_by( accno => '1400' ); # Forderungen
 136   $ap_chart        = SL::DB::Manager::Chart->find_by( accno => '1600' ); # Verbindlichkeiten
 137   $bank            = SL::DB::Manager::Chart->find_by( accno => '1200' ); # Bank
 138   $ar_amount_chart = SL::DB::Manager::Chart->find_by( accno => '8400' ); # Erlöse
 139   $ap_amount_chart = SL::DB::Manager::Chart->find_by( accno => '3400' ); # Wareneingang 19%
 140
 141 }
 142
 143 sub test_ar_transaction {
 144   my (%params) = @_;
 145   my $netamount = 100;
 146   my $amount    = $params{amount} || $::form->round_amount(100 * 1.19,2);
 147   my $invoice   = SL::DB::Invoice->new(
 148       invoice      => 0,
 149       invnumber    => $params{invnumber} || undef, # let it use its own invnumber
 150       amount       => $amount,
 151       netamount    => $netamount,
 152       transdate    => $transdate1,
 153       taxincluded  => 0,
 154       customer_id  => $customer->id,
 155       taxzone_id   => $customer->taxzone_id,
 156       currency_id  => $currency_id,
 157       transactions => [],
 158       payment_id   => $params{payment_id} || undef,
 159       notes        => 'test_ar_transaction',
 160   );
 161   $invoice->add_ar_amount_row(
 162     amount => $invoice->netamount,
 163     chart  => $ar_amount_chart,
 164     tax_id => $tax->id,
 165   );
 166
 167   $invoice->create_ar_row(chart => $ar_chart);
 168   $invoice->save;
 169
 170   is($invoice->currency_id , $currency_id , 'currency_id has been saved');
 171   is($invoice->netamount   , 100          , 'ar amount has been converted');
 172   is($invoice->amount      , 119          , 'ar amount has been converted');
 173   is($invoice->taxincluded , 0            , 'ar transaction doesn\'t have taxincluded');
 174
 175   is(SL::DB::Manager::AccTransaction->find_by(chart_id => $ar_amount_chart->id , trans_id => $invoice->id)->amount , '100.00000'  , $ar_amount_chart->accno . ': has been converted for currency');
 176   is(SL::DB::Manager::AccTransaction->find_by(chart_id => $ar_chart->id        , trans_id => $invoice->id)->amount , '-119.00000' , $ar_chart->accno . ': has been converted for currency');
 177
 178   return $invoice;
 179 };
 180
 181 sub test_ap_transaction {
 182   my (%params) = @_;
 183   my $netamount = 100;
 184   my $amount    = $::form->round_amount($netamount * 1.19,2);
 185   my $invoice   = SL::DB::PurchaseInvoice->new(
 186     invoice      => 0,
 187     invnumber    => $params{invnumber} || 'test_ap_transaction',
 188     amount       => $amount,
 189     netamount    => $netamount,
 190     transdate    => $transdate1,
 191     taxincluded  => 0,
 192     vendor_id    => $vendor->id,
 193     taxzone_id   => $vendor->taxzone_id,
 194     currency_id  => $currency_id,
 195     transactions => [],
 196     notes        => 'test_ap_transaction',
 197   );
 198   $invoice->add_ap_amount_row(
 199     amount     => $invoice->netamount,
 200     chart      => $ap_amount_chart,
 201     tax_id     => $tax_9->id,
 202   );
 203
 204   $invoice->create_ap_row(chart => $ap_chart);
 205   $invoice->save;
 206
 207   is($invoice->currency_id , $currency_id , 'currency_id has been saved');
 208   is($invoice->netamount   , 100          , 'ap amount has been converted');
 209   is($invoice->amount      , 119          , 'ap amount has been converted');
 210   is($invoice->taxincluded , 0            , 'ap transaction doesn\'t have taxincluded');
 211
 212   is(SL::DB::Manager::AccTransaction->find_by(chart_id => $ap_amount_chart->id , trans_id => $invoice->id)->amount , '-100.00000' , $ap_amount_chart->accno . ': has been converted for currency');
 213   is(SL::DB::Manager::AccTransaction->find_by(chart_id => $ap_chart->id        , trans_id => $invoice->id)->amount , '119.00000'  , $ap_chart->accno . ': has been converted for currency');
 214
 215   return $invoice;
 216 };
 217
 218 ###### test cases
 219
 220 sub test1 {
 221
 222   my $testname = 'test1';
 223
 224   $ar_transaction = test_ar_transaction(invnumber => 'salesinv1');
 225
 226   my $bt = SL::Dev::Payment::create_bank_transaction(record => $ar_transaction) or die "Couldn't create bank_transaction";
 227
 228   $::form->{invoice_ids} = {
 229     $bt->id => [ $ar_transaction->id ]
 230   };
 231
 232   save_btcontroller_to_string();
 233
 234   $ar_transaction->load;
 235   $bt->load;
 236   is($ar_transaction->paid   , '119.00000' , "$testname: salesinv1 was paid");
 237   is($ar_transaction->closed , 1           , "$testname: salesinv1 is closed");
 238   is($bt->invoice_amount     , '119.00000' , "$testname: bt invoice amount was assigned");
 239
 240 };
 241
 242 sub test_skonto_exact {
 243
 244   my $testname = 'test_skonto_exact';
 245
 246   $ar_transaction = test_ar_transaction(invnumber => 'salesinv skonto',
 247                                         payment_id => $payment_terms->id,
 248                                        );
 249
 250   my $bt = SL::Dev::Payment::create_bank_transaction(record        => $ar_transaction,
 251                                                      bank_chart_id => $bank->id,
 252                                                      amount        => $ar_transaction->amount_less_skonto
 253                                                     ) or die "Couldn't create bank_transaction";
 254
 255   $::form->{invoice_ids} = {
 256     $bt->id => [ $ar_transaction->id ]
 257   };
 258   $::form->{invoice_skontos} = {
 259     $bt->id => [ 'with_skonto_pt' ]
 260   };
 261
 262   save_btcontroller_to_string();
 263
 264   $ar_transaction->load;
 265   $bt->load;
 266   is($ar_transaction->paid   , '119.00000' , "$testname: salesinv skonto was paid");
 267   is($ar_transaction->closed , 1           , "$testname: salesinv skonto is closed");
 268   is($bt->invoice_amount     , '113.05000' , "$testname: bt invoice amount was assigned");
 269
 270 };
 271
 272 sub test_two_invoices {
 273
 274   my $testname = 'test_two_invoices';
 275
 276   my $ar_transaction_1 = test_ar_transaction(invnumber => 'salesinv_1');
 277   my $ar_transaction_2 = test_ar_transaction(invnumber => 'salesinv_2');
 278
 279   my $bt = SL::Dev::Payment::create_bank_transaction(record        => $ar_transaction_1,
 280                                                      amount        => ($ar_transaction_1->amount + $ar_transaction_2->amount),
 281                                                      purpose       => "Rechnungen " . $ar_transaction_1->invnumber . " und " . $ar_transaction_2->invnumber,
 282                                                      bank_chart_id => $bank->id,
 283                                                     ) or die "Couldn't create bank_transaction";
 284
 285   my ($agreement, $rule_matches) = $bt->get_agreement_with_invoice($ar_transaction_1);
 286   is($agreement, 16, "points for ar_transaction_1 in test_two_invoices ok");
 287
 288   $::form->{invoice_ids} = {
 289     $bt->id => [ $ar_transaction_1->id, $ar_transaction_2->id ]
 290   };
 291
 292   save_btcontroller_to_string();
 293
 294   $ar_transaction_1->load;
 295   $ar_transaction_2->load;
 296   $bt->load;
 297
 298   is($ar_transaction_1->paid   , '119.00000' , "$testname: salesinv_1 was paid");
 299   is($ar_transaction_1->closed , 1           , "$testname: salesinv_1 is closed");
 300   is($ar_transaction_2->paid   , '119.00000' , "$testname: salesinv_2 was paid");
 301   is($ar_transaction_2->closed , 1           , "$testname: salesinv_2 is closed");
 302   is($bt->invoice_amount       , '238.00000' , "$testname: bt invoice amount was assigned");
 303
 304 };
 305
 306 sub test_overpayment {
 307
 308   my $testname = 'test_overpayment';
 309
 310   $ar_transaction = test_ar_transaction(invnumber => 'salesinv overpaid');
 311
 312   # amount 135 > 119
 313   my $bt = SL::Dev::Payment::create_bank_transaction(record        => $ar_transaction,
 314                                                      bank_chart_id => $bank->id,
 315                                                      amount        => 135
 316                                                     ) or die "Couldn't create bank_transaction";
 317
 318   $::form->{invoice_ids} = {
 319     $bt->id => [ $ar_transaction->id ]
 320   };
 321
 322   save_btcontroller_to_string();
 323
 324   $ar_transaction->load;
 325   $bt->load;
 326
 327   is($ar_transaction->paid                     , '135.00000' , "$testname: 'salesinv overpaid' was overpaid");
 328   is($bt->invoice_amount                       , '135.00000' , "$testname: bt invoice amount was assigned overpaid amount");
 329 { local $TODO = 'this currently fails because closed ignores over-payments, see commit d90966c7';
 330   is($ar_transaction->closed                   , 0           , "$testname: 'salesinv overpaid' is open (via 'closed' method')");
 331 }
 332   is($ar_transaction->open_amount == 0 ? 1 : 0 , 0           , "$testname: 'salesinv overpaid is open (via amount-paid)");
 333
 334 };
 335
 336 sub test_overpayment_with_partialpayment {
 337
 338   # two payments on different days, 10 and 119. If there is only one invoice we want it be overpaid.
 339   my $testname = 'test_overpayment_with_partialpayment';
 340
 341   $ar_transaction = test_ar_transaction(invnumber => 'salesinv overpaid partial');
 342
 343   my $bt_1 = SL::Dev::Payment::create_bank_transaction(record        => $ar_transaction,
 344                                                        bank_chart_id => $bank->id,
 345                                                        amount        =>  10
 346                                                       ) or die "Couldn't create bank_transaction";
 347   my $bt_2 = SL::Dev::Payment::create_bank_transaction(record        => $ar_transaction,
 348                                                        amount        => 119,
 349                                                        transdate     => DateTime->today->add(days => 5),
 350                                                        bank_chart_id => $bank->id,
 351                                                       ) or die "Couldn't create bank_transaction";
 352
 353   $::form->{invoice_ids} = {
 354     $bt_1->id => [ $ar_transaction->id ]
 355   };
 356   save_btcontroller_to_string();
 357
 358   $::form->{invoice_ids} = {
 359     $bt_2->id => [ $ar_transaction->id ]
 360   };
 361   save_btcontroller_to_string();
 362
 363   $ar_transaction->load;
 364   $bt_1->load;
 365   $bt_2->load;
 366
 367   is($ar_transaction->paid , '129.00000' , "$testname: 'salesinv overpaid partial' was overpaid");
 368   is($bt_1->invoice_amount ,  '10.00000' , "$testname: bt_1 invoice amount was assigned overpaid amount");
 369   is($bt_2->invoice_amount , '119.00000' , "$testname: bt_2 invoice amount was assigned overpaid amount");
 370
 371 };
 372
 373 sub test_partial_payment {
 374
 375   my $testname = 'test_partial_payment';
 376
 377   $ar_transaction = test_ar_transaction(invnumber => 'salesinv partial payment');
 378
 379   # amount 100 < 119
 380   my $bt = SL::Dev::Payment::create_bank_transaction(record        => $ar_transaction,
 381                                                      bank_chart_id => $bank->id,
 382                                                      amount        => 100
 383                                                     ) or die "Couldn't create bank_transaction";
 384
 385   $::form->{invoice_ids} = {
 386     $bt->id => [ $ar_transaction->id ]
 387   };
 388
 389   save_btcontroller_to_string();
 390
 391   $ar_transaction->load;
 392   $bt->load;
 393
 394   is($ar_transaction->paid , '100.00000' , "$testname: 'salesinv partial payment' was partially paid");
 395   is($bt->invoice_amount   , '100.00000' , "$testname: bt invoice amount was assigned partially paid amount");
 396
 397 };
 398
 399 sub test_credit_note {
 400
 401   my $testname = 'test_credit_note';
 402
 403   my $part1 = SL::Dev::Part::create_part(   partnumber => 'T4254')->save;
 404   my $part2 = SL::Dev::Part::create_service(partnumber => 'Serv1')->save;
 405   my $credit_note = SL::Dev::Record::create_credit_note(
 406     invnumber    => 'cn 1',
 407     customer     => $customer,
 408     taxincluded  => 0,
 409     invoiceitems => [ SL::Dev::Record::create_invoice_item(part => $part1, qty =>  3, sellprice => 70),
 410                       SL::Dev::Record::create_invoice_item(part => $part2, qty => 10, sellprice => 50),
 411                     ]
 412   );
 413   my $bt            = SL::Dev::Payment::create_bank_transaction(record        => $credit_note,
 414                                                                 amount        => $credit_note->amount,
 415                                                                 bank_chart_id => $bank->id,
 416                                                                 transdate     => DateTime->today->add(days => 10),
 417                                                                );
 418   my ($agreement, $rule_matches) = $bt->get_agreement_with_invoice($credit_note);
 419   is($agreement, 13, "points for credit note ok");
 420   is($rule_matches, 'remote_account_number(3) exact_amount(4) wrong_sign(-1) depositor_matches(2) remote_name(2) payment_within_30_days(1) datebonus14(2) ', "rules_matches for credit note ok");
 421
 422   $::form->{invoice_ids} = {
 423     $bt->id => [ $credit_note->id ]
 424   };
 425
 426   save_btcontroller_to_string();
 427
 428   $credit_note->load;
 429   $bt->load;
 430   is($credit_note->amount   , '-844.90000', "$testname: amount ok");
 431   is($credit_note->netamount, '-710.00000', "$testname: netamount ok");
 432   is($credit_note->paid     , '-844.90000', "$testname: paid ok");
 433 }
 434
 435 sub test_neg_ap_transaction {
 436   my (%params) = @_;
 437   my $testname = 'test_neg_ap_transaction';
 438   my $netamount = -20;
 439   my $amount    = $::form->round_amount($netamount * 1.19,2);
 440   my $invoice   = SL::DB::PurchaseInvoice->new(
 441     invoice      => 0,
 442     invnumber    => $params{invnumber} || 'test_neg_ap_transaction',
 443     amount       => $amount,
 444     netamount    => $netamount,
 445     transdate    => $transdate1,
 446     taxincluded  => 0,
 447     vendor_id    => $vendor->id,
 448     taxzone_id   => $vendor->taxzone_id,
 449     currency_id  => $currency_id,
 450     transactions => [],
 451     notes        => 'test_neg_ap_transaction',
 452   );
 453   $invoice->add_ap_amount_row(
 454     amount     => $invoice->netamount,
 455     chart      => $ap_amount_chart,
 456     tax_id     => $tax_9->id,
 457   );
 458
 459   $invoice->create_ap_row(chart => $ap_chart);
 460   $invoice->save;
 461
 462   is($invoice->netamount, -20  , "$testname: netamount ok");
 463   is($invoice->amount   , -23.8, "$testname: amount ok");
 464
 465   my $bt            = SL::Dev::Payment::create_bank_transaction(record        => $invoice,
 466                                                                 amount        => $invoice->amount,
 467                                                                 bank_chart_id => $bank->id,
 468                                                                 transdate     => DateTime->today->add(days => 10),
 469                                                                );
 470   my ($agreement, $rule_matches) = $bt->get_agreement_with_invoice($invoice);
 471   is($agreement, 15, "points for negative ap transaction ok");
 472
 473   $::form->{invoice_ids} = {
 474     $bt->id => [ $invoice->id ]
 475   };
 476
 477   save_btcontroller_to_string();
 478
 479   $invoice->load;
 480   $bt->load;
 481
 482   is($invoice->amount   , '-23.80000', "$testname: amount ok");
 483   is($invoice->netamount, '-20.00000', "$testname: netamount ok");
 484   is($invoice->paid     , '-23.80000', "$testname: paid ok");
 485   is($bt->invoice_amount, '23.80000', "$testname: bt invoice amount for ap was assigned");
 486
 487   return $invoice;
 488 };
 489
 490 1;