SL/Controller/RequirementSpecOrder.pm

   1 package SL::Controller::RequirementSpecOrder;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use List::MoreUtils qw(uniq);
   9 use List::Util qw(first);
  10
  11 use SL::ClientJS;
  12 use SL::DB::Customer;
  13 use SL::DB::Order;
  14 use SL::DB::Part;
  15 use SL::DB::RequirementSpec;
  16 use SL::DB::RequirementSpecOrder;
  17 use SL::Helper::Flash;
  18 use SL::Locale::String;
  19
  20 use constant LIST_SELECTOR  => '#quotations_and_orders';
  21 use constant FORMS_SELECTOR => '#quotations_and_orders_article_assignment,#quotations_and_orders_new,#quotations_and_orders_update';
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25   scalar                  => [ qw(parts) ],
  26   'scalar --get_set_init' => [ qw(requirement_spec rs_order js h_unit_name all_customers all_parts_time_unit section_order_part) ],
  27 );
  28
  29 __PACKAGE__->run_before('setup');
  30
  31 #
  32 # actions
  33 #
  34
  35 sub action_list {
  36   my ($self) = @_;
  37
  38   $self->render('requirement_spec_order/list', { layout => 0 });
  39 }
  40
  41 sub action_new {
  42   my ($self) = @_;
  43
  44   if (!@{ $self->all_parts_time_unit }) {
  45     return $self->js->flash('error', t8('This function requires the presence of articles with a time-based unit such as "h" or "min".'))->render($self);
  46   }
  47
  48   my $html = $self->render('requirement_spec_order/new', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
  49   $self->js->hide(LIST_SELECTOR())
  50            ->after(LIST_SELECTOR(), $html)
  51            ->render($self);
  52 }
  53
  54 sub action_create {
  55   my ($self)         = @_;
  56
  57   if (!$::auth->assert($::form->{quotation} ? 'sales_quotation_edit' : 'sales_order_edit', 1)) {
  58     return $self->js->flash('error', t8("You do not have the permissions to access this function."))->render($self);
  59   }
  60
  61   # 1. Update sections with selected part IDs.
  62   my $section_attrs  = $::form->{sections} || [];
  63   my $sections       = SL::DB::Manager::RequirementSpecItem->get_all_sorted(where => [ id => [ map { $_->{id} } @{ $section_attrs } ] ]);
  64   my %sections_by_id = map { ($_->{id} => $_) } @{ $sections };
  65
  66   $sections_by_id{ $_->{id} }->update_attributes(order_part_id => $_->{order_part_id}) for @{ $section_attrs };
  67
  68   # 2. Create actual quotation/order.
  69   my $order = $self->create_order(sections => $sections, additional_parts => $self->requirement_spec->parts_sorted);
  70   $order->db->with_transaction(sub {
  71     $order->save;
  72
  73     $self->requirement_spec->add_orders(SL::DB::RequirementSpecOrder->new(order => $order, version => $self->requirement_spec->version));
  74     $self->requirement_spec->save;
  75
  76     $self->requirement_spec->link_to_record($order);
  77   }) or do {
  78     $::lxdebug->message(LXDebug::WARN(), "Error creating the order object: $@");
  79   };
  80
  81   $self->init_requirement_spec;
  82
  83   # 3. Notify the user and return to list.
  84   my $html = $self->render('requirement_spec_order/list', { output => 0 });
  85   $self->js->replaceWith(LIST_SELECTOR(), $html)
  86            ->remove(FORMS_SELECTOR())
  87            ->flash('info', $::form->{quotation} ? t8('Sales quotation #1 has been created.', $order->quonumber) : t8('Sales order #1 has been created.', $order->ordnumber))
  88            ->render($self);
  89 }
  90
  91 sub action_update {
  92   my ($self)   = @_;
  93
  94   my $order    = $self->rs_order->order;
  95   my $sections = $self->requirement_spec->sections_sorted;
  96
  97   if (!$::auth->assert($order->quotation ? 'sales_quotation_edit' : 'sales_order_edit', 1)) {
  98     return $self->js->flash('error', t8("You do not have the permissions to access this function."))->render($self);
  99   }
 100
 101   my (@orderitems, %sections_seen);
 102   foreach my $item (@{ $order->items_sorted }) {
 103     my $section = first { my $num = $_->fb_number; $item->description =~ m{\b\Q${num}\E\b} && !$sections_seen{ $_->id } } @{ $sections };
 104
 105     $sections_seen{ $section->id } = 1 if $section;
 106
 107     push @orderitems, { item => $item, section => $section };
 108   }
 109
 110   my $html = $self->render(
 111     'requirement_spec_order/update', { output => 0 },
 112     orderitems         => \@orderitems,
 113     sections           => $sections,
 114     make_section_title => sub { $_[0]->fb_number . ' ' . $_[0]->title },
 115   );
 116
 117   $self->js->hide(LIST_SELECTOR())
 118            ->after(LIST_SELECTOR(), $html)
 119            ->render($self);
 120 }
 121
 122 sub action_do_update {
 123   my ($self)         = @_;
 124
 125   my $order          = $self->rs_order->order;
 126   my @new_orderitems =  $self->do_update_sections;
 127   push @new_orderitems, $self->do_update_additional_parts;
 128
 129   $order->add_orderitems(\@new_orderitems) if @new_orderitems;
 130
 131   $order->calculate_prices_and_taxes;
 132
 133   $order->db->with_transaction(sub {
 134     $order->save;
 135     $self->requirement_spec->link_to_record($order);
 136   }) or do {
 137     $::lxdebug->message(LXDebug::WARN(), "Error updating the order object: $@");
 138   };
 139
 140   $self->init_requirement_spec;
 141
 142   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 143   $self->js->replaceWith(LIST_SELECTOR(), $html)
 144            ->remove(FORMS_SELECTOR())
 145            ->flash('info', $::form->{quotation} ? t8('Sales quotation #1 has been updated.', $order->quonumber) : t8('Sales order #1 has been updated.', $order->ordnumber))
 146            ->render($self);
 147 }
 148
 149 sub action_edit_assignment {
 150   my ($self) = @_;
 151
 152   if (!@{ $self->all_parts_time_unit }) {
 153     return $self->js->flash('error', t8('This function requires the presence of articles with a time-based unit such as "h" or "min".'))->render($self);
 154   }
 155
 156   my $html   = $self->render('requirement_spec_order/edit_assignment', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
 157   $self->js->hide(LIST_SELECTOR())
 158            ->after(LIST_SELECTOR(), $html)
 159            ->reinit_widgets
 160            ->render($self);
 161 }
 162
 163 sub action_save_assignment {
 164   my ($self)   = @_;
 165   my $sections = $::form->{sections} || [];
 166   SL::DB::RequirementSpecItem->new(id => $_->{id})->load->update_attributes(order_part_id => ($_->{order_part_id} || undef)) for @{ $sections };
 167
 168   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 169   $self->js->replaceWith(LIST_SELECTOR(), $html)
 170            ->remove(FORMS_SELECTOR())
 171            ->render($self);
 172 }
 173
 174 sub action_delete {
 175   my ($self) = @_;
 176
 177   my $order  = $self->rs_order->order;
 178
 179   $order->delete;
 180   $self->init_requirement_spec;
 181
 182   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 183   $self->js->replaceWith(LIST_SELECTOR(), $html)
 184            ->flash('info', $order->quotation ? t8('Sales quotation #1 has been deleted.', $order->quonumber) : t8('Sales order #1 has been deleted.', $order->ordnumber))
 185            ->render($self);
 186 }
 187
 188 #
 189 # filters
 190 #
 191
 192 sub setup {
 193   my ($self) = @_;
 194
 195   $::auth->assert('requirement_spec_edit');
 196   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec autocomplete_part);
 197   $::request->{layout}->use_javascript("${_}.js")  for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 198
 199   return 1;
 200 }
 201
 202 sub init_requirement_spec {
 203   my ($self) = @_;
 204   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load) if $::form->{requirement_spec_id};
 205 }
 206
 207 sub init_js {
 208   my ($self) = @_;
 209   $self->js(SL::ClientJS->new);
 210 }
 211
 212 sub init_all_customers { SL::DB::Manager::Customer->get_all_sorted }
 213 sub init_h_unit_name   { SL::DB::Manager::Unit->find_h_unit->name };
 214 sub init_rs_order      { SL::DB::RequirementSpecOrder->new(id => $::form->{rs_order_id})->load };
 215 sub init_section_order_part { my $id = $::instance_conf->get_requirement_spec_section_order_part_id; return $id ? SL::DB::Part->new(id => $id)->load : undef }
 216
 217 sub init_all_parts_time_unit {
 218   my ($self) = @_;
 219
 220   return [] unless $self->h_unit_name;
 221
 222   my @convertible_unit_names = map { $_->name } @{ SL::DB::Manager::Unit->time_based_units };
 223
 224   return SL::DB::Manager::Part->get_all_sorted(where => [ unit => \@convertible_unit_names ]);
 225 }
 226
 227 #
 228 # helpers
 229 #
 230
 231 sub do_update_sections {
 232   my ($self)           = @_;
 233
 234   my $order            = $self->rs_order->order;
 235   my $sections         = $self->requirement_spec->sections_sorted;
 236   my %orderitems_by_id = map { ($_->id => $_) } @{ $order->orderitems };
 237   my %sections_by_id   = map { ($_->id => $_) } @{ $sections };
 238   $self->{parts}       = { map { ($_->id => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq map { $_->order_part_id } @{ $sections } ] ]) } };
 239   my $language_id      = $self->requirement_spec->customer->language_id;
 240
 241   my %sections_seen;
 242
 243   foreach my $attributes (@{ $::form->{orderitems} || [] }) {
 244     my $orderitem = $orderitems_by_id{ $attributes->{id}         };
 245     my $section   = $sections_by_id{   $attributes->{section_id} };
 246     next unless $orderitem && $section;
 247
 248     $self->create_order_item(section => $section, item => $orderitem, language_id => $language_id)->save;
 249     $sections_seen{ $section->id } = 1;
 250   }
 251
 252   my @new_orderitems = map  { $self->create_order_item(section => $_, language_id => $language_id) }
 253                        grep { !$sections_seen{ $_->id } }
 254                        @{ $sections };
 255
 256   return @new_orderitems;
 257 }
 258
 259 sub do_update_additional_parts {
 260   my ($self)        = @_;
 261
 262   my $order         = $self->rs_order->order;
 263   my $add_parts     = $self->requirement_spec->parts_sorted;
 264   my %orderitems_by = map { (($_->parts_id . '-' . $_->description) => $_) } @{ $order->items };
 265   $self->{parts}    = { map { ($_->id => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq map { $_->part_id } @{ $add_parts } ] ]) } };
 266   my $language_id   = $self->requirement_spec->customer->language_id;
 267
 268   my %add_part_seen;
 269   my @new_orderitems;
 270
 271   foreach my $add_part (@{ $add_parts }) {
 272     my $key       = $add_part->part_id . '-' . $add_part->description;
 273     my $orderitem = $orderitems_by{$key};
 274
 275     if ($orderitem) {
 276       $self->create_additional_part_order_item(additional_part => $add_part, item => $orderitem, language_id => $language_id)->save;
 277
 278     } else {
 279       push @new_orderitems, $self->create_additional_part_order_item(additional_part => $add_part, language_id => $language_id);
 280     }
 281   }
 282
 283   return @new_orderitems;
 284 }
 285
 286 sub create_order_item {
 287   my ($self, %params) = @_;
 288
 289   my $section         = $params{section};
 290   my $item            = $params{item} || SL::DB::OrderItem->new;
 291   my $part            = $self->parts->{ $section->order_part_id };
 292   my $translation     = $params{language_id} ? first { $params{language_id} == $_->language_id } @{ $part->translations } : {};
 293   my $description     = $section->{keep_description} ? $item->description : ($translation->{translation} || $part->description);
 294   my $longdescription = $translation->{longdescription} || $part->notes;
 295
 296   if (!$section->{keep_description}) {
 297     $description     = '<%fb_number%> <%title%>' unless $description =~ m{<%};
 298     $longdescription = '&lt;%description%&gt;'   unless $longdescription =~ m{&lt;%};
 299
 300     $description     =~ s{<% (.+?) %>}{ $section->can($1) ? $section->$1 : '<' . t8('Invalid variable #1', $1) . '>' }egx;
 301     $longdescription =~ s{\&lt;\% description \%\&gt;}{!!!!DESCRIPTION!!!!}gx;
 302     $longdescription =~ s{<[pP]> !!!!DESCRIPTION!!!! </[pP]>}{!!!!DESCRIPTION!!!!}gx;
 303     $longdescription =~ s{\&lt;\% (.+?) \%\&gt;}{ $section->can($1) ? $::locale->quote_special_chars('HTML', $section->$1 // '') : '<' . t8('Invalid variable #1', $1) . '>' }egx;
 304     $longdescription =~ s{!!!!DESCRIPTION!!!!}{ $section->description // '' }egx;
 305   }
 306
 307   $item->assign_attributes(
 308     parts_id        => $part->id,
 309     description     => $description,
 310     longdescription => $longdescription,
 311     qty             => $section->time_estimation * 1,
 312     unit            => $self->h_unit_name,
 313     sellprice       => $::form->round_amount($self->requirement_spec->hourly_rate, 2),
 314     lastcost        => $part->lastcost,
 315     discount        => 0,
 316     project_id      => $self->requirement_spec->project_id,
 317   );
 318
 319   return $item;
 320 }
 321
 322 sub create_additional_part_order_item {
 323   my ($self, %params) = @_;
 324
 325   my $add_part        = $params{additional_part};
 326   my $item            = $params{item} || SL::DB::OrderItem->new;
 327   my $part            = $self->parts->{ $add_part->part_id };
 328   my $translation     = $params{language_id} ? first { $params{language_id} == $_->language_id } @{ $part->translations } : {};
 329   my $description     = $item->description              || $add_part->description;
 330   my $longdescription = $translation->{longdescription} || $part->notes;
 331
 332   $item->assign_attributes(
 333     parts_id        => $part->id,
 334     description     => $description,
 335     longdescription => $longdescription,
 336     qty             => $add_part->qty,
 337     unit            => $add_part->unit->name,
 338     sellprice       => $add_part->unit->convert_to($part->sellprice, $part->unit_obj),
 339     lastcost        => $part->lastcost,
 340     discount        => 0,
 341     project_id      => $self->requirement_spec->project_id,
 342   );
 343
 344   return $item;
 345 }
 346
 347 sub create_order {
 348   my ($self, %params) = @_;
 349
 350   my @part_ids = (
 351     map({ $_->{order_part_id} } @{ $params{sections} }),
 352     map({ $_->part_id         } @{ $params{additional_parts} }),
 353   );
 354   $self->{parts} = { map { ($_->{id} => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq @part_ids ] ]) } };
 355
 356   my $customer   = SL::DB::Customer->new(id => $::form->{customer_id})->load;
 357   my @orderitems = map { $self->create_order_item(                section => $_,         language_id => $customer->language_id) } @{ $params{sections} };
 358   my @add_items  = map { $self->create_additional_part_order_item(additional_part => $_, language_id => $customer->language_id) } @{ $params{additional_parts} };
 359   my $employee   = SL::DB::Manager::Employee->current;
 360   my $order      = SL::DB::Order->new(
 361     globalproject_id        => $self->requirement_spec->project_id,
 362     transdate               => DateTime->today_local,
 363     reqdate                 => $::form->{quotation} && $customer->payment_id ? $customer->payment->calc_date : undef,
 364     quotation               => !!$::form->{quotation},
 365     orderitems              => [ @orderitems, @add_items ],
 366     customer_id             => $customer->id,
 367     taxincluded             => $customer->taxincluded,
 368     intnotes                => $customer->notes,
 369     language_id             => $customer->language_id,
 370     payment_id              => $customer->payment_id,
 371     taxzone_id              => $customer->taxzone_id,
 372     employee_id             => $employee->id,
 373     salesman_id             => $employee->id,
 374     transaction_description => $self->requirement_spec->displayable_name,
 375     currency_id             => $::instance_conf->get_currency_id,
 376   );
 377
 378   $order->calculate_prices_and_taxes;
 379
 380   return $order;
 381 }
 382
 383 1;