#====================================================================
# LX-Office ERP
# Copyright (C) 2004
# Based on SQL-Ledger Version 2.1.9
# Web http://www.lx-office.org
#
#=====================================================================
# SQL-Ledger Accounting
# Copyright (C) 1999-2003
#
#  Author: Dieter Simader
#   Email: dsimader@sql-ledger.org
#     Web: http://www.sql-ledger.org
#
#  Contributors:
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#======================================================================
#
# Order entry module
# Quotation
#======================================================================

package OE;

use SL::AM;
use SL::Common;
use SL::DBUtils;

sub transactions {
  $main::lxdebug->enter_sub();

  my ($self, $myconfig, $form) = @_;

  # connect to database
  my $dbh = $form->dbconnect($myconfig);

  my $query;
  my $ordnumber = 'ordnumber';
  my $quotation = '0';

  my @values;
  my $where;

  my $rate = ($form->{vc} eq 'customer') ? 'buy' : 'sell';

  if ($form->{type} =~ /_quotation$/) {
    $quotation = '1';
    $ordnumber = 'quonumber';
  }

  my $vc = $form->{vc} eq "customer" ? "customer" : "vendor";

  $query =
    qq|SELECT o.id, o.ordnumber, o.transdate, o.reqdate, | .
    qq|  o.amount, ct.name, o.netamount, o.${vc}_id, o.globalproject_id, | .
    qq|  o.closed, o.delivered, o.quonumber, o.shippingpoint, o.shipvia, | .
    qq|  o.transaction_description, | .
    qq|  ex.$rate AS exchangerate, | .
    qq|  pr.projectnumber AS globalprojectnumber, | .
    qq|  e.name AS employee | .
    qq|FROM oe o | .
    qq|JOIN $vc ct ON (o.${vc}_id = ct.id) | .
    qq|LEFT JOIN employee e ON (o.employee_id = e.id) | .
    qq|LEFT JOIN exchangerate ex ON (ex.curr = o.curr | .
    qq|  AND ex.transdate = o.transdate) | .
    qq|LEFT JOIN project pr ON (o.globalproject_id = pr.id) | .
    qq|WHERE (o.quotation = ?) |;
  push(@values, $quotation);

  my ($null, $department_id) = split /--/, $form->{department};
  if ($department_id) {
    $query .= qq| AND o.department_id = ?|;
    push(@values, $department_id);
  }

  if ($form->{"project_id"}) {
    $query .=
      qq|AND ((globalproject_id = ?) OR EXISTS | .
      qq|  (SELECT * FROM orderitems oi | .
      qq|   WHERE oi.project_id = ? AND oi.trans_id = o.id))|;
    push(@values, $form->{"project_id"}, $form->{"project_id"});
  }

  if ($form->{"${vc}_id"}) {
    $query .= " AND o.${vc}_id = ?";
    push(@values, $form->{"${vc}_id"});

  } elsif ($form->{$vc}) {
    $query .= " AND ct.name ILIKE ?";
    push(@values, '%' . $form->{$vc} . '%');
  }

  if ($form->{employee_id}) {
    $query .= " AND o.employee_id = ?";
    push @values, conv_i($form->{employee_id});
  }

  if (!$form->{open} && !$form->{closed}) {
    $query .= " AND o.id = 0";
  } elsif (!($form->{open} && $form->{closed})) {
    $query .= ($form->{open}) ? " AND o.closed = '0'" : " AND o.closed = '1'";
  }

  if (($form->{"notdelivered"} || $form->{"delivered"}) &&
      ($form->{"notdelivered"} ne $form->{"delivered"})) {
    $query .= $form->{"delivered"} ?
      " AND o.delivered " : " AND NOT o.delivered";
  }

  if ($form->{$ordnumber}) {
    $query .= qq| AND o.$ordnumber ILIKE ?|;
    push(@values, '%' . $form->{$ordnumber} . '%');
  }

  if($form->{transdatefrom}) {
    $query .= qq| AND o.transdate >= ?|;
    push(@values, conv_date($form->{transdatefrom}));
  }

  if($form->{transdateto}) {
    $query .= qq| AND o.transdate <= ?|;
    push(@values, conv_date($form->{transdateto}));
  }

  if ($form->{transaction_description}) {
    $query .= qq| AND o.transaction_description ILIKE ?|;
    push(@values, '%' . $form->{transaction_description} . '%');
  }

  my $sortorder = join(', ', ("o.id", $form->sort_columns("transdate", $ordnumber, "name")));
  my %allowed_sort_columns =
    ("transdate" => "o.transdate",
     "reqdate" => "o.reqdate",
     "id" => "o.id",
     "ordnumber" => "o.ordnumber",
     "quonumber" => "o.quonumber",
     "name" => "ct.name",
     "employee" => "e.name",
     "shipvia" => "o.shipvia",
     "transaction_description" => "o.transaction_description");
  if ($form->{sort} && grep($form->{sort}, keys(%allowed_sort_columns))) {
    $sortorder = $allowed_sort_columns{$form->{sort}};
  }
  $query .= qq| ORDER by | . $sortorder;

  my $sth = $dbh->prepare($query);
  $sth->execute(@values) ||
    $form->dberror($query . " (" . join(", ", @values) . ")");

  my %id = ();
  $form->{OE} = [];
  while (my $ref = $sth->fetchrow_hashref(NAME_lc)) {
    $ref->{exchangerate} = 1 unless $ref->{exchangerate};
    push @{ $form->{OE} }, $ref if $ref->{id} != $id{ $ref->{id} };
    $id{ $ref->{id} } = $ref->{id};
  }

  $sth->finish;
  $dbh->disconnect;

  $main::lxdebug->leave_sub();
}

