+sub _may_view_or_edit_this_invoice {
+ return 1 if $::auth->assert('ar_transactions', 1); # may edit all invoices
+ return 0 if !$::form->{id}; # creating new invoices isn't allowed without invoice_edit
+ return 0 if !$::form->{globalproject_id}; # existing records without a project ID are not allowed
+ return SL::DB::Project->new(id => $::form->{globalproject_id})->load->may_employee_view_project_invoices(SL::DB::Manager::Employee->current);
+}
+
+sub _assert_access {
+ my $cache = $::request->cache('ar.pl::_assert_access');
+
+ $cache->{_may_view_or_edit_this_invoice} = _may_view_or_edit_this_invoice() if !exists $cache->{_may_view_or_edit_this_invoice};
+ $::form->show_generic_error($::locale->text("You do not have the permissions to access this function.")) if ! $cache->{_may_view_or_edit_this_invoice};
+}
+
+sub load_record_template {
+ $::auth->assert('ar_transactions');
+
+ # Load existing template and verify that its one for this module.
+ my $template = SL::DB::RecordTemplate
+ ->new(id => $::form->{id})
+ ->load(
+ with_object => [ qw(customer payment currency record_items record_items.chart) ],
+ );
+
+ die "invalid template type" unless $template->template_type eq 'ar_transaction';
+
+ $template->substitute_variables;
+
+ # Clean the current $::form before rebuilding it from the template.
+ my $form_defaults = delete $::form->{form_defaults};
+ delete @{ $::form }{ grep { !m{^(?:script|login)$}i } keys %{ $::form } };
+
+ # Fill $::form from the template.
+ my $today = DateTime->today_local;
+ $::form->{title} = "Add";
+ $::form->{currency} = $template->currency->name;
+ $::form->{direct_debit} = $template->direct_debit;
+ $::form->{globalproject_id} = $template->project_id;
+ $::form->{AR_chart_id} = $template->ar_ap_chart_id;
+ $::form->{transdate} = $today->to_kivitendo;
+ $::form->{duedate} = $today->to_kivitendo;
+ $::form->{rowcount} = @{ $template->items };
+ $::form->{paidaccounts} = 1;
+ $::form->{$_} = $template->$_ for qw(department_id ordnumber taxincluded employee_id notes);
+
+ if ($template->customer) {
+ $::form->{customer_id} = $template->customer_id;
+ $::form->{customer} = $template->customer->name;
+ $::form->{duedate} = $template->customer->payment->calc_date(reference_date => $today)->to_kivitendo if $template->customer->payment;
+ }
+
+ my $row = 0;
+ foreach my $item (@{ $template->items }) {
+ $row++;
+
+ my $active_taxkey = $item->chart->get_active_taxkey;
+ my $taxes = SL::DB::Manager::Tax->get_all(
+ where => [ chart_categories => { like => '%' . $item->chart->category . '%' }],
+ sort_by => 'taxkey, rate',
+ );
+
+ my $tax = first { $item->tax_id == $_->id } @{ $taxes };
+ $tax //= first { $active_taxkey->tax_id == $_->id } @{ $taxes };
+ $tax //= $taxes->[0];
+
+ if (!$tax) {
+ $row--;
+ next;
+ }
+
+ $::form->{"AR_amount_chart_id_${row}"} = $item->chart_id;
+ $::form->{"previous_AR_amount_chart_id_${row}"} = $item->chart_id;
+ $::form->{"amount_${row}"} = $::form->format_amount(\%::myconfig, $item->amount1, 2);
+ $::form->{"taxchart_${row}"} = $item->tax_id . '--' . $tax->rate;
+ $::form->{"project_id_${row}"} = $item->project_id;
+ }
+
+ $::form->{$_} = $form_defaults->{$_} for keys %{ $form_defaults // {} };
+
+ flash('info', $::locale->text("The record template '#1' has been loaded.", $template->template_name));
+
+ update(
+ keep_rows_without_amount => 1,
+ dont_add_new_row => 1,
+ );
+}
+
+sub save_record_template {
+ $::auth->assert('ar_transactions');
+
+ my $template = $::form->{record_template_id} ? SL::DB::RecordTemplate->new(id => $::form->{record_template_id})->load : SL::DB::RecordTemplate->new;
+ my $js = SL::ClientJS->new(controller => SL::Controller::Base->new);
+ my $new_name = $template->template_name_to_use($::form->{record_template_new_template_name});
+
+ $js->dialog->close('#record_template_dialog');
+
+ my @items = grep {
+ $_->{chart_id} && (($_->{tax_id} // '') ne '')
+ } map {
+ +{ chart_id => $::form->{"AR_amount_chart_id_${_}"},
+ amount1 => $::form->parse_amount(\%::myconfig, $::form->{"amount_${_}"}),
+ tax_id => (split m{--}, $::form->{"taxchart_${_}"})[0],
+ project_id => $::form->{"project_id_${_}"} || undef,
+ }
+ } (1..($::form->{rowcount} || 1));
+
+ $template->assign_attributes(
+ template_type => 'ar_transaction',
+ template_name => $new_name,
+
+ currency_id => SL::DB::Manager::Currency->find_by(name => $::form->{currency})->id,
+ ar_ap_chart_id => $::form->{AR_chart_id} || undef,
+ customer_id => $::form->{customer_id} || undef,
+ department_id => $::form->{department_id} || undef,
+ project_id => $::form->{globalproject_id} || undef,
+ employee_id => $::form->{employee_id} || undef,
+ taxincluded => $::form->{taxincluded} ? 1 : 0,
+ direct_debit => $::form->{direct_debit} ? 1 : 0,
+ ordnumber => $::form->{ordnumber},
+ notes => $::form->{notes},
+
+ items => \@items,
+ );
+
+ eval {
+ $template->save;
+ 1;
+ } or do {
+ return $js
+ ->flash('error', $::locale->text("Saving the record template '#1' failed.", $new_name))
+ ->render;
+ };
+
+ return $js
+ ->flash('info', $::locale->text("The record template '#1' has been saved.", $new_name))
+ ->render;
+}
+