SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::HTML::Util;
   8 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   9 use SL::Locale::String qw(t8);
  10 use SL::SessionFile::Random;
  11 use SL::PriceSource;
  12 use SL::Webdav;
  13 use SL::File;
  14 use SL::MIME;
  15 use SL::Util qw(trim);
  16 use SL::YAML;
  17 use SL::DB::AdditionalBillingAddress;
  18 use SL::DB::AuthUser;
  19 use SL::DB::History;
  20 use SL::DB::Order;
  21 use SL::DB::Default;
  22 use SL::DB::Unit;
  23 use SL::DB::Part;
  24 use SL::DB::PartClassification;
  25 use SL::DB::PartsGroup;
  26 use SL::DB::Printer;
  27 use SL::DB::Note;
  28 use SL::DB::Language;
  29 use SL::DB::RecordLink;
  30 use SL::DB::RequirementSpec;
  31 use SL::DB::Shipto;
  32 use SL::DB::Translation;
  33
  34 use SL::Helper::CreatePDF qw(:all);
  35 use SL::Helper::PrintOptions;
  36 use SL::Helper::ShippedQty;
  37 use SL::Helper::UserPreferences::DisplayPreferences;
  38 use SL::Helper::UserPreferences::PositionsScrollbar;
  39 use SL::Helper::UserPreferences::UpdatePositions;
  40
  41 use SL::Controller::Helper::GetModels;
  42
  43 use List::Util qw(first sum0);
  44 use List::UtilsBy qw(sort_by uniq_by);
  45 use List::MoreUtils qw(any none pairwise first_index);
  46 use English qw(-no_match_vars);
  47 use File::Spec;
  48 use Cwd;
  49 use Sort::Naturally;
  50
  51 use Rose::Object::MakeMethods::Generic
  52 (
  53  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  54  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  55 );
  56
  57
  58 # safety
  59 __PACKAGE__->run_before('check_auth');
  60
  61 __PACKAGE__->run_before('check_auth_for_edit',
  62                         except => [ qw(edit show_customer_vendor_details_dialog price_popup load_second_rows) ]);
  63
  64 __PACKAGE__->run_before('recalc',
  65                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_final_invoice save_and_ap_transaction
  66                                      print send_email) ]);
  67
  68 __PACKAGE__->run_before('get_unalterable_data',
  69                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_final_invoice save_and_ap_transaction
  70                                      print send_email) ]);
  71
  72 #
  73 # actions
  74 #
  75
  76 # add a new order
  77 sub action_add {
  78   my ($self) = @_;
  79
  80   $self->order->transdate(DateTime->now_local());
  81   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  82                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  83
  84   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  85       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  86       && (!$self->order->reqdate)) {
  87     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  88   }
  89
  90
  91   $self->pre_render();
  92   $self->render(
  93     'order/form',
  94     title => $self->get_title_for('add'),
  95     %{$self->{template_args}}
  96   );
  97 }
  98
  99 # edit an existing order
 100 sub action_edit {
 101   my ($self) = @_;
 102
 103   if ($::form->{id}) {
 104     $self->load_order;
 105
 106   } else {
 107     # this is to edit an order from an unsaved order object
 108
 109     # set item ids to new fake id, to identify them as new items
 110     foreach my $item (@{$self->order->items_sorted}) {
 111       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 112     }
 113     # trigger rendering values for second row as hidden, because they
 114     # are loaded only on demand. So we need to keep the values from
 115     # the source.
 116     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 117   }
 118
 119   $self->recalc();
 120   $self->pre_render();
 121   $self->render(
 122     'order/form',
 123     title => $self->get_title_for('edit'),
 124     %{$self->{template_args}}
 125   );
 126 }
 127
 128 # edit a collective order (consisting of one or more existing orders)
 129 sub action_edit_collective {
 130   my ($self) = @_;
 131
 132   # collect order ids
 133   my @multi_ids = map {
 134     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 135   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 136
 137   # fall back to add if no ids are given
 138   if (scalar @multi_ids == 0) {
 139     $self->action_add();
 140     return;
 141   }
 142
 143   # fall back to save as new if only one id is given
 144   if (scalar @multi_ids == 1) {
 145     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 146     $self->action_save_as_new();
 147     return;
 148   }
 149
 150   # make new order from given orders
 151   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 152   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 153   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 154
 155   $self->action_edit();
 156 }
 157
 158 # delete the order
 159 sub action_delete {
 160   my ($self) = @_;
 161
 162   my $errors = $self->delete();
 163
 164   if (scalar @{ $errors }) {
 165     $self->js->flash('error', $_) foreach @{ $errors };
 166     return $self->js->render();
 167   }
 168
 169   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 170            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 171            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 172            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 173            : '';
 174   flash_later('info', $text);
 175
 176   my @redirect_params = (
 177     action => 'add',
 178     type   => $self->type,
 179   );
 180
 181   $self->redirect_to(@redirect_params);
 182 }
 183
 184 # save the order
 185 sub action_save {
 186   my ($self) = @_;
 187
 188   my $errors = $self->save();
 189
 190   if (scalar @{ $errors }) {
 191     $self->js->flash('error', $_) foreach @{ $errors };
 192     return $self->js->render();
 193   }
 194
 195   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 196            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 197            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 198            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 199            : '';
 200   flash_later('info', $text);
 201
 202   my @redirect_params;
 203   if ($::form->{back_to_caller}) {
 204     @redirect_params = $::form->{callback} ? ($::form->{callback})
 205                                            : (controller => 'LoginScreen', action => 'user_login');
 206
 207   } else {
 208     @redirect_params = (
 209       action   => 'edit',
 210       type     => $self->type,
 211       id       => $self->order->id,
 212       callback => $::form->{callback},
 213     );
 214   }
 215
 216   $self->redirect_to(@redirect_params);
 217 }
 218
 219 # save the order as new document an open it for edit
 220 sub action_save_as_new {
 221   my ($self) = @_;
 222
 223   my $order = $self->order;
 224
 225   if (!$order->id) {
 226     $self->js->flash('error', t8('This object has not been saved yet.'));
 227     return $self->js->render();
 228   }
 229
 230   # load order from db to check if values changed
 231   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 232
 233   my %new_attrs;
 234   # Lets assign a new number if the user hasn't changed the previous one.
 235   # If it has been changed manually then use it as-is.
 236   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 237                         ? ''
 238                         : trim($order->number);
 239
 240   # Clear transdate unless changed
 241   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 242                         ? DateTime->today_local
 243                         : $order->transdate;
 244
 245   # Set new reqdate unless changed if it is enabled in client config
 246   if ($order->reqdate == $saved_order->reqdate) {
 247     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 248                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 249
 250     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 251         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 252       $new_attrs{reqdate} = '';
 253     } else {
 254       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 255     }
 256   } else {
 257     $new_attrs{reqdate} = $order->reqdate;
 258   }
 259
 260   # Update employee
 261   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 262
 263   # Warn on obsolete items
 264   my @obsolete_positions = map { $_->position } grep { $_->part->obsolete } @{ $order->items_sorted };
 265   flash_later('warning', t8('This record containts obsolete items at position #1', join ', ', @obsolete_positions)) if @obsolete_positions;
 266
 267   # Create new record from current one
 268   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 269
 270   # no linked records on save as new
 271   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 272
 273   # save
 274   $self->action_save();
 275 }
 276
 277 # print the order
 278 #
 279 # This is called if "print" is pressed in the print dialog.
 280 # If PDF creation was requested and succeeded, the pdf is offered for download
 281 # via send_file (which uses ajax in this case).
 282 sub action_print {
 283   my ($self) = @_;
 284
 285   my $errors = $self->save();
 286
 287   if (scalar @{ $errors }) {
 288     $self->js->flash('error', $_) foreach @{ $errors };
 289     return $self->js->render();
 290   }
 291
 292   $self->js_reset_order_and_item_ids_after_save;
 293
 294   my $format      = $::form->{print_options}->{format};
 295   my $media       = $::form->{print_options}->{media};
 296   my $formname    = $::form->{print_options}->{formname};
 297   my $copies      = $::form->{print_options}->{copies};
 298   my $groupitems  = $::form->{print_options}->{groupitems};
 299   my $printer_id  = $::form->{print_options}->{printer_id};
 300
 301   # only PDF, OpenDocument & HTML for now
 302   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf html)) {
 303     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 304   }
 305
 306   # only screen or printer by now
 307   if (none { $media eq $_ } qw(screen printer)) {
 308     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 309   }
 310
 311   # create a form for generate_attachment_filename
 312   my $form   = Form->new;
 313   $form->{$self->nr_key()}  = $self->order->number;
 314   $form->{type}             = $self->type;
 315   $form->{format}           = $format;
 316   $form->{formname}         = $formname;
 317   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 318   my $doc_filename          = $form->generate_attachment_filename();
 319
 320   my $doc;
 321   my @errors = $self->generate_doc(\$doc, { media      => $media,
 322                                             format     => $format,
 323                                             formname   => $formname,
 324                                             language   => $self->order->language,
 325                                             printer_id => $printer_id,
 326                                             groupitems => $groupitems });
 327   if (scalar @errors) {
 328     return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render;
 329   }
 330
 331   if ($media eq 'screen') {
 332     # screen/download
 333     $self->js->flash('info', t8('The document has been created.'));
 334     $self->send_file(
 335       \$doc,
 336       type         => SL::MIME->mime_type_from_ext($doc_filename),
 337       name         => $doc_filename,
 338       js_no_render => 1,
 339     );
 340
 341   } elsif ($media eq 'printer') {
 342     # printer
 343     my $printer_id = $::form->{print_options}->{printer_id};
 344     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 345       copies  => $copies,
 346       content => $doc,
 347     );
 348
 349     $self->js->flash('info', t8('The document has been printed.'));
 350   }
 351
 352   my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $doc_filename, $formname);
 353   if (scalar @warnings) {
 354     $self->js->flash('warning', $_) for @warnings;
 355   }
 356
 357   $self->save_history('PRINTED');
 358
 359   $self->js
 360     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 361     ->render;
 362 }
 363 sub action_preview_pdf {
 364   my ($self) = @_;
 365
 366   my $errors = $self->save();
 367   if (scalar @{ $errors }) {
 368     $self->js->flash('error', $_) foreach @{ $errors };
 369     return $self->js->render();
 370   }
 371
 372   $self->js_reset_order_and_item_ids_after_save;
 373
 374   my $format      = 'pdf';
 375   my $media       = 'screen';
 376   my $formname    = $self->type;
 377
 378   # only pdf
 379   # create a form for generate_attachment_filename
 380   my $form   = Form->new;
 381   $form->{$self->nr_key()}  = $self->order->number;
 382   $form->{type}             = $self->type;
 383   $form->{format}           = $format;
 384   $form->{formname}         = $formname;
 385   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 386   my $pdf_filename          = $form->generate_attachment_filename();
 387
 388   my $pdf;
 389   my @errors = $self->generate_doc(\$pdf, { media      => $media,
 390                                             format     => $format,
 391                                             formname   => $formname,
 392                                             language   => $self->order->language,
 393                                           });
 394   if (scalar @errors) {
 395     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 396   }
 397   $self->save_history('PREVIEWED');
 398   $self->js->flash('info', t8('The PDF has been previewed'));
 399   # screen/download
 400   $self->send_file(
 401     \$pdf,
 402     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 403     name         => $pdf_filename,
 404     js_no_render => 0,
 405   );
 406 }
 407
 408 # open the email dialog
 409 sub action_save_and_show_email_dialog {
 410   my ($self) = @_;
 411
 412   my $errors = $self->save();
 413
 414   if (scalar @{ $errors }) {
 415     $self->js->flash('error', $_) foreach @{ $errors };
 416     return $self->js->render();
 417   }
 418
 419   $self->js_reset_order_and_item_ids_after_save;
 420
 421   my $cv_method = $self->cv;
 422
 423   if (!$self->order->$cv_method) {
 424     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 425                     ->render($self);
 426   }
 427
 428   my $email_form;
 429   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 430   $email_form->{to} ||= $self->order->$cv_method->email;
 431   $email_form->{cc}   = $self->order->$cv_method->cc;
 432   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 433   # Todo: get addresses from shipto, if any
 434
 435   my $form = Form->new;
 436   $form->{$self->nr_key()}  = $self->order->number;
 437   $form->{cusordnumber}     = $self->order->cusordnumber;
 438   $form->{formname}         = $self->type;
 439   $form->{type}             = $self->type;
 440   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 441   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 442   $form->{format}           = 'pdf';
 443   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 444
 445   $email_form->{subject}             = $form->generate_email_subject();
 446   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 447   $email_form->{message}             = $form->generate_email_body();
 448   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 449
 450   my %files = $self->get_files_for_email_dialog();
 451
 452   my @employees_with_email = grep {
 453     my $user = SL::DB::Manager::AuthUser->find_by(login => $_->login);
 454     $user && !!trim($user->get_config_value('email'));
 455   } @{ SL::DB::Manager::Employee->get_all_sorted(query => [ deleted => 0 ]) };
 456
 457
 458   my $all_partner_email_addresses = $self->order->customervendor->get_all_email_addresses();
 459
 460   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 461                                   email_form    => $email_form,
 462                                   show_bcc      => $::auth->assert('email_bcc', 'may fail'),
 463                                   FILES         => \%files,
 464                                   is_customer   => $self->cv eq 'customer',
 465                                   ALL_EMPLOYEES => \@employees_with_email,
 466                                   ALL_PARTNER_EMAIL_ADDRESSES => $all_partner_email_addresses,
 467   );
 468
 469   $self->js
 470       ->run('kivi.Order.show_email_dialog', $dialog_html)
 471       ->reinit_widgets
 472       ->render($self);
 473 }
 474
 475 # send email
 476 #
 477 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 478 sub action_send_email {
 479   my ($self) = @_;
 480
 481   my $errors = $self->save();
 482
 483   if (scalar @{ $errors }) {
 484     $self->js->run('kivi.Order.close_email_dialog');
 485     $self->js->flash('error', $_) foreach @{ $errors };
 486     return $self->js->render();
 487   }
 488
 489   $self->js_reset_order_and_item_ids_after_save;
 490
 491   my $email_form  = delete $::form->{email_form};
 492
 493   if ($email_form->{additional_to}) {
 494     $email_form->{to} = join ', ', grep { $_ } $email_form->{to}, @{$email_form->{additional_to}};
 495     delete $email_form->{additional_to};
 496   }
 497
 498   my %field_names = (to => 'email');
 499
 500   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 501
 502   # for Form::cleanup which may be called in Form::send_email
 503   $::form->{cwd}    = getcwd();
 504   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 505
 506   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 507   $::form->{media}  = 'email';
 508
 509   $::form->{attachment_policy} //= '';
 510
 511   # Is an old file version available?
 512   my $attfile;
 513   if ($::form->{attachment_policy} eq 'old_file') {
 514     $attfile = SL::File->get_all(object_id     => $self->order->id,
 515                                  object_type   => $self->type,
 516                                  file_type     => 'document',
 517                                  print_variant => $::form->{formname});
 518   }
 519
 520   if ($::form->{attachment_policy} ne 'no_file' && !($::form->{attachment_policy} eq 'old_file' && $attfile)) {
 521     my $doc;
 522     my @errors = $self->generate_doc(\$doc, {media      => $::form->{media},
 523                                              format     => $::form->{print_options}->{format},
 524                                              formname   => $::form->{print_options}->{formname},
 525                                              language   => $self->order->language,
 526                                              printer_id => $::form->{print_options}->{printer_id},
 527                                              groupitems => $::form->{print_options}->{groupitems}});
 528     if (scalar @errors) {
 529       return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render($self);
 530     }
 531
 532     my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $::form->{attachment_filename}, $::form->{formname});
 533     if (scalar @warnings) {
 534       flash_later('warning', $_) for @warnings;
 535     }
 536
 537     my $sfile = SL::SessionFile::Random->new(mode => "w");
 538     $sfile->fh->print($doc);
 539     $sfile->fh->close;
 540
 541     $::form->{tmpfile} = $sfile->file_name;
 542     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 543   }
 544
 545   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 546   $::form->send_email(\%::myconfig, $::form->{print_options}->{format});
 547
 548   # internal notes unless no email journal
 549   unless ($::instance_conf->get_email_journal) {
 550     my $intnotes = $self->order->intnotes;
 551     $intnotes   .= "\n\n" if $self->order->intnotes;
 552     $intnotes   .= t8('[email]')                                                                                        . "\n";
 553     $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 554     $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 555     $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 556     $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 557     $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 558     $intnotes   .= t8('Message')    . ": " . SL::HTML::Util->strip($::form->{message});
 559
 560     $self->order->update_attributes(intnotes => $intnotes);
 561   }
 562
 563   $self->save_history('MAILED');
 564
 565   flash_later('info', t8('The email has been sent.'));
 566
 567   my @redirect_params = (
 568     action => 'edit',
 569     type   => $self->type,
 570     id     => $self->order->id,
 571   );
 572
 573   $self->redirect_to(@redirect_params);
 574 }
 575
 576 # open the periodic invoices config dialog
 577 #
 578 # If there are values in the form (i.e. dialog was opened before),
 579 # then use this values. Create new ones, else.
 580 sub action_show_periodic_invoices_config_dialog {
 581   my ($self) = @_;
 582
 583   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 584   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 585   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 586                                                    order_value_periodicity => 'p', # = same as periodicity
 587                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 588                                                    extend_automatically_by => 12,
 589                                                    active                  => 1,
 590                                                    email_subject           => GenericTranslations->get(
 591                                                                                 language_id      => $::form->{language_id},
 592                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 593                                                    email_body              => GenericTranslations->get(
 594                                                                                 language_id      => $::form->{language_id},
 595                                                                                 translation_type => "salutation_general")
 596                                                                             . GenericTranslations->get(
 597                                                                                 language_id      => $::form->{language_id},
 598                                                                                 translation_type => "salutation_punctuation_mark") . "\n\n"
 599                                                                             . GenericTranslations->get(
 600                                                                                 language_id      => $::form->{language_id},
 601                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 602   );
 603   # for older configs, replace email preset text if not yet set.
 604   $config->email_subject(GenericTranslations->get(
 605                                               language_id      => $::form->{language_id},
 606                                               translation_type =>"preset_text_periodic_invoices_email_subject")
 607                         ) unless $config->email_subject;
 608
 609   $config->email_body(GenericTranslations->get(
 610                                               language_id      => $::form->{language_id},
 611                                               translation_type => "salutation_general")
 612                     . GenericTranslations->get(
 613                                               language_id      => $::form->{language_id},
 614                                               translation_type => "salutation_punctuation_mark") . "\n\n"
 615                     . GenericTranslations->get(
 616                                               language_id      => $::form->{language_id},
 617                                               translation_type =>"preset_text_periodic_invoices_email_body")
 618                      ) unless $config->email_body;
 619
 620   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 621   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 622
 623   $::form->get_lists(printers => "ALL_PRINTERS",
 624                      charts   => { key       => 'ALL_CHARTS',
 625                                    transdate => 'current_date' });
 626
 627   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 628
 629   if ($::form->{customer_id}) {
 630     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 631     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 632     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 633     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 634     $config->send_email(0) if $::form->{postal_invoice};
 635   }
 636
 637   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 638                 popup_dialog             => 1,
 639                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 640                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 641                 config                   => $config,
 642                 %$::form);
 643 }
 644
 645 # assign the values of the periodic invoices config dialog
 646 # as yaml in the hidden tag and set the status.
 647 sub action_assign_periodic_invoices_config {
 648   my ($self) = @_;
 649
 650   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 651
 652   my $config = { active                     => $::form->{active}       ? 1 : 0,
 653                  terminated                 => $::form->{terminated}   ? 1 : 0,
 654                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 655                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 656                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 657                  start_date_as_date         => $::form->{start_date_as_date},
 658                  end_date_as_date           => $::form->{end_date_as_date},
 659                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 660                  print                      => $::form->{print}      ? 1                         : 0,
 661                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 662                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 663                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 664                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 665                  send_email                 => $::form->{send_email} ? 1 : 0,
 666                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 667                  email_recipient_address    => $::form->{email_recipient_address},
 668                  email_sender               => $::form->{email_sender},
 669                  email_subject              => $::form->{email_subject},
 670                  email_body                 => $::form->{email_body},
 671                };
 672
 673   my $periodic_invoices_config = SL::YAML::Dump($config);
 674
 675   my $status = $self->get_periodic_invoices_status($config);
 676
 677   $self->js
 678     ->remove('#order_periodic_invoices_config')
 679     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 680     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 681     ->html('#periodic_invoices_status', $status)
 682     ->flash('info', t8('The periodic invoices config has been assigned.'))
 683     ->render($self);
 684 }
 685
 686 sub action_get_has_active_periodic_invoices {
 687   my ($self) = @_;
 688
 689   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 690   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 691
 692   my $has_active_periodic_invoices =
 693        $self->type eq sales_order_type()
 694     && $config
 695     && $config->active
 696     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 697     && $config->get_previous_billed_period_start_date;
 698
 699   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 700 }
 701
 702 # save the order and redirect to the frontend subroutine for a new
 703 # delivery order
 704 sub action_save_and_delivery_order {
 705   my ($self) = @_;
 706
 707   $self->save_and_redirect_to(
 708     controller => 'oe.pl',
 709     action     => 'oe_delivery_order_from_order',
 710   );
 711 }
 712
 713 sub action_save_and_supplier_delivery_order {
 714   my ($self) = @_;
 715
 716   $self->save_and_redirect_to(
 717     controller => 'controller.pl',
 718     action     => 'DeliveryOrder/add_from_order',
 719     type       => 'supplier_delivery_order',
 720   );
 721 }
 722
 723 # save the order and redirect to the frontend subroutine for a new
 724 # invoice
 725 sub action_save_and_invoice {
 726   my ($self) = @_;
 727
 728   $self->save_and_redirect_to(
 729     controller => 'oe.pl',
 730     action     => 'oe_invoice_from_order',
 731   );
 732 }
 733
 734 sub action_save_and_invoice_for_advance_payment {
 735   my ($self) = @_;
 736
 737   $self->save_and_redirect_to(
 738     controller       => 'oe.pl',
 739     action           => 'oe_invoice_from_order',
 740     new_invoice_type => 'invoice_for_advance_payment',
 741   );
 742 }
 743
 744 sub action_save_and_final_invoice {
 745   my ($self) = @_;
 746
 747   $self->save_and_redirect_to(
 748     controller       => 'oe.pl',
 749     action           => 'oe_invoice_from_order',
 750     new_invoice_type => 'final_invoice',
 751   );
 752 }
 753
 754 # workflow from sales order to sales quotation
 755 sub action_sales_quotation {
 756   $_[0]->workflow_sales_or_request_for_quotation();
 757 }
 758
 759 # workflow from sales order to sales quotation
 760 sub action_request_for_quotation {
 761   $_[0]->workflow_sales_or_request_for_quotation();
 762 }
 763
 764 # workflow from sales quotation to sales order
 765 sub action_sales_order {
 766   $_[0]->workflow_sales_or_purchase_order();
 767 }
 768
 769 # workflow from rfq to purchase order
 770 sub action_purchase_order {
 771   $_[0]->workflow_sales_or_purchase_order();
 772 }
 773
 774 # workflow from purchase order to ap transaction
 775 sub action_save_and_ap_transaction {
 776   my ($self) = @_;
 777
 778   $self->save_and_redirect_to(
 779     controller => 'ap.pl',
 780     action     => 'add_from_purchase_order',
 781   );
 782 }
 783
 784 # set form elements in respect to a changed customer or vendor
 785 #
 786 # This action is called on an change of the customer/vendor picker.
 787 sub action_customer_vendor_changed {
 788   my ($self) = @_;
 789
 790   setup_order_from_cv($self->order);
 791   $self->recalc();
 792
 793   my $cv_method = $self->cv;
 794
 795   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 796     $self->js->show('#cp_row');
 797   } else {
 798     $self->js->hide('#cp_row');
 799   }
 800
 801   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 802     $self->js->show('#shipto_selection');
 803   } else {
 804     $self->js->hide('#shipto_selection');
 805   }
 806
 807   if ($cv_method eq 'customer') {
 808     my $show_hide = scalar @{ $self->order->customer->additional_billing_addresses } > 0 ? 'show' : 'hide';
 809     $self->js->$show_hide('#billing_address_row');
 810   }
 811
 812   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 813
 814   $self->js
 815     ->replaceWith('#order_cp_id',              $self->build_contact_select)
 816     ->replaceWith('#order_shipto_id',          $self->build_shipto_select)
 817     ->replaceWith('#shipto_inputs  ',          $self->build_shipto_inputs)
 818     ->replaceWith('#order_billing_address_id', $self->build_billing_address_select)
 819     ->replaceWith('#business_info_row',        $self->build_business_info_row)
 820     ->val(        '#order_taxzone_id',         $self->order->taxzone_id)
 821     ->val(        '#order_taxincluded',        $self->order->taxincluded)
 822     ->val(        '#order_currency_id',        $self->order->currency_id)
 823     ->val(        '#order_payment_id',         $self->order->payment_id)
 824     ->val(        '#order_delivery_term_id',   $self->order->delivery_term_id)
 825     ->val(        '#order_intnotes',           $self->order->intnotes)
 826     ->val(        '#order_language_id',        $self->order->$cv_method->language_id)
 827     ->focus(      '#order_' . $self->cv . '_id')
 828     ->run('kivi.Order.update_exchangerate');
 829
 830   $self->js_redisplay_amounts_and_taxes;
 831   $self->js_redisplay_cvpartnumbers;
 832   $self->js->render();
 833 }
 834
 835 # open the dialog for customer/vendor details
 836 sub action_show_customer_vendor_details_dialog {
 837   my ($self) = @_;
 838
 839   my $is_customer = 'customer' eq $::form->{vc};
 840   my $cv;
 841   if ($is_customer) {
 842     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 843   } else {
 844     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 845   }
 846
 847   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 848   $details{discount_as_percent} = $cv->discount_as_percent;
 849   $details{creditlimt}          = $cv->creditlimit_as_number;
 850   $details{business}            = $cv->business->description      if $cv->business;
 851   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 852   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 853   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 854   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 855
 856   if ($is_customer) {
 857     foreach my $entry (@{ $cv->additional_billing_addresses }) {
 858       push @{ $details{ADDITIONAL_BILLING_ADDRESSES} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 859     }
 860   }
 861   foreach my $entry (@{ $cv->shipto }) {
 862     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 863   }
 864   foreach my $entry (@{ $cv->contacts }) {
 865     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 866   }
 867
 868   $_[0]->render('common/show_vc_details', { layout => 0 },
 869                 is_customer => $is_customer,
 870                 %details);
 871
 872 }
 873
 874 # called if a unit in an existing item row is changed
 875 sub action_unit_changed {
 876   my ($self) = @_;
 877
 878   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 879   my $item = $self->order->items_sorted->[$idx];
 880
 881   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 882   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 883
 884   $self->recalc();
 885
 886   $self->js
 887     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 888   $self->js_redisplay_line_values;
 889   $self->js_redisplay_amounts_and_taxes;
 890   $self->js->render();
 891 }
 892
 893 # update item input row when a part ist picked
 894 sub action_update_item_input_row {
 895   my ($self) = @_;
 896
 897   delete $::form->{add_item}->{$_} for qw(create_part_type sellprice_as_number discount_as_percent);
 898
 899   my $form_attr = $::form->{add_item};
 900
 901   return unless $form_attr->{parts_id};
 902
 903   my $record       = $self->order;
 904   my $item         = SL::DB::OrderItem->new(%$form_attr);
 905   $item->unit($item->part->unit);
 906
 907   my ($price_src, $discount_src) = get_best_price_and_discount_source($record, $item, 0);
 908
 909   $self->js
 910     ->val     ('#add_item_unit',                $item->unit)
 911     ->val     ('#add_item_description',         $item->part->description)
 912     ->val     ('#add_item_sellprice_as_number', '')
 913     ->attr    ('#add_item_sellprice_as_number', 'placeholder', $price_src->price_as_number)
 914     ->attr    ('#add_item_sellprice_as_number', 'title',       $price_src->source_description)
 915     ->val     ('#add_item_discount_as_percent', '')
 916     ->attr    ('#add_item_discount_as_percent', 'placeholder', $discount_src->discount_as_percent)
 917     ->attr    ('#add_item_discount_as_percent', 'title',       $discount_src->source_description)
 918     ->render;
 919 }
 920
 921 # add an item row for a new item entered in the input row
 922 sub action_add_item {
 923   my ($self) = @_;
 924
 925   delete $::form->{add_item}->{create_part_type};
 926
 927   my $form_attr = $::form->{add_item};
 928
 929   return unless $form_attr->{parts_id};
 930
 931   my $item = new_item($self->order, $form_attr);
 932
 933   $self->order->add_items($item);
 934
 935   $self->recalc();
 936
 937   $self->get_item_cvpartnumber($item);
 938
 939   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 940   my $row_as_html = $self->p->render('order/tabs/_row',
 941                                      ITEM => $item,
 942                                      ID   => $item_id,
 943                                      SELF => $self,
 944   );
 945
 946   if ($::form->{insert_before_item_id}) {
 947     $self->js
 948       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 949   } else {
 950     $self->js
 951       ->append('#row_table_id', $row_as_html);
 952   }
 953
 954   if ( $item->part->is_assortment ) {
 955     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 956     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 957       my $attr = { parts_id => $assortment_item->parts_id,
 958                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 959                    unit     => $assortment_item->unit,
 960                    description => $assortment_item->part->description,
 961                  };
 962       my $item = new_item($self->order, $attr);
 963
 964       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 965       $item->discount(1) unless $assortment_item->charge;
 966
 967       $self->order->add_items( $item );
 968       $self->recalc();
 969       $self->get_item_cvpartnumber($item);
 970       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 971       my $row_as_html = $self->p->render('order/tabs/_row',
 972                                          ITEM => $item,
 973                                          ID   => $item_id,
 974                                          SELF => $self,
 975       );
 976       if ($::form->{insert_before_item_id}) {
 977         $self->js
 978           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 979       } else {
 980         $self->js
 981           ->append('#row_table_id', $row_as_html);
 982       }
 983     };
 984   };
 985
 986   $self->js
 987     ->val('.add_item_input', '')
 988     ->attr('.add_item_input', 'placeholder', '')
 989     ->attr('.add_item_input', 'title', '')
 990     ->run('kivi.Order.init_row_handlers')
 991     ->run('kivi.Order.renumber_positions')
 992     ->focus('#add_item_parts_id_name');
 993
 994   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 995
 996   $self->js_redisplay_amounts_and_taxes;
 997   $self->js->render();
 998 }
 999
