SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use English qw(-no_match_vars);
   6 use List::Util qw(min);
   7 use List::MoreUtils qw(pairwise any);
   8
   9 use SL::Helper::Csv;
  10
  11 use SL::DB;
  12 use SL::DB::BankAccount;
  13 use SL::DB::Customer;
  14 use SL::DB::Language;
  15 use SL::DB::PaymentTerm;
  16 use SL::DB::DeliveryTerm;
  17 use SL::DB::Vendor;
  18 use SL::DB::Contact;
  19 use SL::DB::History;
  20
  21 use parent qw(Rose::Object);
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25  scalar                  => [ qw(controller file csv test_run save_with_cascade) ],
  26  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by delivery_terms_by all_bank_accounts all_vc vc_by vc_counts_by clone_methods) ],
  27 );
  28
  29 sub run {
  30   my ($self, %params) = @_;
  31
  32   $self->test_run($params{test});
  33
  34   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  35
  36   my $profile = $self->profile;
  37   $self->csv(SL::Helper::Csv->new(file                   => ('SCALAR' eq ref $self->file)? $self->file: $self->file->file_name,
  38                                   encoding               => $self->controller->profile->get('charset'),
  39                                   profile                => [{ profile => $profile, class => $self->class, mapping => $self->controller->mappings_for_profile }],
  40                                   ignore_unknown_columns => 1,
  41                                   strict_profile         => 1,
  42                                   case_insensitive_header => 1,
  43                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  44                                  ));
  45
  46   $self->controller->track_progress(progress => 10);
  47
  48   local $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  49   local $::myconfig{dateformat}   = $self->controller->profile->get('dateformat');
  50
  51   $self->csv->parse;
  52
  53   $self->controller->track_progress(progress => 50);
  54
  55   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  56
  57   return if ( !$self->csv->header || $self->csv->errors );
  58
  59   my $headers         = { headers => [ grep { $self->csv->dispatcher->is_known($_, 0) } @{ $self->csv->header } ] };
  60   $headers->{methods} = [ map { $_->{path} } @{ $self->csv->specs->[0] } ];
  61   $headers->{used}    = { map { ($_ => 1) }  @{ $headers->{headers} } };
  62   $self->controller->headers($headers);
  63   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  64   $self->controller->info_headers({ used => { }, headers => [ ] });
  65
  66   my $objects  = $self->csv->get_objects;
  67
  68   $self->controller->track_progress(progress => 70);
  69
  70   my @raw_data = @{ $self->csv->get_data };
  71
  72   $self->controller->track_progress(progress => 80);
  73
  74   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @$objects, @raw_data ]);
  75
  76   $self->controller->track_progress(progress => 90);
  77
  78   $self->check_objects;
  79   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  80     $self->check_std_duplicates();
  81     $self->check_duplicates();
  82   }
  83   $self->fix_field_lengths;
  84
  85   $self->controller->track_progress(progress => 100);
  86 }
  87
  88 sub add_columns {
  89   my ($self, @columns) = @_;
  90
  91   my $h = $self->controller->headers;
  92
  93   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  94     $h->{used}->{$column} = 1;
  95     push @{ $h->{methods} }, $column;
  96     push @{ $h->{headers} }, $column;
  97   }
  98 }
  99
 100 sub add_info_columns {
 101   my ($self, @columns) = @_;
 102
 103   my $h = $self->controller->info_headers;
 104
 105   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 106     $h->{used}->{ $column->{method} } = 1;
 107     push @{ $h->{methods} }, $column->{method};
 108     push @{ $h->{headers} }, $column->{header};
 109   }
 110 }
 111
 112 sub add_raw_data_columns {
 113   my ($self, @columns) = @_;
 114
 115   my $h = $self->controller->raw_data_headers;
 116
 117   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 118     $h->{used}->{$column} = 1;
 119     push @{ $h->{headers} }, $column;
 120   }
 121 }
 122
 123 sub add_cvar_raw_data_columns {
 124   my ($self) = @_;
 125
 126   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 127 }
 128
 129 sub init_all_cvar_configs {
 130   # Must be overridden by derived specialized importer classes.
 131   return [];
 132 }
 133
 134 sub init_cvar_columns {
 135   my ($self) = @_;
 136
 137   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 138 }
 139
 140 sub init_all_languages {
 141   my ($self) = @_;
 142
 143   return SL::DB::Manager::Language->get_all;
 144 }
 145
 146 sub init_all_bank_accounts {
 147   my ($self) = @_;
 148
 149   return SL::DB::Manager::BankAccount->get_all_sorted( query => [ obsolete => 0 ] );
 150 }
 151
 152 sub init_payment_terms_by {
 153   my ($self) = @_;
 154
 155   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 156   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 157 }
 158
 159 sub init_delivery_terms_by {
 160   my ($self) = @_;
 161
 162   my $all_delivery_terms = SL::DB::Manager::DeliveryTerm->get_all;
 163   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_delivery_terms } } ) } qw(id description) };
 164 }
 165
 166 sub init_all_vc {
 167   my ($self) = @_;
 168
 169   return { customers => SL::DB::Manager::Customer->get_all,
 170            vendors   => SL::DB::Manager::Vendor->get_all };
 171 }
 172
 173 sub init_clone_methods {
 174   {}
 175 }
 176
 177 sub force_allow_columns {
 178   return ();
 179 }
 180
 181 sub init_vc_by {
 182   my ($self)    = @_;
 183
 184   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 185   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 186                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 187   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 188                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 189   my %by_gln    = ( customers => { map { ( $_->gln            => $_ ) } grep $_->gln, @{ $self->all_vc->{customers} } },
 190                     vendors   => { map { ( $_->gln            => $_ ) } grep $_->gln, @{ $self->all_vc->{vendors}   } } );
 191
 192   return { id     => \%by_id,
 193            number => \%by_number,
 194            name   => \%by_name,
 195            gln    => \%by_gln };
 196 }
 197
 198 sub init_vc_counts_by {
 199   my ($self) = @_;
 200
 201   my $vc_counts_by = {};
 202
 203   $vc_counts_by->{number}->{customers}->{$_->customernumber}++ for @{ $self->all_vc->{customers} };
 204   $vc_counts_by->{number}->{vendors}->  {$_->vendornumber}++   for @{ $self->all_vc->{vendors} };
 205   $vc_counts_by->{name}->  {customers}->{$_->name}++           for @{ $self->all_vc->{customers} };
 206   $vc_counts_by->{name}->  {vendors}->  {$_->name}++           for @{ $self->all_vc->{vendors} };
 207   $vc_counts_by->{gln}->   {customers}->{$_->gln}++            for grep $_->gln, @{ $self->all_vc->{customers} };
 208   $vc_counts_by->{gln}->   {vendors}->  {$_->gln}++            for grep $_->gln, @{ $self->all_vc->{vendors} };
 209
 210   return $vc_counts_by;
 211 }
 212
 213 sub check_vc {
 214   my ($self, $entry, $id_column) = @_;
 215
 216   if ($entry->{object}->$id_column) {
 217     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 218   }
 219
 220   my $is_ambiguous;
 221   if (!$entry->{object}->$id_column) {
 222     my $vc;
 223     if ($entry->{raw_data}->{customernumber}) {
 224       $vc = $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} };
 225       if ($vc && $self->vc_counts_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} } > 1) {
 226         $vc = undef;
 227         $is_ambiguous = 1;
 228       }
 229     } elsif ($entry->{raw_data}->{vendornumber}) {
 230       $vc = $self->vc_by->{number}->{vendors}->{ $entry->{raw_data}->{vendornumber} };
 231       if ($vc && $self->vc_counts_by->{number}->{vendors}->{ $entry->{raw_data}->{vendornumber} } > 1) {
 232         $vc = undef;
 233         $is_ambiguous = 1;
 234       }
 235     }
 236
 237     $entry->{object}->$id_column($vc->id) if $vc;
 238   }
 239
 240   if (!$entry->{object}->$id_column) {
 241     my $vc;
 242     if ($entry->{raw_data}->{customer}) {
 243       $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} };
 244       if ($vc && $self->vc_counts_by->{name}->{customers}->{ $entry->{raw_data}->{customer} } > 1) {
 245         $vc = undef;
 246         $is_ambiguous = 1;
 247       }
 248     } elsif ($entry->{raw_data}->{vendor}) {
 249       $vc = $self->vc_by->{name}->{vendors}->{ $entry->{raw_data}->{vendor} };
 250       if ($vc && $self->vc_counts_by->{name}->{vendors}->{ $entry->{raw_data}->{vendor} } > 1) {
 251         $vc = undef;
 252         $is_ambiguous = 1;
 253       }
 254     }
 255
 256     $entry->{object}->$id_column($vc->id) if $vc;
 257   }
 258
 259   if (!$entry->{object}->$id_column) {
 260     my $vc;
 261     if ($entry->{raw_data}->{customer_gln}) {
 262       $vc = $self->vc_by->{gln}->{customers}->{ $entry->{raw_data}->{customer_gln} };
 263       if ($vc && $self->vc_counts_by->{gln}->{customers}->{ $entry->{raw_data}->{customer_gln} } > 1) {
 264         $vc = undef;
 265         $is_ambiguous = 1;
 266       }
 267     } elsif ($entry->{raw_data}->{vendor_gln}) {
 268       $vc = $self->vc_by->{gln}->{vendors}->{ $entry->{raw_data}->{vendor_gln} };
 269       if ($vc && $self->vc_counts_by->{gln}->{vendors}->{ $entry->{raw_data}->{vendor_gln} } > 1) {
 270         $vc = undef;
 271         $is_ambiguous = 1;
 272       }
 273     }
 274     $entry->{object}->$id_column($vc->id) if $vc;
 275   }
 276
 277   if ($entry->{object}->$id_column) {
 278     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 279   } else {
 280     if ($is_ambiguous) {
 281       push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor is ambiguous');
 282     } else {
 283       push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 284     }
 285   }
 286 }
 287
 288 sub handle_cvars {
 289   my ($self, $entry) = @_;
 290
 291   my $object = $entry->{object_to_save} || $entry->{object};
 292   return unless $object->can('cvars_by_config');
 293
 294   my %type_to_column = ( text      => 'text_value',
 295                          textfield => 'text_value',
 296                          select    => 'text_value',
 297                          date      => 'timestamp_value_as_date',
 298                          timestamp => 'timestamp_value_as_date',
 299                          number    => 'number_value_as_number',
 300                          bool      => 'bool_value' );
 301
 302   # autovivify all cvars (cvars_by_config will do that for us)
 303   my @cvars;
 304   my %changed_cvars;
 305   foreach my $config (@{ $self->all_cvar_configs }) {
 306     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 307     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 308     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 309
 310     my $new_cvar = SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 311
 312     push @cvars, $new_cvar;
 313     $changed_cvars{$config->name} = $new_cvar;
 314   }
 315
 316   # merge existing with new cvars. swap every existing with the imported one, push the rest
 317   my @orig_cvars = @{ $object->cvars_by_config };
 318   for (@orig_cvars) {
 319     $_ = $changed_cvars{ $_->config->name } if $changed_cvars{ $_->config->name };
 320     delete $changed_cvars{ $_->config->name };
 321   }
 322   push @orig_cvars, values %changed_cvars;
 323   $object->custom_variables(\@orig_cvars);
 324 }
 325
 326 sub init_profile {
 327   my ($self) = @_;
 328
 329   eval "require " . $self->class;
 330
 331   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 332   delete $unwanted{$_} for ($self->force_allow_columns);
 333
 334   my %profile;
 335   for my $col ($self->class->meta->columns) {
 336     next if $unwanted{$col};
 337
 338     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 339       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 340       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 341       :                                                                     $col->name;
 342
 343     $profile{$col} = $name;
 344   }
 345
 346   $profile{ 'cvar_' . $_->name } = '' for @{ $self->all_cvar_configs };
 347
 348   \%profile;
 349 }
 350
 351 sub add_displayable_columns {
 352   my ($self, @columns) = @_;
 353
 354   my @cols       = @{ $self->controller->displayable_columns || [] };
 355   my %ex_col_map = map { $_->{name} => $_ } @cols;
 356
 357   foreach my $column (@columns) {
 358     if ($ex_col_map{ $column->{name} }) {
 359       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 360     } else {
 361       push @cols, $column;
 362     }
 363   }
 364
 365   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 366 }
 367
 368 sub setup_displayable_columns {
 369   my ($self) = @_;
 370
 371   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 372 }
 373
 374 sub add_cvar_columns_to_displayable_columns {
 375   my ($self) = @_;
 376
 377   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 378                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 379                                      @{ $self->all_cvar_configs });
 380 }
 381
 382 sub init_existing_objects {
 383   my ($self) = @_;
 384
 385   eval "require " . $self->class;
 386   $self->existing_objects($self->manager_class->get_all);
 387 }
 388
 389 sub init_class {
 390   die "class not set";
 391 }
 392
 393 sub init_manager_class {
 394   my ($self) = @_;
 395
 396   $self->class =~ m/^SL::DB::(.+)/;
 397   $self->manager_class("SL::DB::Manager::" . $1);
 398 }
 399
 400 sub is_multiplexed { 0 }
 401
 402 sub check_objects {
 403 }
 404
 405 sub check_duplicates {
 406 }
 407
 408 sub check_auth {
 409   $::auth->assert('config');
 410 }
 411
 412 sub check_std_duplicates {
 413   my $self = shift;
 414
 415   my $duplicates = {};
 416
 417   my $all_fields = $self->get_duplicate_check_fields();
 418
 419   foreach my $key (keys(%{ $all_fields })) {
 420     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 421       $duplicates->{$key} = {};
 422     }
 423   }
 424
 425   my @duplicates_keys = keys(%{ $duplicates });
 426
 427   if ( !scalar(@duplicates_keys) ) {
 428     return;
 429   }
 430
 431   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 432     foreach my $object (@{ $self->existing_objects }) {
 433       foreach my $key (@duplicates_keys) {
 434         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 435         $duplicates->{$key}->{$value} = 'db';
 436       }
 437     }
 438   }
 439
 440   foreach my $entry (@{ $self->controller->data }) {
 441     if ( @{ $entry->{errors} } ) {
 442       next;
 443     }
 444
 445     my $object = $entry->{object};
 446
 447     foreach my $key (@duplicates_keys) {
 448       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 449
 450       if ( exists($duplicates->{$key}->{$value}) ) {
 451         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 452         last;
 453       } else {
 454         $duplicates->{$key}->{$value} = 'csv';
 455       }
 456
 457     }
 458   }
 459
 460 }
 461
 462 sub get_duplicate_check_fields {
 463   return {};
 464 }
 465
 466 sub check_payment {
 467   my ($self, $entry) = @_;
 468
 469   my $object = $entry->{object};
 470
 471   # Check whether or not payment ID is valid.
 472   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 473     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 474     return 0;
 475   }
 476
 477   # Map name to ID if given.
 478   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 479     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 480
 481     if (!$terms) {
 482       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 483       return 0;
 484     }
 485
 486     $object->payment_id($terms->id);
 487
 488     # register payment_id for method copying later
 489     $self->clone_methods->{payment_id} = 1;
 490   }
 491
 492   return 1;
 493 }
 494
 495 sub check_delivery_term {
 496   my ($self, $entry) = @_;
 497
 498   my $object = $entry->{object};
 499
 500   # Check whether or not delivery term ID is valid.
 501   if ($object->delivery_term_id && !$self->delivery_terms_by->{id}->{ $object->delivery_term_id }) {
 502     push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 503     return 0;
 504   }
 505
 506   # Map name to ID if given.
 507   if (!$object->delivery_term_id && $entry->{raw_data}->{delivery_term}) {
 508     my $terms = $self->delivery_terms_by->{description}->{ $entry->{raw_data}->{delivery_term} };
 509
 510     if (!$terms) {
 511       push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 512       return 0;
 513     }
 514
 515     $object->delivery_term_id($terms->id);
 516
 517     # register delivery_term_id for method copying later
 518     $self->clone_methods->{delivery_term_id} = 1;
 519   }
 520
 521   return 1;
 522 }
 523
 524 sub save_objects {
 525   my ($self, %params) = @_;
 526
 527   my $data = $params{data} || $self->controller->data;
 528
 529   return unless $data->[0];
 530   return unless $data->[0]{object};
 531
 532   $self->controller->track_progress(phase => 'saving data', progress => 0); # scale from 45..95%;
 533
 534   my $last_index = $#$data;
 535   my $chunk_size = 100;      # one transaction and progress update every 100 objects
 536
 537   for my $chunk (0 .. $last_index / $chunk_size) {
 538     $self->controller->track_progress(progress => ($chunk_size * $chunk)/scalar(@$data) * 100); # scale from 45..95%;
 539     SL::DB->client->with_transaction(sub {
 540       foreach my $entry_index ($chunk_size * $chunk .. min( $last_index, $chunk_size * ($chunk + 1) - 1 )) {
 541         my $entry = $data->[$entry_index];
 542         next if @{ $entry->{errors} };
 543
 544         my $object = $entry->{object_to_save} || $entry->{object};
 545
 546         my $ret;
 547         if (!eval { $ret = $object->save(cascade => !!$self->save_with_cascade()); 1 }) {
 548           push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $EVAL_ERROR);
 549         } elsif ( !$ret ) {
 550           push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $object->db->error);
 551         } else {
 552           $self->_save_history($object);
 553           $self->save_additions($object);
 554           $self->controller->num_imported($self->controller->num_imported + 1);
 555         }
 556       }
 557       1;
 558     }) or do { die SL::DB->client->error };
 559   }
 560   $self->controller->track_progress(progress => 100);
 561 }
 562
 563 sub field_lengths {
 564   my ($self) = @_;
 565
 566   return map { $_->name => $_->length } grep { $_->type eq 'varchar' } @{$self->class->meta->columns};
 567 }
 568
 569 sub fix_field_lengths {
 570   my ($self) = @_;
 571
 572   my %field_lengths = $self->field_lengths;
 573   foreach my $entry (@{ $self->controller->data }) {
 574     next unless @{ $entry->{errors} };
 575     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 576   }
 577 }
 578
 579 sub clean_fields {
 580   my ($self, $illegal_chars, $object, @fields) = @_;
 581
 582   my @cleaned_fields;
 583   foreach my $field (grep { $object->can($_) } @fields) {
 584     my $value = $object->$field;
 585
 586     next unless defined($value) && ($value =~ s/$illegal_chars/ /g);
 587
 588     $object->$field($value);
 589     push @cleaned_fields, $field;
 590   }
 591
 592   return @cleaned_fields;
 593 }
 594
 595 sub save_additions {
 596   my ($self, $object) = @_;
 597
 598   # Can be overridden by derived specialized importer classes to save
 599   # additional tables (e.g. record links).
 600   # This sub is called after the object is saved successfully in an transaction.
 601
 602   return;
 603 }
 604
 605 sub _save_history {
 606   my ($self, $object) = @_;
 607
 608   if (any { $self->controller->{type} && $_ eq $self->controller->{type} } qw(parts customers_vendors orders delivery_orders ar_transactions)) {
 609     my $snumbers = $self->controller->{type} eq 'parts'             ? 'partnumber_' . $object->partnumber
 610                  : $self->controller->{type} eq 'customers_vendors' ?
 611                      ($self->table eq 'customer' ? 'customernumber_' . $object->customernumber : 'vendornumber_' . $object->vendornumber)
 612                  : $self->controller->{type} eq 'orders'            ? 'ordnumber_' . $object->ordnumber
 613                  : $self->controller->{type} eq 'delivery_orders'   ? 'donumber_'  . $object->donumber
 614                  : $self->controller->{type} eq 'ar_transactions'   ? 'invnumber_' . $object->invnumber
 615                  : '';
 616
 617     my $what_done = '';
 618     if ($self->controller->{type} eq 'orders') {
 619       $what_done = $object->customer_id ? 'sales_order' : 'purchase_order';
 620     }
 621     if ($self->controller->{type} eq 'delivery_orders') {
 622       $what_done = $object->customer_id ? 'sales_delivery_order' : 'purchase_delivery_order';
 623     }
 624
 625     SL::DB::History->new(
 626       trans_id    => $object->id,
 627       snumbers    => $snumbers,
 628       employee_id => $self->controller->{employee_id},
 629       addition    => 'SAVED',
 630       what_done   => $what_done,
 631     )->save();
 632   }
 633 }
 634
 635 1;