SL/AP.pm

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (C) 2001
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #  Contributors:
  16 #
  17 # This program is free software; you can redistribute it and/or modify
  18 # it under the terms of the GNU General Public License as published by
  19 # the Free Software Foundation; either version 2 of the License, or
  20 # (at your option) any later version.
  21 #
  22 # This program is distributed in the hope that it will be useful,
  23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 # GNU General Public License for more details.
  26 # You should have received a copy of the GNU General Public License
  27 # along with this program; if not, write to the Free Software
  28 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
  29 # MA 02110-1335, USA.
  30 #======================================================================
  31 #
  32 # Accounts Payables database backend routines
  33 #
  34 #======================================================================
  35
  36 package AP;
  37
  38 use SL::DATEV qw(:CONSTANTS);
  39 use SL::DBUtils;
  40 use SL::IO;
  41 use SL::MoreCommon;
  42 use SL::DB::Default;
  43 use SL::Util qw(trim);
  44 use SL::DB;
  45 use Data::Dumper;
  46
  47 use strict;
  48
  49 sub post_transaction {
  50   my ($self, $myconfig, $form, $provided_dbh, $payments_only) = @_;
  51   $main::lxdebug->enter_sub();
  52
  53   my $rc = SL::DB->client->with_transaction(\&_post_transaction, $self, $myconfig, $form, $provided_dbh, $payments_only);
  54
  55   $::lxdebug->leave_sub;
  56   return $rc;
  57 }
  58
  59 sub _post_transaction {
  60   my ($self, $myconfig, $form, $provided_dbh, $payments_only) = @_;
  61   my $dbh = $provided_dbh || SL::DB->client->dbh;
  62
  63   my ($null, $taxrate, $amount);
  64   my $exchangerate = 0;
  65
  66   $form->{defaultcurrency} = $form->get_default_currency($myconfig);
  67   $form->{taxincluded} = 0 unless $form->{taxincluded};
  68
  69   ($null, $form->{department_id}) = split(/--/, $form->{department});
  70
  71   if ($form->{currency} eq $form->{defaultcurrency}) {
  72     $form->{exchangerate} = 1;
  73   } else {
  74     $exchangerate         = $form->check_exchangerate($myconfig, $form->{currency}, $form->{transdate}, 'sell');
  75     $form->{exchangerate} = $exchangerate || $form->parse_amount($myconfig, $form->{exchangerate});
  76   }
  77
  78   for my $i (1 .. $form->{rowcount}) {
  79     $form->{AP_amounts}{"amount_$i"} =
  80       (split(/--/, $form->{"AP_amount_$i"}))[0];
  81   }
  82
  83   ($form->{AP_amounts}{payables}) = split(/--/, $form->{APselected});
  84   ($form->{AP_payables})          = split(/--/, $form->{APselected});
  85
  86   # calculate the totals while calculating and reformatting the $amount_$i and $tax_$i
  87   ($form->{netamount},$form->{total_tax},$form->{invtotal}) = $form->calculate_arap('buy',$form->{taxincluded}, $form->{exchangerate});
  88
  89   # adjust paidaccounts if there is no date in the last row
  90   $form->{paidaccounts}-- unless ($form->{"datepaid_$form->{paidaccounts}"});
  91
  92   $form->{invpaid} = 0;
  93
  94   # add payments
  95   for my $i (1 .. $form->{paidaccounts}) {
  96     $form->{"paid_$i"} =
  97       $form->round_amount($form->parse_amount($myconfig, $form->{"paid_$i"}),
  98                           2);
  99
 100     $form->{invpaid} += $form->{"paid_$i"};
 101     $form->{datepaid} = $form->{"datepaid_$i"};
 102
 103   }
 104
 105   $form->{invpaid} =
 106     $form->round_amount($form->{invpaid} * $form->{exchangerate}, 2);
 107
 108   # # store invoice total, this goes into ap table
 109   # $form->{invtotal} = $form->{netamount} + $form->{total_tax};
 110
 111   # amount for total AP
 112   $form->{payables} = $form->{invtotal};
 113
 114   # update exchangerate
 115   if (($form->{currency} ne $form->{defaultcurrency}) && !$exchangerate) {
 116     $form->update_exchangerate($dbh, $form->{currency}, $form->{transdate}, 0,
 117                                $form->{exchangerate});
 118   }
 119
 120   my ($query, $sth, @values);
 121
 122   if (!$payments_only) {
 123     # if we have an id delete old records
 124     if ($form->{id}) {
 125
 126       # delete detail records
 127       $query = qq|DELETE FROM acc_trans WHERE trans_id = ?|;
 128       do_query($form, $dbh, $query, $form->{id});
 129
 130     } else {
 131
 132       ($form->{id}) = selectrow_query($form, $dbh, qq|SELECT nextval('glid')|);
 133
 134       $query =
 135         qq|INSERT INTO ap (id, invnumber, employee_id,currency_id, taxzone_id) | .
 136         qq|VALUES (?, ?, (SELECT e.id FROM employee e WHERE e.login = ?),
 137                       (SELECT id FROM currencies WHERE name = ?), (SELECT taxzone_id FROM vendor WHERE id = ?) )|;
 138       do_query($form, $dbh, $query, $form->{id}, $form->{invnumber}, $::myconfig{login}, $form->{currency}, $form->{vendor_id});
 139
 140     }
 141
 142     $query = qq|UPDATE ap SET invnumber = ?,
 143                 transdate = ?, ordnumber = ?, vendor_id = ?, taxincluded = ?,
 144                 amount = ?, duedate = ?, paid = ?, netamount = ?,
 145                 currency_id = (SELECT id FROM currencies WHERE name = ?), notes = ?, department_id = ?, storno = ?, storno_id = ?,
 146                 globalproject_id = ?, direct_debit = ?
 147                WHERE id = ?|;
 148     @values = ($form->{invnumber}, conv_date($form->{transdate}),
 149                   $form->{ordnumber}, conv_i($form->{vendor_id}),
 150                   $form->{taxincluded} ? 't' : 'f', $form->{invtotal},
 151                   conv_date($form->{duedate}), $form->{invpaid},
 152                   $form->{netamount},
 153                   $form->{currency}, $form->{notes},
 154                   conv_i($form->{department_id}), $form->{storno},
 155                   $form->{storno_id}, conv_i($form->{globalproject_id}),
 156                   $form->{direct_debit} ? 't' : 'f',
 157                   $form->{id});
 158     do_query($form, $dbh, $query, @values);
 159
 160     $form->new_lastmtime('ap');
 161
 162     # add individual transactions
 163     for my $i (1 .. $form->{rowcount}) {
 164       if ($form->{"amount_$i"} != 0) {
 165         my $project_id;
 166         $project_id = conv_i($form->{"project_id_$i"});
 167
 168         # insert detail records in acc_trans
 169         $query =
 170           qq|INSERT INTO acc_trans | .
 171           qq|  (trans_id, chart_id, amount, transdate, project_id, taxkey, tax_id, chart_link)| .
 172           qq|VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), | .
 173           qq|  ?, ?, ?, ?, ?,| .
 174           qq| (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 175         @values = ($form->{id}, $form->{AP_amounts}{"amount_$i"},
 176                    $form->{"amount_$i"}, conv_date($form->{transdate}),
 177                    $project_id, $form->{"taxkey_$i"}, conv_i($form->{"tax_id_$i"}),
 178                    $form->{AP_amounts}{"amount_$i"});
 179         do_query($form, $dbh, $query, @values);
 180
 181         if ($form->{"tax_$i"} != 0) {
 182           # insert detail records in acc_trans
 183           $query =
 184             qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, | .
 185             qq|  project_id, taxkey, tax_id, chart_link) | .
 186             qq|VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), | .
 187             qq|  ?, ?, ?, ?, ?,| .
 188             qq| (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 189           @values = ($form->{id}, $form->{AP_amounts}{"tax_$i"},
 190                      $form->{"tax_$i"}, conv_date($form->{transdate}),
 191                      $project_id, $form->{"taxkey_$i"}, conv_i($form->{"tax_id_$i"}),
 192                      $form->{AP_amounts}{"tax_$i"});
 193           do_query($form, $dbh, $query, @values);
 194         }
 195
 196       }
 197     }
 198
 199     # add payables
 200     $query =
 201       qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, taxkey, tax_id, chart_link) | .
 202       qq|VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, | .
 203       qq|        (SELECT taxkey_id FROM chart WHERE accno = ?),| .
 204       qq|        (SELECT tax_id| .
 205       qq|         FROM taxkeys| .
 206       qq|         WHERE chart_id= (SELECT id | .
 207       qq|                          FROM chart| .
 208       qq|                          WHERE accno = ?)| .
 209       qq|         AND startdate <= ?| .
 210       qq|         ORDER BY startdate DESC LIMIT 1),| .
 211       qq|        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 212     @values = ($form->{id}, $form->{AP_amounts}{payables}, $form->{payables},
 213                conv_date($form->{transdate}), $form->{AP_amounts}{payables}, $form->{AP_amounts}{payables}, conv_date($form->{transdate}),
 214                $form->{AP_amounts}{payables});
 215     do_query($form, $dbh, $query, @values);
 216   }
 217
 218   # if there is no amount but a payment record a payable
 219   if ($form->{amount} == 0 && $form->{invtotal} == 0) {
 220     $form->{payables} = $form->{invpaid};
 221   }
 222
 223   # add paid transactions
 224   for my $i (1 .. $form->{paidaccounts}) {
 225
 226     if ($form->{"acc_trans_id_$i"} && $payments_only && (SL::DB::Default->get->payments_changeable == 0)) {
 227       next;
 228     }
 229
 230     if ($form->{"paid_$i"} != 0) {
 231       my $project_id = conv_i($form->{"paid_project_id_$i"});
 232
 233       $exchangerate = 0;
 234       if ($form->{currency} eq $form->{defaultcurrency}) {
 235         $form->{"exchangerate_$i"} = 1;
 236       } else {
 237         $exchangerate              = $form->check_exchangerate($myconfig, $form->{currency}, $form->{"datepaid_$i"}, 'sell');
 238         $form->{"exchangerate_$i"} = $exchangerate || $form->parse_amount($myconfig, $form->{"exchangerate_$i"});
 239       }
 240       $form->{"AP_paid_$i"} =~ s/\"//g;
 241
 242       # get paid account
 243
 244       ($form->{"AP_paid_account_$i"}) = split(/--/, $form->{"AP_paid_$i"});
 245       $form->{"datepaid_$i"} = $form->{transdate}
 246         unless ($form->{"datepaid_$i"});
 247
 248       # if there is no amount and invtotal is zero there is no exchangerate
 249       if ($form->{amount} == 0 && $form->{invtotal} == 0) {
 250         $form->{exchangerate} = $form->{"exchangerate_$i"};
 251       }
 252
 253       $amount =
 254         $form->round_amount($form->{"paid_$i"} * $form->{exchangerate} * -1,
 255                             2);
 256       if ($form->{payables}) {
 257         $query =
 258           qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, project_id, taxkey, tax_id, chart_link) | .
 259           qq|VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, ?, | .
 260           qq|        (SELECT taxkey_id FROM chart WHERE accno = ?),| .
 261           qq|        (SELECT tax_id| .
 262           qq|         FROM taxkeys| .
 263           qq|         WHERE chart_id= (SELECT id | .
 264           qq|                          FROM chart| .
 265           qq|                          WHERE accno = ?)| .
 266           qq|         AND startdate <= ?| .
 267           qq|         ORDER BY startdate DESC LIMIT 1),| .
 268           qq|        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 269         @values = ($form->{id}, $form->{AP_payables}, $amount,
 270                    conv_date($form->{"datepaid_$i"}), $project_id,
 271                    $form->{AP_payables}, $form->{AP_payables}, conv_date($form->{"datepaid_$i"}),
 272                    $form->{AP_payables});
 273         do_query($form, $dbh, $query, @values);
 274       }
 275       $form->{payables} = $amount;
 276
 277       # add payment
 278       my $gldate = (conv_date($form->{"gldate_$i"}))? conv_date($form->{"gldate_$i"}) : conv_date($form->current_date($myconfig));
 279       $query =
 280         qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, gldate, source, memo, project_id, taxkey, tax_id, chart_link) | .
 281         qq|VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, ?, ?, ?, ?, | .
 282         qq|        (SELECT taxkey_id FROM chart WHERE accno = ?), | .
 283         qq|        (SELECT tax_id| .
 284         qq|         FROM taxkeys| .
 285         qq|         WHERE chart_id= (SELECT id | .
 286         qq|                          FROM chart| .
 287         qq|                          WHERE accno = ?)| .
 288         qq|         AND startdate <= ?| .
 289         qq|         ORDER BY startdate DESC LIMIT 1),| .
 290         qq|        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 291       @values = ($form->{id}, $form->{"AP_paid_account_$i"}, $form->{"paid_$i"},
 292                  conv_date($form->{"datepaid_$i"}), $gldate, $form->{"source_$i"},
 293                  $form->{"memo_$i"}, $project_id, $form->{"AP_paid_account_$i"},
 294                  $form->{"AP_paid_account_$i"}, conv_date($form->{"datepaid_$i"}),
 295                  $form->{"AP_paid_account_$i"});
 296       do_query($form, $dbh, $query, @values);
 297
 298       # add exchange rate difference
 299       $amount =
 300         $form->round_amount($form->{"paid_$i"} *
 301                             ($form->{"exchangerate_$i"} - 1), 2);
 302       if ($amount != 0) {
 303         $query =
 304           qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, fx_transaction, cleared, project_id, taxkey, tax_id, chart_link) | .
 305           qq|VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, 't', 'f', ?, | .
 306           qq|        (SELECT taxkey_id FROM chart WHERE accno = ?), | .
 307           qq|        (SELECT tax_id| .
 308           qq|         FROM taxkeys| .
 309           qq|         WHERE chart_id= (SELECT id | .
 310           qq|                          FROM chart| .
 311           qq|                          WHERE accno = ?)| .
 312           qq|         AND startdate <= ?| .
 313           qq|         ORDER BY startdate DESC LIMIT 1),| .
 314           qq|        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 315         @values = ($form->{id}, $form->{"AP_paid_account_$i"}, $amount,
 316                    conv_date($form->{"datepaid_$i"}), $project_id,
 317                    $form->{"AP_paid_account_$i"},
 318                    $form->{"AP_paid_account_$i"}, conv_date($form->{"datepaid_$i"}),
 319                    $form->{"AP_paid_account_$i"});
 320         do_query($form, $dbh, $query, @values);
 321       }
 322
 323       # exchangerate gain/loss
 324       $amount =
 325         $form->round_amount($form->{"paid_$i"} *
 326                             ($form->{exchangerate} -
 327                              $form->{"exchangerate_$i"}), 2);
 328
 329       if ($amount != 0) {
 330         # fetch fxgain and fxloss chart info from defaults if charts aren't already filled in form
 331         if ( !$form->{fxgain_accno} && $::instance_conf->get_fxgain_accno_id ) {
 332           $form->{fxgain_accno} = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id)->accno;
 333         };
 334         if ( !$form->{fxloss_accno} && $::instance_conf->get_fxloss_accno_id ) {
 335           $form->{fxloss_accno} = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id)->accno;
 336         };
 337         die "fxloss_accno missing" if $amount < 0 and not $form->{fxloss_accno};
 338         die "fxgain_accno missing" if $amount > 0 and not $form->{fxgain_accno};
 339         $query =
 340           qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, fx_transaction, cleared, project_id, taxkey, tax_id, chart_link) | .
 341           qq|VALUES (?, (SELECT id FROM chart WHERE accno = ?), ?, ?, 't', 'f', ?, | .
 342           qq|        (SELECT taxkey_id FROM chart WHERE accno = ?),| .
 343           qq|        (SELECT tax_id| .
 344           qq|         FROM taxkeys| .
 345           qq|         WHERE chart_id= (SELECT id | .
 346           qq|                          FROM chart| .
 347           qq|                          WHERE accno = ?)| .
 348           qq|         AND startdate <= ?| .
 349           qq|         ORDER BY startdate DESC LIMIT 1),| .
 350           qq|        (SELECT c.link FROM chart c WHERE c.accno = ?))|;
 351         @values = ($form->{id},
 352                    ($amount > 0) ? $form->{fxgain_accno} : $form->{fxloss_accno},
 353                    $amount, conv_date($form->{"datepaid_$i"}), $project_id,
 354                    ($amount > 0) ? $form->{fxgain_accno} : $form->{fxloss_accno},
 355                    ($amount > 0) ? $form->{fxgain_accno} : $form->{fxloss_accno}, conv_date($form->{"datepaid_$i"}),
 356                    ($amount > 0) ? $form->{fxgain_accno} : $form->{fxloss_accno});
 357         do_query($form, $dbh, $query, @values);
 358       }
 359
 360       # update exchange rate record
 361       if (($form->{currency} ne $form->{defaultcurrency}) && !$exchangerate) {
 362         $form->update_exchangerate($dbh, $form->{currency},
 363                                    $form->{"datepaid_$i"},
 364                                    0, $form->{"exchangerate_$i"});
 365       }
 366     }
 367   }
 368
 369   if ($payments_only) {
 370     $query = qq|UPDATE ap SET paid = ?, datepaid = ? WHERE id = ?|;
 371     do_query($form, $dbh, $query,  $form->{invpaid}, $form->{invpaid} ? conv_date($form->{datepaid}) : undef, conv_i($form->{id}));
 372     $form->new_lastmtime('ap');
 373   }
 374
 375   IO->set_datepaid(table => 'ap', id => $form->{id}, dbh => $dbh);
 376
 377   # safety check datev export
 378   if ($::instance_conf->get_datev_check_on_ap_transaction) {
 379     my $transdate = $::form->{transdate} ? DateTime->from_lxoffice($::form->{transdate}) : undef;
 380     $transdate  ||= DateTime->today;
 381
 382     my $datev = SL::DATEV->new(
 383       exporttype => DATEV_ET_BUCHUNGEN,
 384       format     => DATEV_FORMAT_KNE,
 385       dbh        => $dbh,
 386       trans_id   => $form->{id},
 387     );
 388
 389     $datev->export;
 390
 391     if ($datev->errors) {
 392       die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 393     }
 394   }
 395
 396   return 1;
 397 }
 398
 399 sub delete_transaction {
 400   $main::lxdebug->enter_sub();
 401
 402   my ($self, $myconfig, $form) = @_;
 403
 404   SL::DB->client->with_transaction(sub {
 405     my $query = qq|DELETE FROM ap WHERE id = ?|;
 406     do_query($form, SL::DB->client->dbh, $query, $form->{id});
 407     1;
 408   }) or do { die SL::DB->client->error };
 409
 410   $main::lxdebug->leave_sub();
 411
 412   return 1;
 413 }
 414
 415 sub ap_transactions {
 416   $main::lxdebug->enter_sub();
 417
 418   my ($self, $myconfig, $form) = @_;
 419
 420   # connect to database
 421   my $dbh = $form->get_standard_dbh($myconfig);
 422
 423   my $query =
 424     qq|SELECT a.id, a.invnumber, a.transdate, a.duedate, a.amount, a.paid, | .
 425     qq|  a.ordnumber, v.name, a.invoice, a.netamount, a.datepaid, a.notes, | .
 426     qq|  a.globalproject_id, a.storno, a.storno_id, a.direct_debit, | .
 427     qq|  pr.projectnumber AS globalprojectnumber, | .
 428     qq|  e.name AS employee, | .
 429     qq|  v.vendornumber, v.country, v.ustid, | .
 430     qq|  tz.description AS taxzone, | .
 431     qq|  pt.description AS payment_terms, | .
 432     qq{  ( SELECT ch.accno || ' -- ' || ch.description
 433            FROM acc_trans at
 434            LEFT JOIN chart ch ON ch.id = at.chart_id
 435            WHERE ch.link ~ 'AP[[:>:]]'
 436             AND at.trans_id = a.id
 437             LIMIT 1
 438           ) AS charts } .
 439     qq|FROM ap a | .
 440     qq|JOIN vendor v ON (a.vendor_id = v.id) | .
 441     qq|LEFT JOIN contacts cp ON (a.cp_id = cp.cp_id) | .
 442     qq|LEFT JOIN employee e ON (a.employee_id = e.id) | .
 443     qq|LEFT JOIN project pr ON (a.globalproject_id = pr.id) | .
 444     qq|LEFT JOIN tax_zones tz ON (tz.id = a.taxzone_id)| .
 445     qq|LEFT JOIN payment_terms pt ON (pt.id = a.payment_id)|;
 446
 447   my $where = '';
 448
 449   unless ( $::auth->assert('show_ap_transactions', 1) ) {
 450     $where .= " AND NOT invoice = 'f' ";  # remove ap transactions from Sales -> Reports -> Invoices
 451   };
 452
 453   my @values;
 454
 455   if ($form->{vendor_id}) {
 456     $where .= " AND a.vendor_id = ?";
 457     push(@values, $form->{vendor_id});
 458   } elsif ($form->{vendor}) {
 459     $where .= " AND v.name ILIKE ?";
 460     push(@values, like($form->{vendor}));
 461   }
 462   if ($form->{"cp_name"}) {
 463     $where .= " AND (cp.cp_name ILIKE ? OR cp.cp_givenname ILIKE ?)";
 464     push(@values, (like($form->{"cp_name"}))x2);
 465   }
 466   if ($form->{department}) {
 467     # ähnlich wie commit 0bbfb33b6aa8e38bb6c81d1684ab7d08e5b5c5af abteilung
 468     # wird so nicht mehr als zeichenkette zusammengebaut
 469     # hätte zu ee9f9f9aa4c3b9d5d20ab10a45c12bcaa6aa78d0 auffallen können ;-) jan
 470     #my ($null, $department_id) = split /--/, $form->{department};
 471     $where .= " AND a.department_id = ?";
 472     push(@values, $form->{department});
 473   }
 474   if ($form->{invnumber}) {
 475     $where .= " AND a.invnumber ILIKE ?";
 476     push(@values, like($form->{invnumber}));
 477   }
 478   if ($form->{ordnumber}) {
 479     $where .= " AND a.ordnumber ILIKE ?";
 480     push(@values, like($form->{ordnumber}));
 481   }
 482   if ($form->{notes}) {
 483     $where .= " AND lower(a.notes) LIKE ?";
 484     push(@values, like($form->{notes}));
 485   }
 486   if ($form->{project_id}) {
 487     $where .=
 488       qq| AND ((a.globalproject_id = ?) OR EXISTS | .
 489       qq|  (SELECT * FROM invoice i | .
 490       qq|   WHERE i.project_id = ? AND i.trans_id = a.id) | .
 491       qq| OR EXISTS | .
 492       qq|  (SELECT * FROM acc_trans at | .
 493       qq|   WHERE at.project_id = ? AND at.trans_id = a.id)| .
 494       qq|  )|;
 495     push(@values, $form->{project_id}, $form->{project_id}, $form->{project_id});
 496   }
 497
 498   if ($form->{transdatefrom}) {
 499     $where .= " AND a.transdate >= ?";
 500     push(@values, trim($form->{transdatefrom}));
 501   }
 502   if ($form->{transdateto}) {
 503     $where .= " AND a.transdate <= ?";
 504     push(@values, trim($form->{transdateto}));
 505   }
 506   if ($form->{open} || $form->{closed}) {
 507     unless ($form->{open} && $form->{closed}) {
 508       $where .= " AND a.amount <> a.paid" if ($form->{open});
 509       $where .= " AND a.amount = a.paid"  if ($form->{closed});
 510     }
 511   }
 512
 513   if ($form->{parts_partnumber}) {
 514     $where .= <<SQL;
 515  AND EXISTS (
 516         SELECT invoice.trans_id
 517         FROM invoice
 518         LEFT JOIN parts ON (invoice.parts_id = parts.id)
 519         WHERE (invoice.trans_id = a.id)
 520           AND (parts.partnumber ILIKE ?)
 521         LIMIT 1
 522       )
 523 SQL
 524     push @values, like($form->{parts_partnumber});
 525   }
 526
 527   if ($form->{parts_description}) {
 528     $where .= <<SQL;
 529  AND EXISTS (
 530         SELECT invoice.trans_id
 531         FROM invoice
 532         WHERE (invoice.trans_id = a.id)
 533           AND (invoice.description ILIKE ?)
 534         LIMIT 1
 535       )
 536 SQL
 537     push @values, like($form->{parts_description});
 538   }
 539
 540   if ($where) {
 541     substr($where, 0, 4, " WHERE ");
 542     $query .= $where;
 543   }
 544
 545   my @a = qw(transdate invnumber name);
 546   push @a, "employee" if $form->{l_employee};
 547   my $sortdir   = !defined $form->{sortdir} ? 'ASC' : $form->{sortdir} ? 'ASC' : 'DESC';
 548   my $sortorder = join(', ', map { "$_ $sortdir" } @a);
 549
 550   if (grep({ $_ eq $form->{sort} } qw(transdate id invnumber ordnumber name netamount tax amount paid datepaid due duedate notes employee transaction_description direct_debit))) {
 551     $sortorder = $form->{sort} . " $sortdir";
 552   }
 553
 554   $query .= " ORDER BY $sortorder";
 555
 556   my @result = selectall_hashref_query($form, $dbh, $query, @values);
 557
 558   $form->{AP} = [ @result ];
 559
 560   $main::lxdebug->leave_sub();
 561 }
 562
 563 sub get_transdate {
 564   $main::lxdebug->enter_sub();
 565
 566   my ($self, $myconfig, $form) = @_;
 567
 568   # connect to database
 569   my $dbh = SL::DB->client->dbh;
 570
 571   my $query =
 572     "SELECT COALESCE(" .
 573     "  (SELECT transdate FROM ap WHERE id = " .
 574     "    (SELECT MAX(id) FROM ap) LIMIT 1), " .
 575     "  current_date)";
 576   ($form->{transdate}) = $dbh->selectrow_array($query);
 577
 578   $main::lxdebug->leave_sub();
 579 }
 580
 581 sub _delete_payments {
 582   $main::lxdebug->enter_sub();
 583
 584   my ($self, $form, $dbh) = @_;
 585
 586   my @delete_acc_trans_ids;
 587
 588   # Delete old payment entries from acc_trans.
 589   my $query =
 590     qq|SELECT acc_trans_id
 591        FROM acc_trans
 592        WHERE (trans_id = ?) AND fx_transaction
 593
 594        UNION
 595
 596        SELECT at.acc_trans_id
 597        FROM acc_trans at
 598        LEFT JOIN chart c ON (at.chart_id = c.id)
 599        WHERE (trans_id = ?) AND (c.link LIKE '%AP_paid%')|;
 600   push @delete_acc_trans_ids, selectall_array_query($form, $dbh, $query, conv_i($form->{id}), conv_i($form->{id}));
 601
 602   $query =
 603     qq|SELECT at.acc_trans_id
 604        FROM acc_trans at
 605        LEFT JOIN chart c ON (at.chart_id = c.id)
 606        WHERE (trans_id = ?)
 607          AND ((c.link = 'AP') OR (c.link LIKE '%:AP') OR (c.link LIKE 'AP:%'))
 608        ORDER BY at.acc_trans_id
 609        OFFSET 1|;
 610   push @delete_acc_trans_ids, selectall_array_query($form, $dbh, $query, conv_i($form->{id}));
 611
 612   if (@delete_acc_trans_ids) {
 613     $query = qq|DELETE FROM acc_trans WHERE acc_trans_id IN (| . join(", ", @delete_acc_trans_ids) . qq|)|;
 614     do_query($form, $dbh, $query);
 615   }
 616
 617   $main::lxdebug->leave_sub();
 618 }
 619
 620 sub post_payment {
 621   my ($self, $myconfig, $form, $locale) = @_;
 622   $main::lxdebug->enter_sub();
 623
 624   my $rc = SL::DB->client->with_transaction(\&_post_payment, $self, $myconfig, $form, $locale);
 625
 626   $::lxdebug->leave_sub;
 627   return $rc;
 628 }
 629
 630 sub _post_payment {
 631   my ($self, $myconfig, $form, $locale) = @_;
 632
 633   my $dbh = SL::DB->client->dbh;
 634
 635   my (%payments, $old_form, $row, $item, $query, %keep_vars);
 636
 637   $old_form = save_form();
 638
 639   # Delete all entries in acc_trans from prior payments.
 640   if (SL::DB::Default->get->payments_changeable != 0) {
 641     $self->_delete_payments($form, $dbh);
 642   }
 643
 644   # Save the new payments the user made before cleaning up $form.
 645   my $payments_re = '^datepaid_\d+$|^gldate_\d+$|^acc_trans_id_\d+$|^memo_\d+$|^source_\d+$|^exchangerate_\d+$|^paid_\d+$|^paid_project_id_\d+$|^AP_paid_\d+$|^paidaccounts$';
 646   map { $payments{$_} = $form->{$_} } grep m/$payments_re/, keys %{ $form };
 647
 648   # Clean up $form so that old content won't tamper the results.
 649   %keep_vars = map { $_, 1 } qw(login password id);
 650   map { delete $form->{$_} unless $keep_vars{$_} } keys %{ $form };
 651
 652   # Retrieve the invoice from the database.
 653   $form->create_links('AP', $myconfig, 'vendor', $dbh);
 654
 655   # Restore the payment options from the user input.
 656   map { $form->{$_} = $payments{$_} } keys %payments;
 657
 658   # Set up the content of $form in the way that AR::post_transaction() expects.
 659
 660   $self->setup_form($form, 1);
 661
 662   $form->{exchangerate}    = $form->format_amount($myconfig, $form->{exchangerate});
 663   $form->{defaultcurrency} = $form->get_default_currency($myconfig);
 664
 665   # Get the AP accno.
 666   $query =
 667     qq|SELECT c.accno
 668        FROM acc_trans at
 669        LEFT JOIN chart c ON (at.chart_id = c.id)
 670        WHERE (trans_id = ?)
 671          AND ((c.link = 'AP') OR (c.link LIKE '%:AP') OR (c.link LIKE 'AP:%'))
 672        ORDER BY at.acc_trans_id
 673        LIMIT 1|;
 674
 675   ($form->{APselected}) = selectfirst_array_query($form, $dbh, $query, conv_i($form->{id}));
 676
 677   # Post the new payments.
 678   $self->post_transaction($myconfig, $form, $dbh, 1);
 679
 680   restore_form($old_form);
 681
 682   return 1;
 683 }
 684
 685 sub setup_form {
 686   $main::lxdebug->enter_sub();
 687
 688   my ($self, $form, $for_post_payments) = @_;
 689
 690   my ($exchangerate, $i, $j, $k, $key, $akey, $ref, $index, $taxamount, $totalamount, $totaltax, $totalwithholding, $withholdingrate,
 691       $tax, $diff);
 692
 693   # forex
 694   $form->{forex} = $form->{exchangerate};
 695   $exchangerate = ($form->{exchangerate}) ? $form->{exchangerate} : 1;
 696
 697   foreach $key (keys %{ $form->{AP_links} }) {
 698     foreach $ref (@{ $form->{AP_links}{$key} }) {
 699       if ($key eq "AP_paid") {
 700         $form->{"select$key"} .= "<option value=\"$ref->{accno}\">$ref->{accno}--$ref->{description}</option>\n";
 701       } else {
 702         $form->{"select$key"} .= "<option value=\"$ref->{accno}--$ref->{tax_id}\">$ref->{accno}--$ref->{description}</option>\n";
 703       }
 704     }
 705
 706     $form->{$key} = $form->{"select$key"};
 707
 708     $j = 0;
 709     $k = 0;
 710
 711     # if there is a value we have an old entry
 712     next unless $form->{acc_trans}{$key};
 713
 714     # do not use old entries for payments. They come from the form
 715     # even if they are not changeable (then they are in hiddens)
 716     next if $for_post_payments && $key eq "AP_paid";
 717
 718     for $i (1 .. scalar @{ $form->{acc_trans}{$key} }) {
 719
 720       if ($key eq "AP_paid") {
 721         $j++;
 722         $form->{"AP_paid_$j"}         = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 723         $form->{"acc_trans_id_$j"}    = $form->{acc_trans}{$key}->[$i - 1]->{acc_trans_id};
 724         $form->{"paid_$j"}            = $form->{acc_trans}{$key}->[$i - 1]->{amount};
 725         $form->{"datepaid_$j"}        = $form->{acc_trans}{$key}->[$i - 1]->{transdate};
 726         $form->{"gldate_$j"}          = $form->{acc_trans}{$key}->[$i - 1]->{gldate};
 727         $form->{"source_$j"}          = $form->{acc_trans}{$key}->[$i - 1]->{source};
 728         $form->{"memo_$j"}            = $form->{acc_trans}{$key}->[$i - 1]->{memo};
 729
 730         $form->{"exchangerate_$i"}    = $form->{acc_trans}{$key}->[$i - 1]->{exchangerate};
 731         $form->{"forex_$j"}           = $form->{"exchangerate_$i"};
 732         $form->{"AP_paid_$j"}         = $form->{acc_trans}{$key}->[$i-1]->{accno};
 733         $form->{"paid_project_id_$j"} = $form->{acc_trans}{$key}->[$i - 1]->{project_id};
 734         $form->{paidaccounts}++;
 735
 736       } else {
 737         $akey = $key;
 738         $akey =~ s/AP_//;
 739
 740         if (($key eq "AP_tax") || ($key eq "AR_tax")) {
 741           $form->{"${key}_$form->{acc_trans}{$key}->[$i-1]->{accno}"}  = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 742           $form->{"${akey}_$form->{acc_trans}{$key}->[$i-1]->{accno}"} = $form->round_amount($form->{acc_trans}{$key}->[$i - 1]->{amount} / $exchangerate, 2);
 743
 744           if ($form->{"$form->{acc_trans}{$key}->[$i-1]->{accno}_rate"} > 0) {
 745             $totaltax += $form->{"${akey}_$form->{acc_trans}{$key}->[$i-1]->{accno}"};
 746           } else {
 747             $totalwithholding += $form->{"${akey}_$form->{acc_trans}{$key}->[$i-1]->{accno}"};
 748             $withholdingrate  += $form->{"$form->{acc_trans}{$key}->[$i-1]->{accno}_rate"};
 749           }
 750
 751           $index                 = $form->{acc_trans}{$key}->[$i - 1]->{index};
 752           $form->{"tax_$index"}  = $form->round_amount($form->{acc_trans}{$key}->[$i - 1]->{amount} * -1 / $exchangerate, 2);
 753           $totaltax             += $form->{"tax_$index"};
 754
 755         } else {
 756           $k++;
 757           $form->{"${akey}_$k"} = $form->round_amount($form->{acc_trans}{$key}->[$i - 1]->{amount} / $exchangerate, 2);
 758
 759           if ($akey eq 'amount') {
 760             $form->{rowcount}++;
 761             $form->{"${akey}_$i"} *= -1;
 762             $totalamount          += $form->{"${akey}_$i"};
 763             $form->{taxrate}       = $form->{acc_trans}{$key}->[$i - 1]->{rate};
 764
 765             $form->{"projectnumber_$k"}    = "$form->{acc_trans}{$key}->[$i-1]->{projectnumber}";
 766             $form->{"oldprojectnumber_$k"} = $form->{"projectnumber_$k"};
 767             $form->{"project_id_$k"}       = "$form->{acc_trans}{$key}->[$i-1]->{project_id}";
 768           }
 769
 770           $form->{"${key}_$k"} = "$form->{acc_trans}{$key}->[$i-1]->{accno}--$form->{acc_trans}{$key}->[$i-1]->{description}";
 771
 772           my $q_description    = quotemeta($form->{acc_trans}{$key}->[$i-1]->{description});
 773           $form->{"select${key}"} =~
 774             m/<option value=\"
 775                 ($form->{acc_trans}{$key}->[$i-1]->{accno}--[^\"]*)
 776               \">
 777               $form->{acc_trans}{$key}->[$i-1]->{accno}
 778               --
 779               ${q_description}
 780               <\/option>\n/x;
 781           $form->{"${key}_$k"} = $1;
 782
 783           if ($akey eq "AP") {
 784             $form->{APselected} = $form->{acc_trans}{$key}->[$i-1]->{accno};
 785
 786           } elsif ($akey eq 'amount') {
 787             $form->{"${key}_$k"}   = $form->{acc_trans}{$key}->[$i-1]->{accno} . "--" . $form->{acc_trans}{$key}->[$i-1]->{id};
 788             $form->{"taxchart_$k"} = $form->{acc_trans}{$key}->[$i-1]->{id}    . "--" . $form->{acc_trans}{$key}->[$i-1]->{rate};
 789           }
 790         }
 791       }
 792     }
 793   }
 794
 795   $form->{paidaccounts} = 1            if not defined $form->{paidaccounts};
 796
 797   if ($form->{taxincluded} && $form->{taxrate} && $totalamount) {
 798     # add tax to amounts and invtotal
 799     for $i (1 .. $form->{rowcount}) {
 800       $taxamount            = ($totaltax + $totalwithholding) * $form->{"amount_$i"} / $totalamount;
 801       $tax                  = $form->round_amount($taxamount, 2);
 802       $diff                += ($taxamount - $tax);
 803       $form->{"amount_$i"} += $form->{"tax_$i"};
 804     }
 805
 806     $form->{amount_1} += $form->round_amount($diff, 2);
 807   }
 808
 809   $taxamount        = $form->round_amount($taxamount, 2);
 810   $form->{invtotal} = $totalamount + $totaltax;
 811
 812   $main::lxdebug->leave_sub();
 813 }
 814
 815 sub storno {
 816   my ($self, $form, $myconfig, $id) = @_;
 817   $main::lxdebug->enter_sub();
 818
 819   my $rc = SL::DB->client->with_transaction(\&_storno, $self, $form, $myconfig, $id);
 820
 821   $::lxdebug->leave_sub;
 822   return $rc;
 823 }
 824
 825 sub _storno {
 826   my ($self, $form, $myconfig, $id) = @_;
 827
 828   my ($query, $new_id, $storno_row, $acc_trans_rows);
 829   my $dbh = SL::DB->client->dbh;
 830
 831   $query = qq|SELECT nextval('glid')|;
 832   ($new_id) = selectrow_query($form, $dbh, $query);
 833
 834   $query = qq|SELECT * FROM ap WHERE id = ?|;
 835   $storno_row = selectfirst_hashref_query($form, $dbh, $query, $id);
 836
 837   $storno_row->{id}         = $new_id;
 838   $storno_row->{storno_id}  = $id;
 839   $storno_row->{storno}     = 't';
 840   $storno_row->{invnumber}  = 'Storno-' . $storno_row->{invnumber};
 841   $storno_row->{amount}    *= -1;
 842   $storno_row->{netamount} *= -1;
 843   $storno_row->{paid}       = $storno_row->{amount};
 844
 845   delete @$storno_row{qw(itime mtime)};
 846
 847   $query = sprintf 'INSERT INTO ap (%s) VALUES (%s)', join(', ', keys %$storno_row), join(', ', map '?', values %$storno_row);
 848   do_query($form, $dbh, $query, (values %$storno_row));
 849
 850   $query = qq|UPDATE ap SET paid = amount + paid, storno = 't' WHERE id = ?|;
 851   do_query($form, $dbh, $query, $id);
 852
 853   $form->new_lastmtime('ap') if $id == $form->{id};
 854
 855   # now copy acc_trans entries
 856   $query = qq|SELECT a.*, c.link FROM acc_trans a LEFT JOIN chart c ON a.chart_id = c.id WHERE a.trans_id = ? ORDER BY a.acc_trans_id|;
 857   my $rowref = selectall_hashref_query($form, $dbh, $query, $id);
 858
 859   # kill all entries containing payments, which are the last 2n rows, of which the last has link =~ /paid/
 860   while ($rowref->[-1]{link} =~ /paid/) {
 861     splice(@$rowref, -2);
 862   }
 863
 864   for my $row (@$rowref) {
 865     delete @$row{qw(itime mtime link acc_trans_id)};
 866     $query = sprintf 'INSERT INTO acc_trans (%s) VALUES (%s)', join(', ', keys %$row), join(', ', map '?', values %$row);
 867     $row->{trans_id}   = $new_id;
 868     $row->{amount}    *= -1;
 869     do_query($form, $dbh, $query, (values %$row));
 870   }
 871
 872   map { IO->set_datepaid(table => 'ap', id => $_, dbh => $dbh) } ($id, $new_id);
 873
 874   return 1;
 875 }
 876
 877 1;