1000 # add item rows for multiple items at once
1001 sub action_add_multi_items {
1002   my ($self) = @_;
1003
1004   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
1005   return $self->js->render() unless scalar @form_attr;
1006
1007   my @items;
1008   foreach my $attr (@form_attr) {
1009     my $item = new_item($self->order, $attr);
1010     push @items, $item;
1011     if ( $item->part->is_assortment ) {
1012       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
1013         my $attr = { parts_id => $assortment_item->parts_id,
1014                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
1015                      unit     => $assortment_item->unit,
1016                      description => $assortment_item->part->description,
1017                    };
1018         my $item = new_item($self->order, $attr);
1019
1020         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
1021         $item->discount(1) unless $assortment_item->charge;
1022         push @items, $item;
1023       }
1024     }
1025   }
1026   $self->order->add_items(@items);
1027
1028   $self->recalc();
1029
1030   foreach my $item (@items) {
1031     $self->get_item_cvpartnumber($item);
1032     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1033     my $row_as_html = $self->p->render('order/tabs/_row',
1034                                        ITEM => $item,
1035                                        ID   => $item_id,
1036                                        SELF => $self,
1037     );
1038
1039     if ($::form->{insert_before_item_id}) {
1040       $self->js
1041         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
1042     } else {
1043       $self->js
1044         ->append('#row_table_id', $row_as_html);
1045     }
1046   }
1047
1048   $self->js
1049     ->run('kivi.Part.close_picker_dialogs')
1050     ->run('kivi.Order.init_row_handlers')
1051     ->run('kivi.Order.renumber_positions')
1052     ->focus('#add_item_parts_id_name');
1053
1054   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
1055
1056   $self->js_redisplay_amounts_and_taxes;
1057   $self->js->render();
1058 }
1059
1060 # recalculate all linetotals, amounts and taxes and redisplay them
1061 sub action_recalc_amounts_and_taxes {
1062   my ($self) = @_;
1063
1064   $self->recalc();
1065
1066   $self->js_redisplay_line_values;
1067   $self->js_redisplay_amounts_and_taxes;
1068   $self->js->render();
1069 }
1070
1071 sub action_update_exchangerate {
1072   my ($self) = @_;
1073
1074   my $data = {
1075     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
1076     currency_name => $self->order->currency->name,
1077     exchangerate  => $self->order->daily_exchangerate_as_null_number,
1078   };
1079
1080   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
1081 }
1082
1083 # redisplay item rows if they are sorted by an attribute
1084 sub action_reorder_items {
1085   my ($self) = @_;
1086
1087   my %sort_keys = (
1088     partnumber   => sub { $_[0]->part->partnumber },
1089     description  => sub { $_[0]->description },
1090     qty          => sub { $_[0]->qty },
1091     sellprice    => sub { $_[0]->sellprice },
1092     discount     => sub { $_[0]->discount },
1093     cvpartnumber => sub { $_[0]->{cvpartnumber} },
1094   );
1095
1096   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1097
1098   my $method = $sort_keys{$::form->{order_by}};
1099   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
1100   if ($::form->{sort_dir}) {
1101     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1102       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
1103     } else {
1104       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
1105     }
1106   } else {
1107     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1108       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
1109     } else {
1110       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
1111     }
1112   }
1113   $self->js
1114     ->run('kivi.Order.redisplay_items', \@to_sort)
1115     ->render;
1116 }
1117
1118 # show the popup to choose a price/discount source
1119 sub action_price_popup {
1120   my ($self) = @_;
1121
1122   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
1123   my $item = $self->order->items_sorted->[$idx];
1124
1125   $self->render_price_dialog($item);
1126 }
1127
1128 # save the order in a session variable and redirect to the part controller
1129 sub action_create_part {
1130   my ($self) = @_;
1131
1132   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
1133
1134   my $callback     = $self->url_for(
1135     action       => 'return_from_create_part',
1136     type         => $self->type, # type is needed for check_auth on return
1137     previousform => $previousform,
1138   );
1139
1140   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
1141
1142   my @redirect_params = (
1143     controller    => 'Part',
1144     action        => 'add',
1145     part_type     => $::form->{add_item}->{create_part_type},
1146     callback      => $callback,
1147     inline_create => 1,
1148   );
1149
1150   $self->redirect_to(@redirect_params);
1151 }
1152
1153 sub action_return_from_create_part {
1154   my ($self) = @_;
1155
1156   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1157
1158   $::auth->restore_form_from_session(delete $::form->{previousform});
1159
1160   # set item ids to new fake id, to identify them as new items
1161   foreach my $item (@{$self->order->items_sorted}) {
1162     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1163   }
1164
1165   $self->recalc();
1166   $self->get_unalterable_data();
1167   $self->pre_render();
1168
1169   # trigger rendering values for second row/longdescription as hidden,
1170   # because they are loaded only on demand. So we need to keep the values
1171   # from the source.
1172   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1173   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1174
1175   $self->render(
1176     'order/form',
1177     title => $self->get_title_for('edit'),
1178     %{$self->{template_args}}
1179   );
1180
1181 }
1182
1183 # load the second row for one or more items
1184 #
1185 # This action gets the html code for all items second rows by rendering a template for
1186 # the second row and sets the html code via client js.
1187 sub action_load_second_rows {
1188   my ($self) = @_;
1189
1190   $self->recalc() if $self->order->is_sales; # for margin calculation
1191
1192   foreach my $item_id (@{ $::form->{item_ids} }) {
1193     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1194     my $item = $self->order->items_sorted->[$idx];
1195
1196     $self->js_load_second_row($item, $item_id, 0);
1197   }
1198
1199   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1200
1201   $self->js->render();
1202 }
1203
1204 # update description, notes and sellprice from master data
1205 sub action_update_row_from_master_data {
1206   my ($self) = @_;
1207
1208   foreach my $item_id (@{ $::form->{item_ids} }) {
1209     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1210     my $item  = $self->order->items_sorted->[$idx];
1211     my $texts = get_part_texts($item->part, $self->order->language_id);
1212
1213     $item->description($texts->{description});
1214     $item->longdescription($texts->{longdescription});
1215
1216     my ($price_src, $discount_src) = get_best_price_and_discount_source($self->order, $item, 1);
1217
1218     $item->sellprice($price_src->price);
1219     $item->active_price_source($price_src);
1220     $item->discount($discount_src->discount);
1221     $item->active_discount_source($discount_src);
1222
1223     my $price_editable = $self->order->is_sales ? $::auth->assert('sales_edit_prices', 1) : $::auth->assert('purchase_edit_prices', 1);
1224
1225     $self->js
1226       ->run('kivi.Order.set_price_and_source_text',    $item_id, $price_src   ->source, $price_src   ->source_description, $item->sellprice_as_number, $price_editable)
1227       ->run('kivi.Order.set_discount_and_source_text', $item_id, $discount_src->source, $discount_src->source_description, $item->discount_as_percent, $price_editable)
1228       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1229       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1230       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1231
1232     if ($self->search_cvpartnumber) {
1233       $self->get_item_cvpartnumber($item);
1234       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1235     }
1236   }
1237
1238   $self->recalc();
1239   $self->js_redisplay_line_values;
1240   $self->js_redisplay_amounts_and_taxes;
1241
1242   $self->js->render();
1243 }
1244
1245 sub action_save_phone_note {
1246   my ($self) = @_;
1247
1248   if (!$::form->{phone_note}->{subject} || !$::form->{phone_note}->{body}) {
1249     return $self->js->flash('error', t8('Phone note needs a subject and a body.'))->render;
1250   }
1251
1252   my $phone_note;
1253   if ($::form->{phone_note}->{id}) {
1254     $phone_note = first { $_->id == $::form->{phone_note}->{id} } @{$self->order->phone_notes};
1255     return $self->js->flash('error', t8('Phone note not found for this order.'))->render if !$phone_note;
1256   }
1257
1258   $phone_note = SL::DB::Note->new() if !$phone_note;
1259   my $is_new  = !$phone_note->id;
1260
1261   $phone_note->assign_attributes(%{ $::form->{phone_note} },
1262                                  trans_id     => $self->order->id,
1263                                  trans_module => 'oe',
1264                                  employee     => SL::DB::Manager::Employee->current);
1265
1266   $phone_note->save;
1267   $self->order(SL::DB::Order->new(id => $self->order->id)->load);
1268
1269   my $tab_as_html = $self->p->render('order/tabs/phone_notes', SELF => $self);
1270
1271   return $self->js
1272     ->replaceWith('#phone-notes', $tab_as_html)
1273     ->html('#num_phone_notes', (scalar @{$self->order->phone_notes}) ? ' (' . scalar @{$self->order->phone_notes} . ')' : '')
1274     ->flash('info', $is_new ? t8('Phone note has been created.') : t8('Phone note has been updated.'))
1275     ->render;
1276 }
1277
1278 sub action_delete_phone_note {
1279   my ($self) = @_;
1280
1281   my $phone_note = first { $_->id == $::form->{phone_note}->{id} } @{$self->order->phone_notes};
1282
1283   return $self->js->flash('error', t8('Phone note not found for this order.'))->render if !$phone_note;
1284
1285   $phone_note->delete;
1286   $self->order(SL::DB::Order->new(id => $self->order->id)->load);
1287
1288   my $tab_as_html = $self->p->render('order/tabs/phone_notes', SELF => $self);
1289
1290   return $self->js
1291     ->replaceWith('#phone-notes', $tab_as_html)
1292     ->html('#num_phone_notes', (scalar @{$self->order->phone_notes}) ? ' (' . scalar @{$self->order->phone_notes} . ')' : '')
1293     ->flash('info', t8('Phone note has been deleted.'))
1294     ->render;
1295 }
1296
1297 sub js_load_second_row {
1298   my ($self, $item, $item_id, $do_parse) = @_;
1299
1300   if ($do_parse) {
1301     # Parse values from form (they are formated while rendering (template)).
1302     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1303     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1304     foreach my $var (@{ $item->cvars_by_config }) {
1305       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1306     }
1307     $item->parse_custom_variable_values;
1308   }
1309
1310   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1311
1312   $self->js
1313     ->html('#second_row_' . $item_id, $row_as_html)
1314     ->data('#second_row_' . $item_id, 'loaded', 1);
1315 }
1316
1317 sub js_redisplay_line_values {
1318   my ($self) = @_;
1319
1320   my $is_sales = $self->order->is_sales;
1321
1322   # sales orders with margins
1323   my @data;
1324   if ($is_sales) {
1325     @data = map {
1326       [
1327        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1328        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1329        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1330       ]} @{ $self->order->items_sorted };
1331   } else {
1332     @data = map {
1333       [
1334        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1335       ]} @{ $self->order->items_sorted };
1336   }
1337
1338   $self->js
1339     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1340 }
1341
1342 sub js_redisplay_amounts_and_taxes {
1343   my ($self) = @_;
1344
1345   if (scalar @{ $self->{taxes} }) {
1346     $self->js->show('#taxincluded_row_id');
1347   } else {
1348     $self->js->hide('#taxincluded_row_id');
1349   }
1350
1351   if ($self->order->taxincluded) {
1352     $self->js->hide('#subtotal_row_id');
1353   } else {
1354     $self->js->show('#subtotal_row_id');
1355   }
1356
1357   if ($self->order->is_sales) {
1358     my $is_neg = $self->order->marge_total < 0;
1359     $self->js
1360       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1361       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1362       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1363       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1364       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1365       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1366       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1367       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1368   }
1369
1370   $self->js
1371     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1372     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1373     ->remove('.tax_row')
1374     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1375 }
1376
1377 sub js_redisplay_cvpartnumbers {
1378   my ($self) = @_;
1379
1380   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1381
1382   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1383
1384   $self->js
1385     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1386 }
1387
1388 sub js_reset_order_and_item_ids_after_save {
1389   my ($self) = @_;
1390
1391   $self->js
1392     ->val('#id', $self->order->id)
1393     ->val('#converted_from_oe_id', '')
1394     ->val('#order_' . $self->nr_key(), $self->order->number);
1395
1396   my $idx = 0;
1397   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1398     next if !$self->order->items_sorted->[$idx]->id;
1399     next if $form_item_id !~ m{^new};
1400     $self->js
1401       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1402       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1403       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1404   } continue {
1405     $idx++;
1406   }
1407   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1408 }
1409
1410 #
1411 # helpers
1412 #
1413
1414 sub init_valid_types {
1415   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1416 }
1417
1418 sub init_type {
1419   my ($self) = @_;
1420
1421   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1422     die "Not a valid type for order";
1423   }
1424
1425   $self->type($::form->{type});
1426 }
1427
1428 sub init_cv {
1429   my ($self) = @_;
1430
1431   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1432          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1433          : die "Not a valid type for order";
1434
1435   return $cv;
1436 }
1437
1438 sub init_search_cvpartnumber {
1439   my ($self) = @_;
1440
1441   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1442   my $search_cvpartnumber;
1443   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1444   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1445
1446   return $search_cvpartnumber;
1447 }
1448
1449 sub init_show_update_button {
1450   my ($self) = @_;
1451
1452   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1453 }
1454
1455 sub init_p {
1456   SL::Presenter->get;
1457 }
1458
1459 sub init_order {
1460   $_[0]->make_order;
1461 }
1462
1463 sub init_all_price_factors {
1464   SL::DB::Manager::PriceFactor->get_all;
1465 }
1466
1467 sub init_part_picker_classification_ids {
1468   my ($self)    = @_;
1469   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1470
1471   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1472 }
1473
1474 sub check_auth {
1475   my ($self) = @_;
1476
1477   my $right_for = { map { $_ => $_.'_edit' . ' | ' . $_.'_view' } @{$self->valid_types} };
1478
1479   my $right   = $right_for->{ $self->type };
1480   $right    ||= 'DOES_NOT_EXIST';
1481
1482   $::auth->assert($right);
1483 }
1484
1485 sub check_auth_for_edit {
1486   my ($self) = @_;
1487
1488   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1489
1490   my $right   = $right_for->{ $self->type };
1491   $right    ||= 'DOES_NOT_EXIST';
1492
1493   $::auth->assert($right);
1494 }
1495
1496 # build the selection box for contacts
1497 #
1498 # Needed, if customer/vendor changed.
1499 sub build_contact_select {
1500   my ($self) = @_;
1501
1502   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1503     value_key  => 'cp_id',
1504     title_key  => 'full_name_dep',
1505     default    => $self->order->cp_id,
1506     with_empty => 1,
1507     style      => 'width: 300px',
1508   );
1509 }
1510
1511 # build the selection box for the additional billing address
1512 #
1513 # Needed, if customer/vendor changed.
1514 sub build_billing_address_select {
1515   my ($self) = @_;
1516
1517   return '' if $self->cv ne 'customer';
1518
1519   select_tag('order.billing_address_id',
1520              [ {displayable_id => '', id => ''}, $self->order->{$self->cv}->additional_billing_addresses ],
1521              value_key  => 'id',
1522              title_key  => 'displayable_id',
1523              default    => $self->order->billing_address_id,
1524              with_empty => 0,
1525              style      => 'width: 300px',
1526   );
1527 }
1528
1529 # build the selection box for shiptos
1530 #
1531 # Needed, if customer/vendor changed.
1532 sub build_shipto_select {
1533   my ($self) = @_;
1534
1535   select_tag('order.shipto_id',
1536              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1537              value_key  => 'shipto_id',
1538              title_key  => 'displayable_id',
1539              default    => $self->order->shipto_id,
1540              with_empty => 0,
1541              style      => 'width: 300px',
1542   );
1543 }
1544
1545 # build the inputs for the cusom shipto dialog
1546 #
1547 # Needed, if customer/vendor changed.
1548 sub build_shipto_inputs {
1549   my ($self) = @_;
1550
1551   my $content = $self->p->render('common/_ship_to_dialog',
1552                                  vc_obj      => $self->order->customervendor,
1553                                  cs_obj      => $self->order->custom_shipto,
1554                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1555                                  id_selector => '#order_shipto_id');
1556
1557   div_tag($content, id => 'shipto_inputs');
1558 }
1559
1560 # render the info line for business
1561 #
1562 # Needed, if customer/vendor changed.
1563 sub build_business_info_row
1564 {
1565   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1566 }
1567
1568 # build the rows for displaying taxes
1569 #
1570 # Called if amounts where recalculated and redisplayed.
1571 sub build_tax_rows {
1572   my ($self) = @_;
1573
1574   my $rows_as_html;
1575   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1576     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1577   }
1578   return $rows_as_html;
1579 }
1580
1581
1582 sub render_price_dialog {
1583   my ($self, $record_item) = @_;
1584
1585   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1586
1587   $self->js
1588     ->run(
1589       'kivi.io.price_chooser_dialog',
1590       t8('Available Prices'),
1591       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1592     )
1593     ->reinit_widgets;
1594
1595 #   if (@errors) {
1596 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1597 #     $self->js->show('#dialog_flash_error');
1598 #   }
1599
1600   $self->js->render;
1601 }
1602
1603 sub load_order {
1604   my ($self) = @_;
1605
1606   return if !$::form->{id};
1607
1608   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1609
1610   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1611   # You need a custom shipto object to call cvars_by_config to get the cvars.
1612   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1613
1614   return $self->order;
1615 }
1616
1617 # load or create a new order object
1618 #
1619 # And assign changes from the form to this object.
1620 # If the order is loaded from db, check if items are deleted in the form,
1621 # remove them form the object and collect them for removing from db on saving.
1622 # Then create/update items from form (via make_item) and add them.
1623 sub make_order {
1624   my ($self) = @_;
1625
1626   # add_items adds items to an order with no items for saving, but they cannot
1627   # be retrieved via items until the order is saved. Adding empty items to new
1628   # order here solves this problem.
1629   my $order;
1630   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1631   $order ||= SL::DB::Order->new(orderitems  => [],
1632                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1633                                 currency_id => $::instance_conf->get_currency_id(),);
1634
1635   my $cv_id_method = $self->cv . '_id';
1636   if (!$::form->{id} && $::form->{$cv_id_method}) {
1637     $order->$cv_id_method($::form->{$cv_id_method});
1638     setup_order_from_cv($order);
1639   }
1640
1641   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1642   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1643
1644   $order->assign_attributes(%{$::form->{order}});
1645
1646   $self->setup_custom_shipto_from_form($order, $::form);
1647
1648   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1649     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1650     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1651   }
1652
1653   # remove deleted items
1654   $self->item_ids_to_delete([]);
1655   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1656     my $item = $order->orderitems->[$idx];
1657     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1658       splice @{$order->orderitems}, $idx, 1;
1659       push @{$self->item_ids_to_delete}, $item->id;
1660     }
1661   }
1662
1663   my @items;
1664   my $pos = 1;
1665   foreach my $form_attr (@{$form_orderitems}) {
1666     my $item = make_item($order, $form_attr);
1667     $item->position($pos);
1668     push @items, $item;
1669     $pos++;
1670   }
1671   $order->add_items(grep {!$_->id} @items);
1672
1673   return $order;
1674 }
1675
1676 # create or update items from form
1677 #
1678 # Make item objects from form values. For items already existing read from db.
1679 # Create a new item else. And assign attributes.
1680 sub make_item {
1681   my ($record, $attr) = @_;
1682
1683   my $item;
1684   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1685
1686   my $is_new = !$item;
1687
1688   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1689   # they cannot be retrieved via custom_variables until the order/orderitem is
1690   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1691   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1692
1693   $item->assign_attributes(%$attr);
1694
1695   if ($is_new) {
1696     my $texts = get_part_texts($item->part, $record->language_id);
1697     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1698     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1699     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1700   }
1701
1702   return $item;
1703 }
1704
1705 # create a new item
1706 #
1707 # This is used to add one item
1708 sub new_item {
1709   my ($record, $attr) = @_;
1710
1711   my $item = SL::DB::OrderItem->new;
1712
1713   # Remove attributes where the user left or set the inputs empty.
1714   # So these attributes will be undefined and we can distinguish them
1715   # from zero later on.
1716   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1717     delete $attr->{$_} if $attr->{$_} eq '';
1718   }
1719
1720   $item->assign_attributes(%$attr);
1721   $item->qty(1.0)                   if !$item->qty;
1722   $item->unit($item->part->unit)    if !$item->unit;
1723
1724   my ($price_src, $discount_src) = get_best_price_and_discount_source($record, $item, 0);
1725
1726   my %new_attr;
1727   $new_attr{description}            = $item->part->description     if ! $item->description;
1728   $new_attr{qty}                    = 1.0                          if ! $item->qty;
1729   $new_attr{price_factor_id}        = $item->part->price_factor_id if ! $item->price_factor_id;
1730   $new_attr{sellprice}              = $price_src->price;
1731   $new_attr{discount}               = $discount_src->discount;
1732   $new_attr{active_price_source}    = $price_src;
1733   $new_attr{active_discount_source} = $discount_src;
1734   $new_attr{longdescription}        = $item->part->notes           if ! defined $attr->{longdescription};
1735   $new_attr{project_id}             = $record->globalproject_id;
1736   $new_attr{lastcost}               = $record->is_sales ? $item->part->lastcost : 0;
1737
1738   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1739   # they cannot be retrieved via custom_variables until the order/orderitem is
1740   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1741   $new_attr{custom_variables} = [];
1742
1743   my $texts = get_part_texts($item->part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1744
1745   $item->assign_attributes(%new_attr, %{ $texts });
1746
1747   return $item;
1748 }
1749
1750 sub setup_order_from_cv {
1751   my ($order) = @_;
1752
1753   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id language_id));
1754
1755   $order->intnotes($order->customervendor->notes);
1756
1757   return if !$order->is_sales;
1758
1759   $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1760   $order->taxincluded(defined($order->customer->taxincluded_checked)
1761                       ? $order->customer->taxincluded_checked
1762                       : $::myconfig{taxincluded_checked});
1763
1764   my $address = $order->customer->default_billing_address;;
1765   $order->billing_address_id($address ? $address->id : undef);
1766 }
1767
1768 # setup custom shipto from form
1769 #
1770 # The dialog returns form variables starting with 'shipto' and cvars starting
1771 # with 'shiptocvar_'.
1772 # Mark it to be deleted if a shipto from master data is selected
1773 # (i.e. order has a shipto).
1774 # Else, update or create a new custom shipto. If the fields are empty, it
1775 # will not be saved on save.
1776 sub setup_custom_shipto_from_form {
1777   my ($self, $order, $form) = @_;
1778
1779   if ($order->shipto) {
1780     $self->is_custom_shipto_to_delete(1);
1781   } else {
1782     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1783
1784     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1785     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1786
1787     $custom_shipto->assign_attributes(%$shipto_attrs);
1788     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1789   }
1790 }
1791
1792 # recalculate prices and taxes
1793 #
1794 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1795 sub recalc {
1796   my ($self) = @_;
1797
1798   my %pat = $self->order->calculate_prices_and_taxes();
1799
1800   $self->{taxes} = [];
1801   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1802     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1803
1804     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1805                                 netamount => $netamount,
1806                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1807   }
1808   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1809 }
1810
1811 # get data for saving, printing, ..., that is not changed in the form
1812 #
1813 # Only cvars for now.
1814 sub get_unalterable_data {
1815   my ($self) = @_;
1816
1817   foreach my $item (@{ $self->order->items }) {
1818     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1819     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1820     foreach my $var (@{ $item->cvars_by_config }) {
1821       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1822     }
1823     $item->parse_custom_variable_values;
1824   }
1825 }
1826
1827 # delete the order
1828 #
1829 # And remove related files in the spool directory
1830 sub delete {
1831   my ($self) = @_;
1832
1833   my $errors = [];
1834   my $db     = $self->order->db;
1835
1836   $db->with_transaction(
1837     sub {
1838       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1839       $self->order->delete;
1840       my $spool = $::lx_office_conf{paths}->{spool};
1841       unlink map { "$spool/$_" } @spoolfiles if $spool;
1842
1843       $self->save_history('DELETED');
1844
1845       1;
1846   }) || push(@{$errors}, $db->error);
1847
1848   return $errors;
1849 }
1850
1851 # save the order
1852 #
1853 # And delete items that are deleted in the form.
1854 sub save {
1855   my ($self) = @_;
1856
1857   my $errors = [];
1858   my $db     = $self->order->db;
1859
1860   # check for new or updated phone note
1861   if ($::form->{phone_note}->{subject} || $::form->{phone_note}->{body}) {
1862     if (!$::form->{phone_note}->{subject} || !$::form->{phone_note}->{body}) {
1863       return [t8('Phone note needs a subject and a body.')];
1864     }
1865
1866     my $phone_note;
1867     if ($::form->{phone_note}->{id}) {
1868       $phone_note = first { $_->id == $::form->{phone_note}->{id} } @{$self->order->phone_notes};
1869       return [t8('Phone note not found for this order.')] if !$phone_note;
1870     }
1871
1872     $phone_note = SL::DB::Note->new() if !$phone_note;
1873     my $is_new  = !$phone_note->id;
1874
1875     $phone_note->assign_attributes(%{ $::form->{phone_note} },
1876                                    trans_id     => $self->order->id,
1877                                    trans_module => 'oe',
1878                                    employee     => SL::DB::Manager::Employee->current);
1879
1880     $self->order->add_phone_notes($phone_note) if $is_new;
1881   }
1882
1883   $db->with_transaction(sub {
1884     # delete custom shipto if it is to be deleted or if it is empty
1885     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1886       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1887       $self->order->custom_shipto(undef);
1888     }
1889
1890     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1891     $self->order->save(cascade => 1);
1892
1893     # link records
1894     if ($::form->{converted_from_oe_id}) {
1895       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1896
1897       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1898         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1899         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1900         $src->link_to_record($self->order);
1901       }
1902       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1903         my $idx = 0;
1904         foreach (@{ $self->order->items_sorted }) {
1905           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1906           next if !$from_id;
1907           SL::DB::RecordLink->new(from_table => 'orderitems',
1908                                   from_id    => $from_id,
1909                                   to_table   => 'orderitems',
1910                                   to_id      => $_->id
1911           )->save;
1912           $idx++;
1913         }
1914       }
1915
1916       $self->link_requirement_specs_linking_to_created_from_objects(@converted_from_oe_ids);
1917     }
1918
1919     $self->set_project_in_linked_requirement_specs if $self->order->globalproject_id;
1920
1921     $self->save_history('SAVED');
1922
1923     1;
1924   }) || push(@{$errors}, $db->error);
1925
1926   return $errors;
1927 }
1928
1929 sub workflow_sales_or_request_for_quotation {
1930   my ($self) = @_;
1931
1932   # always save
1933   my $errors = $self->save();
1934
1935   if (scalar @{ $errors }) {
1936     $self->js->flash('error', $_) for @{ $errors };
1937     return $self->js->render();
1938   }
1939
1940   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1941
1942   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1943   delete $::form->{id};
1944
1945   # no linked records from order to quotations
1946   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
1947
1948   # set item ids to new fake id, to identify them as new items
1949   foreach my $item (@{$self->order->items_sorted}) {
1950     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1951   }
1952
1953   # change form type
1954   $::form->{type} = $destination_type;
1955   $self->type($self->init_type);
1956   $self->cv  ($self->init_cv);
1957   $self->check_auth;
1958
1959   $self->recalc();
1960   $self->get_unalterable_data();
1961   $self->pre_render();
1962
1963   # trigger rendering values for second row as hidden, because they
1964   # are loaded only on demand. So we need to keep the values from the
1965   # source.
1966   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1967
1968   $self->render(
1969     'order/form',
1970     title => $self->get_title_for('edit'),
1971     %{$self->{template_args}}
1972   );
1973 }
1974
1975 sub workflow_sales_or_purchase_order {
1976   my ($self) = @_;
1977
1978   # always save
1979   my $errors = $self->save();
1980
1981   if (scalar @{ $errors }) {
1982     $self->js->flash('error', $_) foreach @{ $errors };
1983     return $self->js->render();
1984   }
1985
1986   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1987                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1988                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1989                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1990                        : '';
1991
1992   # check for direct delivery
1993   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1994   my $custom_shipto;
1995   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1996       && $::form->{use_shipto} && $self->order->shipto) {
1997     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1998   }
1999
2000   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
2001   $self->{converted_from_oe_id} = delete $::form->{id};
2002
2003   # set item ids to new fake id, to identify them as new items
2004   foreach my $item (@{$self->order->items_sorted}) {
2005     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
2006   }
2007
2008   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
2009     if ($::form->{use_shipto}) {
2010       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
2011     } else {
2012       # remove any custom shipto if not wanted
2013       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
2014     }
2015   }
2016
2017   # change form type
2018   $::form->{type} = $destination_type;
2019   $self->type($self->init_type);
2020   $self->cv  ($self->init_cv);
2021   $self->check_auth;
2022
2023   $self->recalc();
2024   $self->get_unalterable_data();
2025   $self->pre_render();
2026
2027   # trigger rendering values for second row as hidden, because they
2028   # are loaded only on demand. So we need to keep the values from the
2029   # source.
2030   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
2031
2032   $self->render(
2033     'order/form',
2034     title => $self->get_title_for('edit'),
2035     %{$self->{template_args}}
2036   );
2037 }
2038
2039
2040 sub pre_render {
2041   my ($self) = @_;
2042
2043   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
2044   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
2045   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
2046   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted( query => [ or => [ obsolete => 0, id => $self->order->language_id ] ] );
2047   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
2048                                                                                               deleted => 0 ] ],
2049                                                                            sort_by => 'name');
2050   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
2051                                                                                               deleted => 0 ] ],
2052                                                                            sort_by => 'name');
2053   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
2054                                                                                                         obsolete => 0 ] ]);
2055   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
2056   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
2057   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
2058   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
2059   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
2060
2061   my $print_form = Form->new('');
2062   $print_form->{type}        = $self->type;
2063   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
2064   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
2065     form => $print_form,
2066     options => {dialog_name_prefix => 'print_options.',
2067                 show_headers       => 1,
2068                 no_queue           => 1,
2069                 no_postscript      => 1,
2070                 no_opendocument    => 0,
2071                 no_html            => 0},
2072   );
2073
2074   foreach my $item (@{$self->order->orderitems}) {
2075     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
2076     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
2077     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
2078   }
2079
2080   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
2081     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
2082     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
2083     # the value from db, which can be set manually or is set when linked delivery orders are saved.
2084     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
2085   }
2086
2087   if ($self->order->number && $::instance_conf->get_webdav) {
2088     my $webdav = SL::Webdav->new(
2089       type     => $self->type,
2090       number   => $self->order->number,
2091     );
2092     my @all_objects = $webdav->get_all_objects;
2093     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
2094                                                     type => t8('File'),
2095                                                     link => File::Spec->catfile($_->full_filedescriptor),
2096                                                 } } @all_objects;
2097   }
2098
2099   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
2100       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
2101     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
2102   }
2103   $self->{template_args}->{longdescription_dialog_size_percentage} = SL::Helper::UserPreferences::DisplayPreferences->new()->get_longdescription_dialog_size_percentage();
2104
2105   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
2106
2107   $self->{template_args}->{num_phone_notes} = scalar @{ $self->order->phone_notes || [] };
2108
2109   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.Validator kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
2110                                                          edit_periodic_invoices_config calculate_qty follow_up show_history);
2111   $self->setup_edit_action_bar;
2112 }
2113
2114 sub setup_edit_action_bar {
2115   my ($self, %params) = @_;
2116
2117   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
2118                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
2119                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
2120
2121   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
2122   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
2123
2124   my $has_invoice_for_advance_payment;
2125   if ($self->order->id && $self->type eq sales_order_type()) {
2126     my $lr = $self->order->linked_records(direction => 'to', to => ['Invoice']);
2127     $has_invoice_for_advance_payment = any {'SL::DB::Invoice' eq ref $_ && "invoice_for_advance_payment" eq $_->type} @$lr;
2128   }
2129
2130   my $has_final_invoice;
2131   if ($self->order->id && $self->type eq sales_order_type()) {
2132     my $lr = $self->order->linked_records(direction => 'to', to => ['Invoice']);
2133     $has_final_invoice               = any {'SL::DB::Invoice' eq ref $_ && "final_invoice" eq $_->type} @$lr;
2134   }
2135
2136   my $right_for         = { map { $_ => $_.'_edit' } @{$self->valid_types} };
2137   my $right             = $right_for->{ $self->type };
2138   $right              ||= 'DOES_NOT_EXIST';
2139   my $may_edit_create   = $::auth->assert($right, 'may fail');
2140
2141   for my $bar ($::request->layout->get('actionbar')) {
2142     $bar->add(
2143       combobox => [
2144         action => [
2145           t8('Save'),
2146           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
2147                                                     $::instance_conf->get_order_warn_no_deliverydate,
2148           ],
2149           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
2150                          @req_trans_cost_art, @req_cusordnumber,
2151           ],
2152           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2153         ],
2154         action => [
2155           t8('Save and Close'),
2156           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
2157                                                     $::instance_conf->get_order_warn_no_deliverydate,
2158                                                     1
2159           ],
2160           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
2161                          @req_trans_cost_art, @req_cusordnumber,
2162           ],
2163           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2164         ],
2165         action => [
2166           t8('Save as new'),
2167           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
2168           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2169                          @req_trans_cost_art, @req_cusordnumber,
2170           ],
2171           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.')
2172                      : !$self->order->id ? t8('This object has not been saved yet.')
2173                      :                     undef,
2174         ],
2175       ], # end of combobox "Save"
2176
2177       combobox => [
2178         action => [
2179           t8('Workflow'),
2180         ],
2181         action => [
2182           t8('Save and Quotation'),
2183           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
2184           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2185           only_if  => (any { $self->type eq $_ } (sales_order_type())),
2186           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2187         ],
2188         action => [
2189           t8('Save and RFQ'),
2190           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
2191           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
2192           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2193         ],
2194         action => [
2195           t8('Save and Sales Order'),
2196           submit   => [ '#order_form', { action => "Order/sales_order" } ],
2197           checks   => [ @req_trans_cost_art ],
2198           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
2199           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2200         ],
2201         action => [
2202           t8('Save and Purchase Order'),
2203           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
2204           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
2205           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
2206           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2207         ],
2208         action => [
2209           t8('Save and Delivery Order'),
2210           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2211                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2212                                                                                                                         ],
2213           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2214                          @req_trans_cost_art, @req_cusordnumber,
2215           ],
2216           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())),
2217           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2218         ],
2219         action => [
2220           t8('Save and Supplier Delivery Order'),
2221           call      => [ 'kivi.Order.save', 'save_and_supplier_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2222                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2223                                                                                                                         ],
2224           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2225                          @req_trans_cost_art, @req_cusordnumber,
2226           ],
2227           only_if   => (any { $self->type eq $_ } (purchase_order_type())),
2228           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2229         ],
2230         action => [
2231           t8('Save and Invoice'),
2232           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2233           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2234                          @req_trans_cost_art, @req_cusordnumber,
2235           ],
2236           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2237         ],
2238         action => [
2239           ($has_invoice_for_advance_payment ? t8('Save and Further Invoice for Advance Payment') : t8('Save and Invoice for Advance Payment')),
2240           call      => [ 'kivi.Order.save', 'save_and_invoice_for_advance_payment', $::instance_conf->get_order_warn_duplicate_parts ],
2241           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2242                          @req_trans_cost_art, @req_cusordnumber,
2243           ],
2244           disabled  => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2245                      : $has_final_invoice ? t8('This order has already a final invoice.')
2246                      :                      undef,
2247           only_if   => (any { $self->type eq $_ } (sales_order_type())),
2248         ],
2249         action => [
2250           t8('Save and Final Invoice'),
2251           call      => [ 'kivi.Order.save', 'save_and_final_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2252           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2253                          @req_trans_cost_art, @req_cusordnumber,
2254           ],
2255           disabled  => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2256                      : $has_final_invoice ? t8('This order has already a final invoice.')
2257                      :                      undef,
2258           only_if   => (any { $self->type eq $_ } (sales_order_type())) && $has_invoice_for_advance_payment,
2259         ],
2260         action => [
2261           t8('Save and AP Transaction'),
2262           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
2263           only_if   => (any { $self->type eq $_ } (purchase_order_type())),
2264           disabled  => !$may_edit_create  ? t8('You do not have the permissions to access this function.') : undef,
2265         ],
2266
2267       ], # end of combobox "Workflow"
2268
2269       combobox => [
2270         action => [
2271           t8('Export'),
2272         ],
2273         action => [
2274           t8('Save and preview PDF'),
2275           call     => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
2276                                                           $::instance_conf->get_order_warn_no_deliverydate,
2277                       ],
2278           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2279           disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.') : undef,
2280         ],
2281         action => [
2282           t8('Save and print'),
2283           call     => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
2284                                                          $::instance_conf->get_order_warn_no_deliverydate,
2285                       ],
2286           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2287           disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.') : undef,
2288         ],
2289         action => [
2290           t8('Save and E-mail'),
2291           id       => 'save_and_email_action',
2292           call     => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
2293                                                                          $::instance_conf->get_order_warn_no_deliverydate,
2294                       ],
2295           disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2296                     : !$self->order->id  ? t8('This object has not been saved yet.')
2297                     :                      undef,
2298         ],
2299         action => [
2300           t8('Download attachments of all parts'),
2301           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2302           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2303           only_if  => $::instance_conf->get_doc_storage,
2304         ],
2305       ], # end of combobox "Export"
2306
2307       action => [
2308         t8('Delete'),
2309         call     => [ 'kivi.Order.delete_order' ],
2310         confirm  => $::locale->text('Do you really want to delete this object?'),
2311         disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2312                   : !$self->order->id  ? t8('This object has not been saved yet.')
2313                   :                      undef,
2314         only_if  => $deletion_allowed,
2315       ],
2316
2317       combobox => [
2318         action => [
2319           t8('more')
2320         ],
2321         action => [
2322           t8('History'),
2323           call     => [ 'set_history_window', $self->order->id, 'id' ],
2324           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2325         ],
2326         action => [
2327           t8('Follow-Up'),
2328           call     => [ 'kivi.Order.follow_up_window' ],
2329           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2330           only_if  => $::auth->assert('productivity', 1),
2331         ],
2332       ], # end of combobox "more"
2333     );
2334   }
2335 }
2336
2337 sub generate_doc {
2338   my ($self, $doc_ref, $params) = @_;
2339
2340   my $order  = $self->order;
2341   my @errors = ();
2342
2343   my $print_form = Form->new('');
2344   $print_form->{type}        = $order->type;
2345   $print_form->{formname}    = $params->{formname} || $order->type;
2346   $print_form->{format}      = $params->{format}   || 'pdf';
2347   $print_form->{media}       = $params->{media}    || 'file';
2348   $print_form->{groupitems}  = $params->{groupitems};
2349   $print_form->{printer_id}  = $params->{printer_id};
2350   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2351
2352   $order->language($params->{language});
2353   $order->flatten_to_form($print_form, format_amounts => 1);
2354
2355   my $template_ext;
2356   my $template_type;
2357   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2358     $template_ext  = 'odt';
2359     $template_type = 'OpenDocument';
2360   } elsif ($print_form->{format} =~ m{html}i) {
2361     $template_ext  = 'html';
2362     $template_type = 'HTML';
2363   }
2364
2365   # search for the template
2366   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2367     name        => $print_form->{formname},
2368     extension   => $template_ext,
2369     email       => $print_form->{media} eq 'email',
2370     language    => $params->{language},
2371     printer_id  => $print_form->{printer_id},
2372   );
2373
2374   if (!defined $template_file) {
2375     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2376   }
2377
2378   return @errors if scalar @errors;
2379
2380   $print_form->throw_on_error(sub {
2381     eval {
2382       $print_form->prepare_for_printing;
2383
2384       $$doc_ref = SL::Helper::CreatePDF->create_pdf(
2385         format        => $print_form->{format},
2386         template_type => $template_type,
2387         template      => $template_file,
2388         variables     => $print_form,
2389         variable_content_types => {
2390           longdescription => 'html',
2391           partnotes       => 'html',
2392           notes           => 'html',
2393           $::form->get_variable_content_types_for_cvars,
2394         },
2395       );
2396       1;
2397     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2398   });
2399
2400   return @errors;
2401 }
2402
2403 sub get_files_for_email_dialog {
2404   my ($self) = @_;
2405
2406   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2407
2408   return %files if !$::instance_conf->get_doc_storage;
2409
2410   if ($self->order->id) {
2411     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2412     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2413     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2414     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2415   }
2416
2417   my @parts =
2418     uniq_by { $_->{id} }
2419     map {
2420       +{ id         => $_->part->id,
2421          partnumber => $_->part->partnumber }
2422     } @{$self->order->items_sorted};
2423
2424   foreach my $part (@parts) {
2425     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2426     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2427   }
2428
2429   foreach my $key (keys %files) {
2430     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2431   }
2432
2433   return %files;
2434 }
2435
2436 sub make_periodic_invoices_config_from_yaml {
2437   my ($yaml_config) = @_;
2438
2439   return if !$yaml_config;
2440   my $attr = SL::YAML::Load($yaml_config);
2441   return if 'HASH' ne ref $attr;
2442   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2443 }
2444
2445
2446 sub get_periodic_invoices_status {
2447   my ($self, $config) = @_;
2448
2449   return                      if $self->type ne sales_order_type();
2450   return t8('not configured') if !$config;
2451
2452   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2453              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2454              :                                                     die "Cannot get status of periodic invoices config";
2455
2456   return $active ? t8('active') : t8('inactive');
2457 }
2458
2459 sub get_title_for {
2460   my ($self, $action) = @_;
2461
2462   return '' if none { lc($action)} qw(add edit);
2463
2464   # for locales:
2465   # $::locale->text("Add Sales Order");
2466   # $::locale->text("Add Purchase Order");
2467   # $::locale->text("Add Quotation");
2468   # $::locale->text("Add Request for Quotation");
2469   # $::locale->text("Edit Sales Order");
2470   # $::locale->text("Edit Purchase Order");
2471   # $::locale->text("Edit Quotation");
2472   # $::locale->text("Edit Request for Quotation");
2473
2474   $action = ucfirst(lc($action));
2475   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2476        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2477        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2478        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2479        : '';
2480 }
2481
2482 sub get_item_cvpartnumber {
2483   my ($self, $item) = @_;
2484
2485   return if !$self->search_cvpartnumber;
2486   return if !$self->order->customervendor;
2487
2488   if ($self->cv eq 'vendor') {
2489     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2490     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2491   } elsif ($self->cv eq 'customer') {
2492     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2493     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2494   }
2495 }
2496
2497 sub get_part_texts {
2498   my ($part_or_id, $language_or_id, %defaults) = @_;
2499
2500   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2501   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2502   my $texts       = {
2503     description     => $defaults{description}     // $part->description,
2504     longdescription => $defaults{longdescription} // $part->notes,
2505   };
2506
2507   return $texts unless $language_id;
2508
2509   my $translation = SL::DB::Manager::Translation->get_first(
2510     where => [
2511       parts_id    => $part->id,
2512       language_id => $language_id,
2513     ]);
2514
2515   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2516   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2517
2518   return $texts;
2519 }
2520
2521 sub get_best_price_and_discount_source {
2522   my ($record, $item, $ignore_given) = @_;
2523
2524   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
2525
2526   my $price_src;
2527   if ( $item->part->is_assortment ) {
2528     # add assortment items with price 0, as the components carry the price
2529     $price_src = $price_source->price_from_source("");
2530     $price_src->price(0);
2531   } elsif (!$ignore_given && defined $item->sellprice) {
2532     $price_src = $price_source->price_from_source("");
2533     $price_src->price($item->sellprice);
2534   } else {
2535     $price_src = $price_source->best_price
2536                ? $price_source->best_price
2537                : $price_source->price_from_source("");
2538     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
2539     $price_src->price(0) if !$price_source->best_price;
2540   }
2541
2542   my $discount_src;
2543   if (!$ignore_given && defined $item->discount) {
2544     $discount_src = $price_source->discount_from_source("");
2545     $discount_src->discount($item->discount);
2546   } else {
2547     $discount_src = $price_source->best_discount
2548                   ? $price_source->best_discount
2549                   : $price_source->discount_from_source("");
2550     $discount_src->discount(0) if !$price_source->best_discount;
2551   }
2552
2553   return ($price_src, $discount_src);
2554 }
2555
2556 sub sales_order_type {
2557   'sales_order';
2558 }
2559
2560 sub purchase_order_type {
2561   'purchase_order';
2562 }
2563
2564 sub sales_quotation_type {
2565   'sales_quotation';
2566 }
2567
2568 sub request_quotation_type {
2569   'request_quotation';
2570 }
2571
2572 sub nr_key {
2573   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2574        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2575        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2576        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2577        : '';
2578 }
2579
2580 sub save_and_redirect_to {
2581   my ($self, %params) = @_;
2582
2583   my $errors = $self->save();
2584
2585   if (scalar @{ $errors }) {
2586     $self->js->flash('error', $_) foreach @{ $errors };
2587     return $self->js->render();
2588   }
2589
2590   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2591            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2592            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2593            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2594            : '';
2595   flash_later('info', $text);
2596
2597   $self->redirect_to(%params, id => $self->order->id);
2598 }
2599
2600 sub save_history {
2601   my ($self, $addition) = @_;
2602
2603   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2604   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2605
2606   SL::DB::History->new(
2607     trans_id    => $self->order->id,
2608     employee_id => SL::DB::Manager::Employee->current->id,
2609     what_done   => $self->order->type,
2610     snumbers    => $snumbers,
2611     addition    => $addition,
2612   )->save;
2613 }
2614
2615 sub store_doc_to_webdav_and_filemanagement {
2616   my ($self, $content, $filename, $variant) = @_;
2617
2618   my $order = $self->order;
2619   my @errors;
2620
2621   # copy file to webdav folder
2622   if ($order->number && $::instance_conf->get_webdav_documents) {
2623     my $webdav = SL::Webdav->new(
2624       type     => $order->type,
2625       number   => $order->number,
2626     );
2627     my $webdav_file = SL::Webdav::File->new(
2628       webdav   => $webdav,
2629       filename => $filename,
2630     );
2631     eval {
2632       $webdav_file->store(data => \$content);
2633       1;
2634     } or do {
2635       push @errors, t8('Storing the document to the WebDAV folder failed: #1', $@);
2636     };
2637   }
2638   if ($order->id && $::instance_conf->get_doc_storage) {
2639     eval {
2640       SL::File->save(object_id     => $order->id,
2641                      object_type   => $order->type,
2642                      mime_type     => SL::MIME->mime_type_from_ext($filename),
2643                      source        => 'created',
2644                      file_type     => 'document',
2645                      file_name     => $filename,
2646                      file_contents => $content,
2647                      print_variant => $variant);
2648       1;
2649     } or do {
2650       push @errors, t8('Storing the document in the storage backend failed: #1', $@);
2651     };
2652   }
2653
2654   return @errors;
2655 }
2656
2657 sub link_requirement_specs_linking_to_created_from_objects {
2658   my ($self, @converted_from_oe_ids) = @_;
2659
2660   return unless @converted_from_oe_ids;
2661
2662   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => \@converted_from_oe_ids ]);
2663   foreach my $rs_order (@{ $rs_orders }) {
2664     SL::DB::RequirementSpecOrder->new(
2665       order_id            => $self->order->id,
2666       requirement_spec_id => $rs_order->requirement_spec_id,
2667       version_id          => $rs_order->version_id,
2668     )->save;
2669   }
2670 }
2671
2672 sub set_project_in_linked_requirement_specs {
2673   my ($self) = @_;
2674
2675   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => $self->order->id ]);
2676   foreach my $rs_order (@{ $rs_orders }) {
2677     next if $rs_order->requirement_spec->project_id == $self->order->globalproject_id;
2678
2679     $rs_order->requirement_spec->update_attributes(project_id => $self->order->globalproject_id);
2680   }
2681 }
2682
2683 1;
2684
2685 __END__
2686
2687 =encoding utf-8
2688
2689 =head1 NAME
2690
2691 SL::Controller::Order - controller for orders
2692
2693 =head1 SYNOPSIS
2694
2695 This is a new form to enter orders, completely rewritten with the use
2696 of controller and java script techniques.
2697
2698 The aim is to provide the user a better experience and a faster workflow. Also
2699 the code should be more readable, more reliable and better to maintain.
2700
2701 =head2 Key Features
2702
2703 =over 4
2704
2705 =item *
2706
2707 One input row, so that input happens every time at the same place.
2708
2709 =item *
2710
2711 Use of pickers where possible.
2712
2713 =item *
2714
2715 Possibility to enter more than one item at once.
2716
2717 =item *
2718
2719 Item list in a scrollable area, so that the workflow buttons stay at
2720 the bottom.
2721
2722 =item *
2723
2724 Reordering item rows with drag and drop is possible. Sorting item rows is
2725 possible (by partnumber, description, qty, sellprice and discount for now).
2726
2727 =item *
2728
2729 No C<update> is necessary. All entries and calculations are managed
2730 with ajax-calls and the page only reloads on C<save>.
2731
2732 =item *
2733
2734 User can see changes immediately, because of the use of java script
2735 and ajax.
2736
2737 =back
2738
2739 =head1 CODE
2740
2741 =head2 Layout
2742
2743 =over 4
2744
2745 =item * C<SL/Controller/Order.pm>
2746
2747 the controller
2748
2749 =item * C<template/webpages/order/form.html>
2750
2751 main form
2752
2753 =item * C<template/webpages/order/tabs/basic_data.html>
2754
2755 Main tab for basic_data.
2756
2757 This is the only tab here for now. "linked records" and "webdav" tabs are
2758 reused from generic code.
2759
2760 =over 4
2761
2762 =item * C<template/webpages/order/tabs/_business_info_row.html>
2763
2764 For displaying information on business type
2765
2766 =item * C<template/webpages/order/tabs/_item_input.html>
2767
2768 The input line for items
2769
2770 =item * C<template/webpages/order/tabs/_row.html>
2771
2772 One row for already entered items
2773
2774 =item * C<template/webpages/order/tabs/_tax_row.html>
2775
2776 Displaying tax information
2777
2778 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2779
2780 Dialog for selecting price and discount sources
2781
2782 =back
2783
2784 =item * C<js/kivi.Order.js>
2785
2786 java script functions
2787
2788 =back
2789
2790 =head1 TODO
2791
2792 =over 4
2793
2794 =item * testing
2795
2796 =item * price sources: little symbols showing better price / better discount
2797
2798 =item * select units in input row?
2799
2800 =item * check for direct delivery (workflow sales order -> purchase order)
2801
2802 =item * access rights
2803
2804 =item * display weights
2805
2806 =item * mtime check
2807
2808 =item * optional client/user behaviour
2809
2810 (transactions has to be set - department has to be set -
2811  force project if enabled in client config)
2812
2813 =back
2814
2815 =head1 KNOWN BUGS AND CAVEATS
2816
2817 =over 4
2818
2819 =item *
2820
2821 No indication that <shift>-up/down expands/collapses second row.
2822
2823 =item *
2824
2825 Table header is not sticky in the scrolling area.
2826
2827 =item *
2828
2829 Sorting does not include C<position>, neither does reordering.
2830
2831 This behavior was implemented intentionally. But we can discuss, which behavior
2832 should be implemented.
2833
2834 =back
2835
2836 =head1 To discuss / Nice to have
2837
2838 =over 4
2839
2840 =item *
2841
2842 How to expand/collapse second row. Now it can be done clicking the icon or
2843 <shift>-up/down.
2844
2845 =item *
2846
2847 This controller uses a (changed) copy of the template for the PriceSource
2848 dialog. Maybe there could be used one code source.
2849
2850 =item *
2851
2852 Rounding-differences between this controller (PriceTaxCalculator) and the old
2853 form. This is not only a problem here, but also in all parts using the PTC.
2854 There exists a ticket and a patch. This patch should be testet.
2855
2856 =item *
2857
2858 An indicator, if the actual inputs are saved (like in an
2859 editor or on text processing application).
2860
2861 =item *
2862
2863 A warning when leaving the page without saveing unchanged inputs.
2864
2865
2866 =back
2867
2868 =head1 AUTHOR
2869
2870 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2871
2872 =cut