SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::HTML::Util;
   8 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   9 use SL::Locale::String qw(t8);
  10 use SL::SessionFile::Random;
  11 use SL::PriceSource;
  12 use SL::Webdav;
  13 use SL::File;
  14 use SL::MIME;
  15 use SL::Util qw(trim);
  16 use SL::YAML;
  17 use SL::DB::AdditionalBillingAddress;
  18 use SL::DB::AuthUser;
  19 use SL::DB::History;
  20 use SL::DB::Order;
  21 use SL::DB::Default;
  22 use SL::DB::Unit;
  23 use SL::DB::Part;
  24 use SL::DB::PartClassification;
  25 use SL::DB::PartsGroup;
  26 use SL::DB::Printer;
  27 use SL::DB::Language;
  28 use SL::DB::RecordLink;
  29 use SL::DB::RequirementSpec;
  30 use SL::DB::Shipto;
  31 use SL::DB::Translation;
  32
  33 use SL::Helper::CreatePDF qw(:all);
  34 use SL::Helper::PrintOptions;
  35 use SL::Helper::ShippedQty;
  36 use SL::Helper::UserPreferences::PositionsScrollbar;
  37 use SL::Helper::UserPreferences::UpdatePositions;
  38
  39 use SL::Controller::Helper::GetModels;
  40
  41 use List::Util qw(first sum0);
  42 use List::UtilsBy qw(sort_by uniq_by);
  43 use List::MoreUtils qw(any none pairwise first_index);
  44 use English qw(-no_match_vars);
  45 use File::Spec;
  46 use Cwd;
  47 use Sort::Naturally;
  48
  49 use Rose::Object::MakeMethods::Generic
  50 (
  51  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  52  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  53 );
  54
  55
  56 # safety
  57 __PACKAGE__->run_before('check_auth');
  58
  59 __PACKAGE__->run_before('check_auth_for_edit',
  60                         except => [ qw(edit show_customer_vendor_details_dialog price_popup load_second_rows) ]);
  61
  62 __PACKAGE__->run_before('recalc',
  63                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_final_invoice save_and_ap_transaction
  64                                      print send_email) ]);
  65
  66 __PACKAGE__->run_before('get_unalterable_data',
  67                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_final_invoice save_and_ap_transaction
  68                                      print send_email) ]);
  69
  70 #
  71 # actions
  72 #
  73
  74 # add a new order
  75 sub action_add {
  76   my ($self) = @_;
  77
  78   $self->order->transdate(DateTime->now_local());
  79   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  80                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  81
  82   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  83       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  84       && (!$self->order->reqdate)) {
  85     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  86   }
  87
  88
  89   $self->pre_render();
  90   $self->render(
  91     'order/form',
  92     title => $self->get_title_for('add'),
  93     %{$self->{template_args}}
  94   );
  95 }
  96
  97 # edit an existing order
  98 sub action_edit {
  99   my ($self) = @_;
 100
 101   if ($::form->{id}) {
 102     $self->load_order;
 103
 104   } else {
 105     # this is to edit an order from an unsaved order object
 106
 107     # set item ids to new fake id, to identify them as new items
 108     foreach my $item (@{$self->order->items_sorted}) {
 109       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 110     }
 111     # trigger rendering values for second row as hidden, because they
 112     # are loaded only on demand. So we need to keep the values from
 113     # the source.
 114     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 115   }
 116
 117   $self->recalc();
 118   $self->pre_render();
 119   $self->render(
 120     'order/form',
 121     title => $self->get_title_for('edit'),
 122     %{$self->{template_args}}
 123   );
 124 }
 125
 126 # edit a collective order (consisting of one or more existing orders)
 127 sub action_edit_collective {
 128   my ($self) = @_;
 129
 130   # collect order ids
 131   my @multi_ids = map {
 132     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 133   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 134
 135   # fall back to add if no ids are given
 136   if (scalar @multi_ids == 0) {
 137     $self->action_add();
 138     return;
 139   }
 140
 141   # fall back to save as new if only one id is given
 142   if (scalar @multi_ids == 1) {
 143     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 144     $self->action_save_as_new();
 145     return;
 146   }
 147
 148   # make new order from given orders
 149   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 150   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 151   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 152
 153   $self->action_edit();
 154 }
 155
 156 # delete the order
 157 sub action_delete {
 158   my ($self) = @_;
 159
 160   my $errors = $self->delete();
 161
 162   if (scalar @{ $errors }) {
 163     $self->js->flash('error', $_) foreach @{ $errors };
 164     return $self->js->render();
 165   }
 166
 167   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 168            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 169            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 170            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 171            : '';
 172   flash_later('info', $text);
 173
 174   my @redirect_params = (
 175     action => 'add',
 176     type   => $self->type,
 177   );
 178
 179   $self->redirect_to(@redirect_params);
 180 }
 181
 182 # save the order
 183 sub action_save {
 184   my ($self) = @_;
 185
 186   my $errors = $self->save();
 187
 188   if (scalar @{ $errors }) {
 189     $self->js->flash('error', $_) foreach @{ $errors };
 190     return $self->js->render();
 191   }
 192
 193   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 194            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 195            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 196            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 197            : '';
 198   flash_later('info', $text);
 199
 200   my @redirect_params;
 201   if ($::form->{back_to_caller}) {
 202     @redirect_params = $::form->{callback} ? ($::form->{callback})
 203                                            : (controller => 'LoginScreen', action => 'user_login');
 204
 205   } else {
 206     @redirect_params = (
 207       action   => 'edit',
 208       type     => $self->type,
 209       id       => $self->order->id,
 210       callback => $::form->{callback},
 211     );
 212   }
 213
 214   $self->redirect_to(@redirect_params);
 215 }
 216
 217 # save the order as new document an open it for edit
 218 sub action_save_as_new {
 219   my ($self) = @_;
 220
 221   my $order = $self->order;
 222
 223   if (!$order->id) {
 224     $self->js->flash('error', t8('This object has not been saved yet.'));
 225     return $self->js->render();
 226   }
 227
 228   # load order from db to check if values changed
 229   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 230
 231   my %new_attrs;
 232   # Lets assign a new number if the user hasn't changed the previous one.
 233   # If it has been changed manually then use it as-is.
 234   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 235                         ? ''
 236                         : trim($order->number);
 237
 238   # Clear transdate unless changed
 239   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 240                         ? DateTime->today_local
 241                         : $order->transdate;
 242
 243   # Set new reqdate unless changed if it is enabled in client config
 244   if ($order->reqdate == $saved_order->reqdate) {
 245     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 246                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 247
 248     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 249         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 250       $new_attrs{reqdate} = '';
 251     } else {
 252       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 253     }
 254   } else {
 255     $new_attrs{reqdate} = $order->reqdate;
 256   }
 257
 258   # Update employee
 259   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 260
 261   # Create new record from current one
 262   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 263
 264   # no linked records on save as new
 265   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 266
 267   # save
 268   $self->action_save();
 269 }
 270
 271 # print the order
 272 #
 273 # This is called if "print" is pressed in the print dialog.
 274 # If PDF creation was requested and succeeded, the pdf is offered for download
 275 # via send_file (which uses ajax in this case).
 276 sub action_print {
 277   my ($self) = @_;
 278
 279   my $errors = $self->save();
 280
 281   if (scalar @{ $errors }) {
 282     $self->js->flash('error', $_) foreach @{ $errors };
 283     return $self->js->render();
 284   }
 285
 286   $self->js_reset_order_and_item_ids_after_save;
 287
 288   my $format      = $::form->{print_options}->{format};
 289   my $media       = $::form->{print_options}->{media};
 290   my $formname    = $::form->{print_options}->{formname};
 291   my $copies      = $::form->{print_options}->{copies};
 292   my $groupitems  = $::form->{print_options}->{groupitems};
 293   my $printer_id  = $::form->{print_options}->{printer_id};
 294
 295   # only PDF, OpenDocument & HTML for now
 296   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf html)) {
 297     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 298   }
 299
 300   # only screen or printer by now
 301   if (none { $media eq $_ } qw(screen printer)) {
 302     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 303   }
 304
 305   # create a form for generate_attachment_filename
 306   my $form   = Form->new;
 307   $form->{$self->nr_key()}  = $self->order->number;
 308   $form->{type}             = $self->type;
 309   $form->{format}           = $format;
 310   $form->{formname}         = $formname;
 311   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 312   my $doc_filename          = $form->generate_attachment_filename();
 313
 314   my $doc;
 315   my @errors = $self->generate_doc(\$doc, { media      => $media,
 316                                             format     => $format,
 317                                             formname   => $formname,
 318                                             language   => $self->order->language,
 319                                             printer_id => $printer_id,
 320                                             groupitems => $groupitems });
 321   if (scalar @errors) {
 322     return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render;
 323   }
 324
 325   if ($media eq 'screen') {
 326     # screen/download
 327     $self->js->flash('info', t8('The document has been created.'));
 328     $self->send_file(
 329       \$doc,
 330       type         => SL::MIME->mime_type_from_ext($doc_filename),
 331       name         => $doc_filename,
 332       js_no_render => 1,
 333     );
 334
 335   } elsif ($media eq 'printer') {
 336     # printer
 337     my $printer_id = $::form->{print_options}->{printer_id};
 338     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 339       copies  => $copies,
 340       content => $doc,
 341     );
 342
 343     $self->js->flash('info', t8('The document has been printed.'));
 344   }
 345
 346   my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $doc_filename, $formname);
 347   if (scalar @warnings) {
 348     $self->js->flash('warning', $_) for @warnings;
 349   }
 350
 351   $self->save_history('PRINTED');
 352
 353   $self->js
 354     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 355     ->render;
 356 }
 357 sub action_preview_pdf {
 358   my ($self) = @_;
 359
 360   my $errors = $self->save();
 361   if (scalar @{ $errors }) {
 362     $self->js->flash('error', $_) foreach @{ $errors };
 363     return $self->js->render();
 364   }
 365
 366   $self->js_reset_order_and_item_ids_after_save;
 367
 368   my $format      = 'pdf';
 369   my $media       = 'screen';
 370   my $formname    = $self->type;
 371
 372   # only pdf
 373   # create a form for generate_attachment_filename
 374   my $form   = Form->new;
 375   $form->{$self->nr_key()}  = $self->order->number;
 376   $form->{type}             = $self->type;
 377   $form->{format}           = $format;
 378   $form->{formname}         = $formname;
 379   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 380   my $pdf_filename          = $form->generate_attachment_filename();
 381
 382   my $pdf;
 383   my @errors = $self->generate_doc(\$pdf, { media      => $media,
 384                                             format     => $format,
 385                                             formname   => $formname,
 386                                             language   => $self->order->language,
 387                                           });
 388   if (scalar @errors) {
 389     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 390   }
 391   $self->save_history('PREVIEWED');
 392   $self->js->flash('info', t8('The PDF has been previewed'));
 393   # screen/download
 394   $self->send_file(
 395     \$pdf,
 396     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 397     name         => $pdf_filename,
 398     js_no_render => 0,
 399   );
 400 }
 401
 402 # open the email dialog
 403 sub action_save_and_show_email_dialog {
 404   my ($self) = @_;
 405
 406   my $errors = $self->save();
 407
 408   if (scalar @{ $errors }) {
 409     $self->js->flash('error', $_) foreach @{ $errors };
 410     return $self->js->render();
 411   }
 412
 413   my $cv_method = $self->cv;
 414
 415   if (!$self->order->$cv_method) {
 416     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 417                     ->render($self);
 418   }
 419
 420   my $email_form;
 421   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 422   $email_form->{to} ||= $self->order->$cv_method->email;
 423   $email_form->{cc}   = $self->order->$cv_method->cc;
 424   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 425   # Todo: get addresses from shipto, if any
 426
 427   my $form = Form->new;
 428   $form->{$self->nr_key()}  = $self->order->number;
 429   $form->{cusordnumber}     = $self->order->cusordnumber;
 430   $form->{formname}         = $self->type;
 431   $form->{type}             = $self->type;
 432   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 433   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 434   $form->{format}           = 'pdf';
 435   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 436
 437   $email_form->{subject}             = $form->generate_email_subject();
 438   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 439   $email_form->{message}             = $form->generate_email_body();
 440   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 441
 442   my %files = $self->get_files_for_email_dialog();
 443
 444   my @employees_with_email = grep {
 445     my $user = SL::DB::Manager::AuthUser->find_by(login => $_->login);
 446     $user && !!trim($user->get_config_value('email'));
 447   } @{ SL::DB::Manager::Employee->get_all_sorted(query => [ deleted => 0 ]) };
 448
 449
 450   my $all_partner_email_addresses = $self->order->customervendor->get_all_email_addresses();
 451
 452   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 453                                   email_form    => $email_form,
 454                                   show_bcc      => $::auth->assert('email_bcc', 'may fail'),
 455                                   FILES         => \%files,
 456                                   is_customer   => $self->cv eq 'customer',
 457                                   ALL_EMPLOYEES => \@employees_with_email,
 458                                   ALL_PARTNER_EMAIL_ADDRESSES => $all_partner_email_addresses,
 459   );
 460
 461   $self->js
 462       ->run('kivi.Order.show_email_dialog', $dialog_html)
 463       ->reinit_widgets
 464       ->render($self);
 465 }
 466
 467 # send email
 468 #
 469 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 470 sub action_send_email {
 471   my ($self) = @_;
 472
 473   my $errors = $self->save();
 474
 475   if (scalar @{ $errors }) {
 476     $self->js->run('kivi.Order.close_email_dialog');
 477     $self->js->flash('error', $_) foreach @{ $errors };
 478     return $self->js->render();
 479   }
 480
 481   $self->js_reset_order_and_item_ids_after_save;
 482
 483   my $email_form  = delete $::form->{email_form};
 484
 485   if ($email_form->{additional_to}) {
 486     $email_form->{to} = join ', ', grep { $_ } $email_form->{to}, @{$email_form->{additional_to}};
 487     delete $email_form->{additional_to};
 488   }
 489
 490   my %field_names = (to => 'email');
 491
 492   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 493
 494   # for Form::cleanup which may be called in Form::send_email
 495   $::form->{cwd}    = getcwd();
 496   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 497
 498   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 499   $::form->{media}  = 'email';
 500
 501   $::form->{attachment_policy} //= '';
 502
 503   # Is an old file version available?
 504   my $attfile;
 505   if ($::form->{attachment_policy} eq 'old_file') {
 506     $attfile = SL::File->get_all(object_id     => $self->order->id,
 507                                  object_type   => $self->type,
 508                                  file_type     => 'document',
 509                                  print_variant => $::form->{formname});
 510   }
 511
 512   if ($::form->{attachment_policy} ne 'no_file' && !($::form->{attachment_policy} eq 'old_file' && $attfile)) {
 513     my $doc;
 514     my @errors = $self->generate_doc(\$doc, {media      => $::form->{media},
 515                                              format     => $::form->{print_options}->{format},
 516                                              formname   => $::form->{print_options}->{formname},
 517                                              language   => $self->order->language,
 518                                              printer_id => $::form->{print_options}->{printer_id},
 519                                              groupitems => $::form->{print_options}->{groupitems}});
 520     if (scalar @errors) {
 521       return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render($self);
 522     }
 523
 524     my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $::form->{attachment_filename}, $::form->{formname});
 525     if (scalar @warnings) {
 526       flash_later('warning', $_) for @warnings;
 527     }
 528
 529     my $sfile = SL::SessionFile::Random->new(mode => "w");
 530     $sfile->fh->print($doc);
 531     $sfile->fh->close;
 532
 533     $::form->{tmpfile} = $sfile->file_name;
 534     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 535   }
 536
 537   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 538   $::form->send_email(\%::myconfig, $::form->{print_options}->{format});
 539
 540   # internal notes unless no email journal
 541   unless ($::instance_conf->get_email_journal) {
 542     my $intnotes = $self->order->intnotes;
 543     $intnotes   .= "\n\n" if $self->order->intnotes;
 544     $intnotes   .= t8('[email]')                                                                                        . "\n";
 545     $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 546     $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 547     $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 548     $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 549     $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 550     $intnotes   .= t8('Message')    . ": " . SL::HTML::Util->strip($::form->{message});
 551
 552     $self->order->update_attributes(intnotes => $intnotes);
 553   }
 554
 555   $self->save_history('MAILED');
 556
 557   flash_later('info', t8('The email has been sent.'));
 558
 559   my @redirect_params = (
 560     action => 'edit',
 561     type   => $self->type,
 562     id     => $self->order->id,
 563   );
 564
 565   $self->redirect_to(@redirect_params);
 566 }
 567
 568 # open the periodic invoices config dialog
 569 #
 570 # If there are values in the form (i.e. dialog was opened before),
 571 # then use this values. Create new ones, else.
 572 sub action_show_periodic_invoices_config_dialog {
 573   my ($self) = @_;
 574
 575   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 576   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 577   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 578                                                    order_value_periodicity => 'p', # = same as periodicity
 579                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 580                                                    extend_automatically_by => 12,
 581                                                    active                  => 1,
 582                                                    email_subject           => GenericTranslations->get(
 583                                                                                 language_id      => $::form->{language_id},
 584                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 585                                                    email_body              => GenericTranslations->get(
 586                                                                                 language_id      => $::form->{language_id},
 587                                                                                 translation_type => "salutation_general")
 588                                                                             . GenericTranslations->get(
 589                                                                                 language_id      => $::form->{language_id},
 590                                                                                 translation_type => "salutation_punctuation_mark") . "\n\n"
 591                                                                             . GenericTranslations->get(
 592                                                                                 language_id      => $::form->{language_id},
 593                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 594   );
 595   # for older configs, replace email preset text if not yet set.
 596   $config->email_subject(GenericTranslations->get(
 597                                               language_id      => $::form->{language_id},
 598                                               translation_type =>"preset_text_periodic_invoices_email_subject")
 599                         ) unless $config->email_subject;
 600
 601   $config->email_body(GenericTranslations->get(
 602                                               language_id      => $::form->{language_id},
 603                                               translation_type => "salutation_general")
 604                     . GenericTranslations->get(
 605                                               language_id      => $::form->{language_id},
 606                                               translation_type => "salutation_punctuation_mark") . "\n\n"
 607                     . GenericTranslations->get(
 608                                               language_id      => $::form->{language_id},
 609                                               translation_type =>"preset_text_periodic_invoices_email_body")
 610                      ) unless $config->email_body;
 611
 612   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 613   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 614
 615   $::form->get_lists(printers => "ALL_PRINTERS",
 616                      charts   => { key       => 'ALL_CHARTS',
 617                                    transdate => 'current_date' });
 618
 619   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 620
 621   if ($::form->{customer_id}) {
 622     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 623     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 624     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 625     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 626     $config->send_email(0) if $::form->{postal_invoice};
 627   }
 628
 629   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 630                 popup_dialog             => 1,
 631                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 632                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 633                 config                   => $config,
 634                 %$::form);
 635 }
 636
 637 # assign the values of the periodic invoices config dialog
 638 # as yaml in the hidden tag and set the status.
 639 sub action_assign_periodic_invoices_config {
 640   my ($self) = @_;
 641
 642   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 643
 644   my $config = { active                     => $::form->{active}       ? 1 : 0,
 645                  terminated                 => $::form->{terminated}   ? 1 : 0,
 646                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 647                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 648                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 649                  start_date_as_date         => $::form->{start_date_as_date},
 650                  end_date_as_date           => $::form->{end_date_as_date},
 651                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 652                  print                      => $::form->{print}      ? 1                         : 0,
 653                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 654                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 655                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 656                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 657                  send_email                 => $::form->{send_email} ? 1 : 0,
 658                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 659                  email_recipient_address    => $::form->{email_recipient_address},
 660                  email_sender               => $::form->{email_sender},
 661                  email_subject              => $::form->{email_subject},
 662                  email_body                 => $::form->{email_body},
 663                };
 664
 665   my $periodic_invoices_config = SL::YAML::Dump($config);
 666
 667   my $status = $self->get_periodic_invoices_status($config);
 668
 669   $self->js
 670     ->remove('#order_periodic_invoices_config')
 671     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 672     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 673     ->html('#periodic_invoices_status', $status)
 674     ->flash('info', t8('The periodic invoices config has been assigned.'))
 675     ->render($self);
 676 }
 677
 678 sub action_get_has_active_periodic_invoices {
 679   my ($self) = @_;
 680
 681   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 682   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 683
 684   my $has_active_periodic_invoices =
 685        $self->type eq sales_order_type()
 686     && $config
 687     && $config->active
 688     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 689     && $config->get_previous_billed_period_start_date;
 690
 691   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 692 }
 693
 694 # save the order and redirect to the frontend subroutine for a new
 695 # delivery order
 696 sub action_save_and_delivery_order {
 697   my ($self) = @_;
 698
 699   $self->save_and_redirect_to(
 700     controller => 'oe.pl',
 701     action     => 'oe_delivery_order_from_order',
 702   );
 703 }
 704
 705 sub action_save_and_supplier_delivery_order {
 706   my ($self) = @_;
 707
 708   $self->save_and_redirect_to(
 709     controller => 'controller.pl',
 710     action     => 'DeliveryOrder/add_from_order',
 711     type       => 'supplier_delivery_order',
 712   );
 713 }
 714
 715 # save the order and redirect to the frontend subroutine for a new
 716 # invoice
 717 sub action_save_and_invoice {
 718   my ($self) = @_;
 719
 720   $self->save_and_redirect_to(
 721     controller => 'oe.pl',
 722     action     => 'oe_invoice_from_order',
 723   );
 724 }
 725
 726 sub action_save_and_invoice_for_advance_payment {
 727   my ($self) = @_;
 728
 729   $self->save_and_redirect_to(
 730     controller       => 'oe.pl',
 731     action           => 'oe_invoice_from_order',
 732     new_invoice_type => 'invoice_for_advance_payment',
 733   );
 734 }
 735
 736 sub action_save_and_final_invoice {
 737   my ($self) = @_;
 738
 739   $self->save_and_redirect_to(
 740     controller       => 'oe.pl',
 741     action           => 'oe_invoice_from_order',
 742     new_invoice_type => 'final_invoice',
 743   );
 744 }
 745
 746 # workflow from sales order to sales quotation
 747 sub action_sales_quotation {
 748   $_[0]->workflow_sales_or_request_for_quotation();
 749 }
 750
 751 # workflow from sales order to sales quotation
 752 sub action_request_for_quotation {
 753   $_[0]->workflow_sales_or_request_for_quotation();
 754 }
 755
 756 # workflow from sales quotation to sales order
 757 sub action_sales_order {
 758   $_[0]->workflow_sales_or_purchase_order();
 759 }
 760
 761 # workflow from rfq to purchase order
 762 sub action_purchase_order {
 763   $_[0]->workflow_sales_or_purchase_order();
 764 }
 765
 766 # workflow from purchase order to ap transaction
 767 sub action_save_and_ap_transaction {
 768   my ($self) = @_;
 769
 770   $self->save_and_redirect_to(
 771     controller => 'ap.pl',
 772     action     => 'add_from_purchase_order',
 773   );
 774 }
 775
 776 # set form elements in respect to a changed customer or vendor
 777 #
 778 # This action is called on an change of the customer/vendor picker.
 779 sub action_customer_vendor_changed {
 780   my ($self) = @_;
 781
 782   setup_order_from_cv($self->order);
 783   $self->recalc();
 784
 785   my $cv_method = $self->cv;
 786
 787   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 788     $self->js->show('#cp_row');
 789   } else {
 790     $self->js->hide('#cp_row');
 791   }
 792
 793   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 794     $self->js->show('#shipto_selection');
 795   } else {
 796     $self->js->hide('#shipto_selection');
 797   }
 798
 799   if ($cv_method eq 'customer') {
 800     my $show_hide = scalar @{ $self->order->customer->additional_billing_addresses } > 0 ? 'show' : 'hide';
 801     $self->js->$show_hide('#billing_address_row');
 802   }
 803
 804   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 805
 806   $self->js
 807     ->replaceWith('#order_cp_id',              $self->build_contact_select)
 808     ->replaceWith('#order_shipto_id',          $self->build_shipto_select)
 809     ->replaceWith('#shipto_inputs  ',          $self->build_shipto_inputs)
 810     ->replaceWith('#order_billing_address_id', $self->build_billing_address_select)
 811     ->replaceWith('#business_info_row',        $self->build_business_info_row)
 812     ->val(        '#order_taxzone_id',         $self->order->taxzone_id)
 813     ->val(        '#order_taxincluded',        $self->order->taxincluded)
 814     ->val(        '#order_currency_id',        $self->order->currency_id)
 815     ->val(        '#order_payment_id',         $self->order->payment_id)
 816     ->val(        '#order_delivery_term_id',   $self->order->delivery_term_id)
 817     ->val(        '#order_intnotes',           $self->order->intnotes)
 818     ->val(        '#order_language_id',        $self->order->$cv_method->language_id)
 819     ->focus(      '#order_' . $self->cv . '_id')
 820     ->run('kivi.Order.update_exchangerate');
 821
 822   $self->js_redisplay_amounts_and_taxes;
 823   $self->js_redisplay_cvpartnumbers;
 824   $self->js->render();
 825 }
 826
 827 # open the dialog for customer/vendor details
 828 sub action_show_customer_vendor_details_dialog {
 829   my ($self) = @_;
 830
 831   my $is_customer = 'customer' eq $::form->{vc};
 832   my $cv;
 833   if ($is_customer) {
 834     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 835   } else {
 836     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 837   }
 838
 839   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 840   $details{discount_as_percent} = $cv->discount_as_percent;
 841   $details{creditlimt}          = $cv->creditlimit_as_number;
 842   $details{business}            = $cv->business->description      if $cv->business;
 843   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 844   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 845   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 846   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 847
 848   if ($is_customer) {
 849     foreach my $entry (@{ $cv->additional_billing_addresses }) {
 850       push @{ $details{ADDITIONAL_BILLING_ADDRESSES} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 851     }
 852   }
 853   foreach my $entry (@{ $cv->shipto }) {
 854     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 855   }
 856   foreach my $entry (@{ $cv->contacts }) {
 857     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 858   }
 859
 860   $_[0]->render('common/show_vc_details', { layout => 0 },
 861                 is_customer => $is_customer,
 862                 %details);
 863
 864 }
 865
 866 # called if a unit in an existing item row is changed
 867 sub action_unit_changed {
 868   my ($self) = @_;
 869
 870   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 871   my $item = $self->order->items_sorted->[$idx];
 872
 873   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 874   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 875
 876   $self->recalc();
 877
 878   $self->js
 879     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 880   $self->js_redisplay_line_values;
 881   $self->js_redisplay_amounts_and_taxes;
 882   $self->js->render();
 883 }
 884
 885 # add an item row for a new item entered in the input row
 886 sub action_add_item {
 887   my ($self) = @_;
 888
 889   delete $::form->{add_item}->{create_part_type};
 890
 891   my $form_attr = $::form->{add_item};
 892
 893   return unless $form_attr->{parts_id};
 894
 895   my $item = new_item($self->order, $form_attr);
 896
 897   $self->order->add_items($item);
 898
 899   $self->recalc();
 900
 901   $self->get_item_cvpartnumber($item);
 902
 903   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 904   my $row_as_html = $self->p->render('order/tabs/_row',
 905                                      ITEM => $item,
 906                                      ID   => $item_id,
 907                                      SELF => $self,
 908   );
 909
 910   if ($::form->{insert_before_item_id}) {
 911     $self->js
 912       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 913   } else {
 914     $self->js
 915       ->append('#row_table_id', $row_as_html);
 916   }
 917
 918   if ( $item->part->is_assortment ) {
 919     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 920     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 921       my $attr = { parts_id => $assortment_item->parts_id,
 922                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 923                    unit     => $assortment_item->unit,
 924                    description => $assortment_item->part->description,
 925                  };
 926       my $item = new_item($self->order, $attr);
 927
 928       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 929       $item->discount(1) unless $assortment_item->charge;
 930
 931       $self->order->add_items( $item );
 932       $self->recalc();
 933       $self->get_item_cvpartnumber($item);
 934       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 935       my $row_as_html = $self->p->render('order/tabs/_row',
 936                                          ITEM => $item,
 937                                          ID   => $item_id,
 938                                          SELF => $self,
 939       );
 940       if ($::form->{insert_before_item_id}) {
 941         $self->js
 942           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 943       } else {
 944         $self->js
 945           ->append('#row_table_id', $row_as_html);
 946       }
 947     };
 948   };
 949
 950   $self->js
 951     ->val('.add_item_input', '')
 952     ->run('kivi.Order.init_row_handlers')
 953     ->run('kivi.Order.renumber_positions')
 954     ->focus('#add_item_parts_id_name');
 955
 956   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 957
 958   $self->js_redisplay_amounts_and_taxes;
 959   $self->js->render();
 960 }
 961
 962 # add item rows for multiple items at once
 963 sub action_add_multi_items {
 964   my ($self) = @_;
 965
 966   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 967   return $self->js->render() unless scalar @form_attr;
 968
 969   my @items;
 970   foreach my $attr (@form_attr) {
 971     my $item = new_item($self->order, $attr);
 972     push @items, $item;
 973     if ( $item->part->is_assortment ) {
 974       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 975         my $attr = { parts_id => $assortment_item->parts_id,
 976                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 977                      unit     => $assortment_item->unit,
 978                      description => $assortment_item->part->description,
 979                    };
 980         my $item = new_item($self->order, $attr);
 981
 982         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 983         $item->discount(1) unless $assortment_item->charge;
 984         push @items, $item;
 985       }
 986     }
 987   }
 988   $self->order->add_items(@items);
 989
 990   $self->recalc();
 991
 992   foreach my $item (@items) {
 993     $self->get_item_cvpartnumber($item);
 994     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 995     my $row_as_html = $self->p->render('order/tabs/_row',
 996                                        ITEM => $item,
 997                                        ID   => $item_id,
 998                                        SELF => $self,
 999     );
1000
1001     if ($::form->{insert_before_item_id}) {
1002       $self->js
1003         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
1004     } else {
1005       $self->js
1006         ->append('#row_table_id', $row_as_html);
1007     }
1008   }
1009
1010   $self->js
1011     ->run('kivi.Part.close_picker_dialogs')
1012     ->run('kivi.Order.init_row_handlers')
1013     ->run('kivi.Order.renumber_positions')
1014     ->focus('#add_item_parts_id_name');
1015
1016   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
1017
1018   $self->js_redisplay_amounts_and_taxes;
1019   $self->js->render();
1020 }
1021
1022 # recalculate all linetotals, amounts and taxes and redisplay them
1023 sub action_recalc_amounts_and_taxes {
1024   my ($self) = @_;
1025
1026   $self->recalc();
1027
1028   $self->js_redisplay_line_values;
1029   $self->js_redisplay_amounts_and_taxes;
1030   $self->js->render();
1031 }
1032
1033 sub action_update_exchangerate {
1034   my ($self) = @_;
1035
1036   my $data = {
1037     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
1038     currency_name => $self->order->currency->name,
1039     exchangerate  => $self->order->daily_exchangerate_as_null_number,
1040   };
1041
1042   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
1043 }
1044
1045 # redisplay item rows if they are sorted by an attribute
1046 sub action_reorder_items {
1047   my ($self) = @_;
1048
1049   my %sort_keys = (
1050     partnumber   => sub { $_[0]->part->partnumber },
1051     description  => sub { $_[0]->description },
1052     qty          => sub { $_[0]->qty },
1053     sellprice    => sub { $_[0]->sellprice },
1054     discount     => sub { $_[0]->discount },
1055     cvpartnumber => sub { $_[0]->{cvpartnumber} },
1056   );
1057
1058   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1059
1060   my $method = $sort_keys{$::form->{order_by}};
1061   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
1062   if ($::form->{sort_dir}) {
1063     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1064       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
1065     } else {
1066       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
1067     }
1068   } else {
1069     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1070       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
1071     } else {
1072       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
1073     }
1074   }
1075   $self->js
1076     ->run('kivi.Order.redisplay_items', \@to_sort)
1077     ->render;
1078 }
1079
1080 # show the popup to choose a price/discount source
1081 sub action_price_popup {
1082   my ($self) = @_;
1083
1084   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
1085   my $item = $self->order->items_sorted->[$idx];
1086
1087   $self->render_price_dialog($item);
1088 }
1089
1090 # save the order in a session variable and redirect to the part controller
1091 sub action_create_part {
1092   my ($self) = @_;
1093
1094   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
1095
1096   my $callback     = $self->url_for(
1097     action       => 'return_from_create_part',
1098     type         => $self->type, # type is needed for check_auth on return
1099     previousform => $previousform,
1100   );
1101
1102   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
1103
1104   my @redirect_params = (
1105     controller => 'Part',
1106     action     => 'add',
1107     part_type  => $::form->{add_item}->{create_part_type},
1108     callback   => $callback,
1109     show_abort => 1,
1110   );
1111
1112   $self->redirect_to(@redirect_params);
1113 }
1114
1115 sub action_return_from_create_part {
1116   my ($self) = @_;
1117
1118   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1119
1120   $::auth->restore_form_from_session(delete $::form->{previousform});
1121
1122   # set item ids to new fake id, to identify them as new items
1123   foreach my $item (@{$self->order->items_sorted}) {
1124     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1125   }
1126
1127   $self->recalc();
1128   $self->get_unalterable_data();
1129   $self->pre_render();
1130
1131   # trigger rendering values for second row/longdescription as hidden,
1132   # because they are loaded only on demand. So we need to keep the values
1133   # from the source.
1134   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1135   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1136
1137   $self->render(
1138     'order/form',
1139     title => $self->get_title_for('edit'),
1140     %{$self->{template_args}}
1141   );
1142
1143 }
1144
1145 # load the second row for one or more items
1146 #
1147 # This action gets the html code for all items second rows by rendering a template for
1148 # the second row and sets the html code via client js.
1149 sub action_load_second_rows {
1150   my ($self) = @_;
1151
1152   $self->recalc() if $self->order->is_sales; # for margin calculation
1153
1154   foreach my $item_id (@{ $::form->{item_ids} }) {
1155     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1156     my $item = $self->order->items_sorted->[$idx];
1157
1158     $self->js_load_second_row($item, $item_id, 0);
1159   }
1160
1161   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1162
1163   $self->js->render();
1164 }
1165
1166 # update description, notes and sellprice from master data
1167 sub action_update_row_from_master_data {
1168   my ($self) = @_;
1169
1170   foreach my $item_id (@{ $::form->{item_ids} }) {
1171     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1172     my $item  = $self->order->items_sorted->[$idx];
1173     my $texts = get_part_texts($item->part, $self->order->language_id);
1174
1175     $item->description($texts->{description});
1176     $item->longdescription($texts->{longdescription});
1177
1178     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1179
1180     my $price_src;
1181     if ($item->part->is_assortment) {
1182     # add assortment items with price 0, as the components carry the price
1183       $price_src = $price_source->price_from_source("");
1184       $price_src->price(0);
1185     } else {
1186       $price_src = $price_source->best_price
1187                  ? $price_source->best_price
1188                  : $price_source->price_from_source("");
1189       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1190       $price_src->price(0) if !$price_source->best_price;
1191     }
1192
1193
1194     $item->sellprice($price_src->price);
1195     $item->active_price_source($price_src);
1196
1197     $self->js
1198       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1199       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1200       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1201       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1202
1203     if ($self->search_cvpartnumber) {
1204       $self->get_item_cvpartnumber($item);
1205       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1206     }
1207   }
1208
1209   $self->recalc();
1210   $self->js_redisplay_line_values;
1211   $self->js_redisplay_amounts_and_taxes;
1212
1213   $self->js->render();
1214 }
1215
1216 sub js_load_second_row {
1217   my ($self, $item, $item_id, $do_parse) = @_;
1218
1219   if ($do_parse) {
1220     # Parse values from form (they are formated while rendering (template)).
1221     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1222     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1223     foreach my $var (@{ $item->cvars_by_config }) {
1224       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1225     }
1226     $item->parse_custom_variable_values;
1227   }
1228
1229   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1230
1231   $self->js
1232     ->html('#second_row_' . $item_id, $row_as_html)
1233     ->data('#second_row_' . $item_id, 'loaded', 1);
1234 }
1235
1236 sub js_redisplay_line_values {
1237   my ($self) = @_;
1238
1239   my $is_sales = $self->order->is_sales;
1240
1241   # sales orders with margins
1242   my @data;
1243   if ($is_sales) {
1244     @data = map {
1245       [
1246        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1247        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1248        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1249       ]} @{ $self->order->items_sorted };
1250   } else {
1251     @data = map {
1252       [
1253        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1254       ]} @{ $self->order->items_sorted };
1255   }
1256
1257   $self->js
1258     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1259 }
1260
1261 sub js_redisplay_amounts_and_taxes {
1262   my ($self) = @_;
1263
1264   if (scalar @{ $self->{taxes} }) {
1265     $self->js->show('#taxincluded_row_id');
1266   } else {
1267     $self->js->hide('#taxincluded_row_id');
1268   }
1269
1270   if ($self->order->taxincluded) {
1271     $self->js->hide('#subtotal_row_id');
1272   } else {
1273     $self->js->show('#subtotal_row_id');
1274   }
1275
1276   if ($self->order->is_sales) {
1277     my $is_neg = $self->order->marge_total < 0;
1278     $self->js
1279       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1280       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1281       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1282       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1283       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1284       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1285       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1286       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1287   }
1288
1289   $self->js
1290     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1291     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1292     ->remove('.tax_row')
1293     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1294 }
1295
1296 sub js_redisplay_cvpartnumbers {
1297   my ($self) = @_;
1298
1299   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1300
1301   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1302
1303   $self->js
1304     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1305 }
1306
1307 sub js_reset_order_and_item_ids_after_save {
1308   my ($self) = @_;
1309
1310   $self->js
1311     ->val('#id', $self->order->id)
1312     ->val('#converted_from_oe_id', '')
1313     ->val('#order_' . $self->nr_key(), $self->order->number);
1314
1315   my $idx = 0;
1316   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1317     next if !$self->order->items_sorted->[$idx]->id;
1318     next if $form_item_id !~ m{^new};
1319     $self->js
1320       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1321       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1322       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1323   } continue {
1324     $idx++;
1325   }
1326   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1327 }
1328
1329 #
1330 # helpers
1331 #
1332
1333 sub init_valid_types {
1334   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1335 }
1336
1337 sub init_type {
1338   my ($self) = @_;
1339
1340   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1341     die "Not a valid type for order";
1342   }
1343
1344   $self->type($::form->{type});
1345 }
1346
1347 sub init_cv {
1348   my ($self) = @_;
1349
1350   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1351          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1352          : die "Not a valid type for order";
1353
1354   return $cv;
1355 }
1356
1357 sub init_search_cvpartnumber {
1358   my ($self) = @_;
1359
1360   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1361   my $search_cvpartnumber;
1362   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1363   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1364
1365   return $search_cvpartnumber;
1366 }
1367
1368 sub init_show_update_button {
1369   my ($self) = @_;
1370
1371   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1372 }
1373
1374 sub init_p {
1375   SL::Presenter->get;
1376 }
1377
1378 sub init_order {
1379   $_[0]->make_order;
1380 }
1381
1382 sub init_all_price_factors {
1383   SL::DB::Manager::PriceFactor->get_all;
1384 }
1385
1386 sub init_part_picker_classification_ids {
1387   my ($self)    = @_;
1388   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1389
1390   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1391 }
1392
1393 sub check_auth {
1394   my ($self) = @_;
1395
1396   my $right_for = { map { $_ => $_.'_edit' . ' | ' . $_.'_view' } @{$self->valid_types} };
1397
1398   my $right   = $right_for->{ $self->type };
1399   $right    ||= 'DOES_NOT_EXIST';
1400
1401   $::auth->assert($right);
1402 }
1403
1404 sub check_auth_for_edit {
1405   my ($self) = @_;
1406
1407   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1408
1409   my $right   = $right_for->{ $self->type };
1410   $right    ||= 'DOES_NOT_EXIST';
1411
1412   $::auth->assert($right);
1413 }
1414
1415 # build the selection box for contacts
1416 #
1417 # Needed, if customer/vendor changed.
1418 sub build_contact_select {
1419   my ($self) = @_;
1420
1421   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1422     value_key  => 'cp_id',
1423     title_key  => 'full_name_dep',
1424     default    => $self->order->cp_id,
1425     with_empty => 1,
1426     style      => 'width: 300px',
1427   );
1428 }
1429
1430 # build the selection box for the additional billing address
1431 #
1432 # Needed, if customer/vendor changed.
1433 sub build_billing_address_select {
1434   my ($self) = @_;
1435
1436   return '' if $self->cv ne 'customer';
1437
1438   select_tag('order.billing_address_id',
1439              [ {displayable_id => '', id => ''}, $self->order->{$self->cv}->additional_billing_addresses ],
1440              value_key  => 'id',
1441              title_key  => 'displayable_id',
1442              default    => $self->order->billing_address_id,
1443              with_empty => 0,
1444              style      => 'width: 300px',
1445   );
1446 }
1447
1448 # build the selection box for shiptos
1449 #
1450 # Needed, if customer/vendor changed.
1451 sub build_shipto_select {
1452   my ($self) = @_;
1453
1454   select_tag('order.shipto_id',
1455              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1456              value_key  => 'shipto_id',
1457              title_key  => 'displayable_id',
1458              default    => $self->order->shipto_id,
1459              with_empty => 0,
1460              style      => 'width: 300px',
1461   );
1462 }
1463
1464 # build the inputs for the cusom shipto dialog
1465 #
1466 # Needed, if customer/vendor changed.
1467 sub build_shipto_inputs {
1468   my ($self) = @_;
1469
1470   my $content = $self->p->render('common/_ship_to_dialog',
1471                                  vc_obj      => $self->order->customervendor,
1472                                  cs_obj      => $self->order->custom_shipto,
1473                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1474                                  id_selector => '#order_shipto_id');
1475
1476   div_tag($content, id => 'shipto_inputs');
1477 }
1478
1479 # render the info line for business
1480 #
1481 # Needed, if customer/vendor changed.
1482 sub build_business_info_row
1483 {
1484   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1485 }
1486
1487 # build the rows for displaying taxes
1488 #
1489 # Called if amounts where recalculated and redisplayed.
1490 sub build_tax_rows {
1491   my ($self) = @_;
1492
1493   my $rows_as_html;
1494   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1495     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1496   }
1497   return $rows_as_html;
1498 }
1499
1500
1501 sub render_price_dialog {
1502   my ($self, $record_item) = @_;
1503
1504   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1505
1506   $self->js
1507     ->run(
1508       'kivi.io.price_chooser_dialog',
1509       t8('Available Prices'),
1510       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1511     )
1512     ->reinit_widgets;
1513
1514 #   if (@errors) {
1515 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1516 #     $self->js->show('#dialog_flash_error');
1517 #   }
1518
1519   $self->js->render;
1520 }
1521
1522 sub load_order {
1523   my ($self) = @_;
1524
1525   return if !$::form->{id};
1526
1527   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1528
1529   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1530   # You need a custom shipto object to call cvars_by_config to get the cvars.
1531   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1532
1533   return $self->order;
1534 }
1535
1536 # load or create a new order object
1537 #
1538 # And assign changes from the form to this object.
1539 # If the order is loaded from db, check if items are deleted in the form,
1540 # remove them form the object and collect them for removing from db on saving.
1541 # Then create/update items from form (via make_item) and add them.
1542 sub make_order {
1543   my ($self) = @_;
1544
1545   # add_items adds items to an order with no items for saving, but they cannot
1546   # be retrieved via items until the order is saved. Adding empty items to new
1547   # order here solves this problem.
1548   my $order;
1549   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1550   $order ||= SL::DB::Order->new(orderitems  => [],
1551                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1552                                 currency_id => $::instance_conf->get_currency_id(),);
1553
1554   my $cv_id_method = $self->cv . '_id';
1555   if (!$::form->{id} && $::form->{$cv_id_method}) {
1556     $order->$cv_id_method($::form->{$cv_id_method});
1557     setup_order_from_cv($order);
1558   }
1559
1560   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1561   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1562
1563   $order->assign_attributes(%{$::form->{order}});
1564
1565   $self->setup_custom_shipto_from_form($order, $::form);
1566
1567   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1568     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1569     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1570   }
1571
1572   # remove deleted items
1573   $self->item_ids_to_delete([]);
1574   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1575     my $item = $order->orderitems->[$idx];
1576     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1577       splice @{$order->orderitems}, $idx, 1;
1578       push @{$self->item_ids_to_delete}, $item->id;
1579     }
1580   }
1581
1582   my @items;
1583   my $pos = 1;
1584   foreach my $form_attr (@{$form_orderitems}) {
1585     my $item = make_item($order, $form_attr);
1586     $item->position($pos);
1587     push @items, $item;
1588     $pos++;
1589   }
1590   $order->add_items(grep {!$_->id} @items);
1591
1592   return $order;
1593 }
1594
1595 # create or update items from form
1596 #
1597 # Make item objects from form values. For items already existing read from db.
1598 # Create a new item else. And assign attributes.
1599 sub make_item {
1600   my ($record, $attr) = @_;
1601
1602   my $item;
1603   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1604
1605   my $is_new = !$item;
1606
1607   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1608   # they cannot be retrieved via custom_variables until the order/orderitem is
1609   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1610   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1611
1612   $item->assign_attributes(%$attr);
1613
1614   if ($is_new) {
1615     my $texts = get_part_texts($item->part, $record->language_id);
1616     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1617     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1618     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1619   }
1620
1621   return $item;
1622 }
1623
1624 # create a new item
1625 #
1626 # This is used to add one item
1627 sub new_item {
1628   my ($record, $attr) = @_;
1629
1630   my $item = SL::DB::OrderItem->new;
1631
1632   # Remove attributes where the user left or set the inputs empty.
1633   # So these attributes will be undefined and we can distinguish them
1634   # from zero later on.
1635   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1636     delete $attr->{$_} if $attr->{$_} eq '';
1637   }
1638
1639   $item->assign_attributes(%$attr);
1640
1641   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1642   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1643
1644   $item->unit($part->unit) if !$item->unit;
1645
1646   my $price_src;
1647   if ( $part->is_assortment ) {
1648     # add assortment items with price 0, as the components carry the price
1649     $price_src = $price_source->price_from_source("");
1650     $price_src->price(0);
1651   } elsif (defined $item->sellprice) {
1652     $price_src = $price_source->price_from_source("");
1653     $price_src->price($item->sellprice);
1654   } else {
1655     $price_src = $price_source->best_price
1656                ? $price_source->best_price
1657                : $price_source->price_from_source("");
1658     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1659     $price_src->price(0) if !$price_source->best_price;
1660   }
1661
1662   my $discount_src;
1663   if (defined $item->discount) {
1664     $discount_src = $price_source->discount_from_source("");
1665     $discount_src->discount($item->discount);
1666   } else {
1667     $discount_src = $price_source->best_discount
1668                   ? $price_source->best_discount
1669                   : $price_source->discount_from_source("");
1670     $discount_src->discount(0) if !$price_source->best_discount;
1671   }
1672
1673   my %new_attr;
1674   $new_attr{part}                   = $part;
1675   $new_attr{description}            = $part->description     if ! $item->description;
1676   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1677   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1678   $new_attr{sellprice}              = $price_src->price;
1679   $new_attr{discount}               = $discount_src->discount;
1680   $new_attr{active_price_source}    = $price_src;
1681   $new_attr{active_discount_source} = $discount_src;
1682   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1683   $new_attr{project_id}             = $record->globalproject_id;
1684   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1685
1686   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1687   # they cannot be retrieved via custom_variables until the order/orderitem is
1688   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1689   $new_attr{custom_variables} = [];
1690
1691   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1692
1693   $item->assign_attributes(%new_attr, %{ $texts });
1694
1695   return $item;
1696 }
1697
1698 sub setup_order_from_cv {
1699   my ($order) = @_;
1700
1701   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id language_id));
1702
1703   $order->intnotes($order->customervendor->notes);
1704
1705   return if !$order->is_sales;
1706
1707   $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1708   $order->taxincluded(defined($order->customer->taxincluded_checked)
1709                       ? $order->customer->taxincluded_checked
1710                       : $::myconfig{taxincluded_checked});
1711
1712   my $address = $order->customer->default_billing_address;;
1713   $order->billing_address_id($address ? $address->id : undef);
1714 }
1715
1716 # setup custom shipto from form
1717 #
1718 # The dialog returns form variables starting with 'shipto' and cvars starting
1719 # with 'shiptocvar_'.
1720 # Mark it to be deleted if a shipto from master data is selected
1721 # (i.e. order has a shipto).
1722 # Else, update or create a new custom shipto. If the fields are empty, it
1723 # will not be saved on save.
1724 sub setup_custom_shipto_from_form {
1725   my ($self, $order, $form) = @_;
1726
1727   if ($order->shipto) {
1728     $self->is_custom_shipto_to_delete(1);
1729   } else {
1730     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1731
1732     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1733     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1734
1735     $custom_shipto->assign_attributes(%$shipto_attrs);
1736     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1737   }
1738 }
1739
1740 # recalculate prices and taxes
1741 #
1742 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1743 sub recalc {
1744   my ($self) = @_;
1745
1746   my %pat = $self->order->calculate_prices_and_taxes();
1747
1748   $self->{taxes} = [];
1749   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1750     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1751
1752     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1753                                 netamount => $netamount,
1754                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1755   }
1756   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1757 }
1758
1759 # get data for saving, printing, ..., that is not changed in the form
1760 #
1761 # Only cvars for now.
1762 sub get_unalterable_data {
1763   my ($self) = @_;
1764
1765   foreach my $item (@{ $self->order->items }) {
1766     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1767     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1768     foreach my $var (@{ $item->cvars_by_config }) {
1769       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1770     }
1771     $item->parse_custom_variable_values;
1772   }
1773 }
1774
1775 # delete the order
1776 #
1777 # And remove related files in the spool directory
1778 sub delete {
1779   my ($self) = @_;
1780
1781   my $errors = [];
1782   my $db     = $self->order->db;
1783
1784   $db->with_transaction(
1785     sub {
1786       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1787       $self->order->delete;
1788       my $spool = $::lx_office_conf{paths}->{spool};
1789       unlink map { "$spool/$_" } @spoolfiles if $spool;
1790
1791       $self->save_history('DELETED');
1792
1793       1;
1794   }) || push(@{$errors}, $db->error);
1795
1796   return $errors;
1797 }
1798
1799 # save the order
1800 #
1801 # And delete items that are deleted in the form.
1802 sub save {
1803   my ($self) = @_;
1804
1805   my $errors = [];
1806   my $db     = $self->order->db;
1807
1808   $db->with_transaction(sub {
1809     # delete custom shipto if it is to be deleted or if it is empty
1810     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1811       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1812       $self->order->custom_shipto(undef);
1813     }
1814
1815     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1816     $self->order->save(cascade => 1);
1817
1818     # link records
1819     if ($::form->{converted_from_oe_id}) {
1820       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1821
1822       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1823         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1824         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1825         $src->link_to_record($self->order);
1826       }
1827       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1828         my $idx = 0;
1829         foreach (@{ $self->order->items_sorted }) {
1830           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1831           next if !$from_id;
1832           SL::DB::RecordLink->new(from_table => 'orderitems',
1833                                   from_id    => $from_id,
1834                                   to_table   => 'orderitems',
1835                                   to_id      => $_->id
1836           )->save;
1837           $idx++;
1838         }
1839       }
1840
1841       $self->link_requirement_specs_linking_to_created_from_objects(@converted_from_oe_ids);
1842     }
1843
1844     $self->set_project_in_linked_requirement_specs if $self->order->globalproject_id;
1845
1846     $self->save_history('SAVED');
1847
1848     1;
1849   }) || push(@{$errors}, $db->error);
1850
1851   return $errors;
1852 }
1853
1854 sub workflow_sales_or_request_for_quotation {
1855   my ($self) = @_;
1856
1857   # always save
1858   my $errors = $self->save();
1859
1860   if (scalar @{ $errors }) {
1861     $self->js->flash('error', $_) for @{ $errors };
1862     return $self->js->render();
1863   }
1864
1865   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1866
1867   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1868   delete $::form->{id};
1869
1870   # no linked records from order to quotations
1871   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
1872
1873   # set item ids to new fake id, to identify them as new items
1874   foreach my $item (@{$self->order->items_sorted}) {
1875     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1876   }
1877
1878   # change form type
1879   $::form->{type} = $destination_type;
1880   $self->type($self->init_type);
1881   $self->cv  ($self->init_cv);
1882   $self->check_auth;
1883
1884   $self->recalc();
1885   $self->get_unalterable_data();
1886   $self->pre_render();
1887
1888   # trigger rendering values for second row as hidden, because they
1889   # are loaded only on demand. So we need to keep the values from the
1890   # source.
1891   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1892
1893   $self->render(
1894     'order/form',
1895     title => $self->get_title_for('edit'),
1896     %{$self->{template_args}}
1897   );
1898 }
1899
1900 sub workflow_sales_or_purchase_order {
1901   my ($self) = @_;
1902
1903   # always save
1904   my $errors = $self->save();
1905
1906   if (scalar @{ $errors }) {
1907     $self->js->flash('error', $_) foreach @{ $errors };
1908     return $self->js->render();
1909   }
1910
1911   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1912                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1913                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1914                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1915                        : '';
1916
1917   # check for direct delivery
1918   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1919   my $custom_shipto;
1920   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1921       && $::form->{use_shipto} && $self->order->shipto) {
1922     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1923   }
1924
1925   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1926   $self->{converted_from_oe_id} = delete $::form->{id};
1927
1928   # set item ids to new fake id, to identify them as new items
1929   foreach my $item (@{$self->order->items_sorted}) {
1930     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1931   }
1932
1933   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1934     if ($::form->{use_shipto}) {
1935       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1936     } else {
1937       # remove any custom shipto if not wanted
1938       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1939     }
1940   }
1941
1942   # change form type
1943   $::form->{type} = $destination_type;
1944   $self->type($self->init_type);
1945   $self->cv  ($self->init_cv);
1946   $self->check_auth;
1947
1948   $self->recalc();
1949   $self->get_unalterable_data();
1950   $self->pre_render();
1951
1952   # trigger rendering values for second row as hidden, because they
1953   # are loaded only on demand. So we need to keep the values from the
1954   # source.
1955   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1956
1957   $self->render(
1958     'order/form',
1959     title => $self->get_title_for('edit'),
1960     %{$self->{template_args}}
1961   );
1962 }
1963
1964
1965 sub pre_render {
1966   my ($self) = @_;
1967
1968   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1969   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1970   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1971   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted( query => [ or => [ obsolete => 0, id => $self->order->language_id ] ] );
1972   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1973                                                                                               deleted => 0 ] ],
1974                                                                            sort_by => 'name');
1975   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1976                                                                                               deleted => 0 ] ],
1977                                                                            sort_by => 'name');
1978   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1979                                                                                                         obsolete => 0 ] ]);
1980   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1981   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1982   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1983   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1984   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1985
1986   my $print_form = Form->new('');
1987   $print_form->{type}        = $self->type;
1988   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1989   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1990     form => $print_form,
1991     options => {dialog_name_prefix => 'print_options.',
1992                 show_headers       => 1,
1993                 no_queue           => 1,
1994                 no_postscript      => 1,
1995                 no_opendocument    => 0,
1996                 no_html            => 0},
1997   );
1998
1999   foreach my $item (@{$self->order->orderitems}) {
2000     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
2001     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
2002     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
2003   }
2004
2005   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
2006     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
2007     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
2008     # the value from db, which can be set manually or is set when linked delivery orders are saved.
2009     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
2010   }
2011
2012   if ($self->order->number && $::instance_conf->get_webdav) {
2013     my $webdav = SL::Webdav->new(
2014       type     => $self->type,
2015       number   => $self->order->number,
2016     );
2017     my @all_objects = $webdav->get_all_objects;
2018     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
2019                                                     type => t8('File'),
2020                                                     link => File::Spec->catfile($_->full_filedescriptor),
2021                                                 } } @all_objects;
2022   }
2023
2024   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
2025       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
2026     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
2027   }
2028
2029   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
2030
2031   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.Validator kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
2032                                                          edit_periodic_invoices_config calculate_qty follow_up show_history);
2033   $self->setup_edit_action_bar;
2034 }
2035
2036 sub setup_edit_action_bar {
2037   my ($self, %params) = @_;
2038
2039   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
2040                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
2041                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
2042
2043   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
2044   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
2045
2046   my $has_invoice_for_advance_payment;
2047   if ($self->order->id && $self->type eq sales_order_type()) {
2048     my $lr = $self->order->linked_records(direction => 'to', to => ['Invoice']);
2049     $has_invoice_for_advance_payment = any {'SL::DB::Invoice' eq ref $_ && "invoice_for_advance_payment" eq $_->type} @$lr;
2050   }
2051
2052   my $has_final_invoice;
2053   if ($self->order->id && $self->type eq sales_order_type()) {
2054     my $lr = $self->order->linked_records(direction => 'to', to => ['Invoice']);
2055     $has_final_invoice               = any {'SL::DB::Invoice' eq ref $_ && "final_invoice" eq $_->type} @$lr;
2056   }
2057
2058   my $right_for         = { map { $_ => $_.'_edit' } @{$self->valid_types} };
2059   my $right             = $right_for->{ $self->type };
2060   $right              ||= 'DOES_NOT_EXIST';
2061   my $may_edit_create   = $::auth->assert($right, 'may fail');
2062
2063   for my $bar ($::request->layout->get('actionbar')) {
2064     $bar->add(
2065       combobox => [
2066         action => [
2067           t8('Save'),
2068           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
2069                                                     $::instance_conf->get_order_warn_no_deliverydate,
2070           ],
2071           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
2072                          @req_trans_cost_art, @req_cusordnumber,
2073           ],
2074           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2075         ],
2076         action => [
2077           t8('Save and Close'),
2078           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
2079                                                     $::instance_conf->get_order_warn_no_deliverydate,
2080                                                     1
2081           ],
2082           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
2083                          @req_trans_cost_art, @req_cusordnumber,
2084           ],
2085           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2086         ],
2087         action => [
2088           t8('Save as new'),
2089           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
2090           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2091                          @req_trans_cost_art, @req_cusordnumber,
2092           ],
2093           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.')
2094                      : !$self->order->id ? t8('This object has not been saved yet.')
2095                      :                     undef,
2096         ],
2097       ], # end of combobox "Save"
2098
2099       combobox => [
2100         action => [
2101           t8('Workflow'),
2102         ],
2103         action => [
2104           t8('Save and Quotation'),
2105           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
2106           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2107           only_if  => (any { $self->type eq $_ } (sales_order_type())),
2108           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2109         ],
2110         action => [
2111           t8('Save and RFQ'),
2112           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
2113           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
2114           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2115         ],
2116         action => [
2117           t8('Save and Sales Order'),
2118           submit   => [ '#order_form', { action => "Order/sales_order" } ],
2119           checks   => [ @req_trans_cost_art ],
2120           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
2121           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2122         ],
2123         action => [
2124           t8('Save and Purchase Order'),
2125           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
2126           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
2127           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
2128           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2129         ],
2130         action => [
2131           t8('Save and Delivery Order'),
2132           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2133                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2134                                                                                                                         ],
2135           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2136                          @req_trans_cost_art, @req_cusordnumber,
2137           ],
2138           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())),
2139           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2140         ],
2141         action => [
2142           t8('Save and Supplier Delivery Order'),
2143           call      => [ 'kivi.Order.save', 'save_and_supplier_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2144                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2145                                                                                                                         ],
2146           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2147                          @req_trans_cost_art, @req_cusordnumber,
2148           ],
2149           only_if   => (any { $self->type eq $_ } (purchase_order_type())),
2150           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2151         ],
2152         action => [
2153           t8('Save and Invoice'),
2154           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2155           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2156                          @req_trans_cost_art, @req_cusordnumber,
2157           ],
2158           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2159         ],
2160         action => [
2161           ($has_invoice_for_advance_payment ? t8('Save and Further Invoice for Advance Payment') : t8('Save and Invoice for Advance Payment')),
2162           call      => [ 'kivi.Order.save', 'save_and_invoice_for_advance_payment', $::instance_conf->get_order_warn_duplicate_parts ],
2163           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2164                          @req_trans_cost_art, @req_cusordnumber,
2165           ],
2166           disabled  => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2167                      : $has_final_invoice ? t8('This order has already a final invoice.')
2168                      :                      undef,
2169           only_if   => (any { $self->type eq $_ } (sales_order_type())),
2170         ],
2171         action => [
2172           t8('Save and Final Invoice'),
2173           call      => [ 'kivi.Order.save', 'save_and_final_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2174           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2175                          @req_trans_cost_art, @req_cusordnumber,
2176           ],
2177           disabled  => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2178                      : $has_final_invoice ? t8('This order has already a final invoice.')
2179                      :                      undef,
2180           only_if   => (any { $self->type eq $_ } (sales_order_type())) && $has_invoice_for_advance_payment,
2181         ],
2182         action => [
2183           t8('Save and AP Transaction'),
2184           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
2185           only_if   => (any { $self->type eq $_ } (purchase_order_type())),
2186           disabled  => !$may_edit_create  ? t8('You do not have the permissions to access this function.') : undef,
2187         ],
2188
2189       ], # end of combobox "Workflow"
2190
2191       combobox => [
2192         action => [
2193           t8('Export'),
2194         ],
2195         action => [
2196           t8('Save and preview PDF'),
2197           call     => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
2198                                                           $::instance_conf->get_order_warn_no_deliverydate,
2199                       ],
2200           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2201           disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.') : undef,
2202         ],
2203         action => [
2204           t8('Save and print'),
2205           call     => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
2206                                                          $::instance_conf->get_order_warn_no_deliverydate,
2207                       ],
2208           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2209           disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.') : undef,
2210         ],
2211         action => [
2212           t8('Save and E-mail'),
2213           id       => 'save_and_email_action',
2214           call     => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
2215                                                                          $::instance_conf->get_order_warn_no_deliverydate,
2216                       ],
2217           disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2218                     : !$self->order->id  ? t8('This object has not been saved yet.')
2219                     :                      undef,
2220         ],
2221         action => [
2222           t8('Download attachments of all parts'),
2223           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2224           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2225           only_if  => $::instance_conf->get_doc_storage,
2226         ],
2227       ], # end of combobox "Export"
2228
2229       action => [
2230         t8('Delete'),
2231         call     => [ 'kivi.Order.delete_order' ],
2232         confirm  => $::locale->text('Do you really want to delete this object?'),
2233         disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2234                   : !$self->order->id  ? t8('This object has not been saved yet.')
2235                   :                      undef,
2236         only_if  => $deletion_allowed,
2237       ],
2238
2239       combobox => [
2240         action => [
2241           t8('more')
2242         ],
2243         action => [
2244           t8('History'),
2245           call     => [ 'set_history_window', $self->order->id, 'id' ],
2246           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2247         ],
2248         action => [
2249           t8('Follow-Up'),
2250           call     => [ 'kivi.Order.follow_up_window' ],
2251           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2252           only_if  => $::auth->assert('productivity', 1),
2253         ],
2254       ], # end of combobox "more"
2255     );
2256   }
2257 }
2258
2259 sub generate_doc {
2260   my ($self, $doc_ref, $params) = @_;
2261
2262   my $order  = $self->order;
2263   my @errors = ();
2264
2265   my $print_form = Form->new('');
2266   $print_form->{type}        = $order->type;
2267   $print_form->{formname}    = $params->{formname} || $order->type;
2268   $print_form->{format}      = $params->{format}   || 'pdf';
2269   $print_form->{media}       = $params->{media}    || 'file';
2270   $print_form->{groupitems}  = $params->{groupitems};
2271   $print_form->{printer_id}  = $params->{printer_id};
2272   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2273
2274   $order->language($params->{language});
2275   $order->flatten_to_form($print_form, format_amounts => 1);
2276
2277   my $template_ext;
2278   my $template_type;
2279   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2280     $template_ext  = 'odt';
2281     $template_type = 'OpenDocument';
2282   } elsif ($print_form->{format} =~ m{html}i) {
2283     $template_ext  = 'html';
2284     $template_type = 'HTML';
2285   }
2286
2287   # search for the template
2288   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2289     name        => $print_form->{formname},
2290     extension   => $template_ext,
2291     email       => $print_form->{media} eq 'email',
2292     language    => $params->{language},
2293     printer_id  => $print_form->{printer_id},
2294   );
2295
2296   if (!defined $template_file) {
2297     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2298   }
2299
2300   return @errors if scalar @errors;
2301
2302   $print_form->throw_on_error(sub {
2303     eval {
2304       $print_form->prepare_for_printing;
2305
2306       $$doc_ref = SL::Helper::CreatePDF->create_pdf(
2307         format        => $print_form->{format},
2308         template_type => $template_type,
2309         template      => $template_file,
2310         variables     => $print_form,
2311         variable_content_types => {
2312           longdescription => 'html',
2313           partnotes       => 'html',
2314           notes           => 'html',
2315           $::form->get_variable_content_types_for_cvars,
2316         },
2317       );
2318       1;
2319     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2320   });
2321
2322   return @errors;
2323 }
2324
2325 sub get_files_for_email_dialog {
2326   my ($self) = @_;
2327
2328   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2329
2330   return %files if !$::instance_conf->get_doc_storage;
2331
2332   if ($self->order->id) {
2333     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2334     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2335     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2336     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2337   }
2338
2339   my @parts =
2340     uniq_by { $_->{id} }
2341     map {
2342       +{ id         => $_->part->id,
2343          partnumber => $_->part->partnumber }
2344     } @{$self->order->items_sorted};
2345
2346   foreach my $part (@parts) {
2347     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2348     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2349   }
2350
2351   foreach my $key (keys %files) {
2352     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2353   }
2354
2355   return %files;
2356 }
2357
2358 sub make_periodic_invoices_config_from_yaml {
2359   my ($yaml_config) = @_;
2360
2361   return if !$yaml_config;
2362   my $attr = SL::YAML::Load($yaml_config);
2363   return if 'HASH' ne ref $attr;
2364   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2365 }
2366
2367
2368 sub get_periodic_invoices_status {
2369   my ($self, $config) = @_;
2370
2371   return                      if $self->type ne sales_order_type();
2372   return t8('not configured') if !$config;
2373
2374   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2375              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2376              :                                                     die "Cannot get status of periodic invoices config";
2377
2378   return $active ? t8('active') : t8('inactive');
2379 }
2380
2381 sub get_title_for {
2382   my ($self, $action) = @_;
2383
2384   return '' if none { lc($action)} qw(add edit);
2385
2386   # for locales:
2387   # $::locale->text("Add Sales Order");
2388   # $::locale->text("Add Purchase Order");
2389   # $::locale->text("Add Quotation");
2390   # $::locale->text("Add Request for Quotation");
2391   # $::locale->text("Edit Sales Order");
2392   # $::locale->text("Edit Purchase Order");
2393   # $::locale->text("Edit Quotation");
2394   # $::locale->text("Edit Request for Quotation");
2395
2396   $action = ucfirst(lc($action));
2397   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2398        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2399        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2400        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2401        : '';
2402 }
2403
2404 sub get_item_cvpartnumber {
2405   my ($self, $item) = @_;
2406
2407   return if !$self->search_cvpartnumber;
2408   return if !$self->order->customervendor;
2409
2410   if ($self->cv eq 'vendor') {
2411     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2412     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2413   } elsif ($self->cv eq 'customer') {
2414     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2415     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2416   }
2417 }
2418
2419 sub get_part_texts {
2420   my ($part_or_id, $language_or_id, %defaults) = @_;
2421
2422   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2423   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2424   my $texts       = {
2425     description     => $defaults{description}     // $part->description,
2426     longdescription => $defaults{longdescription} // $part->notes,
2427   };
2428
2429   return $texts unless $language_id;
2430
2431   my $translation = SL::DB::Manager::Translation->get_first(
2432     where => [
2433       parts_id    => $part->id,
2434       language_id => $language_id,
2435     ]);
2436
2437   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2438   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2439
2440   return $texts;
2441 }
2442
2443 sub sales_order_type {
2444   'sales_order';
2445 }
2446
2447 sub purchase_order_type {
2448   'purchase_order';
2449 }
2450
2451 sub sales_quotation_type {
2452   'sales_quotation';
2453 }
2454
2455 sub request_quotation_type {
2456   'request_quotation';
2457 }
2458
2459 sub nr_key {
2460   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2461        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2462        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2463        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2464        : '';
2465 }
2466
2467 sub save_and_redirect_to {
2468   my ($self, %params) = @_;
2469
2470   my $errors = $self->save();
2471
2472   if (scalar @{ $errors }) {
2473     $self->js->flash('error', $_) foreach @{ $errors };
2474     return $self->js->render();
2475   }
2476
2477   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2478            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2479            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2480            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2481            : '';
2482   flash_later('info', $text);
2483
2484   $self->redirect_to(%params, id => $self->order->id);
2485 }
2486
2487 sub save_history {
2488   my ($self, $addition) = @_;
2489
2490   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2491   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2492
2493   SL::DB::History->new(
2494     trans_id    => $self->order->id,
2495     employee_id => SL::DB::Manager::Employee->current->id,
2496     what_done   => $self->order->type,
2497     snumbers    => $snumbers,
2498     addition    => $addition,
2499   )->save;
2500 }
2501
2502 sub store_doc_to_webdav_and_filemanagement {
2503   my ($self, $content, $filename, $variant) = @_;
2504
2505   my $order = $self->order;
2506   my @errors;
2507
2508   # copy file to webdav folder
2509   if ($order->number && $::instance_conf->get_webdav_documents) {
2510     my $webdav = SL::Webdav->new(
2511       type     => $order->type,
2512       number   => $order->number,
2513     );
2514     my $webdav_file = SL::Webdav::File->new(
2515       webdav   => $webdav,
2516       filename => $filename,
2517     );
2518     eval {
2519       $webdav_file->store(data => \$content);
2520       1;
2521     } or do {
2522       push @errors, t8('Storing the document to the WebDAV folder failed: #1', $@);
2523     };
2524   }
2525   if ($order->id && $::instance_conf->get_doc_storage) {
2526     eval {
2527       SL::File->save(object_id     => $order->id,
2528                      object_type   => $order->type,
2529                      mime_type     => SL::MIME->mime_type_from_ext($filename),
2530                      source        => 'created',
2531                      file_type     => 'document',
2532                      file_name     => $filename,
2533                      file_contents => $content,
2534                      print_variant => $variant);
2535       1;
2536     } or do {
2537       push @errors, t8('Storing the document in the storage backend failed: #1', $@);
2538     };
2539   }
2540
2541   return @errors;
2542 }
2543
2544 sub link_requirement_specs_linking_to_created_from_objects {
2545   my ($self, @converted_from_oe_ids) = @_;
2546
2547   return unless @converted_from_oe_ids;
2548
2549   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => \@converted_from_oe_ids ]);
2550   foreach my $rs_order (@{ $rs_orders }) {
2551     SL::DB::RequirementSpecOrder->new(
2552       order_id            => $self->order->id,
2553       requirement_spec_id => $rs_order->requirement_spec_id,
2554       version_id          => $rs_order->version_id,
2555     )->save;
2556   }
2557 }
2558
2559 sub set_project_in_linked_requirement_specs {
2560   my ($self) = @_;
2561
2562   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => $self->order->id ]);
2563   foreach my $rs_order (@{ $rs_orders }) {
2564     next if $rs_order->requirement_spec->project_id == $self->order->globalproject_id;
2565
2566     $rs_order->requirement_spec->update_attributes(project_id => $self->order->globalproject_id);
2567   }
2568 }
2569
2570 1;
2571
2572 __END__
2573
2574 =encoding utf-8
2575
2576 =head1 NAME
2577
2578 SL::Controller::Order - controller for orders
2579
2580 =head1 SYNOPSIS
2581
2582 This is a new form to enter orders, completely rewritten with the use
2583 of controller and java script techniques.
2584
2585 The aim is to provide the user a better experience and a faster workflow. Also
2586 the code should be more readable, more reliable and better to maintain.
2587
2588 =head2 Key Features
2589
2590 =over 4
2591
2592 =item *
2593
2594 One input row, so that input happens every time at the same place.
2595
2596 =item *
2597
2598 Use of pickers where possible.
2599
2600 =item *
2601
2602 Possibility to enter more than one item at once.
2603
2604 =item *
2605
2606 Item list in a scrollable area, so that the workflow buttons stay at
2607 the bottom.
2608
2609 =item *
2610
2611 Reordering item rows with drag and drop is possible. Sorting item rows is
2612 possible (by partnumber, description, qty, sellprice and discount for now).
2613
2614 =item *
2615
2616 No C<update> is necessary. All entries and calculations are managed
2617 with ajax-calls and the page only reloads on C<save>.
2618
2619 =item *
2620
2621 User can see changes immediately, because of the use of java script
2622 and ajax.
2623
2624 =back
2625
2626 =head1 CODE
2627
2628 =head2 Layout
2629
2630 =over 4
2631
2632 =item * C<SL/Controller/Order.pm>
2633
2634 the controller
2635
2636 =item * C<template/webpages/order/form.html>
2637
2638 main form
2639
2640 =item * C<template/webpages/order/tabs/basic_data.html>
2641
2642 Main tab for basic_data.
2643
2644 This is the only tab here for now. "linked records" and "webdav" tabs are
2645 reused from generic code.
2646
2647 =over 4
2648
2649 =item * C<template/webpages/order/tabs/_business_info_row.html>
2650
2651 For displaying information on business type
2652
2653 =item * C<template/webpages/order/tabs/_item_input.html>
2654
2655 The input line for items
2656
2657 =item * C<template/webpages/order/tabs/_row.html>
2658
2659 One row for already entered items
2660
2661 =item * C<template/webpages/order/tabs/_tax_row.html>
2662
2663 Displaying tax information
2664
2665 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2666
2667 Dialog for selecting price and discount sources
2668
2669 =back
2670
2671 =item * C<js/kivi.Order.js>
2672
2673 java script functions
2674
2675 =back
2676
2677 =head1 TODO
2678
2679 =over 4
2680
2681 =item * testing
2682
2683 =item * price sources: little symbols showing better price / better discount
2684
2685 =item * select units in input row?
2686
2687 =item * check for direct delivery (workflow sales order -> purchase order)
2688
2689 =item * access rights
2690
2691 =item * display weights
2692
2693 =item * mtime check
2694
2695 =item * optional client/user behaviour
2696
2697 (transactions has to be set - department has to be set -
2698  force project if enabled in client config)
2699
2700 =back
2701
2702 =head1 KNOWN BUGS AND CAVEATS
2703
2704 =over 4
2705
2706 =item *
2707
2708 Customer discount is not displayed as a valid discount in price source popup
2709 (this might be a bug in price sources)
2710
2711 (I cannot reproduce this (Bernd))
2712
2713 =item *
2714
2715 No indication that <shift>-up/down expands/collapses second row.
2716
2717 =item *
2718
2719 Inline creation of parts is not currently supported
2720
2721 =item *
2722
2723 Table header is not sticky in the scrolling area.
2724
2725 =item *
2726
2727 Sorting does not include C<position>, neither does reordering.
2728
2729 This behavior was implemented intentionally. But we can discuss, which behavior
2730 should be implemented.
2731
2732 =back
2733
2734 =head1 To discuss / Nice to have
2735
2736 =over 4
2737
2738 =item *
2739
2740 How to expand/collapse second row. Now it can be done clicking the icon or
2741 <shift>-up/down.
2742
2743 =item *
2744
2745 Possibility to select PriceSources in input row?
2746
2747 =item *
2748
2749 This controller uses a (changed) copy of the template for the PriceSource
2750 dialog. Maybe there could be used one code source.
2751
2752 =item *
2753
2754 Rounding-differences between this controller (PriceTaxCalculator) and the old
2755 form. This is not only a problem here, but also in all parts using the PTC.
2756 There exists a ticket and a patch. This patch should be testet.
2757
2758 =item *
2759
2760 An indicator, if the actual inputs are saved (like in an
2761 editor or on text processing application).
2762
2763 =item *
2764
2765 A warning when leaving the page without saveing unchanged inputs.
2766
2767
2768 =back
2769
2770 =head1 AUTHOR
2771
2772 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2773
2774 =cut