SL/Controller/BankTransaction.pm

   1 package SL::Controller::BankTransaction;
   2
   3 # idee- möglichkeit bankdaten zu übernehmen in stammdaten
   4 # erst Kontenabgleich, um alle gl-Einträge wegzuhaben
   5 use strict;
   6
   7 use parent qw(SL::Controller::Base);
   8
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::ReportGenerator;
  12
  13 use SL::DB::BankTransaction;
  14 use SL::Helper::Flash;
  15 use SL::Locale::String;
  16 use SL::SEPA;
  17 use SL::DB::Invoice;
  18 use SL::DB::PurchaseInvoice;
  19 use SL::DB::RecordLink;
  20 use SL::DB::ReconciliationLink;
  21 use SL::JSON;
  22 use SL::DB::Chart;
  23 use SL::DB::AccTransaction;
  24 use SL::DB::BankTransactionAccTrans;
  25 use SL::DB::Tax;
  26 use SL::DB::BankAccount;
  27 use SL::DB::GLTransaction;
  28 use SL::DB::RecordTemplate;
  29 use SL::DB::SepaExportItem;
  30 use SL::DBUtils qw(like do_query);
  31
  32 use SL::Presenter::Tag qw(checkbox_tag html_tag);
  33 use Carp;
  34 use List::UtilsBy qw(partition_by);
  35 use List::MoreUtils qw(any);
  36 use List::Util qw(max);
  37
  38 use Rose::Object::MakeMethods::Generic
  39 (
  40   scalar                  => [ qw(callback transaction) ],
  41   'scalar --get_set_init' => [ qw(models problems) ],
  42 );
  43
  44 __PACKAGE__->run_before('check_auth');
  45
  46
  47 #
  48 # actions
  49 #
  50
  51 sub action_search {
  52   my ($self) = @_;
  53
  54   my $bank_accounts = SL::DB::Manager::BankAccount->get_all_sorted( query => [ obsolete => 0 ] );
  55
  56   $self->setup_search_action_bar;
  57   $self->render('bank_transactions/search',
  58                  BANK_ACCOUNTS => $bank_accounts);
  59 }
  60
  61 sub action_list_all {
  62   my ($self) = @_;
  63
  64   $self->make_filter_summary;
  65   $self->prepare_report;
  66
  67   $self->setup_list_all_action_bar;
  68   $self->report_generator_list_objects(report => $self->{report}, objects => $self->models->get);
  69 }
  70
  71 sub action_list {
  72   my ($self) = @_;
  73
  74   if (!$::form->{filter}{bank_account}) {
  75     flash('error', t8('No bank account chosen!'));
  76     $self->action_search;
  77     return;
  78   }
  79
  80   my $sort_by = $::form->{sort_by} || 'transdate';
  81   $sort_by = 'transdate' if $sort_by eq 'proposal';
  82   $sort_by .= $::form->{sort_dir} ? ' DESC' : ' ASC';
  83
  84   my $fromdate = $::locale->parse_date_to_object($::form->{filter}->{fromdate});
  85   my $todate   = $::locale->parse_date_to_object($::form->{filter}->{todate});
  86   $todate->add( days => 1 ) if $todate;
  87
  88   my @where = ();
  89   push @where, (transdate => { ge => $fromdate }) if ($fromdate);
  90   push @where, (transdate => { lt => $todate })   if ($todate);
  91   my $bank_account = SL::DB::Manager::BankAccount->find_by( id => $::form->{filter}{bank_account} );
  92   # bank_transactions no younger than starting date,
  93   # including starting date (same search behaviour as fromdate)
  94   # but OPEN invoices to be matched may be from before
  95   if ( $bank_account->reconciliation_starting_date ) {
  96     push @where, (transdate => { ge => $bank_account->reconciliation_starting_date });
  97   };
  98
  99   my $bank_transactions = SL::DB::Manager::BankTransaction->get_all(
 100     with_objects => [ 'local_bank_account', 'currency' ],
 101     sort_by      => $sort_by,
 102     limit        => 10000,
 103     where        => [
 104       amount                => {ne => \'invoice_amount'},
 105       local_bank_account_id => $::form->{filter}{bank_account},
 106       cleared               => 0,
 107       @where
 108     ],
 109   );
 110   # credit notes have a negative amount, treat differently
 111   my $all_open_ar_invoices = SL::DB::Manager::Invoice        ->get_all(where => [ or => [ amount => { gt => \'paid' },
 112                                                                                           and => [ type    => 'credit_note',
 113                                                                                                    amount  => { lt => \'paid' }
 114                                                                                                  ],
 115                                                                                         ],
 116                                                                                 ],
 117                                                                        with_objects => ['customer','payment_terms']);
 118
 119   my $all_open_ap_invoices = SL::DB::Manager::PurchaseInvoice->get_all(where => [amount => { ne => \'paid' }], with_objects => ['vendor'  ,'payment_terms']);
 120   my $all_open_sepa_export_items = SL::DB::Manager::SepaExportItem->get_all(where => [chart_id => $bank_account->chart_id ,
 121                                                                              'sepa_export.executed' => 0, 'sepa_export.closed' => 0 ], with_objects => ['sepa_export']);
 122
 123   my @all_open_invoices;
 124   # filter out invoices with less than 1 cent outstanding
 125   push @all_open_invoices, map { $_->{is_ar}=1 ; $_ } grep { abs($_->amount - $_->paid) >= 0.01 } @{ $all_open_ar_invoices };
 126   push @all_open_invoices, map { $_->{is_ar}=0 ; $_ } grep { abs($_->amount - $_->paid) >= 0.01 } @{ $all_open_ap_invoices };
 127
 128   my %sepa_exports;
 129   my %sepa_export_items_by_id = partition_by { $_->ar_id || $_->ap_id } @$all_open_sepa_export_items;
 130
 131   # first collect sepa export items to open invoices
 132   foreach my $open_invoice (@all_open_invoices){
 133     $open_invoice->{realamount}  = $::form->format_amount(\%::myconfig,$open_invoice->amount,2);
 134     $open_invoice->{skonto_type} = 'without_skonto';
 135     foreach (@{ $sepa_export_items_by_id{ $open_invoice->id } || [] }) {
 136       my $factor                   = ($_->ar_id == $open_invoice->id ? 1 : -1);
 137       $open_invoice->{realamount}  = $::form->format_amount(\%::myconfig,$open_invoice->amount*$factor,2);
 138
 139       $open_invoice->{skonto_type} = $_->payment_type;
 140       $sepa_exports{$_->sepa_export_id} ||= { count => 0, is_ar => 0, amount => 0, proposed => 0, invoices => [], item => $_ };
 141       $sepa_exports{$_->sepa_export_id}->{count}++;
 142       $sepa_exports{$_->sepa_export_id}->{is_ar}++ if  $_->ar_id == $open_invoice->id;
 143       $sepa_exports{$_->sepa_export_id}->{amount} += $_->amount * $factor;
 144       push @{ $sepa_exports{$_->sepa_export_id}->{invoices} }, $open_invoice;
 145     }
 146   }
 147
 148   # try to match each bank_transaction with each of the possible open invoices
 149   # by awarding points
 150   my @proposals;
 151
 152   foreach my $bt (@{ $bank_transactions }) {
 153     ## 5 Stellen hinter dem Komma auf 2 Stellen reduzieren
 154     $bt->amount($bt->amount*1);
 155     $bt->invoice_amount($bt->invoice_amount*1);
 156
 157     $bt->{proposals}    = [];
 158     $bt->{rule_matches} = [];
 159
 160     $bt->{remote_name} .= $bt->{remote_name_1} if $bt->{remote_name_1};
 161
 162     if ( $bt->is_batch_transaction ) {
 163       my $found=0;
 164       foreach ( keys  %sepa_exports) {
 165         if ( abs(($sepa_exports{$_}->{amount} * 1) - ($bt->amount * 1)) < 0.01 ) {
 166           ## jupp
 167           @{$bt->{proposals}} = @{$sepa_exports{$_}->{invoices}};
 168           $bt->{sepa_export_ok} = 1;
 169           $sepa_exports{$_}->{proposed}=1;
 170           push(@proposals, $bt);
 171           $found=1;
 172           last;
 173         }
 174       }
 175       next if $found;
 176       # batch transaction has no remotename !!
 177     } else {
 178       next unless $bt->{remote_name};  # bank has no name, usually fees, use create invoice to assign
 179     }
 180
 181     # try to match the current $bt to each of the open_invoices, saving the
 182     # results of get_agreement_with_invoice in $open_invoice->{agreement} and
 183     # $open_invoice->{rule_matches}.
 184
 185     # The values are overwritten each time a new bt is checked, so at the end
 186     # of each bt the likely results are filtered and those values are stored in
 187     # the arrays $bt->{proposals} and $bt->{rule_matches}, and the agreement
 188     # score is stored in $bt->{agreement}
 189
 190     foreach my $open_invoice (@all_open_invoices) {
 191       ($open_invoice->{agreement}, $open_invoice->{rule_matches}) = $bt->get_agreement_with_invoice($open_invoice,
 192         sepa_export_items => $all_open_sepa_export_items,
 193       );
 194       $open_invoice->{realamount} = $::form->format_amount(\%::myconfig,
 195                                       $open_invoice->amount * ($open_invoice->{is_ar} ? 1 : -1), 2);
 196     }
 197
 198     my $agreement = 15;
 199     my $min_agreement = 3; # suggestions must have at least this score
 200
 201     my $max_agreement = max map { $_->{agreement} } @all_open_invoices;
 202
 203     # add open_invoices with highest agreement into array $bt->{proposals}
 204     if ( $max_agreement >= $min_agreement ) {
 205       $bt->{proposals} = [ grep { $_->{agreement} == $max_agreement } @all_open_invoices ];
 206       $bt->{agreement} = $max_agreement; #scalar @{ $bt->{proposals} } ? $agreement + 1 : '';
 207
 208       # store the rule_matches in a separate array, so they can be displayed in template
 209       foreach ( @{ $bt->{proposals} } ) {
 210         push(@{$bt->{rule_matches}}, $_->{rule_matches});
 211       };
 212     };
 213   }  # finished one bt
 214   # finished all bt
 215
 216   # separate filter for proposals (second tab, agreement >= 5 and exactly one match)
 217   # to qualify as a proposal there has to be
 218   # * agreement >= 5  TODO: make threshold configurable in configuration
 219   # * there must be only one exact match
 220   # * depending on whether sales or purchase the amount has to have the correct sign (so Gutschriften don't work?)
 221   my $proposal_threshold = 5;
 222   my @otherproposals = grep {
 223        ($_->{agreement} >= $proposal_threshold)
 224     && (1 == scalar @{ $_->{proposals} })
 225     && (@{ $_->{proposals} }[0]->is_sales ? abs(@{ $_->{proposals} }[0]->amount - $_->amount) < 0.01
 226                                           : abs(@{ $_->{proposals} }[0]->amount + $_->amount) < 0.01)
 227   } @{ $bank_transactions };
 228
 229   push @proposals, @otherproposals;
 230
 231   # sort bank transaction proposals by quality (score) of proposal
 232   if ($::form->{sort_by} && $::form->{sort_by} eq 'proposal') {
 233     if ($::form->{sort_dir}) {
 234       $bank_transactions = [ sort { $a->{agreement} <=> $b->{agreement} } @{ $bank_transactions } ];
 235     } else {
 236       $bank_transactions = [ sort { $b->{agreement} <=> $a->{agreement} } @{ $bank_transactions } ];
 237     }
 238   }
 239
 240   # for testing with t/bank/banktransaction.t :
 241   if ( $::form->{dont_render_for_test} ) {
 242     return ( $bank_transactions , \@proposals );
 243   }
 244
 245   $::request->layout->add_javascripts("kivi.BankTransaction.js");
 246   $self->render('bank_transactions/list',
 247                 title             => t8('Bank transactions MT940'),
 248                 BANK_TRANSACTIONS => $bank_transactions,
 249                 PROPOSALS         => \@proposals,
 250                 bank_account      => $bank_account,
 251                 ui_tab            => scalar(@proposals) > 0?1:0,
 252               );
 253 }
 254
 255 sub action_assign_invoice {
 256   my ($self) = @_;
 257
 258   $self->{transaction} = SL::DB::Manager::BankTransaction->find_by(id => $::form->{bt_id});
 259
 260   $self->render('bank_transactions/assign_invoice',
 261                 { layout => 0 },
 262                 title => t8('Assign invoice'),);
 263 }
 264
 265 sub action_create_invoice {
 266   my ($self) = @_;
 267   my %myconfig = %main::myconfig;
 268
 269   $self->transaction(SL::DB::Manager::BankTransaction->find_by(id => $::form->{bt_id}));
 270
 271   my $vendor_of_transaction = SL::DB::Manager::Vendor->find_by(iban => $self->transaction->{remote_account_number});
 272   my $use_vendor_filter     = $self->transaction->{remote_account_number} && $vendor_of_transaction;
 273
 274   my $templates_ap = SL::DB::Manager::RecordTemplate->get_all(
 275     where        => [ template_type => 'ap_transaction' ],
 276     with_objects => [ qw(employee vendor) ],
 277   );
 278   my $templates_gl = SL::DB::Manager::RecordTemplate->get_all(
 279     query        => [ template_type => 'gl_transaction',
 280                       chart_id      => SL::DB::Manager::BankAccount->find_by(id => $self->transaction->local_bank_account_id)->chart_id,
 281                     ],
 282     with_objects => [ qw(employee record_template_items) ],
 283   );
 284
 285   # pre filter templates_ap, if we have a vendor match (IBAN eq IBAN) - show and allow user to edit this via gui!
 286   $templates_ap = [ grep { $_->vendor_id == $vendor_of_transaction->id } @{ $templates_ap } ] if $use_vendor_filter;
 287
 288   $self->callback($self->url_for(
 289     action                => 'list',
 290     'filter.bank_account' => $::form->{filter}->{bank_account},
 291     'filter.todate'       => $::form->{filter}->{todate},
 292     'filter.fromdate'     => $::form->{filter}->{fromdate},
 293   ));
 294
 295   $self->render(
 296     'bank_transactions/create_invoice',
 297     { layout => 0 },
 298     title        => t8('Create invoice'),
 299     TEMPLATES_GL => $use_vendor_filter && @{ $templates_ap } ? undef : $templates_gl,
 300     TEMPLATES_AP => $templates_ap,
 301     vendor_name  => $use_vendor_filter && @{ $templates_ap } ? $vendor_of_transaction->name : undef,
 302   );
 303 }
 304
 305 sub action_ajax_payment_suggestion {
 306   my ($self) = @_;
 307
 308   # based on a BankTransaction ID and a Invoice or PurchaseInvoice ID passed via $::form,
 309   # create an HTML blob to be used by the js function add_invoices in templates/webpages/bank_transactions/list.html
 310   # and return encoded as JSON
 311
 312   croak("Need bt_id") unless $::form->{bt_id};
 313
 314   my $invoice = SL::DB::Manager::Invoice->find_by( id => $::form->{prop_id} ) || SL::DB::Manager::PurchaseInvoice->find_by( id => $::form->{prop_id} );
 315
 316   croak("No valid invoice found") unless $invoice;
 317
 318   my $html = $self->render(
 319     'bank_transactions/_payment_suggestion', { output => 0 },
 320     bt_id          => $::form->{bt_id},
 321     invoice        => $invoice,
 322   );
 323
 324   $self->render(\ SL::JSON::to_json( { 'html' => "$html" } ), { layout => 0, type => 'json', process => 0 });
 325 };
 326
 327 sub action_filter_templates {
 328   my ($self) = @_;
 329
 330   $self->{transaction}      = SL::DB::Manager::BankTransaction->find_by(id => $::form->{bt_id});
 331
 332   my (@filter, @filter_ap);
 333
 334   # filter => gl and ap | filter_ap = ap (i.e. vendorname)
 335   push @filter,    ('template_name' => { ilike => '%' . $::form->{template} . '%' })  if $::form->{template};
 336   push @filter,    ('reference'     => { ilike => '%' . $::form->{reference} . '%' }) if $::form->{reference};
 337   push @filter_ap, ('vendor.name'   => { ilike => '%' . $::form->{vendor} . '%' })    if $::form->{vendor};
 338   push @filter_ap, @filter;
 339   my $templates_gl = SL::DB::Manager::RecordTemplate->get_all(
 340     query        => [ template_type => 'gl_transaction',
 341                       chart_id      => SL::DB::Manager::BankAccount->find_by(id => $self->transaction->local_bank_account_id)->chart_id,
 342                       (and => \@filter) x !!@filter
 343                     ],
 344     with_objects => [ qw(employee record_template_items) ],
 345   );
 346
 347   my $templates_ap = SL::DB::Manager::RecordTemplate->get_all(
 348     where        => [ template_type => 'ap_transaction', (and => \@filter_ap) x !!@filter_ap ],
 349     with_objects => [ qw(employee vendor) ],
 350   );
 351   $::form->{filter} //= {};
 352
 353   $self->callback($self->url_for(
 354     action                => 'list',
 355     'filter.bank_account' => $::form->{filter}->{bank_account},
 356     'filter.todate'       => $::form->{filter}->{todate},
 357     'filter.fromdate'     => $::form->{filter}->{fromdate},
 358   ));
 359
 360   my $output  = $self->render(
 361     'bank_transactions/_template_list',
 362     { output => 0 },
 363     TEMPLATES_AP => $templates_ap,
 364     TEMPLATES_GL => $templates_gl,
 365   );
 366
 367   $self->render(\to_json({ html => $output }), { type => 'json', process => 0 });
 368 }
 369
 370 sub action_ajax_add_list {
 371   my ($self) = @_;
 372
 373   my @where_sale     = (amount => { ne => \'paid' });
 374   my @where_purchase = (amount => { ne => \'paid' });
 375
 376   if ($::form->{invnumber}) {
 377     push @where_sale,     (invnumber => { ilike => like($::form->{invnumber})});
 378     push @where_purchase, (invnumber => { ilike => like($::form->{invnumber})});
 379   }
 380
 381   if ($::form->{amount}) {
 382     push @where_sale,     (amount => $::form->parse_amount(\%::myconfig, $::form->{amount}));
 383     push @where_purchase, (amount => $::form->parse_amount(\%::myconfig, $::form->{amount}));
 384   }
 385
 386   if ($::form->{vcnumber}) {
 387     push @where_sale,     ('customer.customernumber' => { ilike => like($::form->{vcnumber})});
 388     push @where_purchase, ('vendor.vendornumber'     => { ilike => like($::form->{vcnumber})});
 389   }
 390
 391   if ($::form->{vcname}) {
 392     push @where_sale,     ('customer.name' => { ilike => like($::form->{vcname})});
 393     push @where_purchase, ('vendor.name'   => { ilike => like($::form->{vcname})});
 394   }
 395
 396   if ($::form->{transdatefrom}) {
 397     my $fromdate = $::locale->parse_date_to_object($::form->{transdatefrom});
 398     if ( ref($fromdate) eq 'DateTime' ) {
 399       push @where_sale,     ('transdate' => { ge => $fromdate});
 400       push @where_purchase, ('transdate' => { ge => $fromdate});
 401     };
 402   }
 403
 404   if ($::form->{transdateto}) {
 405     my $todate = $::locale->parse_date_to_object($::form->{transdateto});
 406     if ( ref($todate) eq 'DateTime' ) {
 407       $todate->add(days => 1);
 408       push @where_sale,     ('transdate' => { lt => $todate});
 409       push @where_purchase, ('transdate' => { lt => $todate});
 410     };
 411   }
 412
 413   my $all_open_ar_invoices = SL::DB::Manager::Invoice        ->get_all(where => \@where_sale,     with_objects => 'customer');
 414   my $all_open_ap_invoices = SL::DB::Manager::PurchaseInvoice->get_all(where => \@where_purchase, with_objects => 'vendor');
 415
 416   my @all_open_invoices = @{ $all_open_ar_invoices };
 417   # add ap invoices, filtering out subcent open amounts
 418   push @all_open_invoices, grep { abs($_->amount - $_->paid) >= 0.01 } @{ $all_open_ap_invoices };
 419
 420   @all_open_invoices = sort { $a->id <=> $b->id } @all_open_invoices;
 421
 422   my $output  = $self->render(
 423     'bank_transactions/add_list',
 424     { output => 0 },
 425     INVOICES => \@all_open_invoices,
 426   );
 427
 428   my %result = ( count => 0, html => $output );
 429
 430   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 431 }
 432
 433 sub action_ajax_accept_invoices {
 434   my ($self) = @_;
 435
 436   my @selected_invoices;
 437   foreach my $invoice_id (@{ $::form->{invoice_id} || [] }) {
 438     my $invoice_object = SL::DB::Manager::Invoice->find_by(id => $invoice_id) || SL::DB::Manager::PurchaseInvoice->find_by(id => $invoice_id);
 439     push @selected_invoices, $invoice_object;
 440   }
 441
 442   $self->render(
 443     'bank_transactions/invoices',
 444     { layout => 0 },
 445     INVOICES => \@selected_invoices,
 446     bt_id    => $::form->{bt_id},
 447   );
 448 }
 449
 450 sub save_invoices {
 451   my ($self) = @_;
 452
 453   return 0 if !$::form->{invoice_ids};
 454
 455   my %invoice_hash = %{ delete $::form->{invoice_ids} };  # each key (the bt line with a bt_id) contains an array of invoice_ids
 456
 457   # e.g. three partial payments with bt_ids 54, 55 and 56 for invoice with id 74:
 458   # $invoice_hash = {
 459   #         '55' => [
 460   #                 '74'
 461   #               ],
 462   #         '54' => [
 463   #                 '74'
 464   #               ],
 465   #         '56' => [
 466   #                 '74'
 467   #               ]
 468   #       };
 469   #
 470   # or if the payment with bt_id 44 is used to pay invoices with ids 50, 51 and 52
 471   # $invoice_hash = {
 472   #           '44' => [ '50', '51', 52' ]
 473   #         };
 474
 475   $::form->{invoice_skontos} ||= {}; # hash of arrays containing the payment types, could be empty
 476
 477   # a bank_transaction may be assigned to several invoices, i.e. a customer
 478   # might pay several open invoices with one transaction
 479
 480   $self->problems([]);
 481
 482   my $count = 0;
 483
 484   if ( $::form->{proposal_ids} ) {
 485     foreach (@{ $::form->{proposal_ids} }) {
 486       my  $bank_transaction_id = $_;
 487       my  $invoice_ids = $invoice_hash{$_};
 488       push @{ $self->problems }, $self->save_single_bank_transaction(
 489         bank_transaction_id => $bank_transaction_id,
 490         invoice_ids         => $invoice_ids,
 491         sources             => ($::form->{sources} // {})->{$_},
 492         memos               => ($::form->{memos}   // {})->{$_},
 493       );
 494       $count += scalar( @{$invoice_ids} );
 495     }
 496   } else {
 497     while ( my ($bank_transaction_id, $invoice_ids) = each(%invoice_hash) ) {
 498       push @{ $self->problems }, $self->save_single_bank_transaction(
 499         bank_transaction_id => $bank_transaction_id,
 500         invoice_ids         => $invoice_ids,
 501         sources             => [  map { $::form->{"sources_${bank_transaction_id}_${_}"} } @{ $invoice_ids } ],
 502         memos               => [  map { $::form->{"memos_${bank_transaction_id}_${_}"}   } @{ $invoice_ids } ],
 503       );
 504       $count += scalar( @{$invoice_ids} );
 505     }
 506   }
 507   my $max_count = $count;
 508   foreach (@{ $self->problems }) {
 509     $count-- if $_->{result} eq 'error';
 510   }
 511   return ($count, $max_count);
 512 }
 513
 514 sub action_save_invoices {
 515   my ($self) = @_;
 516   my ($success_count, $max_count) = $self->save_invoices();
 517
 518   if ($success_count == $max_count) {
 519     flash('ok', t8('#1 invoice(s) saved.', $success_count));
 520   } else {
 521     flash('error', t8('At least #1 invoice(s) not saved', $max_count - $success_count));
 522   }
 523
 524   $self->action_list();
 525 }
 526
 527 sub action_save_proposals {
 528   my ($self) = @_;
 529
 530   if ( $::form->{proposal_ids} ) {
 531     my $propcount = scalar(@{ $::form->{proposal_ids} });
 532     if ( $propcount > 0 ) {
 533       my $count = $self->save_invoices();
 534
 535       flash('ok', t8('#1 proposal(s) with #2 invoice(s) saved.',  $propcount, $count));
 536     }
 537   }
 538   $self->action_list();
 539
 540 }
 541
 542 sub save_single_bank_transaction {
 543   my ($self, %params) = @_;
 544
 545   my %data = (
 546     %params,
 547     bank_transaction => SL::DB::Manager::BankTransaction->find_by(id => $params{bank_transaction_id}),
 548     invoices         => [],
 549   );
 550
 551   if (!$data{bank_transaction}) {
 552     return {
 553       %data,
 554       result => 'error',
 555       message => $::locale->text('The ID #1 is not a valid database ID.', $data{bank_transaction_id}),
 556     };
 557   }
 558
 559   my $bank_transaction = $data{bank_transaction};
 560
 561   if ($bank_transaction->closed_period) {
 562     return {
 563       %data,
 564       result => 'error',
 565       message => $::locale->text('Cannot post payment for a closed period!'),
 566     };
 567   }
 568   my (@warnings);
 569
 570   my $worker = sub {
 571     my $bt_id                 = $data{bank_transaction_id};
 572     my $sign                  = $bank_transaction->amount < 0 ? -1 : 1;
 573     my $not_assigned_amount   = $bank_transaction->not_assigned_amount;
 574     my $payment_received      = $bank_transaction->amount > 0;
 575     my $payment_sent          = $bank_transaction->amount < 0;
 576
 577
 578     foreach my $invoice_id (@{ $params{invoice_ids} }) {
 579       my $invoice = SL::DB::Manager::Invoice->find_by(id => $invoice_id) || SL::DB::Manager::PurchaseInvoice->find_by(id => $invoice_id);
 580       if (!$invoice) {
 581         return {
 582           %data,
 583           result  => 'error',
 584           message => $::locale->text("The ID #1 is not a valid database ID.", $invoice_id),
 585         };
 586       }
 587       push @{ $data{invoices} }, $invoice;
 588     }
 589
 590     if (   $payment_received
 591         && any {    ( $_->is_sales && ($_->amount < 0))
 592                  || (!$_->is_sales && ($_->amount > 0))
 593                } @{ $data{invoices} }) {
 594       return {
 595         %data,
 596         result  => 'error',
 597         message => $::locale->text("Received payments can only be posted for sales invoices and purchase credit notes."),
 598       };
 599     }
 600
 601     if (   $payment_sent
 602         && any {    ( $_->is_sales && ($_->amount > 0))
 603                  || (!$_->is_sales && ($_->amount < 0) && ($_->invoice_type eq 'purchase_invoice'))
 604                } @{ $data{invoices} }) {
 605       return {
 606         %data,
 607         result  => 'error',
 608         message => $::locale->text("Sent payments can only be posted for purchase invoices and sales credit notes."),
 609       };
 610     }
 611
 612     my $max_invoices = scalar(@{ $data{invoices} });
 613     my $n_invoices   = 0;
 614
 615     foreach my $invoice (@{ $data{invoices} }) {
 616       my $source = ($data{sources} // [])->[$n_invoices];
 617       my $memo   = ($data{memos}   // [])->[$n_invoices];
 618
 619       $n_invoices++ ;
 620
 621
 622       if (!$not_assigned_amount && $invoice->open_amount) {
 623         return {
 624           %data,
 625           result  => 'error',
 626           message => $::locale->text("A payment can only be posted for multiple invoices if the amount to post is equal to or bigger than the sum of the open amounts of the affected invoices."),
 627         };
 628       }
 629
 630       my $payment_type;
 631       if ( defined $::form->{invoice_skontos}->{"$bt_id"} ) {
 632         $payment_type = shift(@{ $::form->{invoice_skontos}->{"$bt_id"} });
 633       } else {
 634         $payment_type = 'without_skonto';
 635       };
 636     # pay invoice
 637     # TODO rewrite this: really booked amount should be a return value of Payment.pm
 638     # also this controller shouldnt care about how to calc skonto. we simply delegate the
 639     # payment_type to the helper and get the corresponding bank_transaction values back
 640     # hotfix to get the signs right - compare absolute values and later set the signs
 641     # should be better done elsewhere - changing not_assigned_amount to abs feels seriously bogus
 642
 643     my $open_amount = $payment_type eq 'with_skonto_pt' ? $invoice->amount_less_skonto : $invoice->open_amount;
 644     $open_amount         = abs($open_amount);
 645     $not_assigned_amount = abs($not_assigned_amount);
 646     my $amount_for_booking = ($open_amount < $not_assigned_amount) ? $open_amount : $not_assigned_amount;
 647     my $amount_for_payment = $amount_for_booking;
 648
 649     # get the right direction for the payment bookings (all amounts < 0 are stornos, credit notes or negative ap)
 650     $amount_for_payment *= -1 if $invoice->amount < 0;
 651     # get the right direction for the bank transaction
 652     $amount_for_booking *= $sign;
 653
 654     $bank_transaction->invoice_amount($bank_transaction->invoice_amount + $amount_for_booking);
 655
 656     # ... and then pay the invoice
 657     my @acc_ids = $invoice->pay_invoice(chart_id => $bank_transaction->local_bank_account->chart_id,
 658                           trans_id     => $invoice->id,
 659                           amount       => $amount_for_payment,
 660                           payment_type => $payment_type,
 661                           source       => $source,
 662                           memo         => $memo,
 663                           transdate    => $bank_transaction->valutadate->to_kivitendo);
 664     # ... and record the origin via BankTransactionAccTrans
 665     if (scalar(@acc_ids) < 2) {
 666       return {
 667         %data,
 668         result  => 'error',
 669         message => $::locale->text("Unable to book transactions for bank purpose #1", $bank_transaction->purpose),
 670       };
 671     }
 672     foreach my $acc_trans_id (@acc_ids) {
 673         my $id_type = $invoice->is_sales ? 'ar' : 'ap';
 674         my  %props_acc = (
 675           acc_trans_id        => $acc_trans_id,
 676           bank_transaction_id => $bank_transaction->id,
 677           $id_type            => $invoice->id,
 678         );
 679         SL::DB::BankTransactionAccTrans->new(%props_acc)->save;
 680     }
 681       # Record a record link from the bank transaction to the invoice
 682       my %props = (
 683         from_table => 'bank_transactions',
 684         from_id    => $bt_id,
 685         to_table   => $invoice->is_sales ? 'ar' : 'ap',
 686         to_id      => $invoice->id,
 687       );
 688       SL::DB::RecordLink->new(%props)->save;
 689
 690       # "close" a sepa_export_item if it exists
 691       # code duplicated in action_save_proposals!
 692       # currently only works, if there is only exactly one open sepa_export_item
 693       if ( my $seis = $invoice->find_sepa_export_items({ executed => 0 }) ) {
 694         if ( scalar @$seis == 1 ) {
 695           # moved the execution and the check for sepa_export into a method,
 696           # this isn't part of a transaction, though
 697           $seis->[0]->set_executed if $invoice->id == $seis->[0]->arap_id;
 698         }
 699       }
 700
 701     }
 702     $bank_transaction->save;
 703
 704     # 'undef' means 'no error' here.
 705     return undef;
 706   };
 707
 708   my $error;
 709   my $rez = $data{bank_transaction}->db->with_transaction(sub {
 710     eval {
 711       $error = $worker->();
 712       1;
 713
 714     } or do {
 715       $error = {
 716         %data,
 717         result  => 'error',
 718         message => $@,
 719       };
 720     };
 721
 722     # Rollback Fehler nicht weiterreichen
 723     # die if $error;
 724     # aber einen rollback von hand
 725     $::lxdebug->message(LXDebug->DEBUG2(),"finish worker with ". ($error ? $error->{result} : '-'));
 726     $data{bank_transaction}->db->dbh->rollback if $error && $error->{result} eq 'error';
 727   });
 728
 729   return grep { $_ } ($error, @warnings);
 730 }
 731 sub action_unlink_bank_transaction {
 732   my ($self, %params) = @_;
 733
 734   croak("No bank transaction ids") unless scalar @{ $::form->{ids}} > 0;
 735
 736   my $success_count;
 737
 738   foreach my $bt_id (@{ $::form->{ids}} )  {
 739
 740     my $bank_transaction = SL::DB::Manager::BankTransaction->find_by(id => $bt_id);
 741     croak("No valid bank transaction found") unless (ref($bank_transaction)  eq 'SL::DB::BankTransaction');
 742     croak t8('Cannot unlink payment for a closed period!') if $bank_transaction->closed_period;
 743
 744     # everything in one transaction
 745     my $rez = $bank_transaction->db->with_transaction(sub {
 746       # 1. remove all reconciliations (due to underlying trigger, this has to be the first step)
 747       my $rec_links = SL::DB::Manager::ReconciliationLink->get_all(where => [ bank_transaction_id => $bt_id ]);
 748       $_->delete for @{ $rec_links };
 749
 750       my %trans_ids;
 751       foreach my $acc_trans_id_entry (@{ SL::DB::Manager::BankTransactionAccTrans->get_all(where => [bank_transaction_id => $bt_id ] )}) {
 752
 753         my $acc_trans = SL::DB::Manager::AccTransaction->get_all(where => [acc_trans_id => $acc_trans_id_entry->acc_trans_id]);
 754
 755         # save trans_id and type
 756         die "no type" unless ($acc_trans_id_entry->ar_id || $acc_trans_id_entry->ap_id || $acc_trans_id_entry->gl_id);
 757         $trans_ids{$acc_trans_id_entry->ar_id} = 'ar' if $acc_trans_id_entry->ar_id;
 758         $trans_ids{$acc_trans_id_entry->ap_id} = 'ap' if $acc_trans_id_entry->ap_id;
 759         $trans_ids{$acc_trans_id_entry->gl_id} = 'gl' if $acc_trans_id_entry->gl_id;
 760         # 2. all good -> ready to delete acc_trans and bt_acc link
 761         $acc_trans_id_entry->delete;
 762         $_->delete for @{ $acc_trans };
 763       }
 764       # 3. update arap.paid (may not be 0, yet)
 765       #    or in case of gl, delete whole entry
 766       while (my ($trans_id, $type) = each %trans_ids) {
 767         if ($type eq 'gl') {
 768           SL::DB::Manager::GLTransaction->delete_all(where => [ id => $trans_id ]);
 769           next;
 770         }
 771         die ("invalid type") unless $type =~ m/^(ar|ap)$/;
 772
 773         # recalc and set paid via database query
 774         my $query = qq|UPDATE $type SET paid =
 775                         (SELECT COALESCE(abs(sum(amount)),0) FROM acc_trans
 776                          WHERE trans_id = ?
 777                          AND chart_link ilike '%paid%')|;
 778
 779         die if (do_query($::form, $bank_transaction->db->dbh, $query, $trans_id) == -1);
 780       }
 781       # 4. and delete all (if any) record links
 782       my $rl = SL::DB::Manager::RecordLink->delete_all(where => [ from_id => $bt_id, from_table => 'bank_transactions' ]);
 783
 784       # 5. finally reset  this bank transaction
 785       $bank_transaction->invoice_amount(0);
 786       $bank_transaction->cleared(0);
 787       $bank_transaction->save;
 788
 789       1;
 790
 791     }) || die t8('error while unlinking payment #1 : ', $bank_transaction->purpose) . $bank_transaction->db->error . "\n";
 792
 793     $success_count++;
 794   }
 795
 796   flash('ok', t8('#1 bank transaction bookings undone.', $success_count));
 797   $self->action_list_all() unless $params{testcase};
 798 }
 799 #
 800 # filters
 801 #
 802
 803 sub check_auth {
 804   $::auth->assert('bank_transaction');
 805 }
 806
 807 #
 808 # helpers
 809 #
 810
 811 sub make_filter_summary {
 812   my ($self) = @_;
 813
 814   my $filter = $::form->{filter} || {};
 815   my @filter_strings;
 816
 817   my @filters = (
 818     [ $filter->{"transdate:date::ge"},      $::locale->text('Transdate')  . " " . $::locale->text('From Date') ],
 819     [ $filter->{"transdate:date::le"},      $::locale->text('Transdate')  . " " . $::locale->text('To Date')   ],
 820     [ $filter->{"valutadate:date::ge"},     $::locale->text('Valutadate') . " " . $::locale->text('From Date') ],
 821     [ $filter->{"valutadate:date::le"},     $::locale->text('Valutadate') . " " . $::locale->text('To Date')   ],
 822     [ $filter->{"amount:number"},           $::locale->text('Amount')                                          ],
 823     [ $filter->{"bank_account_id:integer"}, $::locale->text('Local bank account')                              ],
 824   );
 825
 826   for (@filters) {
 827     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 828   }
 829
 830   $self->{filter_summary} = join ', ', @filter_strings;
 831 }
 832
 833 sub prepare_report {
 834   my ($self)      = @_;
 835
 836   my $callback    = $self->models->get_callback;
 837
 838   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 839   $self->{report} = $report;
 840
 841   my @columns     = qw(ids local_bank_name transdate valudate remote_name remote_account_number remote_bank_code amount invoice_amount invoices currency purpose local_account_number local_bank_code id);
 842   my @sortable    = qw(local_bank_name transdate valudate remote_name remote_account_number remote_bank_code amount                                  purpose local_account_number local_bank_code);
 843
 844   my %column_defs = (
 845     ids                 => { raw_header_data => checkbox_tag("", id => "check_all", checkall  => "[data-checkall=1]"),
 846                              'align'         => 'center',
 847                              raw_data        => sub { if (@{ $_[0]->linked_invoices }) {
 848                                                         if ($_[0]->closed_period) {
 849                                                           html_tag('text', "X"); #, tooltip => t8('Bank Transaction is in a closed period.')),
 850                                                         } else {
 851                                                           checkbox_tag("ids[]", value => $_[0]->id, "data-checkall" => 1);
 852                                                         }
 853                                                 } } },
 854     transdate             => { sub   => sub { $_[0]->transdate_as_date } },
 855     valutadate            => { sub   => sub { $_[0]->valutadate_as_date } },
 856     remote_name           => { },
 857     remote_account_number => { },
 858     remote_bank_code      => { },
 859     amount                => { sub   => sub { $_[0]->amount_as_number },
 860                                align => 'right' },
 861     invoice_amount        => { sub   => sub { $_[0]->invoice_amount_as_number },
 862                                align => 'right' },
 863     invoices              => { sub   => sub { my @invnumbers; for my $obj (@{ $_[0]->linked_invoices }) {
 864                                                                 next unless $obj; push @invnumbers, $obj->invnumber } return \@invnumbers } },
 865     currency              => { sub   => sub { $_[0]->currency->name } },
 866     purpose               => { },
 867     local_account_number  => { sub   => sub { $_[0]->local_bank_account->account_number } },
 868     local_bank_code       => { sub   => sub { $_[0]->local_bank_account->bank_code } },
 869     local_bank_name       => { sub   => sub { $_[0]->local_bank_account->name } },
 870     id                    => {},
 871   );
 872
 873   map { $column_defs{$_}->{text} ||= $::locale->text( $self->models->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 874
 875   $report->set_options(
 876     std_column_visibility => 1,
 877     controller_class      => 'BankTransaction',
 878     output_format         => 'HTML',
 879     top_info_text         => $::locale->text('Bank transactions'),
 880     title                 => $::locale->text('Bank transactions'),
 881     allow_pdf_export      => 1,
 882     allow_csv_export      => 1,
 883   );
 884   $report->set_columns(%column_defs);
 885   $report->set_column_order(@columns);
 886   $report->set_export_options(qw(list_all filter));
 887   $report->set_options_from_form;
 888   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 889   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 890
 891   my $bank_accounts = SL::DB::Manager::BankAccount->get_all_sorted();
 892
 893   $report->set_options(
 894     raw_top_info_text     => $self->render('bank_transactions/report_top',    { output => 0 }, BANK_ACCOUNTS => $bank_accounts),
 895     raw_bottom_info_text  => $self->render('bank_transactions/report_bottom', { output => 0 }),
 896   );
 897 }
 898
 899 sub init_problems { [] }
 900
 901 sub init_models {
 902   my ($self) = @_;
 903
 904   SL::Controller::Helper::GetModels->new(
 905     controller => $self,
 906     sorted     => {
 907       _default => {
 908         by  => 'transdate',
 909         dir => 0,   # 1 = ASC, 0 = DESC : default sort is newest at top
 910       },
 911       id                    => t8('ID'),
 912       transdate             => t8('Transdate'),
 913       remote_name           => t8('Remote name'),
 914       amount                => t8('Amount'),
 915       invoice_amount        => t8('Assigned'),
 916       invoices              => t8('Linked invoices'),
 917       valutadate            => t8('Valutadate'),
 918       remote_account_number => t8('Remote account number'),
 919       remote_bank_code      => t8('Remote bank code'),
 920       currency              => t8('Currency'),
 921       purpose               => t8('Purpose'),
 922       local_account_number  => t8('Local account number'),
 923       local_bank_code       => t8('Local bank code'),
 924       local_bank_name       => t8('Bank account'),
 925     },
 926     with_objects => [ 'local_bank_account', 'currency' ],
 927   );
 928 }
 929
 930 sub load_ap_record_template_url {
 931   my ($self, $template) = @_;
 932
 933   return $self->url_for(
 934     controller                           => 'ap.pl',
 935     action                               => 'load_record_template',
 936     id                                   => $template->id,
 937     'form_defaults.amount_1'             => $::form->format_amount(\%::myconfig, -1 * $self->transaction->amount, 2),
 938     'form_defaults.transdate'            => $self->transaction->transdate_as_date,
 939     'form_defaults.duedate'              => $self->transaction->transdate_as_date,
 940     'form_defaults.no_payment_bookings'  => 1,
 941     'form_defaults.paid_1_suggestion'    => $::form->format_amount(\%::myconfig, -1 * $self->transaction->amount, 2),
 942     'form_defaults.AP_paid_1_suggestion' => $self->transaction->local_bank_account->chart->accno,
 943     'form_defaults.callback'             => $self->callback,
 944   );
 945 }
 946
 947 sub load_gl_record_template_url {
 948   my ($self, $template) = @_;
 949
 950   return $self->url_for(
 951     controller                           => 'gl.pl',
 952     action                               => 'load_record_template',
 953     id                                   => $template->id,
 954     'form_defaults.amount_1'             => abs($self->transaction->not_assigned_amount), # always positive
 955     'form_defaults.transdate'            => $self->transaction->transdate_as_date,
 956     'form_defaults.callback'             => $self->callback,
 957     'form_defaults.bt_id'                => $self->transaction->id,
 958     'form_defaults.bt_chart_id'          => $self->transaction->local_bank_account->chart->id,
 959   );
 960 }
 961
 962 sub setup_search_action_bar {
 963   my ($self, %params) = @_;
 964
 965   for my $bar ($::request->layout->get('actionbar')) {
 966     $bar->add(
 967       action => [
 968         t8('Filter'),
 969         submit    => [ '#search_form', { action => 'BankTransaction/list' } ],
 970         accesskey => 'enter',
 971       ],
 972     );
 973   }
 974 }
 975
 976 sub setup_list_all_action_bar {
 977   my ($self, %params) = @_;
 978
 979   for my $bar ($::request->layout->get('actionbar')) {
 980     $bar->add(
 981       combobox => [
 982         action => [ t8('Actions') ],
 983         action => [
 984           t8('Unlink bank transactions'),
 985             submit => [ '#form', { action => 'BankTransaction/unlink_bank_transaction' } ],
 986             checks => [ [ 'kivi.check_if_entries_selected', '[name="ids[]"]' ] ],
 987             disabled  => $::instance_conf->get_payments_changeable ? t8('Cannot safely unlink bank transactions, please set the posting configuration for payments to unchangeable.') : undef,
 988           ],
 989         ],
 990         action => [
 991           t8('Filter'),
 992           submit    => [ '#filter_form', { action => 'BankTransaction/list_all' } ],
 993         accesskey => 'enter',
 994       ],
 995     );
 996   }
 997 }
 998
 999 1;
1000 __END__
1001
1002 =pod
1003
1004 =encoding utf8
1005
1006 =head1 NAME
1007
1008 SL::Controller::BankTransaction - Posting payments to invoices from
1009 bank transactions imported earlier
1010
1011 =head1 FUNCTIONS
1012
1013 =over 4
1014
1015 =item C<save_single_bank_transaction %params>
1016
1017 Takes a bank transaction ID (as parameter C<bank_transaction_id> and
1018 tries to post its amount to a certain number of invoices (parameter
1019 C<invoice_ids>, an array ref of database IDs to purchase or sales
1020 invoice objects).
1021
1022 This method handles already partly assigned bank transactions.
1023
1024 This method cannot handle already partly assigned bank transactions, i.e.
1025 a bank transaction that has a invoice_amount <> 0 but not the fully
1026 transaction amount (invoice_amount == amount).
1027
1028 If the amount of the bank transaction is higher than the sum of
1029 the assigned invoices (1 .. n) the bank transaction will only be
1030 partly assigned.
1031
1032 The whole function is wrapped in a database transaction. If an
1033 exception occurs the bank transaction is not posted at all. The same
1034 is true if the code detects an error during the execution, e.g. a bank
1035 transaction that's already been posted earlier. In both cases the
1036 database transaction will be rolled back.
1037
1038 If warnings but not errors occur the database transaction is still
1039 committed.
1040
1041 The return value is an error object or C<undef> if the function
1042 succeeded. The calling function will collect all warnings and errors
1043 and display them in a nicely formatted table if any occurred.
1044
1045 An error object is a hash reference containing the following members:
1046
1047 =over 2
1048
1049 =item * C<result> — can be either C<warning> or C<error>. Warnings are
1050 displayed slightly different than errors.
1051
1052 =item * C<message> — a human-readable message included in the list of
1053 errors meant as the description of why the problem happened
1054
1055 =item * C<bank_transaction_id>, C<invoice_ids> — the same parameters
1056 that the function was called with
1057
1058 =item * C<bank_transaction> — the database object
1059 (C<SL::DB::BankTransaction>) corresponding to C<bank_transaction_id>
1060
1061 =item * C<invoices> — an array ref of the database objects (either
1062 C<SL::DB::Invoice> or C<SL::DB::PurchaseInvoice>) corresponding to
1063 C<invoice_ids>
1064
1065 =back
1066
1067 =item C<action_unlink_bank_transaction>
1068
1069 Takes one or more bank transaction ID (as parameter C<form::ids>) and
1070 tries to revert all payment bookings including already cleared bookings.
1071
1072 This method won't undo payments that are in a closed period and assumes
1073 that payments are not manually changed, i.e. only imported payments.
1074
1075 GL-records will be deleted completely if a bank transaction was the source.
1076
1077 TODO: we still rely on linked_records for the check boxes
1078
1079 =back
1080
1081 =head1 AUTHOR
1082
1083 Niclas Zimmermann E<lt>niclas@kivitendo-premium.deE<gt>,
1084 Geoffrey Richardson E<lt>information@richardson-bueren.deE<gt>
1085
1086 =cut