sub save {
  $main::lxdebug->enter_sub();

  my ($self, $myconfig, $form) = @_;

  # connect to database, turn off autocommit
  my $dbh = $form->dbconnect_noauto($myconfig);

  my ($query, @values, $sth, $null);
  my $exchangerate = 0;

  my $all_units = AM->retrieve_units($myconfig, $form);
  $form->{all_units} = $all_units;

  $form->{employee_id} = (split /--/, $form->{employee})[1] if !$form->{employee_id};
  unless ($form->{employee_id}) {
    $form->get_employee($dbh);
  }

  my $ml = ($form->{type} eq 'sales_order') ? 1 : -1;

  if ($form->{id}) {

    &adj_onhand($dbh, $form, $ml) if $form->{type} =~ /_order$/;

    $query = qq|DELETE FROM orderitems WHERE trans_id = ?|;
    do_query($form, $dbh, $query, $form->{id});

    $query = qq|DELETE FROM shipto | .
             qq|WHERE trans_id = ? AND module = 'OE'|;
    do_query($form, $dbh, $query, $form->{id});

  } else {

    $query = qq|SELECT nextval('id')|;
    ($form->{id}) = selectrow_query($form, $dbh, $query);

    $query = qq|INSERT INTO oe (id, ordnumber, employee_id) VALUES (?, '', ?)|;
    do_query($form, $dbh, $query, $form->{id}, $form->{employee_id});
  }

  my $amount;
  my $linetotal;
  my $discount;
  my $project_id;
  my $reqdate;
  my $taxrate;
  my $taxamount;
  my $fxsellprice;
  my %taxbase;
  my @taxaccounts;
  my %taxaccounts;
  my $netamount = 0;

  for my $i (1 .. $form->{rowcount}) {

    map({ $form->{"${_}_$i"} =
            $form->parse_amount($myconfig, $form->{"${_}_$i"}) } qw(qty ship));

    if ($form->{"id_$i"}) {

      # get item baseunit
      $query = qq|SELECT unit FROM parts WHERE id = ?|;
      my ($item_unit) = selectrow_query($form, $dbh, $query, $form->{"id_$i"});

      my $basefactor = 1;
      if (defined($all_units->{$item_unit}->{factor}) &&
          (($all_units->{$item_unit}->{factor} * 1) != 0)) {
        $basefactor = $all_units->{$form->{"unit_$i"}}->{factor} /
          $all_units->{$item_unit}->{factor};
      }
      my $baseqty = $form->{"qty_$i"} * $basefactor;

      # set values to 0 if nothing entered
      $form->{"discount_$i"} =
        $form->parse_amount($myconfig, $form->{"discount_$i"}) / 100;

      $form->{"sellprice_$i"} =
        $form->parse_amount($myconfig, $form->{"sellprice_$i"});
      $fxsellprice = $form->{"sellprice_$i"};

      my ($dec) = ($form->{"sellprice_$i"} =~ /\.(\d+)/);
      $dec = length($dec);
      my $decimalplaces = ($dec > 2) ? $dec : 2;

      $discount =
        $form->round_amount($form->{"sellprice_$i"} * $form->{"discount_$i"},
                            $decimalplaces);
      $form->{"sellprice_$i"} =
        $form->round_amount($form->{"sellprice_$i"} - $discount,
                            $decimalplaces);

      $form->{"inventory_accno_$i"} *= 1;
      $form->{"expense_accno_$i"}   *= 1;

      $linetotal =
        $form->round_amount($form->{"sellprice_$i"} * $form->{"qty_$i"}, 2);

      @taxaccounts = split(/ /, $form->{"taxaccounts_$i"});
      $taxrate     = 0;
      $taxdiff     = 0;

      map { $taxrate += $form->{"${_}_rate"} } @taxaccounts;

      if ($form->{taxincluded}) {
        $taxamount = $linetotal * $taxrate / (1 + $taxrate);
        $taxbase   = $linetotal - $taxamount;

        # we are not keeping a natural price, do not round
        $form->{"sellprice_$i"} =
          $form->{"sellprice_$i"} * (1 / (1 + $taxrate));
      } else {
        $taxamount = $linetotal * $taxrate;
        $taxbase   = $linetotal;
      }

      if ($form->round_amount($taxrate, 7) == 0) {
        if ($form->{taxincluded}) {
          foreach $item (@taxaccounts) {
            $taxamount =
              $form->round_amount($linetotal * $form->{"${item}_rate"} /
                                    (1 + abs($form->{"${item}_rate"})),
                                  2);

            $taxaccounts{$item} += $taxamount;
            $taxdiff            += $taxamount;

            $taxbase{$item} += $taxbase;
          }
          $taxaccounts{ $taxaccounts[0] } += $taxdiff;
        } else {
          foreach $item (@taxaccounts) {
            $taxaccounts{$item} += $linetotal * $form->{"${item}_rate"};
            $taxbase{$item}     += $taxbase;
          }
        }
      } else {
        foreach $item (@taxaccounts) {
          $taxaccounts{$item} +=
            $taxamount * $form->{"${item}_rate"} / $taxrate;
          $taxbase{$item} += $taxbase;
        }
      }

      $netamount += $form->{"sellprice_$i"} * $form->{"qty_$i"};

      $reqdate =
        ($form->{"reqdate_$i"}) ? $form->{"reqdate_$i"} : undef;

      # get pricegroup_id and save ist
      ($null, my $pricegroup_id) = split(/--/, $form->{"sellprice_pg_$i"});
      $pricegroup_id *= 1;
      $subtotal = $form->{"subtotal_$i"} * 1;

      # save detail record in orderitems table
      @values = ();
      $query = qq|INSERT INTO orderitems (|;
      if ($form->{"orderitems_id_$i"}) {
        $query .= "id, ";
      }
      $query .= qq|trans_id, parts_id, description, longdescription, qty, base_qty, | .
                qq|sellprice, discount, unit, reqdate, project_id, serialnumber, ship, | .
                qq|pricegroup_id, ordnumber, transdate, cusordnumber, subtotal) | .
                qq|VALUES (|;
      if($form->{"orderitems_id_$i"}) {
        $query .= qq|?,|;
        push(@values, $form->{"orderitems_id_$i"});
      }
      $query .= qq|?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?)|;
		  push(@values,
           conv_i($form->{id}), conv_i($form->{"id_$i"}),
           $form->{"description_$i"}, $form->{"longdescription_$i"},
           $form->{"qty_$i"}, $baseqty,
           $fxsellprice, $form->{"discount_$i"},
           $form->{"unit_$i"}, conv_date($reqdate), conv_i($form->{"project_id_$i"}),
           $form->{"serialnumber_$i"}, $form->{"ship_$i"}, conv_i($pricegroup_id),
           $form->{"ordnumber_$i"}, conv_date($form->{"transdate_$i"}),
           $form->{"cusordnumber_$i"}, $subtotal);
      do_query($form, $dbh, $query, @values);

      $form->{"sellprice_$i"} = $fxsellprice;
      $form->{"discount_$i"} *= 100;
    }
  }

  $reqdate = ($form->{reqdate}) ? $form->{reqdate} : undef;

  # add up the tax
  my $tax = 0;
  map { $tax += $form->round_amount($taxaccounts{$_}, 2) } keys %taxaccounts;

  $amount = $form->round_amount($netamount + $tax, 2);
  $netamount = $form->round_amount($netamount, 2);

  if ($form->{currency} eq $form->{defaultcurrency}) {
    $form->{exchangerate} = 1;
  } else {
    $exchangerate =
      $form->check_exchangerate($myconfig,
                                $form->{currency},
                                $form->{transdate},
                                ($form->{vc} eq 'customer') ? 'buy' : 'sell');
  }

  $form->{exchangerate} =
    ($exchangerate)
    ? $exchangerate
    : $form->parse_amount($myconfig, $form->{exchangerate});

  my $quotation;

  # fill in subject if there is none
  if ($form->{type} =~ /_order$/) {
    $quotation = '0';
    $form->{subject} = qq|$form->{label} $form->{ordnumber}|
      unless $form->{subject};
  } else {
    $quotation = '1';
    $form->{subject} = qq|$form->{label} $form->{quonumber}|
      unless $form->{subject};
  }

  # if there is a message stuff it into the intnotes
  my $cc  = "Cc: $form->{cc}\\r\n"   if $form->{cc};
  my $bcc = "Bcc: $form->{bcc}\\r\n" if $form->{bcc};
  my $now = scalar localtime;
  $form->{intnotes} .= qq|\r
\r| if $form->{intnotes};

  $form->{intnotes} .= qq|[email]\r
Date: $now
To: $form->{email}\r
$cc${bcc}Subject: $form->{subject}\r
\r
Message: $form->{message}\r| if $form->{message};

  ($null, $form->{department_id}) = split(/--/, $form->{department});

  # save OE record
  $query =
    qq|UPDATE oe set | .
    qq|ordnumber = ?, quonumber = ?, cusordnumber = ?, transdate = ?, vendor_id = ?, | .
    qq|customer_id = ?, amount = ?, netamount = ?, reqdate = ?, taxincluded = ?, | .
    qq|shippingpoint = ?, shipvia = ?, notes = ?, intnotes = ?, curr = ?, closed = ?, | .
    qq|delivered = ?, proforma = ?, quotation = ?, department_id = ?, language_id = ?, | .
    qq|taxzone_id = ?, shipto_id = ?, payment_id = ?, delivery_vendor_id = ?, delivery_customer_id = ?, | .
    qq|globalproject_id = ?, employee_id = ?, salesman_id = ?, cp_id = ?, transaction_description = ? | .
    qq|WHERE id = ?|;

  @values = ($form->{ordnumber}, $form->{quonumber},
             $form->{cusordnumber}, conv_date($form->{transdate}),
             conv_i($form->{vendor_id}), conv_i($form->{customer_id}),
             $amount, $netamount, conv_date($reqdate),
             $form->{taxincluded} ? 't' : 'f', $form->{shippingpoint},
             $form->{shipvia}, $form->{notes}, $form->{intnotes},
             $form->{currency}, $form->{closed} ? 't' : 'f',
             $form->{delivered} ? "t" : "f", $form->{proforma} ? 't' : 'f',
             $quotation, conv_i($form->{department_id}),
             conv_i($form->{language_id}), conv_i($form->{taxzone_id}),
             conv_i($form->{shipto_id}), conv_i($form->{payment_id}),
             conv_i($form->{delivery_vendor_id}),
             conv_i($form->{delivery_customer_id}),
             conv_i($form->{globalproject_id}), conv_i($form->{employee_id}),
             conv_i($form->{salesman_id}), conv_i($form->{cp_id}),
             $form->{transaction_description},
             conv_i($form->{id}));
  do_query($form, $dbh, $query, @values);

  $form->{ordtotal} = $amount;

  # add shipto
  $form->{name} = $form->{ $form->{vc} };
  $form->{name} =~ s/--$form->{"$form->{vc}_id"}//;

  if (!$form->{shipto_id}) {
    $form->add_shipto($dbh, $form->{id}, "OE");
  }

  # save printed, emailed, queued
  $form->save_status($dbh);

  if (($form->{currency} ne $form->{defaultcurrency}) && !$exchangerate) {
    if ($form->{vc} eq 'customer') {
      $form->update_exchangerate($dbh, $form->{currency}, $form->{transdate},
                                 $form->{exchangerate}, 0);
    }
    if ($form->{vc} eq 'vendor') {
      $form->update_exchangerate($dbh, $form->{currency}, $form->{transdate},
                                 0, $form->{exchangerate});
    }
  }

  if ($form->{type} =~ /_order$/) {

    # adjust onhand
    &adj_onhand($dbh, $form, $ml * -1);
  }

  my $rc = $dbh->commit;
  $dbh->disconnect;

  $form->{saved_xyznumber} = $form->{$form->{type} =~ /_quotation$/ ?
                                       "quonumber" : "ordnumber"};

  Common::webdav_folder($form) if ($main::webdav);

  $main::lxdebug->leave_sub();

  return $rc;
}

