t/helper/shipped_qty.t

   1 use strict;
   2 use Test::More;
   3
   4 use lib 't';
   5 use Support::TestSetup;
   6 use Carp;
   7 use Test::Exception;
   8 use Data::Dumper;
   9 use SL::DB::Part;
  10 use SL::DB::Inventory;
  11 use SL::DB::TransferType;
  12 use SL::DB::Order;
  13 use SL::DB::DeliveryOrder;
  14 use SL::DB::Customer;
  15 use SL::DB::Vendor;
  16 use SL::DB::RecordLink;
  17 use SL::DB::DeliveryOrderItemsStock;
  18 use SL::DB::Bin;
  19 use SL::WH;
  20 use SL::AM;
  21 use SL::Dev::ALL qw(:ALL);
  22 use SL::Helper::ShippedQty;
  23 use DateTime;
  24
  25 Support::TestSetup::login();
  26
  27 clear_up();
  28
  29 my ($customer, $vendor, @parts, $unit);
  30
  31 $customer = new_customer(name => 'Testkunde'    )->save;
  32 $vendor   = new_vendor(  name => 'Testlieferant')->save;
  33
  34 my $default_sellprice = 10;
  35 my $default_lastcost  =  4;
  36
  37 my ($wh) = create_warehouse_and_bins();
  38 my $bin1 = SL::DB::Manager::Bin->find_by(description => "Bin 1");
  39 my $bin2 = SL::DB::Manager::Bin->find_by(description => "Bin 2");
  40
  41 my %part_defaults = (
  42     sellprice    => $default_sellprice,
  43     warehouse_id => $wh->id,
  44     bin_id       => $bin1->id
  45 );
  46
  47 # create 3 parts to be used in test
  48 for my $i ( 1 .. 4 ) {
  49   new_part( %part_defaults, partnumber => $i, description => "part $i test" )->save;
  50 };
  51
  52 my $part1 = SL::DB::Manager::Part->find_by( partnumber => '1' );
  53 my $part2 = SL::DB::Manager::Part->find_by( partnumber => '2' );
  54 my $part3 = SL::DB::Manager::Part->find_by( partnumber => '3' );
  55 my $part4 = SL::DB::Manager::Part->find_by( partnumber => '4' );
  56
  57 my @part_ids; # list of all part_ids to run checks against
  58 push( @part_ids, $_->id ) foreach ( $part1, $part2, $part3, $part4 );
  59 my %default_transfer_params = ( wh => $wh, bin => $bin1, unit => 'Stck');
  60
  61
  62 # test purchases first, so there is actually stock available when sales is tested
  63
  64 note("testing purchases, no fill_up");
  65
  66 $::form->{type} = 'purchase_order';
  67 my $purchase_order = create_purchase_order(
  68   save       => 1,
  69   orderitems => [ create_order_item(part => $part1, qty => 11),
  70                   create_order_item(part => $part2, qty => 12),
  71                   create_order_item(part => $part3, qty => 13),
  72                 ]
  73 );
  74
  75 Rose::DB::Object::Helpers::forget_related($purchase_order, 'orderitems');
  76 $purchase_order->orderitems;
  77
  78 SL::Helper::ShippedQty
  79   ->new(require_stock_out => 1)  # should make no difference while there is no delivery order
  80   ->calculate($purchase_order)
  81   ->write_to_objects;
  82
  83 is($purchase_order->items_sorted->[0]->{shipped_qty}, 0, "first purchase orderitem has no shipped_qty");
  84 ok(!$purchase_order->items_sorted->[0]->{delivered},     "first purchase orderitem is not delivered");
  85
  86 my $purchase_orderitem_part1 = SL::DB::Manager::OrderItem->find_by( parts_id => $part1->id, trans_id => $purchase_order->id);
  87
  88 is($purchase_orderitem_part1->shipped_qty, 0, "OrderItem shipped_qty method ok");
  89
  90 is($purchase_order->closed,     0, 'purchase order is open');
  91 ok(!$purchase_order->delivered,    'purchase order is not delivered');
  92
  93 note('converting purchase order to delivery order');
  94 # create purchase delivery order from purchase order
  95 my $purchase_delivery_order = $purchase_order->convert_to_delivery_order;
  96 is($purchase_order->closed,    0, 'purchase order is open');
  97 ok($purchase_order->delivered,    'purchase order is now delivered');
  98
  99 SL::Helper::ShippedQty
 100   ->new(require_stock_out => 0)
 101   ->calculate($purchase_order)
 102   ->write_to_objects;
 103
 104 is($purchase_order->items_sorted->[0]->{shipped_qty}, 11, "require_stock_out => 0: first purchase orderitem has shipped_qty");
 105 ok($purchase_order->items_sorted->[0]->{delivered},       "require_stock_out => 0: first purchase orderitem is delivered");
 106
 107 Rose::DB::Object::Helpers::forget_related($purchase_order, 'orderitems');
 108 $purchase_order->orderitems;
 109
 110 SL::Helper::ShippedQty
 111   ->new(require_stock_out => 1)
 112   ->calculate($purchase_order)
 113   ->write_to_objects;
 114
 115 is($purchase_order->items_sorted->[0]->{shipped_qty}, 0,  "require_stock_out => 1: first purchase orderitem has no shipped_qty");
 116 ok(!$purchase_order->items_sorted->[0]->{delivered},      "require_stock_out => 1: first purchase orderitem is not delivered");
 117
 118 # ship items from delivery order
 119 transfer_purchase_delivery_order($purchase_delivery_order);
 120
 121 Rose::DB::Object::Helpers::forget_related($purchase_order, 'orderitems');
 122 $purchase_order->orderitems;
 123
 124 SL::Helper::ShippedQty
 125   ->new(require_stock_out => 1, keep_matches => 1)  # shouldn't make a difference now after shipping
 126   ->calculate($purchase_order)
 127   ->write_to_objects;
 128
 129 is($purchase_order->items_sorted->[0]->{shipped_qty}, 11, "require_stock_out => 1: first purchase orderitem has shipped_qty");
 130 ok($purchase_order->items_sorted->[0]->{delivered},       "require_stock_out => 1: first purchase orderitem is delivered");
 131
 132 my $purchase_orderitem_part2 = SL::DB::Manager::OrderItem->find_by(parts_id => $part1->id, trans_id => $purchase_order->id);
 133
 134 is($purchase_orderitem_part2->shipped_qty(require_stock_out => 1), 11, "OrderItem shipped_qty from helper ok");
 135
 136
 137 note('testing sales, no fill_up');
 138
 139 $::form->{type} = 'sales_order';
 140 my $sales_order = create_sales_order(
 141   save       => 1,
 142   orderitems => [ create_order_item(part => $part1, qty => 5),
 143                   create_order_item(part => $part2, qty => 6),
 144                   create_order_item(part => $part3, qty => 7),
 145                 ]
 146 );
 147
 148 Rose::DB::Object::Helpers::forget_related($sales_order, 'orderitems');
 149 $sales_order->orderitems;
 150
 151 SL::Helper::ShippedQty
 152   ->new(require_stock_out => 1)  # should make no difference while there is no delivery order
 153   ->calculate($sales_order)
 154   ->write_to_objects;
 155
 156 is($sales_order->items_sorted->[0]->{shipped_qty}, 0,  "first sales orderitem has no shipped_qty");
 157 ok(!$sales_order->items_sorted->[0]->{delivered},      "first sales orderitem is not delivered");
 158
 159 my $orderitem_part1 = SL::DB::Manager::OrderItem->find_by(parts_id => $part1->id, trans_id => $sales_order->id);
 160 my $orderitem_part2 = SL::DB::Manager::OrderItem->find_by(parts_id => $part2->id, trans_id => $sales_order->id);
 161
 162 is($orderitem_part1->shipped_qty, 0, "OrderItem shipped_qty method ok");
 163
 164 # create sales delivery order from sales order
 165 my $sales_delivery_order = $sales_order->convert_to_delivery_order;
 166
 167 SL::Helper::ShippedQty
 168   ->new(require_stock_out => 0)
 169   ->calculate($sales_order)
 170   ->write_to_objects;
 171
 172 is($sales_order->items_sorted->[0]->{shipped_qty}, 5, "require_stock_out => 0: first sales orderitem has shipped_qty");
 173 ok($sales_order->items_sorted->[0]->{delivered},      "require_stock_out => 0: first sales orderitem is delivered");
 174
 175 Rose::DB::Object::Helpers::forget_related($sales_order, 'orderitems');
 176 $sales_order->orderitems;
 177
 178 SL::Helper::ShippedQty
 179   ->new(require_stock_out => 1)
 180   ->calculate($sales_order)
 181   ->write_to_objects;
 182
 183 is($sales_order->items_sorted->[0]->{shipped_qty}, 0,  "require_stock_out => 1: first sales orderitem has no shipped_qty");
 184 ok(!$sales_order->items_sorted->[0]->{delivered},      "require_stock_out => 1: first sales orderitem is not delivered");
 185
 186 # ship items from delivery order
 187 transfer_sales_delivery_order($sales_delivery_order);
 188
 189 Rose::DB::Object::Helpers::forget_related($sales_order, 'orderitems');
 190 $sales_order->orderitems;
 191
 192 SL::Helper::ShippedQty
 193   ->new(require_stock_out => 1)
 194   ->calculate($sales_order)
 195   ->write_to_objects;
 196
 197 is($sales_order->items_sorted->[0]->{shipped_qty}, 5, "require_stock_out => 1: first sales orderitem has no shipped_qty");
 198 ok($sales_order->items_sorted->[0]->{delivered},      "require_stock_out => 1: first sales orderitem is not delivered");
 199
 200 $orderitem_part1 = SL::DB::Manager::OrderItem->find_by(parts_id => $part1->id, trans_id => $sales_order->id);
 201
 202 is($orderitem_part1->shipped_qty(require_stock_out => 1), 5, "OrderItem shipped_qty from helper ok");
 203
 204
 205 note('misc tests');
 206 my $number_of_linked_items = SL::DB::Manager::RecordLink->get_all_count( where => [ from_table => 'orderitems', to_table => 'delivery_order_items' ] );
 207 is ($number_of_linked_items , 6, "6 record_links for items, 3 from sales order, 3 from purchase order");
 208
 209 note('testing optional orderitems');
 210
 211 my $item_optional = create_order_item(part => $part3, qty => 7, optional => 1);
 212 ok($item_optional->{optional},       "optional order item");
 213
 214 my $sales_order_opt = create_sales_order(
 215   save       => 1,
 216   orderitems => [ create_order_item(part => $part1, qty => 5),
 217                   create_order_item(part => $part2, qty => 6),
 218                   $item_optional,
 219                 ]
 220 );
 221
 222
 223 SL::Helper::ShippedQty
 224   ->new(require_stock_out => 1)  # should make no difference while there is no delivery order
 225   ->calculate($sales_order_opt)
 226   ->write_to_objects;
 227
 228 is($sales_order_opt->items_sorted->[2]->{shipped_qty}, 0,  "third optional sales orderitem has no shipped_qty");
 229 ok(!$sales_order_opt->items_sorted->[2]->{delivered},      "third optional sales orderitem is not delivered");
 230 ok($sales_order_opt->items_sorted->[2]->{optional},        "third optional sales orderitem is optional");
 231
 232 my $orderitem_part3_opt = SL::DB::Manager::OrderItem->find_by(parts_id => $part3->id, trans_id => $sales_order_opt->id);
 233 is($orderitem_part3_opt->shipped_qty, 0, "OrderItem shipped_qty method ok");
 234
 235 # create sales delivery order from sales order
 236 my $sales_delivery_order_opt = $sales_order_opt->convert_to_delivery_order;
 237 is(scalar @{ $sales_delivery_order_opt->items_sorted }, 3,   "third optional sales delivery orderitem is there");
 238
 239 # and delete third item
 240 my $optional =  SL::DB::Manager::DeliveryOrderItem->find_by(parts_id => $part3->id, delivery_order_id => $sales_delivery_order_opt->id);
 241 SL::DB::DeliveryOrderItem->new(id => $optional->id)->delete;
 242 $sales_delivery_order_opt->save(cascade => 1);
 243 my $new_sales_delivery_order_opt = SL::DB::Manager::DeliveryOrder->find_by(id => $sales_delivery_order_opt->id);
 244 is(scalar @{ $new_sales_delivery_order_opt->items_sorted }, 2,   "third optional sales delivery orderitem is undef");
 245
 246 SL::Helper::ShippedQty
 247   ->new(require_stock_out => 0)
 248   ->calculate($sales_order_opt)
 249   ->write_to_objects;
 250
 251 is($sales_order_opt->items_sorted->[0]->{shipped_qty}, 5,  "require_stock_out => 0: first sales orderitem has shipped_qty");
 252 ok($sales_order_opt->items_sorted->[0]->{delivered},       "require_stock_out => 0: first sales orderitem is delivered");
 253 ok($sales_order_opt->items_sorted->[1]->{delivered},       "require_stock_out => 0: second sales orderitem is delivered");
 254 ok(!$sales_order_opt->items_sorted->[2]->{delivered},      "require_stock_out => 0: third sales orderitem is NOT delivered");
 255 is($sales_order_opt->items_sorted->[2]->{shipped_qty}, 0,  "require_stock_out => 0: third sales orderitem has no shipped_qty");
 256 ok($sales_order_opt->{delivered},                          "require_stock_out => 0: order IS delivered");
 257
 258 clear_up();
 259
 260 {
 261 #  legacy unlinked scenario:
 262 #
 263 #  order with two positions of the same part, qtys: 5, 3.
 264 #  3 linked delivery orders, with positions:
 265 #    1:  3 unlinked
 266 #    2:  1 linked to 1, 3 linked to 2
 267 #    3:  1 linked to 1
 268 #
 269 #  should be resolved under fill_up as 5/3, but gets resolved as 4/4
 270   my $part = new_part()->save;
 271   my $order = create_sales_order(
 272     orderitems => [
 273       create_order_item(part => $part, qty => 5),
 274       create_order_item(part => $part, qty => 3),
 275     ],
 276   )->save;
 277   my $do1 = create_sales_delivery_order(
 278     orderitems => [
 279       create_delivery_order_item(part => $part, qty => 3),
 280     ],
 281   );
 282   my $do2 = create_sales_delivery_order(
 283     orderitems => [
 284       create_delivery_order_item(part => $part, qty => 1),
 285       create_delivery_order_item(part => $part, qty => 3),
 286     ],
 287   );
 288   my $do3 = create_sales_delivery_order(
 289     orderitems => [
 290       create_delivery_order_item(part => $part, qty => 1),
 291     ],
 292   );
 293   $order->link_to_record($do1);
 294   $order->link_to_record($do2);
 295   $order->items_sorted->[0]->link_to_record($do2->items_sorted->[0]);
 296   $order->items_sorted->[1]->link_to_record($do2->items_sorted->[1]);
 297   $order->link_to_record($do3);
 298   $order->items_sorted->[0]->link_to_record($do3->items->[0]);
 299
 300   SL::Helper::ShippedQty
 301     ->new(fill_up => 1, require_stock_out => 0)
 302     ->calculate($order)
 303     ->write_to_objects;
 304
 305   is $order->items_sorted->[0]->{shipped_qty}, 5, 'unlinked legacy position test 1';
 306   is $order->items_sorted->[1]->{shipped_qty}, 3, 'unlinked legacy position test 2';
 307 }
 308
 309 clear_up();
 310
 311 done_testing;
 312
 313 sub clear_up {
 314   foreach ( qw(Inventory DeliveryOrderItem DeliveryOrder Price OrderItem Order Part Customer Vendor Bin Warehouse) ) {
 315     "SL::DB::Manager::${_}"->delete_all(all => 1);
 316   }
 317 };