SL/AP.pm

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (C) 2001
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #  Contributors:
  16 #
  17 # This program is free software; you can redistribute it and/or modify
  18 # it under the terms of the GNU General Public License as published by
  19 # the Free Software Foundation; either version 2 of the License, or
  20 # (at your option) any later version.
  21 #
  22 # This program is distributed in the hope that it will be useful,
  23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 # GNU General Public License for more details.
  26 # You should have received a copy of the GNU General Public License
  27 # along with this program; if not, write to the Free Software
  28 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  29 #======================================================================
  30 #
  31 # Accounts Payables database backend routines
  32 #
  33 #======================================================================
  34
  35 package AP;
  36
  37 use SL::DATEV qw(:CONSTANTS);
  38 use SL::DBUtils;
  39 use SL::IO;
  40 use SL::MoreCommon;
  41 use SL::DB::Default;
  42 use Data::Dumper;
  43
  44 use strict;
  45
  46 sub post_transaction {
  47   $main::lxdebug->enter_sub();
  48
  49   my ($self, $myconfig, $form, $provided_dbh, $payments_only) = @_;
  50   my $rc = 0; # return code auf false setzen
  51   # connect to database
  52   my $dbh = $provided_dbh ? $provided_dbh : $form->dbconnect_noauto($myconfig);
  53
  54   my ($null, $taxrate, $amount);
  55   my $exchangerate = 0;
  56
  57   $form->{defaultcurrency} = $form->get_default_currency($myconfig);
  58
  59   ($null, $form->{department_id}) = split(/--/, $form->{department});
  60
  61   if ($form->{currency} eq $form->{defaultcurrency}) {
  62     $form->{exchangerate} = 1;
  63   } else {
  64     $exchangerate         = $form->check_exchangerate($myconfig, $form->{currency}, $form->{transdate}, 'sell');
  65     $form->{exchangerate} = $exchangerate || $form->parse_amount($myconfig, $form->{exchangerate});
  66   }
  67
  68   for my $i (1 .. $form->{rowcount}) {
  69     $form->{AP_amounts}{"amount_$i"} =
  70       (split(/--/, $form->{"AP_amount_$i"}))[0];
  71   }
  72   ($form->{AP_amounts}{payables}) = split(/--/, $form->{APselected});
  73   ($form->{AP_payables})          = split(/--/, $form->{APselected});
  74
  75   # reverse and parse amounts
  76   for my $i (1 .. $form->{rowcount}) {
  77     $form->{"amount_$i"} =
  78       $form->round_amount(
  79                          $form->parse_amount($myconfig, $form->{"amount_$i"}) *
  80                            $form->{exchangerate} * -1,
  81                          2);
  82     $amount += ($form->{"amount_$i"} * -1);
  83
  84     # parse tax_$i for later
  85     $form->{"tax_$i"} = $form->parse_amount($myconfig, $form->{"tax_$i"}) * -1;
  86   }
  87
  88   # this is for ap
  89   $form->{amount} = $amount;
  90
  91   # taxincluded doesn't make sense if there is no amount
  92   $form->{taxincluded} = 0 if ($form->{amount} == 0);
  93
  94   for my $i (1 .. $form->{rowcount}) {
  95     ($form->{"tax_id_$i"}, undef) = split /--/, $form->{"taxchart_$i"};
  96
  97     my $query =
  98       qq|SELECT c.accno, t.taxkey, t.rate | .
  99       qq|FROM tax t LEFT JOIN chart c on (c.id=t.chart_id) | .
 100       qq|WHERE t.id = ? | .
 101       qq|ORDER BY c.accno|;
 102     my $sth = $dbh->prepare($query);
 103     $sth->execute($form->{"tax_id_$i"}) || $form->dberror($query . " (" . $form->{"tax_id_$i"} . ")");
 104     ($form->{AP_amounts}{"tax_$i"}, $form->{"taxkey_$i"}, $form->{"taxrate_$i"}) = $sth->fetchrow_array();
 105
 106     $sth->finish;
 107
 108     my ($tax, $diff);
 109     if ($form->{taxincluded} *= 1) {
 110       $tax = $form->{"amount_$i"} - ($form->{"amount_$i"} / ($form->{"taxrate_$i"} + 1));
 111       $amount = $form->{"amount_$i"} - $tax;
 112       $form->{"amount_$i"} = $form->round_amount($amount, 2);
 113       $diff += $amount - $form->{"amount_$i"};
 114       $form->{"tax_$i"} = $form->round_amount($tax, 2);
 115       $form->{netamount} += $form->{"amount_$i"};
 116     } else {
 117       $form->{"tax_$i"} = $form->{"amount_$i"} * $form->{"taxrate_$i"};
 118       $form->{netamount} += $form->{"amount_$i"};
 119     }
 120     $form->{total_tax} += $form->{"tax_$i"} * -1;
 121   }
 122
 123   # adjust paidaccounts if there is no date in the last row
 124   $form->{paidaccounts}-- unless ($form->{"datepaid_$form->{paidaccounts}"});
 125
 126   $form->{invpaid} = 0;
 127   $form->{netamount} *= -1;
 128
 129   # add payments
 130   for my $i (1 .. $form->{paidaccounts}) {
 131     $form->{"paid_$i"} =
 132       $form->round_amount($form->parse_amount($myconfig, $form->{"paid_$i"}),
 133                           2);
 134
 135     $form->{invpaid} += $form->{"paid_$i"};
 136     $form->{datepaid} = $form->{"datepaid_$i"};
 137
 138   }
 139
 140   $form->{invpaid} =
 141     $form->round_amount($form->{invpaid} * $form->{exchangerate}, 2);
 142
 143   # store invoice total, this goes into ap table
 144   $form->{invtotal} = $form->{netamount} + $form->{total_tax};
 145
 146   # amount for total AP
 147   $form->{payables} = $form->{invtotal};
 148
 149   # update exchangerate
 150   if (($form->{currency} ne $form->{defaultcurrency}) && !$exchangerate) {
 151     $form->update_exchangerate($dbh, $form->{currency}, $form->{transdate}, 0,
 152                                $form->{exchangerate});
 153   }
 154
 155   my ($query, $sth, @values);
 156
 157   if (!$payments_only) {
 158     # if we have an id delete old records
 159     if ($form->{id}) {
 160
 161       # delete detail records
 162       $query = qq|DELETE FROM acc_trans WHERE trans_id = ?|;
 163       do_query($form, $dbh, $query, $form->{id});
 164
 165     } else {
 166       my $uid = rand() . time;
 167
 168       $uid .= $form->{login};
 169
 170       $uid = substr($uid, 2, 75);
 171
 172       $query =
 173         qq|INSERT INTO ap (invnumber, employee_id) | .
 174         qq|VALUES (?, (SELECT e.id FROM employee e WHERE e.login = ?))|;
 175       do_query($form, $dbh, $query, $uid, $form->{login});
 176
 177       $query = qq|SELECT a.id FROM ap a
 178                   WHERE a.invnumber = ?|;
 179       ($form->{id}) = selectrow_query($form, $dbh, $query, $uid);
 180     }
 181
 182     $form->{invnumber} = $form->{id} unless $form->{invnumber};
 183
 184     $query = qq|UPDATE ap SET
 185                 invnumber = ?, transdate = ?, ordnumber = ?, vendor_id = ?, taxincluded = ?,
 186                 amount = ?, duedate = ?, paid = ?, netamount = ?,
 187                 currency_id = (SELECT id FROM currencies WHERE name = ?), notes = ?, department_id = ?, storno = ?, storno_id = ?,
 188                 globalproject_id = ?, direct_debit = ?
 189                WHERE id = ?|;
 190     @values = ($form->{invnumber}, conv_date($form->{transdate}),
 191                   $form->{ordnumber}, conv_i($form->{vendor_id}),
 192                   $form->{taxincluded} ? 't' : 'f', $form->{invtotal},
 193                   conv_date($form->{duedate}), $form->{invpaid},
 194                   $form->{netamount},
 195                   $form->{currency}, $form->{notes},
 196                   conv_i($form->{department_id}), $form->{storno},
 197                   $form->{storno_id}, conv_i($form->{globalproject_id}),
 198                   $form->{direct_debit} ? 't' : 'f',
 199                   $form->{id});
 200     do_query($form, $dbh, $query, @values);
 201
 202     # add individual transactions
 203     for my $i (1 .. $form->{rowcount}) {
 204       if ($form->{"amount_$i"} != 0) {
 205         my $project_id;
 206         $project_id = conv_i($form->{"project_id_$i"});
 207
 208         # insert detail records in acc_trans
 209         $query =
 210           qq|INSERT INTO acc_trans | .
 211           qq|  (trans_id, chart_id, amount, transdate, project_id, taxkey, tax_id, chart_link)| .
 212           qq|VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), | .
 213           qq|  ?, ?, ?, ?, ?,| .
 214           qq| (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 215         @values = ($form->{id}, $form->{AP_amounts}{"amount_$i"},
 216                    $form->{"amount_$i"}, conv_date($form->{transdate}),
 217                    $project_id, $form->{"taxkey_$i"}, conv_i($form->{"tax_id_$i"}),
 218                    $form->{AP_amounts}{"amount_$i"});
 219         do_query($form, $dbh, $query, @values);
 220
 221         if ($form->{"tax_$i"} != 0) {
 222           # insert detail records in acc_trans
 223           $query =
 224             qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, | .
 225             qq|  project_id, taxkey, tax_id, chart_link) | .
 226             qq|VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), | .
 227             qq|  ?, ?, ?, ?, ?,| .
 228             qq| (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 229           @values = ($form->{id}, $form->{AP_amounts}{"tax_$i"},
 230                      $form->{"tax_$i"}, conv_date($form->{transdate}),
 231                      $project_id, $form->{"taxkey_$i"}, conv_i($form->{"tax_id_$i"}),
 232                      $form->{AP_amounts}{"tax_$i"});
 233           do_query($form, $dbh, $query, @values);
 234         }
 235
 236       }
 237     }
 238
 239     # add payables
 240     $query =
 241       qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, taxkey, tax_id, chart_link) | .
 242       qq|VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, | .
 243       qq|        (SELECT taxkey_id FROM chart WHERE accno = ?),| .
 244       qq|        (SELECT tax_id| .
 245       qq|         FROM taxkeys| .
 246       qq|         WHERE chart_id= (SELECT id | .
 247       qq|                          FROM chart| .
 248       qq|                          WHERE accno = ?)| .
 249       qq|         AND startdate <= ?| .
 250       qq|         ORDER BY startdate DESC LIMIT 1),| .
 251       qq|        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 252     @values = ($form->{id}, $form->{AP_amounts}{payables}, $form->{payables},
 253                conv_date($form->{transdate}), $form->{AP_amounts}{payables}, $form->{AP_amounts}{payables}, conv_date($form->{transdate}),
 254                $form->{AP_amounts}{payables});
 255     do_query($form, $dbh, $query, @values);
 256   }
 257
 258   # if there is no amount but a payment record a payable
 259   if ($form->{amount} == 0 && $form->{invtotal} == 0) {
 260     $form->{payables} = $form->{invpaid};
 261   }
 262
 263   # add paid transactions
 264   for my $i (1 .. $form->{paidaccounts}) {
 265
 266     if ($form->{"acc_trans_id_$i"} && $payments_only && (SL::DB::Default->get->payments_changeable == 0)) {
 267       next;
 268     }
 269
 270     if ($form->{"paid_$i"} != 0) {
 271       my $project_id = conv_i($form->{"paid_project_id_$i"});
 272
 273       $exchangerate = 0;
 274       if ($form->{currency} eq $form->{defaultcurrency}) {
 275         $form->{"exchangerate_$i"} = 1;
 276       } else {
 277         $exchangerate              = $form->check_exchangerate($myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'sell');
 278         $form->{"exchangerate_$i"} = $exchangerate || $form->parse_amount($myconfig, $form->{"exchangerate_$i"});
 279       }
 280       $form->{"AP_paid_$i"} =~ s/\"//g;
 281
 282       # get paid account
 283
 284       ($form->{"AP_paid_account_$i"}) = split(/--/, $form->{"AP_paid_$i"});
 285       $form->{"datepaid_$i"} = $form->{transdate}
 286         unless ($form->{"datepaid_$i"});
 287
 288       # if there is no amount and invtotal is zero there is no exchangerate
 289       if ($form->{amount} == 0 && $form->{invtotal} == 0) {
 290         $form->{exchangerate} = $form->{"exchangerate_$i"};
 291       }
 292
 293       $amount =
 294         $form->round_amount($form->{"paid_$i"} * $form->{exchangerate} * -1,
 295                             2);
 296       if ($form->{payables}) {
 297         $query =
 298           qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, project_id, taxkey, tax_id, chart_link) | .
 299           qq|VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, ?, | .
 300           qq|        (SELECT taxkey_id FROM chart WHERE accno = ?),| .
 301           qq|        (SELECT tax_id| .
 302           qq|         FROM taxkeys| .
 303           qq|         WHERE chart_id= (SELECT id | .
 304           qq|                          FROM chart| .
 305           qq|                          WHERE accno = ?)| .
 306           qq|         AND startdate <= ?| .
 307           qq|         ORDER BY startdate DESC LIMIT 1),| .
 308           qq|        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 309         @values = ($form->{id}, $form->{AP_payables}, $amount,
 310                    conv_date($form->{"datepaid_$i"}), $project_id,
 311                    $form->{AP_payables}, $form->{AP_payables}, conv_date($form->{"datepaid_$i"}),
 312                    $form->{AP_payables});
 313         do_query($form, $dbh, $query, @values);
 314       }
 315       $form->{payables} = $amount;
 316
 317       # add payment
 318       my $gldate = (conv_date($form->{"gldate_$i"}))? conv_date($form->{"gldate_$i"}) : conv_date($form->current_date($myconfig));
 319       $query =
 320         qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, gldate, source, memo, project_id, taxkey, tax_id, chart_link) | .
 321         qq|VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, ?, ?, ?, ?, | .
 322         qq|        (SELECT taxkey_id FROM chart WHERE accno = ?), | .
 323         qq|        (SELECT tax_id| .
 324         qq|         FROM taxkeys| .
 325         qq|         WHERE chart_id= (SELECT id | .
 326         qq|                          FROM chart| .
 327         qq|                          WHERE accno = ?)| .
 328         qq|         AND startdate <= ?| .
 329         qq|         ORDER BY startdate DESC LIMIT 1),| .
 330         qq|        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 331       @values = ($form->{id}, $form->{"AP_paid_account_$i"}, $form->{"paid_$i"},
 332                  conv_date($form->{"datepaid_$i"}), $gldate, $form->{"source_$i"},
 333                  $form->{"memo_$i"}, $project_id, $form->{"AP_paid_account_$i"},
 334                  $form->{"AP_paid_account_$i"}, conv_date($form->{"datepaid_$i"}),
 335                  $form->{"AP_paid_account_$i"});
 336       do_query($form, $dbh, $query, @values);
 337
 338       # add exchange rate difference
 339       $amount =
 340         $form->round_amount($form->{"paid_$i"} *
 341                             ($form->{"exchangerate_$i"} - 1), 2);
 342       if ($amount != 0) {
 343         $query =
 344           qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, fx_transaction, cleared, project_id, taxkey, tax_id, chart_link) | .
 345           qq|VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, 't', 'f', ?, | .
 346           qq|        (SELECT taxkey_id FROM chart WHERE accno = ?), | .
 347           qq|        (SELECT tax_id| .
 348           qq|         FROM taxkeys| .
 349           qq|         WHERE chart_id= (SELECT id | .
 350           qq|                          FROM chart| .
 351           qq|                          WHERE accno = ?)| .
 352           qq|         AND startdate <= ?| .
 353           qq|         ORDER BY startdate DESC LIMIT 1),| .
 354           qq|        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 355         @values = ($form->{id}, $form->{"AP_paid_account_$i"}, $amount,
 356                    conv_date($form->{"datepaid_$i"}), $project_id,
 357                    $form->{"AP_paid_account_$i"},
 358                    $form->{"AP_paid_account_$i"}, conv_date($form->{"datepaid_$i"}),
 359                    $form->{"AP_paid_account_$i"});
 360         do_query($form, $dbh, $query, @values);
 361       }
 362
 363       # exchangerate gain/loss
 364       $amount =
 365         $form->round_amount($form->{"paid_$i"} *
 366                             ($form->{exchangerate} -
 367                              $form->{"exchangerate_$i"}), 2);
 368
 369       if ($amount != 0) {
 370         $query =
 371           qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, fx_transaction, cleared, project_id, taxkey, tax_id, chart_link) | .
 372           qq|VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, 't', 'f', ?, | .
 373           qq|        (SELECT taxkey_id FROM chart WHERE accno = ?)| .
 374           qq|        (SELECT tax_id| .
 375           qq|         FROM taxkeys| .
 376           qq|         WHERE chart_id= (SELECT id | .
 377           qq|                          FROM chart| .
 378           qq|                          WHERE accno = ?)| .
 379           qq|         AND startdate <= ?| .
 380           qq|         ORDER BY startdate DESC LIMIT 1),| .
 381           qq|        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 382         @values = ($form->{id},
 383                    ($amount > 0) ? $form->{fxgain_accno} : $form->{fxloss_accno},
 384                    $amount, conv_date($form->{"datepaid_$i"}), $project_id,
 385                    ($amount > 0) ? $form->{fxgain_accno} : $form->{fxloss_accno},
 386                    ($amount > 0) ? $form->{fxgain_accno} : $form->{fxloss_accno}, conv_date($form->{"datepaid_$i"}),
 387                    ($amount > 0) ? $form->{fxgain_accno} : $form->{fxloss_accno});
 388         do_query($form, $dbh, $query, @values);
 389       }
 390
 391       # update exchange rate record
 392       if (($form->{currency} ne $form->{defaultcurrency}) && !$exchangerate) {
 393         $form->update_exchangerate($dbh, $form->{currency},
 394                                    $form->{"datepaid_$i"},
 395                                    0, $form->{"exchangerate_$i"});
 396       }
 397     }
 398   }
 399
 400   if ($payments_only) {
 401     $query = qq|UPDATE ap SET paid = ?, datepaid = ? WHERE id = ?|;
 402     do_query($form, $dbh, $query,  $form->{invpaid}, $form->{invpaid} ? conv_date($form->{datepaid}) : undef, conv_i($form->{id}));
 403   }
 404
 405   IO->set_datepaid(table => 'ap', id => $form->{id}, dbh => $dbh);
 406
 407   # safety check datev export
 408   if ($::instance_conf->get_datev_check_on_ap_transaction) {
 409     my $transdate = $::form->{transdate} ? DateTime->from_lxoffice($::form->{transdate}) : undef;
 410     $transdate  ||= DateTime->today;
 411
 412     my $datev = SL::DATEV->new(
 413       exporttype => DATEV_ET_BUCHUNGEN,
 414       format     => DATEV_FORMAT_KNE,
 415       dbh        => $dbh,
 416       from       => $transdate,
 417       to         => $transdate,
 418       trans_id   => $form->{id},
 419     );
 420
 421     $datev->export;
 422
 423     if ($datev->errors) {
 424       $dbh->rollback;
 425       die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 426     }
 427   }
 428
 429   if (!$provided_dbh) {
 430     $dbh->commit();
 431     $dbh->disconnect();
 432   }
 433
 434   $rc = 1; #  Den return-code auf true setzen, aber nur falls beim commit alles i.O. ist
 435
 436   $main::lxdebug->leave_sub();
 437
 438   return $rc;
 439 }
 440
 441 sub delete_transaction {
 442   $main::lxdebug->enter_sub();
 443
 444   my ($self, $myconfig, $form) = @_;
 445
 446   # connect to database
 447   my $dbh = $form->dbconnect_noauto($myconfig);
 448
 449   # acc_trans entries are deleted by database triggers.
 450   my $query = qq|DELETE FROM ap WHERE id = ?|;
 451   do_query($form, $dbh, $query, $form->{id});
 452
 453   my $rc = $dbh->commit;
 454   $dbh->disconnect;
 455
 456   $main::lxdebug->leave_sub();
 457
 458   return $rc;
 459 }
 460
 461 sub ap_transactions {
 462   $main::lxdebug->enter_sub();
 463
 464   my ($self, $myconfig, $form) = @_;
 465
 466   # connect to database
 467   my $dbh = $form->get_standard_dbh($myconfig);
 468
 469   my $query =
 470     qq|SELECT a.id, a.invnumber, a.transdate, a.duedate, a.amount, a.paid, | .
 471     qq|  a.ordnumber, v.name, a.invoice, a.netamount, a.datepaid, a.notes, | .
 472     qq|  a.globalproject_id, a.storno, a.storno_id, | .
 473     qq|  pr.projectnumber AS globalprojectnumber, | .
 474     qq|  e.name AS employee, | .
 475     qq|  v.vendornumber, v.country, v.ustid, | .
 476     qq|  tz.description AS taxzone, | .
 477     qq|  pt.description AS payment_terms, | .
 478     qq{  ( SELECT ch.accno || ' -- ' || ch.description
 479            FROM acc_trans at
 480            LEFT JOIN chart ch ON ch.id = at.chart_id
 481            WHERE ch.link ~ 'AP[[:>:]]'
 482             AND at.trans_id = a.id
 483             LIMIT 1
 484           ) AS charts } .
 485     qq|FROM ap a | .
 486     qq|JOIN vendor v ON (a.vendor_id = v.id) | .
 487     qq|LEFT JOIN employee e ON (a.employee_id = e.id) | .
 488     qq|LEFT JOIN project pr ON (a.globalproject_id = pr.id) | .
 489     qq|LEFT JOIN tax_zones tz ON (tz.id = v.taxzone_id)| .
 490     qq|LEFT JOIN payment_terms pt ON (pt.id = v.payment_id)|;
 491
 492   my $where = '';
 493   my @values;
 494
 495   if ($form->{vendor_id}) {
 496     $where .= " AND a.vendor_id = ?";
 497     push(@values, $form->{vendor_id});
 498   } elsif ($form->{vendor}) {
 499     $where .= " AND v.name ILIKE ?";
 500     push(@values, $form->like($form->{vendor}));
 501   }
 502   if ($form->{department}) {
 503     # ähnlich wie commit 0bbfb33b6aa8e38bb6c81d1684ab7d08e5b5c5af abteilung
 504     # wird so nicht mehr als zeichenkette zusammengebaut
 505     # hätte zu ee9f9f9aa4c3b9d5d20ab10a45c12bcaa6aa78d0 auffallen können ;-) jan
 506     #my ($null, $department_id) = split /--/, $form->{department};
 507     $where .= " AND a.department_id = ?";
 508     push(@values, $form->{department});
 509   }
 510   if ($form->{invnumber}) {
 511     $where .= " AND a.invnumber ILIKE ?";
 512     push(@values, $form->like($form->{invnumber}));
 513   }
 514   if ($form->{ordnumber}) {
 515     $where .= " AND a.ordnumber ILIKE ?";
 516     push(@values, $form->like($form->{ordnumber}));
 517   }
 518   if ($form->{notes}) {
 519     $where .= " AND lower(a.notes) LIKE ?";
 520     push(@values, $form->like($form->{notes}));
 521   }
 522   if ($form->{project_id}) {
 523     $where .=
 524       qq|AND ((a.globalproject_id = ?) OR EXISTS | .
 525       qq|  (SELECT * FROM invoice i | .
 526       qq|   WHERE i.project_id = ? AND i.trans_id = a.id) | .
 527       qq| OR EXISTS | .
 528       qq|  (SELECT * FROM acc_trans at | .
 529       qq|   WHERE at.project_id = ? AND at.trans_id = a.id)| .
 530       qq|  )|;
 531     push(@values, $form->{project_id}, $form->{project_id}, $form->{project_id});
 532   }
 533
 534   if ($form->{transdatefrom}) {
 535     $where .= " AND a.transdate >= ?";
 536     push(@values, $form->{transdatefrom});
 537   }
 538   if ($form->{transdateto}) {
 539     $where .= " AND a.transdate <= ?";
 540     push(@values, $form->{transdateto});
 541   }
 542   if ($form->{open} || $form->{closed}) {
 543     unless ($form->{open} && $form->{closed}) {
 544       $where .= " AND a.amount <> a.paid" if ($form->{open});
 545       $where .= " AND a.amount = a.paid"  if ($form->{closed});
 546     }
 547   }
 548
 549   if ($where) {
 550     substr($where, 0, 4, " WHERE ");
 551     $query .= $where;
 552   }
 553
 554   my @a = qw(transdate invnumber name);
 555   push @a, "employee" if $form->{l_employee};
 556   my $sortdir   = !defined $form->{sortdir} ? 'ASC' : $form->{sortdir} ? 'ASC' : 'DESC';
 557   my $sortorder = join(', ', map { "$_ $sortdir" } @a);
 558
 559   if (grep({ $_ eq $form->{sort} } qw(transdate id invnumber ordnumber name netamount tax amount paid datepaid due duedate notes employee transaction_description))) {
 560     $sortorder = $form->{sort} . " $sortdir";
 561   }
 562
 563   $query .= " ORDER BY $sortorder";
 564
 565   my @result = selectall_hashref_query($form, $dbh, $query, @values);
 566
 567   $form->{AP} = [ @result ];
 568
 569   $main::lxdebug->leave_sub();
 570 }
 571
 572 sub get_transdate {
 573   $main::lxdebug->enter_sub();
 574
 575   my ($self, $myconfig, $form) = @_;
 576
 577   # connect to database
 578   my $dbh = $form->dbconnect($myconfig);
 579
 580   my $query =
 581     "SELECT COALESCE(" .
 582     "  (SELECT transdate FROM ap WHERE id = " .
 583     "    (SELECT MAX(id) FROM ap) LIMIT 1), " .
 584     "  current_date)";
 585   ($form->{transdate}) = $dbh->selectrow_array($query);
 586
 587   $dbh->disconnect;
 588
 589   $main::lxdebug->leave_sub();
 590 }
 591
 592 sub _delete_payments {
 593   $main::lxdebug->enter_sub();
 594
 595   my ($self, $form, $dbh) = @_;
 596
 597   my @delete_acc_trans_ids;
 598
 599   # Delete old payment entries from acc_trans.
 600   my $query =
 601     qq|SELECT acc_trans_id
 602        FROM acc_trans
 603        WHERE (trans_id = ?) AND fx_transaction
 604
 605        UNION
 606
 607        SELECT at.acc_trans_id
 608        FROM acc_trans at
 609        LEFT JOIN chart c ON (at.chart_id = c.id)
 610        WHERE (trans_id = ?) AND (c.link LIKE '%AP_paid%')|;
 611   push @delete_acc_trans_ids, selectall_array_query($form, $dbh, $query, conv_i($form->{id}), conv_i($form->{id}));
 612
 613   $query =
 614     qq|SELECT at.acc_trans_id
 615        FROM acc_trans at
 616        LEFT JOIN chart c ON (at.chart_id = c.id)
 617        WHERE (trans_id = ?)
 618          AND ((c.link = 'AP') OR (c.link LIKE '%:AP') OR (c.link LIKE 'AP:%'))
 619        ORDER BY at.acc_trans_id
 620        OFFSET 1|;
 621   push @delete_acc_trans_ids, selectall_array_query($form, $dbh, $query, conv_i($form->{id}));
 622
 623   if (@delete_acc_trans_ids) {
 624     $query = qq|DELETE FROM acc_trans WHERE acc_trans_id IN (| . join(", ", @delete_acc_trans_ids) . qq|)|;
 625     do_query($form, $dbh, $query);
 626   }
 627
 628   $main::lxdebug->leave_sub();
 629 }
 630
 631 sub post_payment {
 632   $main::lxdebug->enter_sub();
 633
 634   my ($self, $myconfig, $form, $locale) = @_;
 635
 636   # connect to database, turn off autocommit
 637   my $dbh = $form->dbconnect_noauto($myconfig);
 638
 639   my (%payments, $old_form, $row, $item, $query, %keep_vars);
 640
 641   $old_form = save_form();
 642
 643   # Delete all entries in acc_trans from prior payments.
 644   if (SL::DB::Default->get->payments_changeable != 0) {
 645     $self->_delete_payments($form, $dbh);
 646   }
 647
 648   # Save the new payments the user made before cleaning up $form.
 649   my $payments_re = '^datepaid_\d+$|^gldate_\d+$|^acc_trans_id_\d+$|^memo_\d+$|^source_\d+$|^exchangerate_\d+$|^paid_\d+$|^paid_project_id_\d+$|^AP_paid_\d+$|^paidaccounts$';
 650   map { $payments{$_} = $form->{$_} } grep m/$payments_re/, keys %{ $form };
 651
 652   # Clean up $form so that old content won't tamper the results.
 653   %keep_vars = map { $_, 1 } qw(login password id);
 654   map { delete $form->{$_} unless $keep_vars{$_} } keys %{ $form };
 655
 656   # Retrieve the invoice from the database.
 657   $form->create_links('AP', $myconfig, 'vendor', $dbh);
 658
 659   # Restore the payment options from the user input.
 660   map { $form->{$_} = $payments{$_} } keys %payments;
 661
 662   # Set up the content of $form in the way that AR::post_transaction() expects.
 663
 664   $self->setup_form($form, 1);
 665
 666   $form->{exchangerate}    = $form->format_amount($myconfig, $form->{exchangerate});
 667   $form->{defaultcurrency} = $form->get_default_currency($myconfig);
 668
 669   # Get the AP accno.
 670   $query =
 671     qq|SELECT c.accno
 672        FROM acc_trans at
 673        LEFT JOIN chart c ON (at.chart_id = c.id)
 674        WHERE (trans_id = ?)
 675          AND ((c.link = 'AP') OR (c.link LIKE '%:AP') OR (c.link LIKE 'AP:%'))
 676        ORDER BY at.acc_trans_id
 677        LIMIT 1|;
 678
 679   ($form->{APselected}) = selectfirst_array_query($form, $dbh, $query, conv_i($form->{id}));
 680
 681   # Post the new payments.
 682   $self->post_transaction($myconfig, $form, $dbh, 1);
 683
 684   restore_form($old_form);
 685
 686   my $rc = $dbh->commit();
 687   $dbh->disconnect();
 688
 689   $main::lxdebug->leave_sub();
 690
 691   return $rc;
 692 }
 693
 694 sub setup_form {
 695   $main::lxdebug->enter_sub();
 696
 697   my ($self, $form, $for_post_payments) = @_;
 698
 699   my ($exchangerate, $i, $j, $k, $key, $akey, $ref, $index, $taxamount, $totalamount, $totaltax, $totalwithholding, $withholdingrate,
 700       $taxincluded, $tax, $diff);
 701
 702   # forex
 703   $form->{forex} = $form->{exchangerate};
 704   $exchangerate = ($form->{exchangerate}) ? $form->{exchangerate} : 1;
 705
 706   foreach $key (keys %{ $form->{AP_links} }) {
 707     foreach $ref (@{ $form->{AP_links}{$key} }) {
 708       if ($key eq "AP_paid") {
 709         $form->{"select$key"} .= "<option value=\"$ref->{accno}\">$ref->{accno}--$ref->{description}</option>\n";
 710       } else {
 711         $form->{"select$key"} .= "<option value=\"$ref->{accno}--$ref->{tax_id}\">$ref->{accno}--$ref->{description}</option>\n";
 712       }
 713     }
 714
 715     $form->{$key} = $form->{"select$key"};
 716
 717     $j = 0;
 718     $k = 0;
 719
 720     # if there is a value we have an old entry
 721     next unless $form->{acc_trans}{$key};
 722
 723     # do not use old entries for payments. They come from the form
 724     # even if they are not changeable (then they are in hiddens)
 725     next if $for_post_payments && $key eq "AP_paid";
 726
 727     for $i (1 .. scalar @{ $form->{acc_trans}{$key} }) {
 728
 729       if ($key eq "AP_paid") {
 730         $j++;
 731         $form->{"AP_paid_$j"}         = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 732         $form->{"acc_trans_id_$j"}    = $form->{acc_trans}{$key}->[$i - 1]->{acc_trans_id};
 733         $form->{"paid_$j"}            = $form->{acc_trans}{$key}->[$i - 1]->{amount};
 734         $form->{"datepaid_$j"}        = $form->{acc_trans}{$key}->[$i - 1]->{transdate};
 735         $form->{"gldate_$j"}          = $form->{acc_trans}{$key}->[$i - 1]->{gldate};
 736         $form->{"source_$j"}          = $form->{acc_trans}{$key}->[$i - 1]->{source};
 737         $form->{"memo_$j"}            = $form->{acc_trans}{$key}->[$i - 1]->{memo};
 738
 739         $form->{"exchangerate_$i"}    = $form->{acc_trans}{$key}->[$i - 1]->{exchangerate};
 740         $form->{"forex_$j"}           = $form->{"exchangerate_$i"};
 741         $form->{"AP_paid_$j"}         = $form->{acc_trans}{$key}->[$i-1]->{accno};
 742         $form->{"paid_project_id_$j"} = $form->{acc_trans}{$key}->[$i - 1]->{project_id};
 743         $form->{paidaccounts}++;
 744
 745       } else {
 746         $akey = $key;
 747         $akey =~ s/AP_//;
 748
 749         if (($key eq "AP_tax") || ($key eq "AR_tax")) {
 750           $form->{"${key}_$form->{acc_trans}{$key}->[$i-1]->{accno}"}  = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 751           $form->{"${akey}_$form->{acc_trans}{$key}->[$i-1]->{accno}"} = $form->round_amount($form->{acc_trans}{$key}->[$i - 1]->{amount} / $exchangerate, 2);
 752
 753           if ($form->{"$form->{acc_trans}{$key}->[$i-1]->{accno}_rate"} > 0) {
 754             $totaltax += $form->{"${akey}_$form->{acc_trans}{$key}->[$i-1]->{accno}"};
 755           } else {
 756             $totalwithholding += $form->{"${akey}_$form->{acc_trans}{$key}->[$i-1]->{accno}"};
 757             $withholdingrate  += $form->{"$form->{acc_trans}{$key}->[$i-1]->{accno}_rate"};
 758           }
 759
 760           $index                 = $form->{acc_trans}{$key}->[$i - 1]->{index};
 761           $form->{"tax_$index"}  = $form->{acc_trans}{$key}->[$i - 1]->{amount} * -1;
 762           $totaltax             += $form->{"tax_$index"};
 763
 764         } else {
 765           $k++;
 766           $form->{"${akey}_$k"} = $form->round_amount($form->{acc_trans}{$key}->[$i - 1]->{amount} / $exchangerate, 2);
 767
 768           if ($akey eq 'amount') {
 769             $form->{rowcount}++;
 770             $form->{"${akey}_$i"} *= -1;
 771             $totalamount          += $form->{"${akey}_$i"};
 772             $form->{taxrate}       = $form->{acc_trans}{$key}->[$i - 1]->{rate};
 773
 774             $form->{"projectnumber_$k"}    = "$form->{acc_trans}{$key}->[$i-1]->{projectnumber}";
 775             $form->{"oldprojectnumber_$k"} = $form->{"projectnumber_$k"};
 776             $form->{"project_id_$k"}       = "$form->{acc_trans}{$key}->[$i-1]->{project_id}";
 777           }
 778
 779           $form->{"${key}_$k"} = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 780
 781           my $q_description    = quotemeta($form->{acc_trans}{$key}->[$i-1]->{description});
 782           $form->{"select${key}"} =~
 783             m/<option value=\"
 784                 ($form->{acc_trans}{$key}->[$i-1]->{accno}--[^\"]*)
 785               \">
 786               $form->{acc_trans}{$key}->[$i-1]->{accno}
 787               --
 788               ${q_description}
 789               <\/option>\n/x;
 790           $form->{"${key}_$k"} = $1;
 791
 792           if ($akey eq "AP") {
 793             $form->{APselected} = $form->{acc_trans}{$key}->[$i-1]->{accno};
 794
 795           } elsif ($akey eq 'amount') {
 796             $form->{"${key}_$k"}   = $form->{acc_trans}{$key}->[$i-1]->{accno} . "--" . $form->{acc_trans}{$key}->[$i-1]->{id};
 797             $form->{"taxchart_$k"} = $form->{acc_trans}{$key}->[$i-1]->{id}    . "--" . $form->{acc_trans}{$key}->[$i-1]->{rate};
 798           }
 799         }
 800       }
 801     }
 802   }
 803
 804   $form->{taxincluded}  = $taxincluded if ($form->{id});
 805   $form->{paidaccounts} = 1            if not defined $form->{paidaccounts};
 806
 807   if ($form->{taxincluded} && $form->{taxrate} && $totalamount) {
 808     # add tax to amounts and invtotal
 809     for $i (1 .. $form->{rowcount}) {
 810       $taxamount            = ($totaltax + $totalwithholding) * $form->{"amount_$i"} / $totalamount;
 811       $tax                  = $form->round_amount($taxamount, 2);
 812       $diff                += ($taxamount - $tax);
 813       $form->{"amount_$i"} += $form->{"tax_$i"};
 814     }
 815
 816     $form->{amount_1} += $form->round_amount($diff, 2);
 817   }
 818
 819   $taxamount        = $form->round_amount($taxamount, 2);
 820   $form->{invtotal} = $totalamount + $totaltax;
 821
 822   $main::lxdebug->leave_sub();
 823 }
 824
 825 sub storno {
 826   $main::lxdebug->enter_sub();
 827
 828   my ($self, $form, $myconfig, $id) = @_;
 829
 830   my ($query, $new_id, $storno_row, $acc_trans_rows);
 831   my $dbh = $form->get_standard_dbh($myconfig);
 832
 833   $query = qq|SELECT nextval('glid')|;
 834   ($new_id) = selectrow_query($form, $dbh, $query);
 835
 836   $query = qq|SELECT * FROM ap WHERE id = ?|;
 837   $storno_row = selectfirst_hashref_query($form, $dbh, $query, $id);
 838
 839   $storno_row->{id}         = $new_id;
 840   $storno_row->{storno_id}  = $id;
 841   $storno_row->{storno}     = 't';
 842   $storno_row->{invnumber}  = 'Storno-' . $storno_row->{invnumber};
 843   $storno_row->{amount}    *= -1;
 844   $storno_row->{netamount} *= -1;
 845   $storno_row->{paid}       = $storno_row->{amount};
 846
 847   delete @$storno_row{qw(itime mtime)};
 848
 849   $query = sprintf 'INSERT INTO ap (%s) VALUES (%s)', join(', ', keys %$storno_row), join(', ', map '?', values %$storno_row);
 850   do_query($form, $dbh, $query, (values %$storno_row));
 851
 852   $query = qq|UPDATE ap SET paid = amount + paid, storno = 't' WHERE id = ?|;
 853   do_query($form, $dbh, $query, $id);
 854
 855   # now copy acc_trans entries
 856   $query = qq|SELECT a.*, c.link FROM acc_trans a LEFT JOIN chart c ON a.chart_id = c.id WHERE a.trans_id = ? ORDER BY a.acc_trans_id|;
 857   my $rowref = selectall_hashref_query($form, $dbh, $query, $id);
 858
 859   # kill all entries containing payments, which are the last 2n rows, of which the last has link =~ /paid/
 860   while ($rowref->[-1]{link} =~ /paid/) {
 861     splice(@$rowref, -2);
 862   }
 863
 864   for my $row (@$rowref) {
 865     delete @$row{qw(itime mtime link acc_trans_id)};
 866     $query = sprintf 'INSERT INTO acc_trans (%s) VALUES (%s)', join(', ', keys %$row), join(', ', map '?', values %$row);
 867     $row->{trans_id}   = $new_id;
 868     $row->{amount}    *= -1;
 869     do_query($form, $dbh, $query, (values %$row));
 870   }
 871
 872   map { IO->set_datepaid(table => 'ap', id => $_, dbh => $dbh) } ($id, $new_id);
 873
 874   $dbh->commit;
 875
 876   $main::lxdebug->leave_sub();
 877 }
 878
 879 1;
 880