SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::HTML::Util;
   8 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   9 use SL::Locale::String qw(t8);
  10 use SL::SessionFile::Random;
  11 use SL::PriceSource;
  12 use SL::Webdav;
  13 use SL::File;
  14 use SL::MIME;
  15 use SL::Util qw(trim);
  16 use SL::YAML;
  17 use SL::DB::AdditionalBillingAddress;
  18 use SL::DB::AuthUser;
  19 use SL::DB::History;
  20 use SL::DB::Order;
  21 use SL::DB::Default;
  22 use SL::DB::Unit;
  23 use SL::DB::Part;
  24 use SL::DB::PartClassification;
  25 use SL::DB::PartsGroup;
  26 use SL::DB::Printer;
  27 use SL::DB::Language;
  28 use SL::DB::RecordLink;
  29 use SL::DB::RequirementSpec;
  30 use SL::DB::Shipto;
  31 use SL::DB::Translation;
  32
  33 use SL::Helper::CreatePDF qw(:all);
  34 use SL::Helper::PrintOptions;
  35 use SL::Helper::ShippedQty;
  36 use SL::Helper::UserPreferences::DisplayPreferences;
  37 use SL::Helper::UserPreferences::PositionsScrollbar;
  38 use SL::Helper::UserPreferences::UpdatePositions;
  39
  40 use SL::Controller::Helper::GetModels;
  41
  42 use List::Util qw(first sum0);
  43 use List::UtilsBy qw(sort_by uniq_by);
  44 use List::MoreUtils qw(any none pairwise first_index);
  45 use English qw(-no_match_vars);
  46 use File::Spec;
  47 use Cwd;
  48 use Sort::Naturally;
  49
  50 use Rose::Object::MakeMethods::Generic
  51 (
  52  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  53  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  54 );
  55
  56
  57 # safety
  58 __PACKAGE__->run_before('check_auth');
  59
  60 __PACKAGE__->run_before('check_auth_for_edit',
  61                         except => [ qw(edit show_customer_vendor_details_dialog price_popup load_second_rows) ]);
  62
  63 __PACKAGE__->run_before('recalc',
  64                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_final_invoice save_and_ap_transaction
  65                                      print send_email) ]);
  66
  67 __PACKAGE__->run_before('get_unalterable_data',
  68                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_final_invoice save_and_ap_transaction
  69                                      print send_email) ]);
  70
  71 #
  72 # actions
  73 #
  74
  75 # add a new order
  76 sub action_add {
  77   my ($self) = @_;
  78
  79   $self->order->transdate(DateTime->now_local());
  80   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  81                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  82
  83   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  84       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  85       && (!$self->order->reqdate)) {
  86     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  87   }
  88
  89
  90   $self->pre_render();
  91   $self->render(
  92     'order/form',
  93     title => $self->get_title_for('add'),
  94     %{$self->{template_args}}
  95   );
  96 }
  97
  98 # edit an existing order
  99 sub action_edit {
 100   my ($self) = @_;
 101
 102   if ($::form->{id}) {
 103     $self->load_order;
 104
 105   } else {
 106     # this is to edit an order from an unsaved order object
 107
 108     # set item ids to new fake id, to identify them as new items
 109     foreach my $item (@{$self->order->items_sorted}) {
 110       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 111     }
 112     # trigger rendering values for second row as hidden, because they
 113     # are loaded only on demand. So we need to keep the values from
 114     # the source.
 115     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 116   }
 117
 118   $self->recalc();
 119   $self->pre_render();
 120   $self->render(
 121     'order/form',
 122     title => $self->get_title_for('edit'),
 123     %{$self->{template_args}}
 124   );
 125 }
 126
 127 # edit a collective order (consisting of one or more existing orders)
 128 sub action_edit_collective {
 129   my ($self) = @_;
 130
 131   # collect order ids
 132   my @multi_ids = map {
 133     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 134   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 135
 136   # fall back to add if no ids are given
 137   if (scalar @multi_ids == 0) {
 138     $self->action_add();
 139     return;
 140   }
 141
 142   # fall back to save as new if only one id is given
 143   if (scalar @multi_ids == 1) {
 144     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 145     $self->action_save_as_new();
 146     return;
 147   }
 148
 149   # make new order from given orders
 150   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 151   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 152   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 153
 154   $self->action_edit();
 155 }
 156
 157 # delete the order
 158 sub action_delete {
 159   my ($self) = @_;
 160
 161   my $errors = $self->delete();
 162
 163   if (scalar @{ $errors }) {
 164     $self->js->flash('error', $_) foreach @{ $errors };
 165     return $self->js->render();
 166   }
 167
 168   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 169            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 170            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 171            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 172            : '';
 173   flash_later('info', $text);
 174
 175   my @redirect_params = (
 176     action => 'add',
 177     type   => $self->type,
 178   );
 179
 180   $self->redirect_to(@redirect_params);
 181 }
 182
 183 # save the order
 184 sub action_save {
 185   my ($self) = @_;
 186
 187   my $errors = $self->save();
 188
 189   if (scalar @{ $errors }) {
 190     $self->js->flash('error', $_) foreach @{ $errors };
 191     return $self->js->render();
 192   }
 193
 194   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 195            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 196            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 197            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 198            : '';
 199   flash_later('info', $text);
 200
 201   my @redirect_params;
 202   if ($::form->{back_to_caller}) {
 203     @redirect_params = $::form->{callback} ? ($::form->{callback})
 204                                            : (controller => 'LoginScreen', action => 'user_login');
 205
 206   } else {
 207     @redirect_params = (
 208       action   => 'edit',
 209       type     => $self->type,
 210       id       => $self->order->id,
 211       callback => $::form->{callback},
 212     );
 213   }
 214
 215   $self->redirect_to(@redirect_params);
 216 }
 217
 218 # save the order as new document an open it for edit
 219 sub action_save_as_new {
 220   my ($self) = @_;
 221
 222   my $order = $self->order;
 223
 224   if (!$order->id) {
 225     $self->js->flash('error', t8('This object has not been saved yet.'));
 226     return $self->js->render();
 227   }
 228
 229   # load order from db to check if values changed
 230   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 231
 232   my %new_attrs;
 233   # Lets assign a new number if the user hasn't changed the previous one.
 234   # If it has been changed manually then use it as-is.
 235   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 236                         ? ''
 237                         : trim($order->number);
 238
 239   # Clear transdate unless changed
 240   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 241                         ? DateTime->today_local
 242                         : $order->transdate;
 243
 244   # Set new reqdate unless changed if it is enabled in client config
 245   if ($order->reqdate == $saved_order->reqdate) {
 246     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 247                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 248
 249     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 250         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 251       $new_attrs{reqdate} = '';
 252     } else {
 253       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 254     }
 255   } else {
 256     $new_attrs{reqdate} = $order->reqdate;
 257   }
 258
 259   # Update employee
 260   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 261
 262   # Create new record from current one
 263   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 264
 265   # no linked records on save as new
 266   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 267
 268   # save
 269   $self->action_save();
 270 }
 271
 272 # print the order
 273 #
 274 # This is called if "print" is pressed in the print dialog.
 275 # If PDF creation was requested and succeeded, the pdf is offered for download
 276 # via send_file (which uses ajax in this case).
 277 sub action_print {
 278   my ($self) = @_;
 279
 280   my $errors = $self->save();
 281
 282   if (scalar @{ $errors }) {
 283     $self->js->flash('error', $_) foreach @{ $errors };
 284     return $self->js->render();
 285   }
 286
 287   $self->js_reset_order_and_item_ids_after_save;
 288
 289   my $format      = $::form->{print_options}->{format};
 290   my $media       = $::form->{print_options}->{media};
 291   my $formname    = $::form->{print_options}->{formname};
 292   my $copies      = $::form->{print_options}->{copies};
 293   my $groupitems  = $::form->{print_options}->{groupitems};
 294   my $printer_id  = $::form->{print_options}->{printer_id};
 295
 296   # only PDF, OpenDocument & HTML for now
 297   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf html)) {
 298     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 299   }
 300
 301   # only screen or printer by now
 302   if (none { $media eq $_ } qw(screen printer)) {
 303     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 304   }
 305
 306   # create a form for generate_attachment_filename
 307   my $form   = Form->new;
 308   $form->{$self->nr_key()}  = $self->order->number;
 309   $form->{type}             = $self->type;
 310   $form->{format}           = $format;
 311   $form->{formname}         = $formname;
 312   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 313   my $doc_filename          = $form->generate_attachment_filename();
 314
 315   my $doc;
 316   my @errors = $self->generate_doc(\$doc, { media      => $media,
 317                                             format     => $format,
 318                                             formname   => $formname,
 319                                             language   => $self->order->language,
 320                                             printer_id => $printer_id,
 321                                             groupitems => $groupitems });
 322   if (scalar @errors) {
 323     return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render;
 324   }
 325
 326   if ($media eq 'screen') {
 327     # screen/download
 328     $self->js->flash('info', t8('The document has been created.'));
 329     $self->send_file(
 330       \$doc,
 331       type         => SL::MIME->mime_type_from_ext($doc_filename),
 332       name         => $doc_filename,
 333       js_no_render => 1,
 334     );
 335
 336   } elsif ($media eq 'printer') {
 337     # printer
 338     my $printer_id = $::form->{print_options}->{printer_id};
 339     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 340       copies  => $copies,
 341       content => $doc,
 342     );
 343
 344     $self->js->flash('info', t8('The document has been printed.'));
 345   }
 346
 347   my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $doc_filename, $formname);
 348   if (scalar @warnings) {
 349     $self->js->flash('warning', $_) for @warnings;
 350   }
 351
 352   $self->save_history('PRINTED');
 353
 354   $self->js
 355     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 356     ->render;
 357 }
 358 sub action_preview_pdf {
 359   my ($self) = @_;
 360
 361   my $errors = $self->save();
 362   if (scalar @{ $errors }) {
 363     $self->js->flash('error', $_) foreach @{ $errors };
 364     return $self->js->render();
 365   }
 366
 367   $self->js_reset_order_and_item_ids_after_save;
 368
 369   my $format      = 'pdf';
 370   my $media       = 'screen';
 371   my $formname    = $self->type;
 372
 373   # only pdf
 374   # create a form for generate_attachment_filename
 375   my $form   = Form->new;
 376   $form->{$self->nr_key()}  = $self->order->number;
 377   $form->{type}             = $self->type;
 378   $form->{format}           = $format;
 379   $form->{formname}         = $formname;
 380   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 381   my $pdf_filename          = $form->generate_attachment_filename();
 382
 383   my $pdf;
 384   my @errors = $self->generate_doc(\$pdf, { media      => $media,
 385                                             format     => $format,
 386                                             formname   => $formname,
 387                                             language   => $self->order->language,
 388                                           });
 389   if (scalar @errors) {
 390     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 391   }
 392   $self->save_history('PREVIEWED');
 393   $self->js->flash('info', t8('The PDF has been previewed'));
 394   # screen/download
 395   $self->send_file(
 396     \$pdf,
 397     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 398     name         => $pdf_filename,
 399     js_no_render => 0,
 400   );
 401 }
 402
 403 # open the email dialog
 404 sub action_save_and_show_email_dialog {
 405   my ($self) = @_;
 406
 407   my $errors = $self->save();
 408
 409   if (scalar @{ $errors }) {
 410     $self->js->flash('error', $_) foreach @{ $errors };
 411     return $self->js->render();
 412   }
 413
 414   my $cv_method = $self->cv;
 415
 416   if (!$self->order->$cv_method) {
 417     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 418                     ->render($self);
 419   }
 420
 421   my $email_form;
 422   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 423   $email_form->{to} ||= $self->order->$cv_method->email;
 424   $email_form->{cc}   = $self->order->$cv_method->cc;
 425   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 426   # Todo: get addresses from shipto, if any
 427
 428   my $form = Form->new;
 429   $form->{$self->nr_key()}  = $self->order->number;
 430   $form->{cusordnumber}     = $self->order->cusordnumber;
 431   $form->{formname}         = $self->type;
 432   $form->{type}             = $self->type;
 433   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 434   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 435   $form->{format}           = 'pdf';
 436   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 437
 438   $email_form->{subject}             = $form->generate_email_subject();
 439   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 440   $email_form->{message}             = $form->generate_email_body();
 441   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 442
 443   my %files = $self->get_files_for_email_dialog();
 444
 445   my @employees_with_email = grep {
 446     my $user = SL::DB::Manager::AuthUser->find_by(login => $_->login);
 447     $user && !!trim($user->get_config_value('email'));
 448   } @{ SL::DB::Manager::Employee->get_all_sorted(query => [ deleted => 0 ]) };
 449
 450
 451   my $all_partner_email_addresses = $self->order->customervendor->get_all_email_addresses();
 452
 453   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 454                                   email_form    => $email_form,
 455                                   show_bcc      => $::auth->assert('email_bcc', 'may fail'),
 456                                   FILES         => \%files,
 457                                   is_customer   => $self->cv eq 'customer',
 458                                   ALL_EMPLOYEES => \@employees_with_email,
 459                                   ALL_PARTNER_EMAIL_ADDRESSES => $all_partner_email_addresses,
 460   );
 461
 462   $self->js
 463       ->run('kivi.Order.show_email_dialog', $dialog_html)
 464       ->reinit_widgets
 465       ->render($self);
 466 }
 467
 468 # send email
 469 #
 470 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 471 sub action_send_email {
 472   my ($self) = @_;
 473
 474   my $errors = $self->save();
 475
 476   if (scalar @{ $errors }) {
 477     $self->js->run('kivi.Order.close_email_dialog');
 478     $self->js->flash('error', $_) foreach @{ $errors };
 479     return $self->js->render();
 480   }
 481
 482   $self->js_reset_order_and_item_ids_after_save;
 483
 484   my $email_form  = delete $::form->{email_form};
 485
 486   if ($email_form->{additional_to}) {
 487     $email_form->{to} = join ', ', grep { $_ } $email_form->{to}, @{$email_form->{additional_to}};
 488     delete $email_form->{additional_to};
 489   }
 490
 491   my %field_names = (to => 'email');
 492
 493   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 494
 495   # for Form::cleanup which may be called in Form::send_email
 496   $::form->{cwd}    = getcwd();
 497   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 498
 499   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 500   $::form->{media}  = 'email';
 501
 502   $::form->{attachment_policy} //= '';
 503
 504   # Is an old file version available?
 505   my $attfile;
 506   if ($::form->{attachment_policy} eq 'old_file') {
 507     $attfile = SL::File->get_all(object_id     => $self->order->id,
 508                                  object_type   => $self->type,
 509                                  file_type     => 'document',
 510                                  print_variant => $::form->{formname});
 511   }
 512
 513   if ($::form->{attachment_policy} ne 'no_file' && !($::form->{attachment_policy} eq 'old_file' && $attfile)) {
 514     my $doc;
 515     my @errors = $self->generate_doc(\$doc, {media      => $::form->{media},
 516                                              format     => $::form->{print_options}->{format},
 517                                              formname   => $::form->{print_options}->{formname},
 518                                              language   => $self->order->language,
 519                                              printer_id => $::form->{print_options}->{printer_id},
 520                                              groupitems => $::form->{print_options}->{groupitems}});
 521     if (scalar @errors) {
 522       return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render($self);
 523     }
 524
 525     my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $::form->{attachment_filename}, $::form->{formname});
 526     if (scalar @warnings) {
 527       flash_later('warning', $_) for @warnings;
 528     }
 529
 530     my $sfile = SL::SessionFile::Random->new(mode => "w");
 531     $sfile->fh->print($doc);
 532     $sfile->fh->close;
 533
 534     $::form->{tmpfile} = $sfile->file_name;
 535     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 536   }
 537
 538   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 539   $::form->send_email(\%::myconfig, $::form->{print_options}->{format});
 540
 541   # internal notes unless no email journal
 542   unless ($::instance_conf->get_email_journal) {
 543     my $intnotes = $self->order->intnotes;
 544     $intnotes   .= "\n\n" if $self->order->intnotes;
 545     $intnotes   .= t8('[email]')                                                                                        . "\n";
 546     $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 547     $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 548     $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 549     $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 550     $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 551     $intnotes   .= t8('Message')    . ": " . SL::HTML::Util->strip($::form->{message});
 552
 553     $self->order->update_attributes(intnotes => $intnotes);
 554   }
 555
 556   $self->save_history('MAILED');
 557
 558   flash_later('info', t8('The email has been sent.'));
 559
 560   my @redirect_params = (
 561     action => 'edit',
 562     type   => $self->type,
 563     id     => $self->order->id,
 564   );
 565
 566   $self->redirect_to(@redirect_params);
 567 }
 568
 569 # open the periodic invoices config dialog
 570 #
 571 # If there are values in the form (i.e. dialog was opened before),
 572 # then use this values. Create new ones, else.
 573 sub action_show_periodic_invoices_config_dialog {
 574   my ($self) = @_;
 575
 576   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 577   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 578   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 579                                                    order_value_periodicity => 'p', # = same as periodicity
 580                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 581                                                    extend_automatically_by => 12,
 582                                                    active                  => 1,
 583                                                    email_subject           => GenericTranslations->get(
 584                                                                                 language_id      => $::form->{language_id},
 585                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 586                                                    email_body              => GenericTranslations->get(
 587                                                                                 language_id      => $::form->{language_id},
 588                                                                                 translation_type => "salutation_general")
 589                                                                             . GenericTranslations->get(
 590                                                                                 language_id      => $::form->{language_id},
 591                                                                                 translation_type => "salutation_punctuation_mark") . "\n\n"
 592                                                                             . GenericTranslations->get(
 593                                                                                 language_id      => $::form->{language_id},
 594                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 595   );
 596   # for older configs, replace email preset text if not yet set.
 597   $config->email_subject(GenericTranslations->get(
 598                                               language_id      => $::form->{language_id},
 599                                               translation_type =>"preset_text_periodic_invoices_email_subject")
 600                         ) unless $config->email_subject;
 601
 602   $config->email_body(GenericTranslations->get(
 603                                               language_id      => $::form->{language_id},
 604                                               translation_type => "salutation_general")
 605                     . GenericTranslations->get(
 606                                               language_id      => $::form->{language_id},
 607                                               translation_type => "salutation_punctuation_mark") . "\n\n"
 608                     . GenericTranslations->get(
 609                                               language_id      => $::form->{language_id},
 610                                               translation_type =>"preset_text_periodic_invoices_email_body")
 611                      ) unless $config->email_body;
 612
 613   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 614   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 615
 616   $::form->get_lists(printers => "ALL_PRINTERS",
 617                      charts   => { key       => 'ALL_CHARTS',
 618                                    transdate => 'current_date' });
 619
 620   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 621
 622   if ($::form->{customer_id}) {
 623     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 624     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 625     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 626     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 627     $config->send_email(0) if $::form->{postal_invoice};
 628   }
 629
 630   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 631                 popup_dialog             => 1,
 632                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 633                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 634                 config                   => $config,
 635                 %$::form);
 636 }
 637
 638 # assign the values of the periodic invoices config dialog
 639 # as yaml in the hidden tag and set the status.
 640 sub action_assign_periodic_invoices_config {
 641   my ($self) = @_;
 642
 643   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 644
 645   my $config = { active                     => $::form->{active}       ? 1 : 0,
 646                  terminated                 => $::form->{terminated}   ? 1 : 0,
 647                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 648                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 649                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 650                  start_date_as_date         => $::form->{start_date_as_date},
 651                  end_date_as_date           => $::form->{end_date_as_date},
 652                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 653                  print                      => $::form->{print}      ? 1                         : 0,
 654                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 655                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 656                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 657                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 658                  send_email                 => $::form->{send_email} ? 1 : 0,
 659                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 660                  email_recipient_address    => $::form->{email_recipient_address},
 661                  email_sender               => $::form->{email_sender},
 662                  email_subject              => $::form->{email_subject},
 663                  email_body                 => $::form->{email_body},
 664                };
 665
 666   my $periodic_invoices_config = SL::YAML::Dump($config);
 667
 668   my $status = $self->get_periodic_invoices_status($config);
 669
 670   $self->js
 671     ->remove('#order_periodic_invoices_config')
 672     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 673     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 674     ->html('#periodic_invoices_status', $status)
 675     ->flash('info', t8('The periodic invoices config has been assigned.'))
 676     ->render($self);
 677 }
 678
 679 sub action_get_has_active_periodic_invoices {
 680   my ($self) = @_;
 681
 682   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 683   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 684
 685   my $has_active_periodic_invoices =
 686        $self->type eq sales_order_type()
 687     && $config
 688     && $config->active
 689     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 690     && $config->get_previous_billed_period_start_date;
 691
 692   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 693 }
 694
 695 # save the order and redirect to the frontend subroutine for a new
 696 # delivery order
 697 sub action_save_and_delivery_order {
 698   my ($self) = @_;
 699
 700   $self->save_and_redirect_to(
 701     controller => 'oe.pl',
 702     action     => 'oe_delivery_order_from_order',
 703   );
 704 }
 705
 706 sub action_save_and_supplier_delivery_order {
 707   my ($self) = @_;
 708
 709   $self->save_and_redirect_to(
 710     controller => 'controller.pl',
 711     action     => 'DeliveryOrder/add_from_order',
 712     type       => 'supplier_delivery_order',
 713   );
 714 }
 715
 716 # save the order and redirect to the frontend subroutine for a new
 717 # invoice
 718 sub action_save_and_invoice {
 719   my ($self) = @_;
 720
 721   $self->save_and_redirect_to(
 722     controller => 'oe.pl',
 723     action     => 'oe_invoice_from_order',
 724   );
 725 }
 726
 727 sub action_save_and_invoice_for_advance_payment {
 728   my ($self) = @_;
 729
 730   $self->save_and_redirect_to(
 731     controller       => 'oe.pl',
 732     action           => 'oe_invoice_from_order',
 733     new_invoice_type => 'invoice_for_advance_payment',
 734   );
 735 }
 736
 737 sub action_save_and_final_invoice {
 738   my ($self) = @_;
 739
 740   $self->save_and_redirect_to(
 741     controller       => 'oe.pl',
 742     action           => 'oe_invoice_from_order',
 743     new_invoice_type => 'final_invoice',
 744   );
 745 }
 746
 747 # workflow from sales order to sales quotation
 748 sub action_sales_quotation {
 749   $_[0]->workflow_sales_or_request_for_quotation();
 750 }
 751
 752 # workflow from sales order to sales quotation
 753 sub action_request_for_quotation {
 754   $_[0]->workflow_sales_or_request_for_quotation();
 755 }
 756
 757 # workflow from sales quotation to sales order
 758 sub action_sales_order {
 759   $_[0]->workflow_sales_or_purchase_order();
 760 }
 761
 762 # workflow from rfq to purchase order
 763 sub action_purchase_order {
 764   $_[0]->workflow_sales_or_purchase_order();
 765 }
 766
 767 # workflow from purchase order to ap transaction
 768 sub action_save_and_ap_transaction {
 769   my ($self) = @_;
 770
 771   $self->save_and_redirect_to(
 772     controller => 'ap.pl',
 773     action     => 'add_from_purchase_order',
 774   );
 775 }
 776
 777 # set form elements in respect to a changed customer or vendor
 778 #
 779 # This action is called on an change of the customer/vendor picker.
 780 sub action_customer_vendor_changed {
 781   my ($self) = @_;
 782
 783   setup_order_from_cv($self->order);
 784   $self->recalc();
 785
 786   my $cv_method = $self->cv;
 787
 788   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 789     $self->js->show('#cp_row');
 790   } else {
 791     $self->js->hide('#cp_row');
 792   }
 793
 794   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 795     $self->js->show('#shipto_selection');
 796   } else {
 797     $self->js->hide('#shipto_selection');
 798   }
 799
 800   if ($cv_method eq 'customer') {
 801     my $show_hide = scalar @{ $self->order->customer->additional_billing_addresses } > 0 ? 'show' : 'hide';
 802     $self->js->$show_hide('#billing_address_row');
 803   }
 804
 805   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 806
 807   $self->js
 808     ->replaceWith('#order_cp_id',              $self->build_contact_select)
 809     ->replaceWith('#order_shipto_id',          $self->build_shipto_select)
 810     ->replaceWith('#shipto_inputs  ',          $self->build_shipto_inputs)
 811     ->replaceWith('#order_billing_address_id', $self->build_billing_address_select)
 812     ->replaceWith('#business_info_row',        $self->build_business_info_row)
 813     ->val(        '#order_taxzone_id',         $self->order->taxzone_id)
 814     ->val(        '#order_taxincluded',        $self->order->taxincluded)
 815     ->val(        '#order_currency_id',        $self->order->currency_id)
 816     ->val(        '#order_payment_id',         $self->order->payment_id)
 817     ->val(        '#order_delivery_term_id',   $self->order->delivery_term_id)
 818     ->val(        '#order_intnotes',           $self->order->intnotes)
 819     ->val(        '#order_language_id',        $self->order->$cv_method->language_id)
 820     ->focus(      '#order_' . $self->cv . '_id')
 821     ->run('kivi.Order.update_exchangerate');
 822
 823   $self->js_redisplay_amounts_and_taxes;
 824   $self->js_redisplay_cvpartnumbers;
 825   $self->js->render();
 826 }
 827
 828 # open the dialog for customer/vendor details
 829 sub action_show_customer_vendor_details_dialog {
 830   my ($self) = @_;
 831
 832   my $is_customer = 'customer' eq $::form->{vc};
 833   my $cv;
 834   if ($is_customer) {
 835     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 836   } else {
 837     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 838   }
 839
 840   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 841   $details{discount_as_percent} = $cv->discount_as_percent;
 842   $details{creditlimt}          = $cv->creditlimit_as_number;
 843   $details{business}            = $cv->business->description      if $cv->business;
 844   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 845   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 846   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 847   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 848
 849   if ($is_customer) {
 850     foreach my $entry (@{ $cv->additional_billing_addresses }) {
 851       push @{ $details{ADDITIONAL_BILLING_ADDRESSES} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 852     }
 853   }
 854   foreach my $entry (@{ $cv->shipto }) {
 855     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 856   }
 857   foreach my $entry (@{ $cv->contacts }) {
 858     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 859   }
 860
 861   $_[0]->render('common/show_vc_details', { layout => 0 },
 862                 is_customer => $is_customer,
 863                 %details);
 864
 865 }
 866
 867 # called if a unit in an existing item row is changed
 868 sub action_unit_changed {
 869   my ($self) = @_;
 870
 871   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 872   my $item = $self->order->items_sorted->[$idx];
 873
 874   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 875   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 876
 877   $self->recalc();
 878
 879   $self->js
 880     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 881   $self->js_redisplay_line_values;
 882   $self->js_redisplay_amounts_and_taxes;
 883   $self->js->render();
 884 }
 885
 886 # add an item row for a new item entered in the input row
 887 sub action_add_item {
 888   my ($self) = @_;
 889
 890   delete $::form->{add_item}->{create_part_type};
 891
 892   my $form_attr = $::form->{add_item};
 893
 894   return unless $form_attr->{parts_id};
 895
 896   my $item = new_item($self->order, $form_attr);
 897
 898   $self->order->add_items($item);
 899
 900   $self->recalc();
 901
 902   $self->get_item_cvpartnumber($item);
 903
 904   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 905   my $row_as_html = $self->p->render('order/tabs/_row',
 906                                      ITEM => $item,
 907                                      ID   => $item_id,
 908                                      SELF => $self,
 909   );
 910
 911   if ($::form->{insert_before_item_id}) {
 912     $self->js
 913       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 914   } else {
 915     $self->js
 916       ->append('#row_table_id', $row_as_html);
 917   }
 918
 919   if ( $item->part->is_assortment ) {
 920     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 921     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 922       my $attr = { parts_id => $assortment_item->parts_id,
 923                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 924                    unit     => $assortment_item->unit,
 925                    description => $assortment_item->part->description,
 926                  };
 927       my $item = new_item($self->order, $attr);
 928
 929       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 930       $item->discount(1) unless $assortment_item->charge;
 931
 932       $self->order->add_items( $item );
 933       $self->recalc();
 934       $self->get_item_cvpartnumber($item);
 935       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 936       my $row_as_html = $self->p->render('order/tabs/_row',
 937                                          ITEM => $item,
 938                                          ID   => $item_id,
 939                                          SELF => $self,
 940       );
 941       if ($::form->{insert_before_item_id}) {
 942         $self->js
 943           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 944       } else {
 945         $self->js
 946           ->append('#row_table_id', $row_as_html);
 947       }
 948     };
 949   };
 950
 951   $self->js
 952     ->val('.add_item_input', '')
 953     ->run('kivi.Order.init_row_handlers')
 954     ->run('kivi.Order.renumber_positions')
 955     ->focus('#add_item_parts_id_name');
 956
 957   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 958
 959   $self->js_redisplay_amounts_and_taxes;
 960   $self->js->render();
 961 }
 962
 963 # add item rows for multiple items at once
 964 sub action_add_multi_items {
 965   my ($self) = @_;
 966
 967   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 968   return $self->js->render() unless scalar @form_attr;
 969
 970   my @items;
 971   foreach my $attr (@form_attr) {
 972     my $item = new_item($self->order, $attr);
 973     push @items, $item;
 974     if ( $item->part->is_assortment ) {
 975       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 976         my $attr = { parts_id => $assortment_item->parts_id,
 977                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 978                      unit     => $assortment_item->unit,
 979                      description => $assortment_item->part->description,
 980                    };
 981         my $item = new_item($self->order, $attr);
 982
 983         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 984         $item->discount(1) unless $assortment_item->charge;
 985         push @items, $item;
 986       }
 987     }
 988   }
 989   $self->order->add_items(@items);
 990
 991   $self->recalc();
 992
 993   foreach my $item (@items) {
 994     $self->get_item_cvpartnumber($item);
 995     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 996     my $row_as_html = $self->p->render('order/tabs/_row',
 997                                        ITEM => $item,
 998                                        ID   => $item_id,
 999                                        SELF => $self,
1000     );
1001
1002     if ($::form->{insert_before_item_id}) {
1003       $self->js
1004         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
1005     } else {
1006       $self->js
1007         ->append('#row_table_id', $row_as_html);
1008     }
1009   }
1010
1011   $self->js
1012     ->run('kivi.Part.close_picker_dialogs')
1013     ->run('kivi.Order.init_row_handlers')
1014     ->run('kivi.Order.renumber_positions')
1015     ->focus('#add_item_parts_id_name');
1016
1017   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
1018
1019   $self->js_redisplay_amounts_and_taxes;
1020   $self->js->render();
1021 }
1022
1023 # recalculate all linetotals, amounts and taxes and redisplay them
1024 sub action_recalc_amounts_and_taxes {
1025   my ($self) = @_;
1026
1027   $self->recalc();
1028
1029   $self->js_redisplay_line_values;
1030   $self->js_redisplay_amounts_and_taxes;
1031   $self->js->render();
1032 }
1033
1034 sub action_update_exchangerate {
1035   my ($self) = @_;
1036
1037   my $data = {
1038     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
1039     currency_name => $self->order->currency->name,
1040     exchangerate  => $self->order->daily_exchangerate_as_null_number,
1041   };
1042
1043   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
1044 }
1045
1046 # redisplay item rows if they are sorted by an attribute
1047 sub action_reorder_items {
1048   my ($self) = @_;
1049
1050   my %sort_keys = (
1051     partnumber   => sub { $_[0]->part->partnumber },
1052     description  => sub { $_[0]->description },
1053     qty          => sub { $_[0]->qty },
1054     sellprice    => sub { $_[0]->sellprice },
1055     discount     => sub { $_[0]->discount },
1056     cvpartnumber => sub { $_[0]->{cvpartnumber} },
1057   );
1058
1059   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1060
1061   my $method = $sort_keys{$::form->{order_by}};
1062   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
1063   if ($::form->{sort_dir}) {
1064     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1065       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
1066     } else {
1067       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
1068     }
1069   } else {
1070     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1071       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
1072     } else {
1073       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
1074     }
1075   }
1076   $self->js
1077     ->run('kivi.Order.redisplay_items', \@to_sort)
1078     ->render;
1079 }
1080
1081 # show the popup to choose a price/discount source
1082 sub action_price_popup {
1083   my ($self) = @_;
1084
1085   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
1086   my $item = $self->order->items_sorted->[$idx];
1087
1088   $self->render_price_dialog($item);
1089 }
1090
1091 # save the order in a session variable and redirect to the part controller
1092 sub action_create_part {
1093   my ($self) = @_;
1094
1095   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
1096
1097   my $callback     = $self->url_for(
1098     action       => 'return_from_create_part',
1099     type         => $self->type, # type is needed for check_auth on return
1100     previousform => $previousform,
1101   );
1102
1103   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
1104
1105   my @redirect_params = (
1106     controller => 'Part',
1107     action     => 'add',
1108     part_type  => $::form->{add_item}->{create_part_type},
1109     callback   => $callback,
1110     show_abort => 1,
1111   );
1112
1113   $self->redirect_to(@redirect_params);
1114 }
1115
1116 sub action_return_from_create_part {
1117   my ($self) = @_;
1118
1119   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1120
1121   $::auth->restore_form_from_session(delete $::form->{previousform});
1122
1123   # set item ids to new fake id, to identify them as new items
1124   foreach my $item (@{$self->order->items_sorted}) {
1125     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1126   }
1127
1128   $self->recalc();
1129   $self->get_unalterable_data();
1130   $self->pre_render();
1131
1132   # trigger rendering values for second row/longdescription as hidden,
1133   # because they are loaded only on demand. So we need to keep the values
1134   # from the source.
1135   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1136   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1137
1138   $self->render(
1139     'order/form',
1140     title => $self->get_title_for('edit'),
1141     %{$self->{template_args}}
1142   );
1143
1144 }
1145
1146 # load the second row for one or more items
1147 #
1148 # This action gets the html code for all items second rows by rendering a template for
1149 # the second row and sets the html code via client js.
1150 sub action_load_second_rows {
1151   my ($self) = @_;
1152
1153   $self->recalc() if $self->order->is_sales; # for margin calculation
1154
1155   foreach my $item_id (@{ $::form->{item_ids} }) {
1156     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1157     my $item = $self->order->items_sorted->[$idx];
1158
1159     $self->js_load_second_row($item, $item_id, 0);
1160   }
1161
1162   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1163
1164   $self->js->render();
1165 }
1166
1167 # update description, notes and sellprice from master data
1168 sub action_update_row_from_master_data {
1169   my ($self) = @_;
1170
1171   foreach my $item_id (@{ $::form->{item_ids} }) {
1172     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1173     my $item  = $self->order->items_sorted->[$idx];
1174     my $texts = get_part_texts($item->part, $self->order->language_id);
1175
1176     $item->description($texts->{description});
1177     $item->longdescription($texts->{longdescription});
1178
1179     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1180
1181     my $price_src;
1182     if ($item->part->is_assortment) {
1183     # add assortment items with price 0, as the components carry the price
1184       $price_src = $price_source->price_from_source("");
1185       $price_src->price(0);
1186     } else {
1187       $price_src = $price_source->best_price
1188                  ? $price_source->best_price
1189                  : $price_source->price_from_source("");
1190       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1191       $price_src->price(0) if !$price_source->best_price;
1192     }
1193
1194
1195     $item->sellprice($price_src->price);
1196     $item->active_price_source($price_src);
1197
1198     $self->js
1199       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1200       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1201       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1202       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1203
1204     if ($self->search_cvpartnumber) {
1205       $self->get_item_cvpartnumber($item);
1206       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1207     }
1208   }
1209
1210   $self->recalc();
1211   $self->js_redisplay_line_values;
1212   $self->js_redisplay_amounts_and_taxes;
1213
1214   $self->js->render();
1215 }
1216
1217 sub js_load_second_row {
1218   my ($self, $item, $item_id, $do_parse) = @_;
1219
1220   if ($do_parse) {
1221     # Parse values from form (they are formated while rendering (template)).
1222     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1223     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1224     foreach my $var (@{ $item->cvars_by_config }) {
1225       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1226     }
1227     $item->parse_custom_variable_values;
1228   }
1229
1230   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1231
1232   $self->js
1233     ->html('#second_row_' . $item_id, $row_as_html)
1234     ->data('#second_row_' . $item_id, 'loaded', 1);
1235 }
1236
1237 sub js_redisplay_line_values {
1238   my ($self) = @_;
1239
1240   my $is_sales = $self->order->is_sales;
1241
1242   # sales orders with margins
1243   my @data;
1244   if ($is_sales) {
1245     @data = map {
1246       [
1247        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1248        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1249        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1250       ]} @{ $self->order->items_sorted };
1251   } else {
1252     @data = map {
1253       [
1254        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1255       ]} @{ $self->order->items_sorted };
1256   }
1257
1258   $self->js
1259     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1260 }
1261
1262 sub js_redisplay_amounts_and_taxes {
1263   my ($self) = @_;
1264
1265   if (scalar @{ $self->{taxes} }) {
1266     $self->js->show('#taxincluded_row_id');
1267   } else {
1268     $self->js->hide('#taxincluded_row_id');
1269   }
1270
1271   if ($self->order->taxincluded) {
1272     $self->js->hide('#subtotal_row_id');
1273   } else {
1274     $self->js->show('#subtotal_row_id');
1275   }
1276
1277   if ($self->order->is_sales) {
1278     my $is_neg = $self->order->marge_total < 0;
1279     $self->js
1280       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1281       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1282       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1283       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1284       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1285       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1286       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1287       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1288   }
1289
1290   $self->js
1291     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1292     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1293     ->remove('.tax_row')
1294     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1295 }
1296
1297 sub js_redisplay_cvpartnumbers {
1298   my ($self) = @_;
1299
1300   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1301
1302   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1303
1304   $self->js
1305     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1306 }
1307
1308 sub js_reset_order_and_item_ids_after_save {
1309   my ($self) = @_;
1310
1311   $self->js
1312     ->val('#id', $self->order->id)
1313     ->val('#converted_from_oe_id', '')
1314     ->val('#order_' . $self->nr_key(), $self->order->number);
1315
1316   my $idx = 0;
1317   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1318     next if !$self->order->items_sorted->[$idx]->id;
1319     next if $form_item_id !~ m{^new};
1320     $self->js
1321       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1322       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1323       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1324   } continue {
1325     $idx++;
1326   }
1327   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1328 }
1329
1330 #
1331 # helpers
1332 #
1333
1334 sub init_valid_types {
1335   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1336 }
1337
1338 sub init_type {
1339   my ($self) = @_;
1340
1341   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1342     die "Not a valid type for order";
1343   }
1344
1345   $self->type($::form->{type});
1346 }
1347
1348 sub init_cv {
1349   my ($self) = @_;
1350
1351   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1352          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1353          : die "Not a valid type for order";
1354
1355   return $cv;
1356 }
1357
1358 sub init_search_cvpartnumber {
1359   my ($self) = @_;
1360
1361   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1362   my $search_cvpartnumber;
1363   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1364   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1365
1366   return $search_cvpartnumber;
1367 }
1368
1369 sub init_show_update_button {
1370   my ($self) = @_;
1371
1372   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1373 }
1374
1375 sub init_p {
1376   SL::Presenter->get;
1377 }
1378
1379 sub init_order {
1380   $_[0]->make_order;
1381 }
1382
1383 sub init_all_price_factors {
1384   SL::DB::Manager::PriceFactor->get_all;
1385 }
1386
1387 sub init_part_picker_classification_ids {
1388   my ($self)    = @_;
1389   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1390
1391   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1392 }
1393
1394 sub check_auth {
1395   my ($self) = @_;
1396
1397   my $right_for = { map { $_ => $_.'_edit' . ' | ' . $_.'_view' } @{$self->valid_types} };
1398
1399   my $right   = $right_for->{ $self->type };
1400   $right    ||= 'DOES_NOT_EXIST';
1401
1402   $::auth->assert($right);
1403 }
1404
1405 sub check_auth_for_edit {
1406   my ($self) = @_;
1407
1408   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1409
1410   my $right   = $right_for->{ $self->type };
1411   $right    ||= 'DOES_NOT_EXIST';
1412
1413   $::auth->assert($right);
1414 }
1415
1416 # build the selection box for contacts
1417 #
1418 # Needed, if customer/vendor changed.
1419 sub build_contact_select {
1420   my ($self) = @_;
1421
1422   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1423     value_key  => 'cp_id',
1424     title_key  => 'full_name_dep',
1425     default    => $self->order->cp_id,
1426     with_empty => 1,
1427     style      => 'width: 300px',
1428   );
1429 }
1430
1431 # build the selection box for the additional billing address
1432 #
1433 # Needed, if customer/vendor changed.
1434 sub build_billing_address_select {
1435   my ($self) = @_;
1436
1437   return '' if $self->cv ne 'customer';
1438
1439   select_tag('order.billing_address_id',
1440              [ {displayable_id => '', id => ''}, $self->order->{$self->cv}->additional_billing_addresses ],
1441              value_key  => 'id',
1442              title_key  => 'displayable_id',
1443              default    => $self->order->billing_address_id,
1444              with_empty => 0,
1445              style      => 'width: 300px',
1446   );
1447 }
1448
1449 # build the selection box for shiptos
1450 #
1451 # Needed, if customer/vendor changed.
1452 sub build_shipto_select {
1453   my ($self) = @_;
1454
1455   select_tag('order.shipto_id',
1456              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1457              value_key  => 'shipto_id',
1458              title_key  => 'displayable_id',
1459              default    => $self->order->shipto_id,
1460              with_empty => 0,
1461              style      => 'width: 300px',
1462   );
1463 }
1464
1465 # build the inputs for the cusom shipto dialog
1466 #
1467 # Needed, if customer/vendor changed.
1468 sub build_shipto_inputs {
1469   my ($self) = @_;
1470
1471   my $content = $self->p->render('common/_ship_to_dialog',
1472                                  vc_obj      => $self->order->customervendor,
1473                                  cs_obj      => $self->order->custom_shipto,
1474                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1475                                  id_selector => '#order_shipto_id');
1476
1477   div_tag($content, id => 'shipto_inputs');
1478 }
1479
1480 # render the info line for business
1481 #
1482 # Needed, if customer/vendor changed.
1483 sub build_business_info_row
1484 {
1485   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1486 }
1487
1488 # build the rows for displaying taxes
1489 #
1490 # Called if amounts where recalculated and redisplayed.
1491 sub build_tax_rows {
1492   my ($self) = @_;
1493
1494   my $rows_as_html;
1495   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1496     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1497   }
1498   return $rows_as_html;
1499 }
1500
1501
1502 sub render_price_dialog {
1503   my ($self, $record_item) = @_;
1504
1505   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1506
1507   $self->js
1508     ->run(
1509       'kivi.io.price_chooser_dialog',
1510       t8('Available Prices'),
1511       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1512     )
1513     ->reinit_widgets;
1514
1515 #   if (@errors) {
1516 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1517 #     $self->js->show('#dialog_flash_error');
1518 #   }
1519
1520   $self->js->render;
1521 }
1522
1523 sub load_order {
1524   my ($self) = @_;
1525
1526   return if !$::form->{id};
1527
1528   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1529
1530   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1531   # You need a custom shipto object to call cvars_by_config to get the cvars.
1532   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1533
1534   return $self->order;
1535 }
1536
1537 # load or create a new order object
1538 #
1539 # And assign changes from the form to this object.
1540 # If the order is loaded from db, check if items are deleted in the form,
1541 # remove them form the object and collect them for removing from db on saving.
1542 # Then create/update items from form (via make_item) and add them.
1543 sub make_order {
1544   my ($self) = @_;
1545
1546   # add_items adds items to an order with no items for saving, but they cannot
1547   # be retrieved via items until the order is saved. Adding empty items to new
1548   # order here solves this problem.
1549   my $order;
1550   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1551   $order ||= SL::DB::Order->new(orderitems  => [],
1552                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1553                                 currency_id => $::instance_conf->get_currency_id(),);
1554
1555   my $cv_id_method = $self->cv . '_id';
1556   if (!$::form->{id} && $::form->{$cv_id_method}) {
1557     $order->$cv_id_method($::form->{$cv_id_method});
1558     setup_order_from_cv($order);
1559   }
1560
1561   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1562   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1563
1564   $order->assign_attributes(%{$::form->{order}});
1565
1566   $self->setup_custom_shipto_from_form($order, $::form);
1567
1568   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1569     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1570     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1571   }
1572
1573   # remove deleted items
1574   $self->item_ids_to_delete([]);
1575   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1576     my $item = $order->orderitems->[$idx];
1577     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1578       splice @{$order->orderitems}, $idx, 1;
1579       push @{$self->item_ids_to_delete}, $item->id;
1580     }
1581   }
1582
1583   my @items;
1584   my $pos = 1;
1585   foreach my $form_attr (@{$form_orderitems}) {
1586     my $item = make_item($order, $form_attr);
1587     $item->position($pos);
1588     push @items, $item;
1589     $pos++;
1590   }
1591   $order->add_items(grep {!$_->id} @items);
1592
1593   return $order;
1594 }
1595
1596 # create or update items from form
1597 #
1598 # Make item objects from form values. For items already existing read from db.
1599 # Create a new item else. And assign attributes.
1600 sub make_item {
1601   my ($record, $attr) = @_;
1602
1603   my $item;
1604   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1605
1606   my $is_new = !$item;
1607
1608   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1609   # they cannot be retrieved via custom_variables until the order/orderitem is
1610   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1611   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1612
1613   $item->assign_attributes(%$attr);
1614
1615   if ($is_new) {
1616     my $texts = get_part_texts($item->part, $record->language_id);
1617     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1618     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1619     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1620   }
1621
1622   return $item;
1623 }
1624
1625 # create a new item
1626 #
1627 # This is used to add one item
1628 sub new_item {
1629   my ($record, $attr) = @_;
1630
1631   my $item = SL::DB::OrderItem->new;
1632
1633   # Remove attributes where the user left or set the inputs empty.
1634   # So these attributes will be undefined and we can distinguish them
1635   # from zero later on.
1636   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1637     delete $attr->{$_} if $attr->{$_} eq '';
1638   }
1639
1640   $item->assign_attributes(%$attr);
1641
1642   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1643   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1644
1645   $item->unit($part->unit) if !$item->unit;
1646
1647   my $price_src;
1648   if ( $part->is_assortment ) {
1649     # add assortment items with price 0, as the components carry the price
1650     $price_src = $price_source->price_from_source("");
1651     $price_src->price(0);
1652   } elsif (defined $item->sellprice) {
1653     $price_src = $price_source->price_from_source("");
1654     $price_src->price($item->sellprice);
1655   } else {
1656     $price_src = $price_source->best_price
1657                ? $price_source->best_price
1658                : $price_source->price_from_source("");
1659     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1660     $price_src->price(0) if !$price_source->best_price;
1661   }
1662
1663   my $discount_src;
1664   if (defined $item->discount) {
1665     $discount_src = $price_source->discount_from_source("");
1666     $discount_src->discount($item->discount);
1667   } else {
1668     $discount_src = $price_source->best_discount
1669                   ? $price_source->best_discount
1670                   : $price_source->discount_from_source("");
1671     $discount_src->discount(0) if !$price_source->best_discount;
1672   }
1673
1674   my %new_attr;
1675   $new_attr{part}                   = $part;
1676   $new_attr{description}            = $part->description     if ! $item->description;
1677   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1678   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1679   $new_attr{sellprice}              = $price_src->price;
1680   $new_attr{discount}               = $discount_src->discount;
1681   $new_attr{active_price_source}    = $price_src;
1682   $new_attr{active_discount_source} = $discount_src;
1683   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1684   $new_attr{project_id}             = $record->globalproject_id;
1685   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1686
1687   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1688   # they cannot be retrieved via custom_variables until the order/orderitem is
1689   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1690   $new_attr{custom_variables} = [];
1691
1692   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1693
1694   $item->assign_attributes(%new_attr, %{ $texts });
1695
1696   return $item;
1697 }
1698
1699 sub setup_order_from_cv {
1700   my ($order) = @_;
1701
1702   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id language_id));
1703
1704   $order->intnotes($order->customervendor->notes);
1705
1706   return if !$order->is_sales;
1707
1708   $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1709   $order->taxincluded(defined($order->customer->taxincluded_checked)
1710                       ? $order->customer->taxincluded_checked
1711                       : $::myconfig{taxincluded_checked});
1712
1713   my $address = $order->customer->default_billing_address;;
1714   $order->billing_address_id($address ? $address->id : undef);
1715 }
1716
1717 # setup custom shipto from form
1718 #
1719 # The dialog returns form variables starting with 'shipto' and cvars starting
1720 # with 'shiptocvar_'.
1721 # Mark it to be deleted if a shipto from master data is selected
1722 # (i.e. order has a shipto).
1723 # Else, update or create a new custom shipto. If the fields are empty, it
1724 # will not be saved on save.
1725 sub setup_custom_shipto_from_form {
1726   my ($self, $order, $form) = @_;
1727
1728   if ($order->shipto) {
1729     $self->is_custom_shipto_to_delete(1);
1730   } else {
1731     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1732
1733     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1734     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1735
1736     $custom_shipto->assign_attributes(%$shipto_attrs);
1737     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1738   }
1739 }
1740
1741 # recalculate prices and taxes
1742 #
1743 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1744 sub recalc {
1745   my ($self) = @_;
1746
1747   my %pat = $self->order->calculate_prices_and_taxes();
1748
1749   $self->{taxes} = [];
1750   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1751     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1752
1753     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1754                                 netamount => $netamount,
1755                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1756   }
1757   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1758 }
1759
1760 # get data for saving, printing, ..., that is not changed in the form
1761 #
1762 # Only cvars for now.
1763 sub get_unalterable_data {
1764   my ($self) = @_;
1765
1766   foreach my $item (@{ $self->order->items }) {
1767     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1768     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1769     foreach my $var (@{ $item->cvars_by_config }) {
1770       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1771     }
1772     $item->parse_custom_variable_values;
1773   }
1774 }
1775
1776 # delete the order
1777 #
1778 # And remove related files in the spool directory
1779 sub delete {
1780   my ($self) = @_;
1781
1782   my $errors = [];
1783   my $db     = $self->order->db;
1784
1785   $db->with_transaction(
1786     sub {
1787       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1788       $self->order->delete;
1789       my $spool = $::lx_office_conf{paths}->{spool};
1790       unlink map { "$spool/$_" } @spoolfiles if $spool;
1791
1792       $self->save_history('DELETED');
1793
1794       1;
1795   }) || push(@{$errors}, $db->error);
1796
1797   return $errors;
1798 }
1799
1800 # save the order
1801 #
1802 # And delete items that are deleted in the form.
1803 sub save {
1804   my ($self) = @_;
1805
1806   my $errors = [];
1807   my $db     = $self->order->db;
1808
1809   $db->with_transaction(sub {
1810     # delete custom shipto if it is to be deleted or if it is empty
1811     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1812       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1813       $self->order->custom_shipto(undef);
1814     }
1815
1816     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1817     $self->order->save(cascade => 1);
1818
1819     # link records
1820     if ($::form->{converted_from_oe_id}) {
1821       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1822
1823       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1824         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1825         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1826         $src->link_to_record($self->order);
1827       }
1828       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1829         my $idx = 0;
1830         foreach (@{ $self->order->items_sorted }) {
1831           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1832           next if !$from_id;
1833           SL::DB::RecordLink->new(from_table => 'orderitems',
1834                                   from_id    => $from_id,
1835                                   to_table   => 'orderitems',
1836                                   to_id      => $_->id
1837           )->save;
1838           $idx++;
1839         }
1840       }
1841
1842       $self->link_requirement_specs_linking_to_created_from_objects(@converted_from_oe_ids);
1843     }
1844
1845     $self->set_project_in_linked_requirement_specs if $self->order->globalproject_id;
1846
1847     $self->save_history('SAVED');
1848
1849     1;
1850   }) || push(@{$errors}, $db->error);
1851
1852   return $errors;
1853 }
1854
1855 sub workflow_sales_or_request_for_quotation {
1856   my ($self) = @_;
1857
1858   # always save
1859   my $errors = $self->save();
1860
1861   if (scalar @{ $errors }) {
1862     $self->js->flash('error', $_) for @{ $errors };
1863     return $self->js->render();
1864   }
1865
1866   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1867
1868   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1869   delete $::form->{id};
1870
1871   # no linked records from order to quotations
1872   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
1873
1874   # set item ids to new fake id, to identify them as new items
1875   foreach my $item (@{$self->order->items_sorted}) {
1876     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1877   }
1878
1879   # change form type
1880   $::form->{type} = $destination_type;
1881   $self->type($self->init_type);
1882   $self->cv  ($self->init_cv);
1883   $self->check_auth;
1884
1885   $self->recalc();
1886   $self->get_unalterable_data();
1887   $self->pre_render();
1888
1889   # trigger rendering values for second row as hidden, because they
1890   # are loaded only on demand. So we need to keep the values from the
1891   # source.
1892   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1893
1894   $self->render(
1895     'order/form',
1896     title => $self->get_title_for('edit'),
1897     %{$self->{template_args}}
1898   );
1899 }
1900
1901 sub workflow_sales_or_purchase_order {
1902   my ($self) = @_;
1903
1904   # always save
1905   my $errors = $self->save();
1906
1907   if (scalar @{ $errors }) {
1908     $self->js->flash('error', $_) foreach @{ $errors };
1909     return $self->js->render();
1910   }
1911
1912   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1913                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1914                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1915                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1916                        : '';
1917
1918   # check for direct delivery
1919   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1920   my $custom_shipto;
1921   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1922       && $::form->{use_shipto} && $self->order->shipto) {
1923     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1924   }
1925
1926   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1927   $self->{converted_from_oe_id} = delete $::form->{id};
1928
1929   # set item ids to new fake id, to identify them as new items
1930   foreach my $item (@{$self->order->items_sorted}) {
1931     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1932   }
1933
1934   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1935     if ($::form->{use_shipto}) {
1936       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1937     } else {
1938       # remove any custom shipto if not wanted
1939       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1940     }
1941   }
1942
1943   # change form type
1944   $::form->{type} = $destination_type;
1945   $self->type($self->init_type);
1946   $self->cv  ($self->init_cv);
1947   $self->check_auth;
1948
1949   $self->recalc();
1950   $self->get_unalterable_data();
1951   $self->pre_render();
1952
1953   # trigger rendering values for second row as hidden, because they
1954   # are loaded only on demand. So we need to keep the values from the
1955   # source.
1956   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1957
1958   $self->render(
1959     'order/form',
1960     title => $self->get_title_for('edit'),
1961     %{$self->{template_args}}
1962   );
1963 }
1964
1965
1966 sub pre_render {
1967   my ($self) = @_;
1968
1969   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1970   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1971   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1972   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted( query => [ or => [ obsolete => 0, id => $self->order->language_id ] ] );
1973   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1974                                                                                               deleted => 0 ] ],
1975                                                                            sort_by => 'name');
1976   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1977                                                                                               deleted => 0 ] ],
1978                                                                            sort_by => 'name');
1979   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1980                                                                                                         obsolete => 0 ] ]);
1981   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1982   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1983   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1984   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1985   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1986
1987   my $print_form = Form->new('');
1988   $print_form->{type}        = $self->type;
1989   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1990   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1991     form => $print_form,
1992     options => {dialog_name_prefix => 'print_options.',
1993                 show_headers       => 1,
1994                 no_queue           => 1,
1995                 no_postscript      => 1,
1996                 no_opendocument    => 0,
1997                 no_html            => 0},
1998   );
1999
2000   foreach my $item (@{$self->order->orderitems}) {
2001     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
2002     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
2003     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
2004   }
2005
2006   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
2007     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
2008     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
2009     # the value from db, which can be set manually or is set when linked delivery orders are saved.
2010     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
2011   }
2012
2013   if ($self->order->number && $::instance_conf->get_webdav) {
2014     my $webdav = SL::Webdav->new(
2015       type     => $self->type,
2016       number   => $self->order->number,
2017     );
2018     my @all_objects = $webdav->get_all_objects;
2019     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
2020                                                     type => t8('File'),
2021                                                     link => File::Spec->catfile($_->full_filedescriptor),
2022                                                 } } @all_objects;
2023   }
2024
2025   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
2026       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
2027     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
2028   }
2029   $self->{template_args}->{longdescription_dialog_size_percentage} = SL::Helper::UserPreferences::DisplayPreferences->new()->get_longdescription_dialog_size_percentage();
2030
2031   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
2032
2033   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.Validator kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
2034                                                          edit_periodic_invoices_config calculate_qty follow_up show_history);
2035   $self->setup_edit_action_bar;
2036 }
2037
2038 sub setup_edit_action_bar {
2039   my ($self, %params) = @_;
2040
2041   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
2042                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
2043                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
2044
2045   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
2046   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
2047
2048   my $has_invoice_for_advance_payment;
2049   if ($self->order->id && $self->type eq sales_order_type()) {
2050     my $lr = $self->order->linked_records(direction => 'to', to => ['Invoice']);
2051     $has_invoice_for_advance_payment = any {'SL::DB::Invoice' eq ref $_ && "invoice_for_advance_payment" eq $_->type} @$lr;
2052   }
2053
2054   my $has_final_invoice;
2055   if ($self->order->id && $self->type eq sales_order_type()) {
2056     my $lr = $self->order->linked_records(direction => 'to', to => ['Invoice']);
2057     $has_final_invoice               = any {'SL::DB::Invoice' eq ref $_ && "final_invoice" eq $_->type} @$lr;
2058   }
2059
2060   my $right_for         = { map { $_ => $_.'_edit' } @{$self->valid_types} };
2061   my $right             = $right_for->{ $self->type };
2062   $right              ||= 'DOES_NOT_EXIST';
2063   my $may_edit_create   = $::auth->assert($right, 'may fail');
2064
2065   for my $bar ($::request->layout->get('actionbar')) {
2066     $bar->add(
2067       combobox => [
2068         action => [
2069           t8('Save'),
2070           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
2071                                                     $::instance_conf->get_order_warn_no_deliverydate,
2072           ],
2073           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
2074                          @req_trans_cost_art, @req_cusordnumber,
2075           ],
2076           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2077         ],
2078         action => [
2079           t8('Save and Close'),
2080           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
2081                                                     $::instance_conf->get_order_warn_no_deliverydate,
2082                                                     1
2083           ],
2084           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
2085                          @req_trans_cost_art, @req_cusordnumber,
2086           ],
2087           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2088         ],
2089         action => [
2090           t8('Save as new'),
2091           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
2092           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2093                          @req_trans_cost_art, @req_cusordnumber,
2094           ],
2095           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.')
2096                      : !$self->order->id ? t8('This object has not been saved yet.')
2097                      :                     undef,
2098         ],
2099       ], # end of combobox "Save"
2100
2101       combobox => [
2102         action => [
2103           t8('Workflow'),
2104         ],
2105         action => [
2106           t8('Save and Quotation'),
2107           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
2108           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2109           only_if  => (any { $self->type eq $_ } (sales_order_type())),
2110           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2111         ],
2112         action => [
2113           t8('Save and RFQ'),
2114           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
2115           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
2116           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2117         ],
2118         action => [
2119           t8('Save and Sales Order'),
2120           submit   => [ '#order_form', { action => "Order/sales_order" } ],
2121           checks   => [ @req_trans_cost_art ],
2122           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
2123           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2124         ],
2125         action => [
2126           t8('Save and Purchase Order'),
2127           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
2128           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
2129           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
2130           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2131         ],
2132         action => [
2133           t8('Save and Delivery Order'),
2134           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2135                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2136                                                                                                                         ],
2137           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2138                          @req_trans_cost_art, @req_cusordnumber,
2139           ],
2140           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())),
2141           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2142         ],
2143         action => [
2144           t8('Save and Supplier Delivery Order'),
2145           call      => [ 'kivi.Order.save', 'save_and_supplier_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2146                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2147                                                                                                                         ],
2148           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2149                          @req_trans_cost_art, @req_cusordnumber,
2150           ],
2151           only_if   => (any { $self->type eq $_ } (purchase_order_type())),
2152           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2153         ],
2154         action => [
2155           t8('Save and Invoice'),
2156           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2157           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2158                          @req_trans_cost_art, @req_cusordnumber,
2159           ],
2160           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2161         ],
2162         action => [
2163           ($has_invoice_for_advance_payment ? t8('Save and Further Invoice for Advance Payment') : t8('Save and Invoice for Advance Payment')),
2164           call      => [ 'kivi.Order.save', 'save_and_invoice_for_advance_payment', $::instance_conf->get_order_warn_duplicate_parts ],
2165           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2166                          @req_trans_cost_art, @req_cusordnumber,
2167           ],
2168           disabled  => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2169                      : $has_final_invoice ? t8('This order has already a final invoice.')
2170                      :                      undef,
2171           only_if   => (any { $self->type eq $_ } (sales_order_type())),
2172         ],
2173         action => [
2174           t8('Save and Final Invoice'),
2175           call      => [ 'kivi.Order.save', 'save_and_final_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2176           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2177                          @req_trans_cost_art, @req_cusordnumber,
2178           ],
2179           disabled  => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2180                      : $has_final_invoice ? t8('This order has already a final invoice.')
2181                      :                      undef,
2182           only_if   => (any { $self->type eq $_ } (sales_order_type())) && $has_invoice_for_advance_payment,
2183         ],
2184         action => [
2185           t8('Save and AP Transaction'),
2186           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
2187           only_if   => (any { $self->type eq $_ } (purchase_order_type())),
2188           disabled  => !$may_edit_create  ? t8('You do not have the permissions to access this function.') : undef,
2189         ],
2190
2191       ], # end of combobox "Workflow"
2192
2193       combobox => [
2194         action => [
2195           t8('Export'),
2196         ],
2197         action => [
2198           t8('Save and preview PDF'),
2199           call     => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
2200                                                           $::instance_conf->get_order_warn_no_deliverydate,
2201                       ],
2202           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2203           disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.') : undef,
2204         ],
2205         action => [
2206           t8('Save and print'),
2207           call     => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
2208                                                          $::instance_conf->get_order_warn_no_deliverydate,
2209                       ],
2210           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2211           disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.') : undef,
2212         ],
2213         action => [
2214           t8('Save and E-mail'),
2215           id       => 'save_and_email_action',
2216           call     => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
2217                                                                          $::instance_conf->get_order_warn_no_deliverydate,
2218                       ],
2219           disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2220                     : !$self->order->id  ? t8('This object has not been saved yet.')
2221                     :                      undef,
2222         ],
2223         action => [
2224           t8('Download attachments of all parts'),
2225           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2226           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2227           only_if  => $::instance_conf->get_doc_storage,
2228         ],
2229       ], # end of combobox "Export"
2230
2231       action => [
2232         t8('Delete'),
2233         call     => [ 'kivi.Order.delete_order' ],
2234         confirm  => $::locale->text('Do you really want to delete this object?'),
2235         disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2236                   : !$self->order->id  ? t8('This object has not been saved yet.')
2237                   :                      undef,
2238         only_if  => $deletion_allowed,
2239       ],
2240
2241       combobox => [
2242         action => [
2243           t8('more')
2244         ],
2245         action => [
2246           t8('History'),
2247           call     => [ 'set_history_window', $self->order->id, 'id' ],
2248           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2249         ],
2250         action => [
2251           t8('Follow-Up'),
2252           call     => [ 'kivi.Order.follow_up_window' ],
2253           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2254           only_if  => $::auth->assert('productivity', 1),
2255         ],
2256       ], # end of combobox "more"
2257     );
2258   }
2259 }
2260
2261 sub generate_doc {
2262   my ($self, $doc_ref, $params) = @_;
2263
2264   my $order  = $self->order;
2265   my @errors = ();
2266
2267   my $print_form = Form->new('');
2268   $print_form->{type}        = $order->type;
2269   $print_form->{formname}    = $params->{formname} || $order->type;
2270   $print_form->{format}      = $params->{format}   || 'pdf';
2271   $print_form->{media}       = $params->{media}    || 'file';
2272   $print_form->{groupitems}  = $params->{groupitems};
2273   $print_form->{printer_id}  = $params->{printer_id};
2274   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2275
2276   $order->language($params->{language});
2277   $order->flatten_to_form($print_form, format_amounts => 1);
2278
2279   my $template_ext;
2280   my $template_type;
2281   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2282     $template_ext  = 'odt';
2283     $template_type = 'OpenDocument';
2284   } elsif ($print_form->{format} =~ m{html}i) {
2285     $template_ext  = 'html';
2286     $template_type = 'HTML';
2287   }
2288
2289   # search for the template
2290   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2291     name        => $print_form->{formname},
2292     extension   => $template_ext,
2293     email       => $print_form->{media} eq 'email',
2294     language    => $params->{language},
2295     printer_id  => $print_form->{printer_id},
2296   );
2297
2298   if (!defined $template_file) {
2299     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2300   }
2301
2302   return @errors if scalar @errors;
2303
2304   $print_form->throw_on_error(sub {
2305     eval {
2306       $print_form->prepare_for_printing;
2307
2308       $$doc_ref = SL::Helper::CreatePDF->create_pdf(
2309         format        => $print_form->{format},
2310         template_type => $template_type,
2311         template      => $template_file,
2312         variables     => $print_form,
2313         variable_content_types => {
2314           longdescription => 'html',
2315           partnotes       => 'html',
2316           notes           => 'html',
2317           $::form->get_variable_content_types_for_cvars,
2318         },
2319       );
2320       1;
2321     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2322   });
2323
2324   return @errors;
2325 }
2326
2327 sub get_files_for_email_dialog {
2328   my ($self) = @_;
2329
2330   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2331
2332   return %files if !$::instance_conf->get_doc_storage;
2333
2334   if ($self->order->id) {
2335     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2336     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2337     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2338     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2339   }
2340
2341   my @parts =
2342     uniq_by { $_->{id} }
2343     map {
2344       +{ id         => $_->part->id,
2345          partnumber => $_->part->partnumber }
2346     } @{$self->order->items_sorted};
2347
2348   foreach my $part (@parts) {
2349     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2350     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2351   }
2352
2353   foreach my $key (keys %files) {
2354     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2355   }
2356
2357   return %files;
2358 }
2359
2360 sub make_periodic_invoices_config_from_yaml {
2361   my ($yaml_config) = @_;
2362
2363   return if !$yaml_config;
2364   my $attr = SL::YAML::Load($yaml_config);
2365   return if 'HASH' ne ref $attr;
2366   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2367 }
2368
2369
2370 sub get_periodic_invoices_status {
2371   my ($self, $config) = @_;
2372
2373   return                      if $self->type ne sales_order_type();
2374   return t8('not configured') if !$config;
2375
2376   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2377              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2378              :                                                     die "Cannot get status of periodic invoices config";
2379
2380   return $active ? t8('active') : t8('inactive');
2381 }
2382
2383 sub get_title_for {
2384   my ($self, $action) = @_;
2385
2386   return '' if none { lc($action)} qw(add edit);
2387
2388   # for locales:
2389   # $::locale->text("Add Sales Order");
2390   # $::locale->text("Add Purchase Order");
2391   # $::locale->text("Add Quotation");
2392   # $::locale->text("Add Request for Quotation");
2393   # $::locale->text("Edit Sales Order");
2394   # $::locale->text("Edit Purchase Order");
2395   # $::locale->text("Edit Quotation");
2396   # $::locale->text("Edit Request for Quotation");
2397
2398   $action = ucfirst(lc($action));
2399   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2400        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2401        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2402        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2403        : '';
2404 }
2405
2406 sub get_item_cvpartnumber {
2407   my ($self, $item) = @_;
2408
2409   return if !$self->search_cvpartnumber;
2410   return if !$self->order->customervendor;
2411
2412   if ($self->cv eq 'vendor') {
2413     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2414     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2415   } elsif ($self->cv eq 'customer') {
2416     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2417     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2418   }
2419 }
2420
2421 sub get_part_texts {
2422   my ($part_or_id, $language_or_id, %defaults) = @_;
2423
2424   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2425   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2426   my $texts       = {
2427     description     => $defaults{description}     // $part->description,
2428     longdescription => $defaults{longdescription} // $part->notes,
2429   };
2430
2431   return $texts unless $language_id;
2432
2433   my $translation = SL::DB::Manager::Translation->get_first(
2434     where => [
2435       parts_id    => $part->id,
2436       language_id => $language_id,
2437     ]);
2438
2439   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2440   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2441
2442   return $texts;
2443 }
2444
2445 sub sales_order_type {
2446   'sales_order';
2447 }
2448
2449 sub purchase_order_type {
2450   'purchase_order';
2451 }
2452
2453 sub sales_quotation_type {
2454   'sales_quotation';
2455 }
2456
2457 sub request_quotation_type {
2458   'request_quotation';
2459 }
2460
2461 sub nr_key {
2462   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2463        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2464        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2465        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2466        : '';
2467 }
2468
2469 sub save_and_redirect_to {
2470   my ($self, %params) = @_;
2471
2472   my $errors = $self->save();
2473
2474   if (scalar @{ $errors }) {
2475     $self->js->flash('error', $_) foreach @{ $errors };
2476     return $self->js->render();
2477   }
2478
2479   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2480            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2481            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2482            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2483            : '';
2484   flash_later('info', $text);
2485
2486   $self->redirect_to(%params, id => $self->order->id);
2487 }
2488
2489 sub save_history {
2490   my ($self, $addition) = @_;
2491
2492   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2493   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2494
2495   SL::DB::History->new(
2496     trans_id    => $self->order->id,
2497     employee_id => SL::DB::Manager::Employee->current->id,
2498     what_done   => $self->order->type,
2499     snumbers    => $snumbers,
2500     addition    => $addition,
2501   )->save;
2502 }
2503
2504 sub store_doc_to_webdav_and_filemanagement {
2505   my ($self, $content, $filename, $variant) = @_;
2506
2507   my $order = $self->order;
2508   my @errors;
2509
2510   # copy file to webdav folder
2511   if ($order->number && $::instance_conf->get_webdav_documents) {
2512     my $webdav = SL::Webdav->new(
2513       type     => $order->type,
2514       number   => $order->number,
2515     );
2516     my $webdav_file = SL::Webdav::File->new(
2517       webdav   => $webdav,
2518       filename => $filename,
2519     );
2520     eval {
2521       $webdav_file->store(data => \$content);
2522       1;
2523     } or do {
2524       push @errors, t8('Storing the document to the WebDAV folder failed: #1', $@);
2525     };
2526   }
2527   if ($order->id && $::instance_conf->get_doc_storage) {
2528     eval {
2529       SL::File->save(object_id     => $order->id,
2530                      object_type   => $order->type,
2531                      mime_type     => SL::MIME->mime_type_from_ext($filename),
2532                      source        => 'created',
2533                      file_type     => 'document',
2534                      file_name     => $filename,
2535                      file_contents => $content,
2536                      print_variant => $variant);
2537       1;
2538     } or do {
2539       push @errors, t8('Storing the document in the storage backend failed: #1', $@);
2540     };
2541   }
2542
2543   return @errors;
2544 }
2545
2546 sub link_requirement_specs_linking_to_created_from_objects {
2547   my ($self, @converted_from_oe_ids) = @_;
2548
2549   return unless @converted_from_oe_ids;
2550
2551   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => \@converted_from_oe_ids ]);
2552   foreach my $rs_order (@{ $rs_orders }) {
2553     SL::DB::RequirementSpecOrder->new(
2554       order_id            => $self->order->id,
2555       requirement_spec_id => $rs_order->requirement_spec_id,
2556       version_id          => $rs_order->version_id,
2557     )->save;
2558   }
2559 }
2560
2561 sub set_project_in_linked_requirement_specs {
2562   my ($self) = @_;
2563
2564   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => $self->order->id ]);
2565   foreach my $rs_order (@{ $rs_orders }) {
2566     next if $rs_order->requirement_spec->project_id == $self->order->globalproject_id;
2567
2568     $rs_order->requirement_spec->update_attributes(project_id => $self->order->globalproject_id);
2569   }
2570 }
2571
2572 1;
2573
2574 __END__
2575
2576 =encoding utf-8
2577
2578 =head1 NAME
2579
2580 SL::Controller::Order - controller for orders
2581
2582 =head1 SYNOPSIS
2583
2584 This is a new form to enter orders, completely rewritten with the use
2585 of controller and java script techniques.
2586
2587 The aim is to provide the user a better experience and a faster workflow. Also
2588 the code should be more readable, more reliable and better to maintain.
2589
2590 =head2 Key Features
2591
2592 =over 4
2593
2594 =item *
2595
2596 One input row, so that input happens every time at the same place.
2597
2598 =item *
2599
2600 Use of pickers where possible.
2601
2602 =item *
2603
2604 Possibility to enter more than one item at once.
2605
2606 =item *
2607
2608 Item list in a scrollable area, so that the workflow buttons stay at
2609 the bottom.
2610
2611 =item *
2612
2613 Reordering item rows with drag and drop is possible. Sorting item rows is
2614 possible (by partnumber, description, qty, sellprice and discount for now).
2615
2616 =item *
2617
2618 No C<update> is necessary. All entries and calculations are managed
2619 with ajax-calls and the page only reloads on C<save>.
2620
2621 =item *
2622
2623 User can see changes immediately, because of the use of java script
2624 and ajax.
2625
2626 =back
2627
2628 =head1 CODE
2629
2630 =head2 Layout
2631
2632 =over 4
2633
2634 =item * C<SL/Controller/Order.pm>
2635
2636 the controller
2637
2638 =item * C<template/webpages/order/form.html>
2639
2640 main form
2641
2642 =item * C<template/webpages/order/tabs/basic_data.html>
2643
2644 Main tab for basic_data.
2645
2646 This is the only tab here for now. "linked records" and "webdav" tabs are
2647 reused from generic code.
2648
2649 =over 4
2650
2651 =item * C<template/webpages/order/tabs/_business_info_row.html>
2652
2653 For displaying information on business type
2654
2655 =item * C<template/webpages/order/tabs/_item_input.html>
2656
2657 The input line for items
2658
2659 =item * C<template/webpages/order/tabs/_row.html>
2660
2661 One row for already entered items
2662
2663 =item * C<template/webpages/order/tabs/_tax_row.html>
2664
2665 Displaying tax information
2666
2667 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2668
2669 Dialog for selecting price and discount sources
2670
2671 =back
2672
2673 =item * C<js/kivi.Order.js>
2674
2675 java script functions
2676
2677 =back
2678
2679 =head1 TODO
2680
2681 =over 4
2682
2683 =item * testing
2684
2685 =item * price sources: little symbols showing better price / better discount
2686
2687 =item * select units in input row?
2688
2689 =item * check for direct delivery (workflow sales order -> purchase order)
2690
2691 =item * access rights
2692
2693 =item * display weights
2694
2695 =item * mtime check
2696
2697 =item * optional client/user behaviour
2698
2699 (transactions has to be set - department has to be set -
2700  force project if enabled in client config)
2701
2702 =back
2703
2704 =head1 KNOWN BUGS AND CAVEATS
2705
2706 =over 4
2707
2708 =item *
2709
2710 Customer discount is not displayed as a valid discount in price source popup
2711 (this might be a bug in price sources)
2712
2713 (I cannot reproduce this (Bernd))
2714
2715 =item *
2716
2717 No indication that <shift>-up/down expands/collapses second row.
2718
2719 =item *
2720
2721 Inline creation of parts is not currently supported
2722
2723 =item *
2724
2725 Table header is not sticky in the scrolling area.
2726
2727 =item *
2728
2729 Sorting does not include C<position>, neither does reordering.
2730
2731 This behavior was implemented intentionally. But we can discuss, which behavior
2732 should be implemented.
2733
2734 =back
2735
2736 =head1 To discuss / Nice to have
2737
2738 =over 4
2739
2740 =item *
2741
2742 How to expand/collapse second row. Now it can be done clicking the icon or
2743 <shift>-up/down.
2744
2745 =item *
2746
2747 Possibility to select PriceSources in input row?
2748
2749 =item *
2750
2751 This controller uses a (changed) copy of the template for the PriceSource
2752 dialog. Maybe there could be used one code source.
2753
2754 =item *
2755
2756 Rounding-differences between this controller (PriceTaxCalculator) and the old
2757 form. This is not only a problem here, but also in all parts using the PTC.
2758 There exists a ticket and a patch. This patch should be testet.
2759
2760 =item *
2761
2762 An indicator, if the actual inputs are saved (like in an
2763 editor or on text processing application).
2764
2765 =item *
2766
2767 A warning when leaving the page without saveing unchanged inputs.
2768
2769
2770 =back
2771
2772 =head1 AUTHOR
2773
2774 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2775
2776 =cut