# this function closes multiple orders given in $form->{ordnumber_#}.
# use this for multiple orders that don't have to be saved back
# single orders should use OE::save instead.
sub close_orders {
  $main::lxdebug->enter_sub();

  my ($self, $myconfig, $form) = @_;

  # get ids from $form
  map { push @ids, $form->{"ordnumber_$_"} if $form->{"ordnumber_$_"} }
    (1 .. $form->{rowcount});

  my $dbh = $form->dbconnect($myconfig);
  $query = qq|UPDATE oe SET | .
           qq|closed = TRUE | .
           qq|WHERE ordnumber IN (|
    . join(', ', map { $dbh->quote($_) } @ids) . qq|)|;
  $dbh->do($query) || $form->dberror($query);
  $dbh->disconnect;

  $main::lxdebug->leave_sub();
}

sub close_order {
  $main::lxdebug->enter_sub();

  my ($self, $myconfig, $form) = @_;

  $main::lxdebug->leave_sub() unless ($form->{"id"});

  my $dbh = $form->dbconnect($myconfig);
  do_query($form, $dbh, qq|UPDATE oe SET closed = TRUE where id = ?|,
           $form->{"id"});
  $dbh->disconnect;

  $main::lxdebug->leave_sub();
}

sub delete {
  $main::lxdebug->enter_sub();

  my ($self, $myconfig, $form, $spool) = @_;

  # connect to database
  my $dbh = $form->dbconnect_noauto($myconfig);

  # delete spool files
  my $query = qq|SELECT s.spoolfile FROM status s | .
              qq|WHERE s.trans_id = ?|;
  my @values = (conv_i($form->{id}));
  $sth = $dbh->prepare($query);
  $sth->execute(@values) || $self->dberror($query);

  my $spoolfile;
  my @spoolfiles = ();

  while (($spoolfile) = $sth->fetchrow_array) {
    push @spoolfiles, $spoolfile;
  }
  $sth->finish;

  $query = qq|SELECT o.parts_id, o.ship FROM orderitems o | .
           qq|WHERE o.trans_id = ?|;
  @values = (conv_i($form->{id}));
  $sth = $dbh->prepare($query);
  $sth->execute(@values) || $self->dberror($query);

  while (my ($id, $ship) = $sth->fetchrow_array) {
    $form->update_balance($dbh, "parts", "onhand", qq|id = $id|, $ship * -1);
  }
  $sth->finish;

  # delete-values
  @values = (conv_i($form->{id}));

  # delete inventory
  $query = qq|DELETE FROM inventory | .
           qq|WHERE oe_id = ?|;
  do_query($form, $dbh, $query, @values);

  # delete status entries
  $query = qq|DELETE FROM status | .
           qq|WHERE trans_id = ?|;
  do_query($form, $dbh, $query, @values);

  # delete OE record
  $query = qq|DELETE FROM oe | .
           qq|WHERE id = ?|;
  do_query($form, $dbh, $query, @values);

  # delete individual entries
  $query = qq|DELETE FROM orderitems | .
           qq|WHERE trans_id = ?|;
  do_query($form, $dbh, $query, @values);

  $query = qq|DELETE FROM shipto | .
           qq|WHERE trans_id = ? AND module = 'OE'|;
  do_query($form, $dbh, $query, @values);

  my $rc = $dbh->commit;
  $dbh->disconnect;

  if ($rc) {
    foreach $spoolfile (@spoolfiles) {
      unlink "$spool/$spoolfile" if $spoolfile;
    }
  }

  $main::lxdebug->leave_sub();

  return $rc;
}

