SL/Controller/Letter.pm

   1 package SL::Controller::Letter;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Carp;
   7 use File::Basename;
   8 use POSIX qw(strftime);
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::CT;
  12 use SL::DB::Letter;
  13 use SL::DB::LetterDraft;
  14 use SL::DB::Employee;
  15 use SL::Helper::Flash qw(flash flash_later);
  16 use SL::Helper::CreatePDF;
  17 use SL::Helper::PrintOptions;
  18 use SL::Locale::String qw(t8);
  19 use SL::Mailer;
  20 use SL::IS;
  21 use SL::ReportGenerator;
  22 use SL::Webdav;
  23 use SL::Webdav::File;
  24
  25 use Rose::Object::MakeMethods::Generic (
  26   'scalar --get_set_init' => [ qw(letter all_employees models webdav_objects) ],
  27 );
  28
  29 __PACKAGE__->run_before('check_auth_edit');
  30 __PACKAGE__->run_before('check_auth_report', only => [ qw(list) ]);
  31
  32 use constant TEXT_CREATED_FOR_VALUES => (qw(presskit fax letter));
  33 use constant PAGE_CREATED_FOR_VALUES => (qw(sketch 1 2));
  34
  35 my %sort_columns = (
  36   date                  => t8('Date'),
  37   subject               => t8('Subject'),
  38   letternumber          => t8('Letternumber'),
  39   vc_id                 => t8('Customer'),
  40   contact               => t8('Contact'),
  41 );
  42
  43 sub action_add {
  44   my ($self, %params) = @_;
  45
  46   return if $self->load_letter_draft(%params);
  47
  48   $self->letter->employee_id(SL::DB::Manager::Employee->current->id);
  49   $self->letter->salesman_id(SL::DB::Manager::Employee->current->id);
  50
  51   $self->_display(
  52     title       => t8('Add Letter'),
  53     language_id => $params{language_id},
  54   );
  55 }
  56
  57 sub action_edit {
  58   my ($self, %params) = @_;
  59
  60   return $self->action_add
  61     unless $::form->{letter} || $::form->{draft};
  62
  63   $self->letter(SL::DB::Letter->new_from_draft($::form->{draft}{id}))
  64     if $::form->{draft};
  65
  66   $self->_display(
  67     title  => t8('Edit Letter'),
  68   );
  69 }
  70
  71 sub action_save {
  72   my ($self, %params) = @_;
  73
  74   my $letter = $self->_update;
  75
  76   if (!$self->check_letter($letter)) {
  77     return $self->_display;
  78   }
  79
  80   $self->check_number;
  81
  82   if (!$letter->save) {
  83     flash('error', t8('There was an error saving the letter'));
  84     return $self->_display;
  85   }
  86
  87   flash('info', t8('Letter saved!'));
  88
  89   $self->_display;
  90 }
  91
  92 sub action_update_contacts {
  93   my ($self) = @_;
  94
  95   my $letter = $self->letter;
  96
  97   if (!$self->letter->vc_id || !$self->letter->customer) {
  98     return $self->js
  99       ->replaceWith(
 100         '#letter_cp_id',
 101         SL::Presenter->get->select_tag('letter.cp_id', [], value_key => 'cp_id', title_key => 'full_name')
 102       )
 103       ->render;
 104   }
 105
 106   my $contacts = $letter->customer->contacts;
 107
 108   my $default;
 109   if (   $letter->contact
 110       && $letter->contact->cp_cv_id
 111       && $letter->contact->cp_cv_id == $letter->vc_id) {
 112     $default = $letter->contact->cp_id;
 113   } else {
 114     $default = '';
 115   }
 116
 117   $self->js
 118     ->replaceWith(
 119       '#letter_cp_id',
 120       SL::Presenter->get->select_tag('letter.cp_id', $contacts, default => $default, value_key => 'cp_id', title_key => 'full_name')
 121     )
 122     ->render;
 123 }
 124
 125 sub action_save_letter_draft {
 126   my ($self, %params) = @_;
 127
 128   $self->check_letter;
 129
 130   my $letter_draft = SL::DB::LetterDraft->new_from_letter($self->_update);
 131
 132   if (!$letter_draft->save) {
 133     flash('error', t8('There was an error saving the letter draft'));
 134     return $self->_display;
 135   }
 136
 137   flash('info', t8('Draft for this Letter saved!'));
 138
 139   $self->_display;
 140 }
 141
 142 sub action_delete {
 143   my ($self, %params) = @_;
 144
 145   if (!$self->letter->delete) {
 146     flash('error', t8('An error occured. Letter could not be deleted.'));
 147     return $self->action_update;
 148   }
 149
 150   flash_later('info', t8('Letter deleted'));
 151   $self->redirect_to(action => 'list');
 152 }
 153
 154 sub action_delete_letter_drafts {
 155   my ($self, %params) = @_;
 156
 157   my @ids =  grep { /^checked_(.*)/ && $::form->{$_} } keys %$::form;
 158
 159   SL::DB::Manager::LetterDraft->delete_all(query => [ ids => \@ids ]) if @ids;
 160
 161   $self->redirect_to(action => 'add');
 162 }
 163
 164 sub action_list {
 165   my ($self, %params) = @_;
 166
 167   $self->make_filter_summary;
 168   $self->prepare_report;
 169
 170   my $letters = $self->models->get;
 171   $self->report_generator_list_objects(report => $self->{report}, objects => $letters);
 172
 173 }
 174
 175 sub action_print_letter {
 176   my ($self, %params) = @_;
 177
 178   my $display_form = $::form->{display_form} || "display_form";
 179   my $letter       = $self->_update;
 180
 181   $self->export_letter_to_form($letter);
 182   $::form->{formname} = "letter";
 183   $::form->{type}     = "letter";
 184   $::form->{format}   = "pdf";
 185
 186   my $language_saved      = $::form->{language_id};
 187   my $greeting_saved      = $::form->{greeting};
 188   my $cp_id_saved         = $::form->{cp_id};
 189
 190   $::form->{customer_id} = $self->letter->vc_id;
 191   IS->customer_details(\%::myconfig, $::form);
 192
 193   if (!$cp_id_saved) {
 194     # No contact was selected. Delete all contact variables because
 195     # IS->customer_details() and IR->vendor_details() get the default
 196     # contact anyway.
 197     map({ delete($::form->{$_}); } grep(/^cp_/, keys(%{ $::form })));
 198   }
 199
 200   $::form->{greeting} = $greeting_saved;
 201   $::form->{language_id} = $language_saved;
 202
 203   if ($::form->{cp_id}) {
 204     CT->get_contact(\%::myconfig, $::form);
 205   }
 206
 207   $::form->{cp_contact_formal} = ($::form->{cp_greeting} ? "$::form->{cp_greeting} " : '') . ($::form->{cp_givenname} ? "$::form->{cp_givenname} " : '') . $::form->{cp_name};
 208
 209   $::form->get_employee_data('prefix' => 'employee', 'id' => $letter->{employee_id});
 210   $::form->get_employee_data('prefix' => 'salesman', 'id' => $letter->{salesman_id});
 211
 212   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
 213     name        => 'letter',
 214     printer_id  => $::form->{printer_id},
 215     language_id => $::form->{language_id},
 216     formname    => 'letter',
 217     format      => 'pdf',
 218   );
 219
 220   if (!defined $template_file) {
 221     $::form->error($::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files));
 222   }
 223
 224   my %create_params = (
 225     template  => $template_file,
 226     variables => $::form,
 227     return    => 'file_name',
 228     variable_content_types => {
 229       body                 => 'html',
 230     },
 231   );
 232
 233   my $pdf_file_name;
 234   eval {
 235     $pdf_file_name          = SL::Helper::CreatePDF->create_pdf(%create_params);
 236
 237     $::form->{letternumber} = $self->letter->letternumber;
 238     my $attachment_name     = $::form->generate_attachment_filename;
 239
 240     if ($::instance_conf->get_webdav_documents) {
 241       my $webdav_file = SL::Webdav::File->new(
 242         filename => $attachment_name,
 243         webdav   => SL::Webdav->new(
 244           type   => 'letter',
 245           number => $self->letter->letternumber,
 246         ),
 247       );
 248
 249       $webdav_file->store(file => $pdf_file_name);
 250     }
 251
 252     # set some form defaults for printing webdav copy variables
 253     if ( $::form->{media} eq 'email') {
 254       my $mail             = Mailer->new;
 255       my $signature        = $::myconfig{signature};
 256       $mail->{$_}          = $params{email}->{$_} for qw(to cc subject message bcc);
 257       $mail->{from}        = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 258       $mail->{attachments} = [{ filename => $pdf_file_name,
 259                                 name     => $params{email}->{attachment_filename} }];
 260       $mail->{message}    .=  "\n-- \n$signature";
 261       $mail->{message}     =~ s/\r//g;
 262
 263       $mail->send;
 264       unlink $pdf_file_name;
 265
 266       flash_later('info', t8('The email has been sent.'));
 267       $self->redirect_to(action => 'edit', 'letter.id' => $self->letter->id);
 268
 269       return 1;
 270     }
 271
 272     if (!$::form->{printer_id} || $::form->{media} eq 'screen') {
 273       $self->send_file($pdf_file_name, name => $attachment_name);
 274       unlink $pdf_file_name;
 275
 276       return 1;
 277     }
 278
 279     my $printer = SL::DB::Printer->new(id => $::form->{printer_id})->load;
 280     $printer->print_document(
 281       copies    => $::form->{copies},
 282       file_name => $pdf_file_name,
 283     );
 284
 285     unlink $pdf_file_name;
 286
 287     flash_later('info', t8('The documents have been sent to the printer \'#1\'.', $printer->printer_description));
 288     $self->redirect_to(action => 'edit', 'letter.id' => $self->letter->id, media => 'printer', printer_id => $::form->{printer_id});
 289     1;
 290   } or do {
 291     unlink $pdf_file_name if $pdf_file_name;
 292     $::form->error(t8("Creating the PDF failed:") . " " . $@);
 293   };
 294 }
 295
 296 sub action_update {
 297   my ($self, $name_selected) = @_;
 298
 299   $self->_display(
 300     letter => $self->_update,
 301   );
 302 }
 303
 304 sub action_skip_draft {
 305   my ($self) = @_;
 306   $self->action_add(skip_drafts => 1);
 307 }
 308
 309 sub action_delete_drafts {
 310   my ($self) = @_;
 311   delete_letter_drafts();
 312   $self->action_add(skip_drafts => 1);
 313 }
 314
 315 sub action_edit_email {
 316   my ($self) = @_;
 317
 318   my $letter = $self->_update;
 319   $self->export_letter_to_form($letter);
 320
 321   $::form->{formname}     = "letter";
 322   $::form->{type}         = "letter";
 323   $::form->{letternumber} = $self->letter->letternumber;
 324
 325   my @hiddens = map {
 326     my $value = $letter->$_;
 327     $value    = $value->to_kivitendo if ref($_) =~ m{Date};
 328
 329     { name => "letter.$_", value => $value }
 330   } ($letter->meta->columns);
 331
 332   my %vars = (
 333     script     => 'controller.pl',
 334     title      => t8('Send letter via e-mail'),
 335     email      => $letter->contact ? $letter->contact->cp_email : '',
 336     subject    => $::form->generate_email_subject,
 337     a_filename => $::form->generate_attachment_filename,
 338     action     => 'Letter/send_email',
 339     HIDDEN     => \@hiddens,
 340     SHOW_BCC   => $::auth->assert('email_bcc', 'may fail'),
 341   );
 342
 343   $self->render('generic/edit_email', %vars);
 344 }
 345
 346 sub action_send_email {
 347   my ($self) = @_;
 348
 349   $::form->{media} = 'email';
 350   $self->action_print_letter(
 351     email => {
 352       to => $::form->{email},
 353       map { ($_ => $::form->{$_}) } qw(cc bcc subject attachment_filename message)
 354     }
 355   );
 356 }
 357
 358 sub _display {
 359   my ($self, %params) = @_;
 360
 361   $::request->{layout}->use_javascript("${_}.js") for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 362
 363   my $letter = $self->letter;
 364
 365  $params{title} ||= t8('Edit Letter');
 366
 367   $::form->{type}             = 'letter';   # needed for print_options
 368   $::form->{vc}               = 'customer'; # needs to be for _get_contacts...
 369
 370   $::request->layout->add_javascripts('customer_or_vendor_selection.js');
 371   $::request->layout->add_javascripts('edit_part_window.js');
 372
 373   $::form->{language_id} ||= $params{language_id};
 374   $::form->{printers}      = SL::DB::Manager::Printer->get_all_sorted;
 375
 376   $self->render('letter/edit',
 377     %params,
 378     TCF           => [ map { key => $_, value => t8(ucfirst $_) }, TEXT_CREATED_FOR_VALUES() ],
 379     PCF           => [ map { key => $_, value => t8(ucfirst $_) }, PAGE_CREATED_FOR_VALUES() ],
 380     letter        => $letter,
 381     employees     => $self->all_employees,
 382     print_options => SL::Helper::PrintOptions->get_print_options (
 383       options => { no_postscript   => 1,
 384                    no_opendocument => 1,
 385                    no_html         => 1,
 386                    no_queue        => 1 }),
 387
 388   );
 389 }
 390
 391 sub _update {
 392   my ($self, %params) = @_;
 393
 394   my $letter = $self->letter;
 395
 396   $self->check_date;
 397   $self->set_greetings;
 398
 399   return $letter;
 400 }
 401
 402 sub prepare_report {
 403   my ($self) = @_;
 404
 405   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 406   $self->{report} = $report;
 407
 408   my @columns  = qw(date subject letternumber vc_id contact date);
 409   my @sortable = qw(date subject letternumber vc_id contact date);
 410
 411   my %column_defs = (
 412     date                  => { text => t8('Date'),         sub => sub { $_[0]->date_as_date } },
 413     subject               => { text => t8('Subject'),      sub => sub { $_[0]->subject },
 414                                obj_link => sub { $self->url_for(action => 'edit', 'letter.id' => $_[0]->id, callback => $self->models->get_callback) }  },
 415     letternumber          => { text => t8('Letternumber'), sub => sub { $_[0]->letternumber },
 416                                obj_link => sub { $self->url_for(action => 'edit', 'letter.id' => $_[0]->id, callback => $self->models->get_callback) }  },
 417     vc_id                 => { text => t8('Customer'),      sub => sub { SL::DB::Manager::Customer->find_by_or_create(id => $_[0]->vc_id)->displayable_name } },
 418     contact               => { text => t8('Contact'),       sub => sub { $_[0]->contact ? $_[0]->contact->full_name : '' } },
 419   );
 420
 421   $column_defs{$_}{text} = $sort_columns{$_} for keys %column_defs;
 422
 423   $report->set_options(
 424     std_column_visibility => 1,
 425     controller_class      => 'Letter',
 426     output_format         => 'HTML',
 427     top_info_text         => t8('Letters'),
 428     title                 => t8('Letters'),
 429     allow_pdf_export      => 1,
 430     allow_csv_export      => 1,
 431   );
 432
 433   $report->set_columns(%column_defs);
 434   $report->set_column_order(@columns);
 435   $report->set_export_options(qw(list filter));
 436   $report->set_options_from_form;
 437
 438   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 439   $self->models->finalize;
 440   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 441
 442   $report->set_options(
 443     raw_top_info_text    => $self->render('letter/report_top',    { output => 0 }),
 444     raw_bottom_info_text => $self->render('letter/report_bottom', { output => 0 }, models => $self->models),
 445     attachment_basename  => t8('letters_list') . strftime('_%Y%m%d', localtime time),
 446   );
 447 }
 448
 449 sub make_filter_summary {
 450   my ($self) = @_;
 451
 452   my $filter = $::form->{filter} || {};
 453   my @filter_strings;
 454
 455   my $employee = $filter->{employee_id} ? SL::DB::Employee->new(id => $filter->{employee_id})->load->name : '';
 456   my $salesman = $filter->{salesman_id} ? SL::DB::Employee->new(id => $filter->{salesman_id})->load->name : '';
 457
 458   my @filters = (
 459     [ $filter->{"letternumber:substr::ilike"},  t8('Number')     ],
 460     [ $filter->{"subject:substr::ilike"},       t8('Subject')    ],
 461     [ $filter->{"body:substr::ilike"},          t8('Body')       ],
 462     [ $filter->{"date:date::ge"},               t8('From Date')  ],
 463     [ $filter->{"date:date::le"},               t8('To Date')    ],
 464     [ $employee,                                t8('Employee')   ],
 465     [ $salesman,                                t8('Salesman')   ],
 466   );
 467
 468   my %flags = (
 469   );
 470   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 471
 472   for (@flags) {
 473     push @filter_strings, $_ if $_;
 474   }
 475   for (@filters) {
 476     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 477   }
 478
 479   $self->{filter_summary} = join ', ', @filter_strings;
 480 }
 481
 482 sub load_letter_draft {
 483   my ($self, %params) = @_;
 484
 485   return 0 if $params{skip_drafts};
 486
 487   my $letter_drafts = SL::DB::Manager::LetterDraft->get_all;
 488
 489   return unless @$letter_drafts;
 490
 491   $self->render('letter/load_drafts',
 492     title         => t8('Letter Draft'),
 493     LETTER_DRAFTS => $letter_drafts,
 494   );
 495
 496   return 1;
 497 }
 498
 499 sub check_date {
 500   my ($self) = @_;
 501   my $letter = $self->letter;
 502
 503   return unless $letter;
 504   return if $letter->date;
 505
 506   $letter->date(DateTime->today)
 507 }
 508
 509 sub check_letter {
 510   my ($self, $letter) = @_;
 511
 512   $letter ||= $self->letter;
 513
 514   my $error;
 515
 516   if (!$letter->subject) {
 517     flash('error', t8('The subject is missing.'));
 518     $error = 1;
 519   }
 520   if (!$letter->body) {
 521     flash('error', t8('The body is missing.'));
 522     $error = 1;
 523   }
 524   if (!$letter->employee_id) {
 525     flash('error', t8('The employee is missing.'));
 526     $error = 1;
 527   }
 528
 529   return !$error;
 530 }
 531
 532 sub check_number {
 533   my ($self, $letter) = @_;
 534
 535   $letter ||= $self->letter;
 536
 537   return if $letter->letternumber;
 538
 539   $letter->letternumber(SL::TransNumber->new(type => 'letter', id => $self->{id}, number => $self->{letternumber})->create_unique);
 540 }
 541
 542 sub set_greetings {
 543   my ($self) = @_;
 544   my $letter = $self->letter;
 545
 546   return unless $letter;
 547   return if $letter->greeting;
 548
 549   $letter->greeting(t8('Dear Sir or Madam,'));
 550 }
 551
 552 sub export_letter_to_form {
 553   my ($self, $letter) = @_;
 554   # nope, not pretty.
 555
 556   $letter ||= $self->letter;
 557
 558   for ($letter->meta->columns) {
 559     if ((ref $_) =~ /Date/i) {
 560       $::form->{$_->name} = $letter->$_->to_kivitendo;
 561     } else {
 562       $::form->{$_->name} = $letter->$_;
 563     }
 564   }
 565 }
 566
 567 sub init_letter {
 568   my ($self) = @_;
 569
 570   my $letter      = SL::DB::Manager::Letter->find_by_or_create(id => $::form->{letter}{id} || 0)
 571                                            ->assign_attributes(%{ $::form->{letter} });
 572
 573   if ($letter->cp_id) {
 574 #     $letter->vc_id($letter->contact->cp_cv_id);
 575       # contacts don't have language_id yet
 576 #     $letter->greeting(GenericTranslations->get(
 577 #       translation_type => 'greetings::' . ($letter->contact->cp_gender eq 'f' ? 'female' : 'male'),
 578 #       language_id      => $letter->contact->language_id,
 579 #       allow_fallback   => 1
 580 #     ));
 581   }
 582
 583   $letter;
 584 }
 585
 586 sub init_models {
 587   my ($self) = @_;
 588
 589   SL::Controller::Helper::GetModels->new(
 590     controller   => $self,
 591     model        => 'Letter',
 592     sorted       => \%sort_columns,
 593     with_objects => [ 'contact', 'salesman', 'employee' ],
 594   );
 595 }
 596
 597 sub init_all_employees {
 598   SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 599 }
 600
 601 sub init_webdav_objects {
 602   my ($self) = @_;
 603
 604   return [] if !$self->letter || !$self->letter->letternumber || !$::instance_conf->get_webdav;
 605
 606   my $webdav = SL::Webdav->new(
 607     type     => 'letter',
 608     number   => $self->letter->letternumber,
 609   );
 610
 611   my $webdav_path = $webdav->webdav_path;
 612   my @all_objects = $webdav->get_all_objects;
 613
 614   return [ map {
 615     +{ name => $_->filename,
 616        type => t8('File'),
 617        link => File::Spec->catdir($webdav_path, $_->filename),
 618      }
 619   } @all_objects ];
 620 }
 621
 622 sub check_auth_edit {
 623   $::auth->assert('sales_letter_edit');
 624 }
 625
 626 sub check_auth_report {
 627   $::auth->assert('sales_letter_report');
 628 }
 629
 630 1;
 631
 632 __END__
 633
 634 =encoding utf-8
 635
 636 =head1 NAME
 637
 638 SL::Controller::Letter - Letters CRUD and printing
 639
 640 =head1 DESCRIPTION
 641
 642 Simple letter CRUD controller with drafting capabilities.
 643
 644 =head1 TODO
 645
 646   Customer/Vendor switch for dealing with vendor letters
 647
 648 copy to webdav is crap
 649
 650 customer/vendor stuff
 651
 652 =head1 AUTHOR
 653
 654 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 655
 656 =cut