sub retrieve {
  $main::lxdebug->enter_sub();

  my ($self, $myconfig, $form) = @_;

  # connect to database
  my $dbh = $form->dbconnect_noauto($myconfig);

  my ($query, @values, @ids);

  # translate the ids (given by id_# and trans_id_#) into one array of ids, so we can join them later
  map {
    push @ids, $form->{"trans_id_$_"}
      if ($form->{"multi_id_$_"} and $form->{"trans_id_$_"})
  } (1 .. $form->{"rowcount"});

  # if called in multi id mode, and still only got one id, switch back to single id
  if ($form->{"rowcount"} and $#ids == 0) {
    $form->{"id"} = $ids[0];
    undef @ids;
  }

  if ($form->{id}) {

    # get default accounts and last order number
    $query =
      qq|SELECT (SELECT c.accno FROM chart c | .
      qq|        WHERE d.inventory_accno_id = c.id) AS inventory_accno, | .
      qq|       (SELECT c.accno FROM chart c | .
      qq|        WHERE d.income_accno_id = c.id) AS income_accno, | .
      qq|       (SELECT c.accno FROM chart c | .
      qq|        WHERE d.expense_accno_id = c.id) AS expense_accno, | .
      qq|       (SELECT c.accno FROM chart c | .
      qq|        WHERE d.fxgain_accno_id = c.id) AS fxgain_accno, | .
      qq|       (SELECT c.accno FROM chart c | .
      qq|        WHERE d.fxloss_accno_id = c.id) AS fxloss_accno, | .
      qq|d.curr AS currencies | .
      qq|FROM defaults d|;
  } else {
    $query =
      qq|SELECT (SELECT c.accno FROM chart c | .
      qq|        WHERE d.inventory_accno_id = c.id) AS inventory_accno, | .
      qq|       (SELECT c.accno FROM chart c | .
      qq|        WHERE d.income_accno_id = c.id) AS income_accno, | .
      qq|       (SELECT c.accno FROM chart c | .
      qq|        WHERE d.expense_accno_id = c.id) AS expense_accno, | .
      qq|       (SELECT c.accno FROM chart c | .
      qq|        WHERE d.fxgain_accno_id = c.id) AS fxgain_accno, | .
      qq|       (SELECT c.accno FROM chart c | .
      qq|        WHERE d.fxloss_accno_id = c.id) AS fxloss_accno, | .
      qq|d.curr AS currencies, | .
      qq|current_date AS transdate, current_date AS reqdate | .
      qq|FROM defaults d|;
  }
  my $sth = $dbh->prepare($query);
  $sth->execute || $form->dberror($query);

  my $ref = $sth->fetchrow_hashref(NAME_lc);
  map { $form->{$_} = $ref->{$_} } keys %$ref;
  $sth->finish;

  ($form->{currency}) = split(/:/, $form->{currencies});

  # set reqdate if this is an invoice->order conversion. If someone knows a better check to ensure
  # we come from invoices, feel free.
  $form->{reqdate} = $form->{deliverydate}
    if (    $form->{deliverydate}
        and $form->{callback} =~ /action=ar_transactions/);

  my $vc = $form->{vc} eq "customer" ? "customer" : "vendor";

  if ($form->{id} or @ids) {

    # retrieve order for single id
    # NOTE: this query is intended to fetch all information only ONCE.
    # so if any of these infos is important (or even different) for any item,
    # it will be killed out and then has to be fetched from the item scope query further down
    $query =
      qq|SELECT o.cp_id, o.ordnumber, o.transdate, o.reqdate, | .
      qq|  o.taxincluded, o.shippingpoint, o.shipvia, o.notes, o.intnotes, | .
      qq|  o.curr AS currency, e.name AS employee, o.employee_id, o.salesman_id, | .
      qq|  o.${vc}_id, cv.name AS ${vc}, o.amount AS invtotal, | .
      qq|  o.closed, o.reqdate, o.quonumber, o.department_id, o.cusordnumber, | .
      qq|  d.description AS department, o.payment_id, o.language_id, o.taxzone_id, | .
      qq|  o.delivery_customer_id, o.delivery_vendor_id, o.proforma, o.shipto_id, | .
      qq|  o.globalproject_id, o.delivered, o.transaction_description | .
      qq|FROM oe o | .
      qq|JOIN ${vc} cv ON (o.${vc}_id = cv.id) | .
      qq|LEFT JOIN employee e ON (o.employee_id = e.id) | .
      qq|LEFT JOIN department d ON (o.department_id = d.id) | .
 		  ($form->{id} ? qq|WHERE o.id = ?| :
       qq|WHERE o.id IN (| . join(', ', map("? ", @ids)) . qq|)|);
    @values = $form->{id} ? ($form->{id}) : @ids;
    $sth = prepare_execute_query($form, $dbh, $query, @values);

    $ref = $sth->fetchrow_hashref(NAME_lc);
    map { $form->{$_} = $ref->{$_} } keys %$ref;

    $form->{saved_xyznumber} = $form->{$form->{type} =~ /_quotation$/ ?
                                         "quonumber" : "ordnumber"};

    # set all entries for multiple ids blank that yield different information
    while ($ref = $sth->fetchrow_hashref(NAME_lc)) {
      map { $form->{$_} = '' if ($ref->{$_} ne $form->{$_}) } keys %$ref;
    }

    # if not given, fill transdate with current_date
    $form->{transdate} = $form->current_date($myconfig)
      unless $form->{transdate};

    $sth->finish;

    if ($form->{delivery_customer_id}) {
      $query = qq|SELECT name FROM customer WHERE id = ?|;
      ($form->{delivery_customer_string}) =
        selectrow_query($form, $dbh, $query, $form->{delivery_customer_id});
    }

    if ($form->{delivery_vendor_id}) {
      $query = qq|SELECT name FROM customer WHERE id = ?|;
      ($form->{delivery_vendor_string}) =
        selectrow_query($form, $dbh, $query, $form->{delivery_vendor_id});
    }

    # shipto and pinted/mailed/queued status makes only sense for single id retrieve
    if (!@ids) {
      $query = qq|SELECT s.* FROM shipto s | .
               qq|WHERE s.trans_id = ? AND s.module = 'OE'|;
      $sth = prepare_execute_query($form, $dbh, $query, $form->{id});

      $ref = $sth->fetchrow_hashref(NAME_lc);
      delete($ref->{id});
      map { $form->{$_} = $ref->{$_} } keys %$ref;
      $sth->finish;

      # get printed, emailed and queued
      $query = qq|SELECT s.printed, s.emailed, s.spoolfile, s.formname | .
               qq|FROM status s | .
               qq|WHERE s.trans_id = ?|;
      $sth = prepare_execute_query($form, $dbh, $query, $form->{id});

      while ($ref = $sth->fetchrow_hashref(NAME_lc)) {
        $form->{printed} .= "$ref->{formname} " if $ref->{printed};
        $form->{emailed} .= "$ref->{formname} " if $ref->{emailed};
        $form->{queued} .= "$ref->{formname} $ref->{spoolfile} "
          if $ref->{spoolfile};
      }
      $sth->finish;
      map { $form->{$_} =~ s/ +$//g } qw(printed emailed queued);
    }    # if !@ids

    my %oid = ('Pg'     => 'oid',
               'Oracle' => 'rowid');

    my $transdate =
      $form->{transdate} ? $dbh->quote($form->{transdate}) : "current_date";

    $form->{taxzone_id} = 0 unless ($form->{taxzone_id});

    # retrieve individual items
    # this query looks up all information about the items
    # stuff different from the whole will not be overwritten, but saved with a suffix.
    $query =
      qq|SELECT o.id AS orderitems_id, | .
      qq|  c1.accno AS inventory_accno, c1.new_chart_id AS inventory_new_chart, date($transdate) - c1.valid_from as inventory_valid, | .
      qq|  c2.accno AS income_accno, c2.new_chart_id AS income_new_chart, date($transdate)  - c2.valid_from as income_valid, | .
      qq|  c3.accno AS expense_accno, c3.new_chart_id AS expense_new_chart, date($transdate) - c3.valid_from as expense_valid, | .
      qq|  oe.ordnumber AS ordnumber_oe, oe.transdate AS transdate_oe, oe.cusordnumber AS cusordnumber_oe,  | .
      qq|  p.partnumber, p.assembly, o.description, o.qty, | .
      qq|  o.sellprice, o.parts_id AS id, o.unit, o.discount, p.bin, p.notes AS partnotes, p.inventory_accno_id AS part_inventory_accno_id, | .
      qq|  o.reqdate, o.project_id, o.serialnumber, o.ship, | .
      qq|  o.ordnumber, o.transdate, o.cusordnumber, o.subtotal, o.longdescription, | .
      qq|  pr.projectnumber, p.formel, | .
      qq|  pg.partsgroup, o.pricegroup_id, (SELECT pricegroup FROM pricegroup WHERE id=o.pricegroup_id) as pricegroup | .
      qq|FROM orderitems o | .
      qq|JOIN parts p ON (o.parts_id = p.id) | .
      qq|JOIN oe ON (o.trans_id = oe.id) | .
      qq|LEFT JOIN chart c1 ON ((SELECT inventory_accno_id FROM buchungsgruppen WHERE id=p.buchungsgruppen_id) = c1.id) | .
      qq|LEFT JOIN chart c2 ON ((SELECT income_accno_id_$form->{taxzone_id} FROM buchungsgruppen WHERE id=p.buchungsgruppen_id) = c2.id) | .
      qq|LEFT JOIN chart c3 ON ((SELECT expense_accno_id_$form->{taxzone_id} FROM buchungsgruppen WHERE id=p.buchungsgruppen_id) = c3.id) | .
      qq|LEFT JOIN project pr ON (o.project_id = pr.id) | .
      qq|LEFT JOIN partsgroup pg ON (p.partsgroup_id = pg.id) | .
      ($form->{id} ? qq|WHERE o.trans_id = ?| :
       qq|WHERE o.trans_id IN (| . join(", ", map("?", @ids)) . qq|)|) .
      qq|ORDER BY o.$oid{$myconfig->{dbdriver}}|;

    @ids = $form->{id} ? ($form->{id}) : @ids;
    $sth = prepare_execute_query($form, $dbh, $query, @values);

    while ($ref = $sth->fetchrow_hashref(NAME_lc)) {
      if (!$ref->{"part_inventory_accno_id"}) {
        map({ delete($ref->{$_}); } qw(inventory_accno inventory_new_chart inventory_valid));
      }
      delete($ref->{"part_inventory_accno_id"});

      # in collective order, copy global ordnumber, transdate, cusordnumber into item scope
      #   unless already present there
      # remove _oe entries afterwards
      map { $ref->{$_} = $ref->{"${_}_oe"} if ($ref->{$_} eq '') }
        qw|ordnumber transdate cusordnumber|
        if (@ids);
      map { delete $ref->{$_} } qw|ordnumber_oe transdate_oe cusordnumber_oe|;



      while ($ref->{inventory_new_chart} && ($ref->{inventory_valid} >= 0)) {
        my $query =
          qq|SELECT accno AS inventory_accno, | .
          qq|  new_chart_id AS inventory_new_chart, | .
          qq|  date($transdate) - valid_from AS inventory_valid | .
          qq|FROM chart WHERE id = $ref->{inventory_new_chart}|;
        ($ref->{inventory_accno}, $ref->{inventory_new_chart},
         $ref->{inventory_valid}) = selectrow_query($form, $dbh, $query);
      }

      while ($ref->{income_new_chart} && ($ref->{income_valid} >= 0)) {
        my $query =
          qq|SELECT accno AS income_accno, | .
          qq|  new_chart_id AS income_new_chart, | .
          qq|  date($transdate) - valid_from AS income_valid | .
          qq|FROM chart WHERE id = $ref->{income_new_chart}|;
        ($ref->{income_accno}, $ref->{income_new_chart},
         $ref->{income_valid}) = selectrow_query($form, $dbh, $query);
      }

      while ($ref->{expense_new_chart} && ($ref->{expense_valid} >= 0)) {
        my $query =
          qq|SELECT accno AS expense_accno, | .
          qq|  new_chart_id AS expense_new_chart, | .
          qq|  date($transdate) - valid_from AS expense_valid | .
          qq|FROM chart WHERE id = $ref->{expense_new_chart}|;
        ($ref->{expense_accno}, $ref->{expense_new_chart},
         $ref->{expense_valid}) = selectrow_query($form, $dbh, $query);
      }

      # delete orderitems_id in collective orders, so that they get cloned no matter what
      delete $ref->{orderitems_id} if (@ids);

      # get tax rates and description
      $accno_id =
        ($form->{vc} eq "customer") ? $ref->{income_accno} : $ref->{expense_accno};
      $query =
        qq|SELECT c.accno, t.taxdescription, t.rate, t.taxnumber | .
        qq|FROM tax t LEFT JOIN chart c on (c.id = t.chart_id) | .
        qq|WHERE t.id IN (SELECT tk.tax_id FROM taxkeys tk | .
        qq|               WHERE tk.chart_id = (SELECT id FROM chart WHERE accno = ?) | .
        qq|                 AND startdate <= $transdate ORDER BY startdate DESC LIMIT 1) | .
        qq|ORDER BY c.accno|;
      $stw = prepare_execute_query($form, $dbh, $query, $accno_id);
      $ref->{taxaccounts} = "";
      my $i = 0;
      while ($ptr = $stw->fetchrow_hashref(NAME_lc)) {
        if (($ptr->{accno} eq "") && ($ptr->{rate} == 0)) {
          $i++;
          $ptr->{accno} = $i;
        }
        $ref->{taxaccounts} .= "$ptr->{accno} ";
        if (!($form->{taxaccounts} =~ /$ptr->{accno}/)) {
          $form->{"$ptr->{accno}_rate"}        = $ptr->{rate};
          $form->{"$ptr->{accno}_description"} = $ptr->{taxdescription};
          $form->{"$ptr->{accno}_taxnumber"}   = $ptr->{taxnumber};
          $form->{taxaccounts} .= "$ptr->{accno} ";
        }

      }

      chop $ref->{taxaccounts};
      push @{ $form->{form_details} }, $ref;
      $stw->finish;
    }
    $sth->finish;

  } else {

    # get last name used
    $form->lastname_used($dbh, $myconfig, $form->{vc})
      unless $form->{"$form->{vc}_id"};

  }

  $form->{exchangerate} =
    $form->get_exchangerate($dbh, $form->{currency}, $form->{transdate},
                            ($form->{vc} eq 'customer') ? "buy" : "sell");

  Common::webdav_folder($form) if ($main::webdav);

  my $rc = $dbh->commit;
  $dbh->disconnect;

  $main::lxdebug->leave_sub();

  return $rc;
}

sub order_details {
  $main::lxdebug->enter_sub();

  my ($self, $myconfig, $form) = @_;

  # connect to database
  my $dbh = $form->dbconnect($myconfig);
  my $query;
  my @values = ();
  my $sth;
  my $nodiscount;
  my $yesdiscount;
  my $nodiscount_subtotal = 0;
  my $discount_subtotal = 0;
  my $item;
  my $i;
  my @partsgroup = ();
  my $partsgroup;
  my $position = 0;
  my $subtotal_header = 0;
  my $subposition = 0;

  my %oid = ('Pg'     => 'oid',
             'Oracle' => 'rowid');

  my (@project_ids, %projectnumbers);

  push(@project_ids, $form->{"globalproject_id"}) if ($form->{"globalproject_id"});

  # sort items by partsgroup
  for $i (1 .. $form->{rowcount}) {
    $partsgroup = "";
    if ($form->{"partsgroup_$i"} && $form->{groupitems}) {
      $partsgroup = $form->{"partsgroup_$i"};
    }
    push @partsgroup, [$i, $partsgroup];
    push(@project_ids, $form->{"project_id_$i"}) if ($form->{"project_id_$i"});
  }

  if (@project_ids) {
    $query = "SELECT id, projectnumber FROM project WHERE id IN (" .
      join(", ", map("?", @project_ids)) . ")";
    $sth = prepare_execute_query($form, $dbh, $query, @project_ids);
    while (my $ref = $sth->fetchrow_hashref()) {
      $projectnumbers{$ref->{id}} = $ref->{projectnumber};
    }
    $sth->finish();
  }

  $form->{"globalprojectnumber"} =
    $projectnumbers{$form->{"globalproject_id"}};

  my @arrays =
    qw(runningnumber number description longdescription qty ship unit bin
       partnotes serialnumber reqdate sellprice listprice netprice
       discount p_discount discount_sub nodiscount_sub
       linetotal  nodiscount_linetotal tax_rate projectnumber);

  my $sameitem = "";
  foreach $item (sort { $a->[1] cmp $b->[1] } @partsgroup) {
    $i = $item->[0];

    if ($item->[1] ne $sameitem) {
      push(@{ $form->{description} }, qq|$item->[1]|);
      $sameitem = $item->[1];

      map({ push(@{ $form->{$_} }, "") } grep({ $_ ne "description" } @arrays));
    }

    $form->{"qty_$i"} = $form->parse_amount($myconfig, $form->{"qty_$i"});

    if ($form->{"id_$i"} != 0) {

      # add number, description and qty to $form->{number}, ....

      if ($form->{"subtotal_$i"} && !$subtotal_header) {
        $subtotal_header = $i;
        $position = int($position);
        $subposition = 0;
        $position++;
      } elsif ($subtotal_header) {
        $subposition += 1;
        $position = int($position);
        $position = $position.".".$subposition;
      } else {
        $position = int($position);
        $position++;
      }

      push(@{ $form->{runningnumber} }, $i);
      push(@{ $form->{number} },        qq|$form->{"partnumber_$i"}|);
      push(@{ $form->{description} },   qq|$form->{"description_$i"}|);
      push(@{ $form->{longdescription} },   qq|$form->{"longdescription_$i"}|);
      push(@{ $form->{qty} },
           $form->format_amount($myconfig, $form->{"qty_$i"}));
      push(@{ $form->{ship} },
           $form->format_amount($myconfig, $form->{"ship_$i"}));
      push(@{ $form->{unit} },         qq|$form->{"unit_$i"}|);
      push(@{ $form->{bin} },          qq|$form->{"bin_$i"}|);
      push(@{ $form->{"partnotes"} },  qq|$form->{"partnotes_$i"}|);
      push(@{ $form->{serialnumber} }, qq|$form->{"serialnumber_$i"}|);
      push(@{ $form->{reqdate} },      qq|$form->{"reqdate_$i"}|);

      push(@{ $form->{sellprice} }, $form->{"sellprice_$i"});

      push(@{ $form->{listprice} }, $form->{"listprice_$i"});

      my $sellprice = $form->parse_amount($myconfig, $form->{"sellprice_$i"});
      my ($dec) = ($sellprice =~ /\.(\d+)/);
      $dec = length $dec;
      my $decimalplaces = ($dec > 2) ? $dec : 2;

      my $i_discount =
        $form->round_amount(
                            $sellprice * $form->parse_amount($myconfig,
                                                 $form->{"discount_$i"}) / 100,
                            $decimalplaces);

      my $discount =
        $form->round_amount($form->{"qty_$i"} * $i_discount, $decimalplaces);

      # keep a netprice as well, (sellprice - discount)
      #$form->{"netprice_$i"} = $sellprice - $discount;
      $form->{"netprice_$i"} = $sellprice - $i_discount;
      my $nodiscount_linetotal =
        $form->round_amount($form->{"qty_$i"} * $sellprice, 2);
      my $linetotal =
        $form->round_amount($form->{"qty_$i"} * $form->{"netprice_$i"}, 2);

      push(@{ $form->{netprice} },
           ($form->{"netprice_$i"} != 0)
           ? $form->format_amount(
                                 $myconfig, $form->{"netprice_$i"},
                                 $decimalplaces
             )
           : " ");

      $discount =
        ($discount != 0)
        ? $form->format_amount($myconfig, $discount * -1, $decimalplaces)
        : " ";
      $linetotal = ($linetotal != 0) ? $linetotal : " ";

      push(@{ $form->{discount} },   $discount);
      push(@{ $form->{p_discount} }, $form->{"discount_$i"});

      $form->{ordtotal} += $linetotal;
      $discount_subtotal += $linetotal;
      $form->{nodiscount_total} += $nodiscount_linetotal;
      $nodiscount_subtotal += $nodiscount_linetotal;
      $form->{discount_total} += $form->parse_amount($myconfig, $discount);

      if ($form->{"subtotal_$i"} && $subtotal_header && ($subtotal_header != $i)) {
        $discount_subtotal = $form->format_amount($myconfig, $discount_subtotal, 2);
        push(@{ $form->{discount_sub} },  $discount_subtotal);
        $nodiscount_subtotal = $form->format_amount($myconfig, $nodiscount_subtotal, 2);
        push(@{ $form->{nodiscount_sub} }, $nodiscount_subtotal);
        $discount_subtotal = 0;
        $nodiscount_subtotal = 0;
        $subtotal_header = 0;
      } else {
        push(@{ $form->{discount_sub} }, "");
        push(@{ $form->{nodiscount_sub} }, "");
      }

      if ($linetotal == $netto_linetotal) {
        $nodiscount += $linetotal;
      }
      push(@{ $form->{linetotal} },
           $form->format_amount($myconfig, $linetotal, 2));
      push(@{ $form->{nodiscount_linetotal} },
           $form->format_amount($myconfig, $nodiscount_linetotal, 2));

      push(@{ $form->{projectnumber} }, $projectnumbers{$form->{"project_id_$i"}});

      my ($taxamount, $taxbase);
      my $taxrate = 0;

      map { $taxrate += $form->{"${_}_rate"} } split(/ /, $form->{"taxaccounts_$i"});

      if ($form->{taxincluded}) {

        # calculate tax
        $taxamount = $linetotal * $taxrate / (1 + $taxrate);
        $taxbase = $linetotal / (1 + $taxrate);
      } else {
        $taxamount = $linetotal * $taxrate;
        $taxbase   = $linetotal;
      }

      if ($taxamount != 0) {
        foreach my $item (split / /, $form->{"taxaccounts_$i"}) {
          $taxaccounts{$item} +=
            $taxamount * $form->{"${item}_rate"} / $taxrate;
          $taxbase{$item} += $taxbase;
        }
      }

      $tax_rate = $taxrate * 100;
      push(@{ $form->{tax_rate} }, qq|$tax_rate|);

      if ($form->{"assembly_$i"}) {
        $sameitem = "";

        # get parts and push them onto the stack
        my $sortorder = "";
        if ($form->{groupitems}) {
          $sortorder =
            qq|ORDER BY pg.partsgroup, a.$oid{$myconfig->{dbdriver}}|;
        } else {
          $sortorder = qq|ORDER BY a.$oid{$myconfig->{dbdriver}}|;
        }

        $query = qq|SELECT p.partnumber, p.description, p.unit, a.qty, | .
	               qq|pg.partsgroup | .
	               qq|FROM assembly a | .
		             qq|  JOIN parts p ON (a.parts_id = p.id) | .
		             qq|    LEFT JOIN partsgroup pg ON (p.partsgroup_id = pg.id) | .
		             qq|    WHERE a.bom = '1' | .
		             qq|    AND a.id = ? | . $sortorder;
		    @values = ($form->{"id_$i"});
        $sth = $dbh->prepare($query);
        $sth->execute(@values) || $form->dberror($query);

        while (my $ref = $sth->fetchrow_hashref(NAME_lc)) {
          if ($form->{groupitems} && $ref->{partsgroup} ne $sameitem) {
            map({ push(@{ $form->{$_} }, "") }
                grep({ $_ ne "description" } @arrays));
            $sameitem = ($ref->{partsgroup}) ? $ref->{partsgroup} : "--";
            push(@{ $form->{description} }, $sameitem);
          }

          push(@{ $form->{description} },
               $form->format_amount($myconfig, $ref->{qty} * $form->{"qty_$i"}
                 )
                 . qq|, $ref->{partnumber}, $ref->{description}|);

          map({ push(@{ $form->{$_} }, "") }
              grep({ $_ ne "description" } @arrays));
        }
        $sth->finish;
      }

    }
  }

  my $tax = 0;
  foreach $item (sort keys %taxaccounts) {
    push(@{ $form->{taxbase} },
         $form->format_amount($myconfig, $taxbase{$item}, 2));

    $tax += $taxamount = $form->round_amount($taxaccounts{$item}, 2);

    push(@{ $form->{tax} }, $form->format_amount($myconfig, $taxamount, 2));
    push(@{ $form->{taxdescription} }, $form->{"${item}_description"}  . q{ } . 100 * $form->{"${item}_rate"} . q{%});
    push(@{ $form->{taxrate} },
         $form->format_amount($myconfig, $form->{"${item}_rate"} * 100));
    push(@{ $form->{taxnumber} }, $form->{"${item}_taxnumber"});
  }
  $yesdiscount = $form->{nodiscount_total} - $nodiscount;
  $form->{nodiscount_subtotal} = $form->format_amount($myconfig, $form->{nodiscount_total}, 2);
  $form->{discount_total} = $form->format_amount($myconfig, $form->{discount_total}, 2);
  $form->{nodiscount} = $form->format_amount($myconfig, $nodiscount, 2);
  $form->{yesdiscount} = $form->format_amount($myconfig, $yesdiscount, 2);

  if($form->{taxincluded}) {
    $form->{subtotal} = $form->format_amount($myconfig, $form->{ordtotal} - $tax, 2);
  }
  else {
    $form->{subtotal} = $form->format_amount($myconfig, $form->{ordtotal}, 2);
  }
  $form->{ordtotal} =
    ($form->{taxincluded}) ? $form->{ordtotal} : $form->{ordtotal} + $tax;

  # format amounts
  $form->{quototal} = $form->{ordtotal} =
    $form->format_amount($myconfig, $form->{ordtotal}, 2);

  if ($form->{type} =~ /_quotation/) {
    $form->set_payment_options($myconfig, $form->{quodate});
  } else {
    $form->set_payment_options($myconfig, $form->{orddate});
  }

  $form->{username} = $myconfig->{name};

  $dbh->disconnect;

  $main::lxdebug->leave_sub();
}

sub project_description {
  $main::lxdebug->enter_sub();

  my ($self, $dbh, $id) = @_;

  my $query = qq|SELECT description FROM project WHERE id = ?|;
  my ($value) = selectrow_query($form, $dbh, $query, $id);

  $main::lxdebug->leave_sub();

  return $value;
}

sub adj_onhand {
  $main::lxdebug->enter_sub();

  my ($dbh, $form, $ml) = @_;

  my $all_units = $form->{all_units};

  my $query =
    qq|SELECT oi.parts_id, oi.ship, oi.unit, p.inventory_accno_id, p.assembly | .
    qq|   FROM orderitems oi | .
    qq|   JOIN parts p ON (p.id = oi.parts_id) | .
    qq|   WHERE oi.trans_id = ?|;
  my @values = ($form->{id});
  my $sth = $dbh->prepare($query);
  $sth->execute(@values) || $form->dberror($query);

  $query =
    qq|SELECT sum(p.inventory_accno_id) | .
    qq|FROM parts p | .
    qq|JOIN assembly a ON (a.parts_id = p.id) | .
    qq|WHERE a.id = ?|;
  my $ath = $dbh->prepare($query) || $form->dberror($query);

  my $ispa;

  while (my $ref = $sth->fetchrow_hashref(NAME_lc)) {
    if ($ref->{inventory_accno_id} || $ref->{assembly}) {

      # do not update if assembly consists of all services
      if ($ref->{assembly}) {
        $ath->execute($ref->{parts_id}) || $form->dberror($query);

        ($ispa) = $sth->fetchrow_array;
        $ath->finish;

        next unless $ispa;

      }

      # get item baseunit
      $query = qq|SELECT unit FROM parts WHERE id = ?|;
      my ($item_unit) = selectrow_query($form, $dbh, $query, $ref->{parts_id});

      my $basefactor = 1;
      if (defined($all_units->{$item_unit}->{factor}) &&
          (($all_units->{$item_unit}->{factor} * 1) != 0)) {
        $basefactor = $all_units->{$ref->{unit}}->{factor} /
          $all_units->{$item_unit}->{factor};
      }
      my $baseqty = $ref->{ship} * $basefactor;

      # adjust onhand in parts table
      $form->update_balance($dbh, "parts", "onhand",
                            qq|id = $ref->{parts_id}|,
                            $baseqty * $ml);
    }
  }

  $sth->finish;

  $main::lxdebug->leave_sub();
}

1;